@etherisc/gif-next 0.0.2-10490c8-152 → 0.0.2-104f68e-724

package/contracts/instance/Instance.sol

@@ -0,0 +1,229 @@
+// SPDX-License-Identifier: Apache-2.0
+pragma solidity ^0.8.20;
+
+import {AccessManagedUpgradeable} from "@openzeppelin/contracts-upgradeable/access/manager/AccessManagedUpgradeable.sol";
+
+import {Amount} from "../type/Amount.sol";
+import {BundleSet} from "./BundleSet.sol";
+import {IInstance} from "./IInstance.sol";
+import {IInstanceService} from "./IInstanceService.sol";
+import {InstanceReader} from "./InstanceReader.sol";
+import {InstanceAdmin} from "./InstanceAdmin.sol";
+import {InstanceStore} from "./InstanceStore.sol";
+import {INSTANCE} from "../type/ObjectType.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {Registerable} from "../shared/Registerable.sol";
+import {RoleId} from "../type/RoleId.sol";
+import {Seconds} from "../type/Seconds.sol";
+import {UFixed} from "../type/UFixed.sol";
+import {VersionPart, VersionPartLib} from "../type/Version.sol";
+
+contract Instance is
+    IInstance,
+    AccessManagedUpgradeable,
+    Registerable
+{
+    uint256 public constant GIF_MAJOR_VERSION = 3;
+
+    bool private _initialized;
+
+    IInstanceService internal _instanceService;
+    InstanceAdmin internal _instanceAdmin;
+    InstanceReader internal _instanceReader;
+    BundleSet internal _bundleManager;
+    InstanceStore internal _instanceStore;
+
+    modifier onlyChainNft() {
+        if(msg.sender != getRegistry().getChainNftAddress()) {
+            revert();
+        }
+        _;
+    }
+
+    function initialize(
+        InstanceAdmin instanceAdmin, 
+        InstanceStore instanceStore,
+        BundleSet bundleManager,
+        InstanceReader instanceReader,
+        IRegistry registry, 
+        address initialOwner
+    ) 
+        external 
+        initializer()
+    {
+        _instanceAdmin = instanceAdmin;
+        if(_instanceAdmin.authority() == address(0)) {
+            // TODO rename error
+            revert ErrorInstanceInstanceAdminZero();
+        }
+
+        // set authority to instance admin authority
+        __AccessManaged_init(_instanceAdmin.authority());
+
+        // setup instance object info
+        _initializeRegisterable(
+            address(registry), 
+            registry.getNftId(), 
+            INSTANCE(), 
+            true, 
+            initialOwner, 
+            "");
+
+        // store instance supporting contracts
+        _instanceStore = instanceStore;
+        _bundleManager = bundleManager;
+        _instanceReader = instanceReader;
+
+        // initialize instance supporting contracts
+        _instanceStore.initialize();
+        _bundleManager.initialize();
+        _instanceReader.initialize();
+
+        _instanceService = IInstanceService(
+            getRegistry().getServiceAddress(
+                INSTANCE(), 
+                getMajorVersion()));
+
+        _registerInterface(type(IInstance).interfaceId);    
+    }
+
+    //--- Staking ----------------------------------------------------------//
+
+    function setStakingLockingPeriod(Seconds stakeLockingPeriod)
+        external
+        // TODO decide if onlyOwner or restricted to instance owner role is better
+        onlyOwner()
+    {
+        _instanceService.setStakingLockingPeriod(stakeLockingPeriod);
+    }
+
+    function setStakingRewardRate(UFixed rewardRate)
+        external
+        onlyOwner()
+    {
+        _instanceService.setStakingRewardRate(rewardRate);
+    }
+
+    function refillStakingRewardReserves(Amount dipAmount)
+        external
+        onlyOwner()
+    {
+        address instanceOwner = msg.sender;
+        _instanceService.refillStakingRewardReserves(instanceOwner, dipAmount);
+    }
+
+    function withdrawStakingRewardReserves(Amount dipAmount)
+        external
+        onlyOwner()
+        returns (Amount newBalance)
+    {
+        return _instanceService.withdrawStakingRewardReserves(dipAmount);
+    }
+
+    //--- Roles ------------------------------------------------------------//
+
+    function createRole(string memory roleName, string memory adminName)
+        external
+        onlyOwner()
+        returns (RoleId roleId, RoleId admin)
+    {
+        // TODO refactor
+        // (roleId, admin) = _instanceAdmin.createRole(roleName, adminName);
+    }
+
+    function grantRole(RoleId roleId, address account) 
+        external 
+        onlyOwner()
+    {
+        _instanceAdmin.grantRole(roleId, account);
+    }
+
+    function revokeRole(RoleId roleId, address account) 
+        external 
+        onlyOwner()
+    {
+        // TODO refactor
+        // AccessManagerExtendedInitializeable(authority()).revokeRole(roleId.toInt(), account);
+    }
+
+    //--- Targets ------------------------------------------------------------//
+
+    function createTarget(address target, string memory name) 
+        external 
+        onlyOwner()
+    {
+        // TODO refactor
+        // _instanceAdmin.createTarget(target, name);
+    }
+
+    function setTargetFunctionRole(
+        string memory targetName,
+        bytes4[] calldata selectors,
+        RoleId roleId
+    ) 
+        external 
+        onlyOwner()
+    {
+        // TODO refactor
+        // _instanceAdmin.setTargetFunctionRoleByInstance(targetName, selectors, roleId);
+    }
+
+    function setTargetLocked(address target, bool locked)
+        external 
+        onlyOwner()
+    {
+        // TODO refactor
+        // _instanceAdmin.setTargetLockedByInstance(target, locked);
+    }
+
+    //--- ITransferInterceptor ----------------------------------------------//
+
+    // TODO interception of child components nfts
+    function nftMint(address to, uint256 tokenId) external onlyChainNft {
+        // TODO refactor
+        // _instanceAdmin.transferInstanceOwnerRole(address(0), to);
+    }
+
+    function nftTransferFrom(address from, address to, uint256 tokenId) external onlyChainNft {
+        // TODO refactor
+        // _instanceAdmin.transferInstanceOwnerRole(from, to);
+    }
+
+    //--- initial setup functions -------------------------------------------//
+
+
+    function setInstanceReader(InstanceReader instanceReader)
+        external
+        restricted()
+    {
+        if(instanceReader.getInstance() != Instance(this)) {
+            revert ErrorInstanceInstanceReaderInstanceMismatch(address(this));
+        }
+
+        _instanceReader = instanceReader;
+    }
+
+    //--- external view functions -------------------------------------------//
+
+    function getInstanceReader() external view returns (InstanceReader) {
+        return _instanceReader;
+    }
+
+    function getBundleSet() external view returns (BundleSet) {
+        return _bundleManager;
+    }
+
+    function getInstanceAdmin() external view returns (InstanceAdmin) {
+        return _instanceAdmin;
+    }
+
+    function getInstanceStore() external view returns (InstanceStore) {
+        return _instanceStore;
+    }
+
+    function getMajorVersion() public pure returns (VersionPart majorVersion) {
+        return VersionPartLib.toVersionPart(GIF_MAJOR_VERSION);
+    }
+
+    //--- internal view/pure functions --------------------------------------//
+}

package/contracts/instance/InstanceAdmin.sol

@@ -0,0 +1,285 @@
+// SPDX-License-Identifier: UNLICENSED
+pragma solidity ^0.8.20;
+
+import {AccessManager} from "@openzeppelin/contracts/access/manager/AccessManager.sol";
+
+import {AccessAdmin} from "../authorization/AccessAdmin.sol";
+import {AccessManagerCloneable} from "../authorization/AccessManagerCloneable.sol";
+import {IAccessAdmin} from "../authorization/IAccessAdmin.sol";
+import {IAuthorization} from "../authorization/IAuthorization.sol";
+import {IComponent} from "../shared/IComponent.sol";
+import {IModuleAuthorization} from "../authorization/IModuleAuthorization.sol";
+import {IRegistry} from "../registry/IRegistry.sol";
+import {IInstance} from "./IInstance.sol";
+import {IService} from "../shared/IService.sol";
+import {ObjectType, ObjectTypeLib, ALL, POOL, RELEASE} from "../type/ObjectType.sol";
+import {RoleId, RoleIdLib, ADMIN_ROLE, PUBLIC_ROLE, DISTRIBUTION_OWNER_ROLE, ORACLE_OWNER_ROLE, POOL_OWNER_ROLE, PRODUCT_OWNER_ROLE} from "../type/RoleId.sol";
+import {Str, StrLib} from "../type/String.sol";
+import {TokenHandler} from "../shared/TokenHandler.sol";
+import {VersionPart} from "../type/Version.sol";
+
+
+contract InstanceAdmin is
+    AccessAdmin
+{
+    string public constant INSTANCE_TARGET_NAME = "Instance";
+    string public constant INSTANCE_STORE_TARGET_NAME = "InstanceStore";
+    string public constant INSTANCE_ADMIN_TARGET_NAME = "InstanceAdmin";
+    string public constant BUNDLE_SET_TARGET_NAME = "BundleSet";
+
+    uint64 public constant CUSTOM_ROLE_ID_MIN = 10000; // MUST be even
+
+    error ErrorInstanceAdminNotRegistered(address target);
+    error ErrorInstanceAdminAlreadyAuthorized(address target);
+    error ErrorInstanceAdminReleaseMismatch();
+    error ErrorInstanceAdminExpectedTargetMissing(string targetName);
+
+    IInstance _instance;
+    IRegistry internal _registry;
+    uint64 _idNext;
+
+    IModuleAuthorization _instanceAuthorization;
+
+    /// @dev Only used for master instance admin.
+    /// Contracts created via constructor come with disabled initializers.
+    constructor(
+        IModuleAuthorization instanceAuthorization
+    )
+        AccessAdmin()
+    {
+        _instanceAuthorization = instanceAuthorization;
+    }
+
+    /// @dev Initializes this instance admin with the provided instances authorization specification.
+    /// Internally the function creates an instance specific OpenZeppelin AccessManager that is used as the authority
+    /// for the inststance authorizatios.
+    /// Important: Initialization of this instance admin is only complete after calling function initializeInstance. 
+    function initialize(
+        AccessManagerCloneable accessManager,
+        IModuleAuthorization instanceAuthorization
+    )
+        external
+        initializer() 
+    {
+        // create new access manager for this instance admin
+        _initializeAuthority(address(accessManager));
+
+        // create basic instance independent setup
+        _createAdminAndPublicRoles();
+
+        // store instance authorization specification
+        _instanceAuthorization = IModuleAuthorization(instanceAuthorization);
+    }
+
+    function _checkTargetIsReadyForAuthorization(address target)
+        internal
+        view
+    {
+        if (address(_registry) != address(0) && !_registry.isRegistered(target)) {
+            revert ErrorInstanceAdminNotRegistered(target);
+        }
+
+        if (targetExists(target)) {
+            revert ErrorInstanceAdminAlreadyAuthorized(target);
+        }
+    }
+
+    /// @dev Completes the initialization of this instance admin using the provided instance.
+    /// Important: The instance MUST be registered and all instance supporting contracts must be wired to this instance.
+    function initializeInstanceAuthorization(address instanceAddress)
+        external
+    {
+        _checkTargetIsReadyForAuthorization(instanceAddress);
+
+        _idNext = CUSTOM_ROLE_ID_MIN;
+        _instance = IInstance(instanceAddress);
+        _registry = _instance.getRegistry();
+
+        // check matching releases
+        if (_instanceAuthorization.getRelease() != _instance.getMajorVersion()) {
+            revert ErrorInstanceAdminReleaseMismatch();
+        }
+
+        // add instance authorization
+        _createRoles(_instanceAuthorization);
+        _createModuleTargetsWithRoles();
+        _createTargetAuthorizations(_instanceAuthorization);
+
+        // grant component owner roles to instance owner
+        _grantComponentOwnerRoles();
+    }
+
+
+    /// @dev Initializes the authorization for the specified component.
+    /// Important: The component MUST be registered.
+    function initializeComponentAuthorization(
+        IComponent component,
+        IAuthorization authorization
+    )
+        external
+    {
+        _checkTargetIsReadyForAuthorization(address(component));
+
+        _createRoles(authorization);
+
+        // create component target
+        _createTarget(
+            address(component), 
+            authorization.getTargetName(), 
+            true, // checkAuthority
+            false); // custom
+
+        _createTarget(
+            address(component.getTokenHandler()), 
+            string(abi.encodePacked(authorization.getTargetName(), "TH")), 
+            true, 
+            false);
+        
+        // FIXME: make this a bit nicer and work with IAuthorization. Use a specific role, not public - access to TokenHandler must be restricted
+        FunctionInfo[] memory functions = new FunctionInfo[](3);
+        functions[0] = toFunction(TokenHandler.collectTokens.selector, "collectTokens");
+        functions[1] = toFunction(TokenHandler.collectTokensToThreeRecipients.selector, "collectTokensToThreeRecipients");
+        functions[2] = toFunction(TokenHandler.distributeTokens.selector, "distributeTokens");
+
+        _authorizeTargetFunctions(
+            address(component.getTokenHandler()),
+            getPublicRole(),
+            functions);
+
+        _grantRoleToAccount(
+            authorization.getTargetRole(
+                authorization.getTarget()), 
+            address(component));
+        
+        _createTargetAuthorizations(authorization);
+    }
+
+
+    function _grantComponentOwnerRoles()
+        internal
+    {
+        address instanceOwner = _registry.ownerOf(_instance.getNftId());
+        _grantRoleToAccount(DISTRIBUTION_OWNER_ROLE(), instanceOwner);
+        _grantRoleToAccount(ORACLE_OWNER_ROLE(), instanceOwner);
+        _grantRoleToAccount(POOL_OWNER_ROLE(), instanceOwner);
+        _grantRoleToAccount(PRODUCT_OWNER_ROLE(), instanceOwner);
+    }
+
+    /// @dev Creates a custom role
+    // TODO implement
+    // function createRole()
+    //     external
+    //     restricted()
+    // {
+
+    // }
+
+    /// @dev Grants the provided role to the specified account
+    function grantRole(
+        RoleId roleId, 
+        address account)
+        external
+        restricted()
+    {
+        _grantRoleToAccount(roleId, account);
+    }
+
+    /// @dev Returns the instance authorization specification used to set up this instance admin.
+    function getInstanceAuthorization()
+        external
+        view
+        returns (IModuleAuthorization instanceAuthorizaion)
+    {
+        return _instanceAuthorization;
+    }
+
+
+    function _createRoles(IAuthorization authorization)
+        internal
+    {
+        RoleId[] memory roles = authorization.getRoles();
+        RoleId roleId;
+        RoleInfo memory roleInfo;
+
+        for(uint256 i = 0; i < roles.length; i++) {
+            roleId = roles[i];
+            _createRole(
+                roleId,
+                authorization.getRoleInfo(roleId));
+        }
+    }
+
+
+    function _createTargetAuthorizations(IAuthorization authorization)
+        internal
+    {
+        Str[] memory targets = authorization.getTargets();
+        Str target;
+
+        for(uint256 i = 0; i < targets.length; i++) {
+            target = targets[i];
+            RoleId[] memory authorizedRoles = authorization.getAuthorizedRoles(target);
+            RoleId authorizedRole;
+
+            for(uint256 j = 0; j < authorizedRoles.length; j++) {
+                authorizedRole = authorizedRoles[j];
+
+                _authorizeTargetFunctions(
+                    getTargetForName(target),
+                    authorizedRole,
+                    authorization.getAuthorizedFunctions(
+                        target, 
+                        authorizedRole));
+            }
+        }
+    }
+
+    function _checkAndCreateTargetWithRole(
+        address target,
+        string memory targetName
+    )
+        internal
+    {
+        // check that target name is defined in authorization specification
+        Str name = StrLib.toStr(targetName);
+        if (!_instanceAuthorization.targetExists(name)) {
+            revert ErrorInstanceAdminExpectedTargetMissing(targetName);
+        }
+
+        // create named target
+        _createTarget(
+            target, 
+            targetName, 
+            false, // check authority TODO check normal targets, don't check service targets (they share authority with registry admin)
+            false);
+
+        // assign target role if defined
+        RoleId targetRoleId = _instanceAuthorization.getTargetRole(name);
+        if (targetRoleId != RoleIdLib.zero()) {
+            _grantRoleToAccount(targetRoleId, target);
+        }
+    }
+
+    function _createModuleTargetsWithRoles()
+        internal
+    {
+        // create module targets
+        _checkAndCreateTargetWithRole(address(_instance), INSTANCE_TARGET_NAME);
+        _checkAndCreateTargetWithRole(address(_instance.getInstanceStore()), INSTANCE_STORE_TARGET_NAME);
+        _checkAndCreateTargetWithRole(address(_instance.getInstanceAdmin()), INSTANCE_ADMIN_TARGET_NAME);
+        _checkAndCreateTargetWithRole(address(_instance.getBundleSet()), BUNDLE_SET_TARGET_NAME);
+
+        // create targets for services that need to access the module targets
+        ObjectType[] memory serviceDomains = _instanceAuthorization.getServiceDomains();
+        VersionPart release = _instanceAuthorization.getRelease();
+        ObjectType serviceDomain;
+
+        for (uint256 i = 0; i < serviceDomains.length; i++) {
+            serviceDomain = serviceDomains[i];
+
+            _checkAndCreateTargetWithRole(
+                _registry.getServiceAddress(serviceDomain, release),
+                _instanceAuthorization.getServiceTarget(serviceDomain).toString());
+        }
+    }
+}