@ensuro/core 2.0.0-beta1 → 2.0.0-beta11

package/contracts/FlightDelayRiskModule.sol

@@ -1,217 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.0;
-
-import {IPolicyPool} from "./interfaces/IPolicyPool.sol";
-import {IPremiumsAccount} from "./interfaces/IPremiumsAccount.sol";
-import {Policy} from "./Policy.sol";
-import {RiskModule} from "./RiskModule.sol";
-import {Chainlink} from "@chainlink/contracts/src/v0.8/Chainlink.sol";
-import {ChainlinkClientUpgradeable} from "./dependencies/ChainlinkClientUpgradeable.sol";
-
-/**
- * @title Flight Delay Risk Module
- * @dev Risk Module that resolves policy based in actualarrivaldate of flight
- * @custom:security-contact security@ensuro.co
- * @author Ensuro
- */
-contract FlightDelayRiskModule is RiskModule, ChainlinkClientUpgradeable {
-  using Chainlink for Chainlink.Request;
-
-  bytes32 public constant PRICER_ROLE = keccak256("PRICER_ROLE");
-  bytes32 public constant ORACLE_ADMIN_ROLE = keccak256("ORACLE_ADMIN_ROLE");
-  // Multiplier to calculate expiration = expectedArrival + tolerance + delayTime * DELAY_EXPIRATION_TIMES
-  uint40 public constant DELAY_EXPIRATION_TIMES = 5;
-
-  struct PolicyData {
-    Policy.PolicyData ensuroPolicy;
-    string flight;
-    uint40 departure;
-    uint40 expectedArrival;
-    uint40 tolerance;
-  }
-
-  struct OracleParams {
-    address oracle;
-    uint96 delayTime;
-    uint256 fee;
-    bytes16 dataJobId;
-    bytes16 sleepJobId;
-  }
-
-  OracleParams internal _oracleParams;
-
-  mapping(bytes32 => uint256) internal _pendingQueries;
-  mapping(uint256 => PolicyData) internal _policies;
-
-  /// @custom:oz-upgrades-unsafe-allow constructor
-  // solhint-disable-next-line no-empty-blocks
-  constructor(IPolicyPool policyPool_, IPremiumsAccount premiumsAccount_)
-    RiskModule(policyPool_, premiumsAccount_)
-  {} // solhint-disable-line no-empty-blocks
-
-  /**
-   * @dev Initializes the RiskModule
-   * @param name_ Name of the Risk Module
-   * @param collRatio_ Collateralization ratio to compute solvency requirement as % of payout (in ray)
-   * @param ensuroPpFee_ % of pure premium that will go for Ensuro treasury (in ray)
-   * @param srRoc_ return on capital paid to Senior LPs (annualized percentage - in ray)
-   * @param maxPayoutPerPolicy_ Maximum payout per policy (in wad)
-   * @param exposureLimit_ Max exposure (sum of payouts) to be allocated to this module (in wad)
-   * @param wallet_ Address of the RiskModule provider
-   * @param linkToken_ Address of ChainLink LINK token
-   * @param oracleParams_ Parameters of the Oracle
-   */
-  function initialize(
-    string memory name_,
-    uint256 collRatio_,
-    uint256 ensuroPpFee_,
-    uint256 srRoc_,
-    uint256 maxPayoutPerPolicy_,
-    uint256 exposureLimit_,
-    address wallet_,
-    address linkToken_,
-    OracleParams memory oracleParams_
-  ) public initializer {
-    __RiskModule_init(
-      name_,
-      collRatio_,
-      ensuroPpFee_,
-      srRoc_,
-      maxPayoutPerPolicy_,
-      exposureLimit_,
-      wallet_
-    );
-    __ChainlinkClient_init();
-    __FlightDelayRiskModule_init_unchained(linkToken_, oracleParams_);
-  }
-
-  // solhint-disable-next-line func-name-mixedcase
-  function __FlightDelayRiskModule_init_unchained(
-    address linkToken_,
-    OracleParams memory oracleParams_
-  ) internal initializer {
-    setChainlinkToken(linkToken_);
-    _oracleParams = oracleParams_;
-  }
-
-  function setOracleParams(OracleParams memory newParams)
-    external
-    onlyComponentRole(ORACLE_ADMIN_ROLE)
-  {
-    _oracleParams = newParams;
-  }
-
-  function oracleParams() external view returns (OracleParams memory) {
-    return _oracleParams;
-  }
-
-  /**
-   * @dev Creates a new policy
-   * @param flight Flight Number as String (ex: NAX105)
-   * @param departure Departure in epoch seconds (ex: 1631817600)
-   * @param expectedArrival Expected arrival in epoch seconds (ex: 1631824800)
-   * @param tolerance In seconds, the tolerance margin after expectedArrival before trigger the policy
-   * @param payout Payout for customer in case policy is triggered
-   * @param premium Premium the customer pays
-   * @param lossProb Probability of policy being triggered
-   * @param customer Customer address (to take premium from and send payout)
-   */
-  function newPolicy(
-    string memory flight,
-    uint40 departure,
-    uint40 expectedArrival,
-    uint40 tolerance,
-    uint256 payout,
-    uint256 premium,
-    uint256 lossProb,
-    address customer,
-    uint96 internalId
-  ) external onlyComponentRole(PRICER_ROLE) returns (uint256) {
-    require(expectedArrival > block.timestamp, "expectedArrival can't be in the past");
-    require(departure != 0 && expectedArrival > departure, "expectedArrival <= departure!");
-    uint40 expiration = expectedArrival +
-      tolerance +
-      uint40(_oracleParams.delayTime) *
-      DELAY_EXPIRATION_TIMES;
-    Policy.PolicyData memory ensuroPolicy = _newPolicy(
-      payout,
-      premium,
-      lossProb,
-      expiration,
-      customer,
-      internalId
-    );
-    PolicyData storage policy = _policies[ensuroPolicy.id];
-    policy.ensuroPolicy = ensuroPolicy;
-    policy.flight = flight;
-    policy.departure = departure;
-    policy.expectedArrival = expectedArrival;
-    policy.tolerance = tolerance;
-
-    uint256 until = expectedArrival + tolerance + uint256(_oracleParams.delayTime);
-    _chainlinkRequest(ensuroPolicy.id, policy, until);
-    return ensuroPolicy.id;
-  }
-
-  function _chainlinkRequest(
-    uint256 policyId,
-    PolicyData storage policy,
-    uint256 until
-  ) internal {
-    // request takes a JobID, a callback address, and callback function as input
-    Chainlink.Request memory req = buildChainlinkRequest(
-      until == 0 ? _oracleParams.dataJobId : _oracleParams.sleepJobId,
-      address(this),
-      this.fulfill.selector
-    );
-    req.add("flight", policy.flight);
-    req.add("endpoint", "actualarrivaldate");
-    req.addUint("departure", policy.departure);
-    if (until > 0) {
-      req.addUint("until", until);
-    }
-
-    // Sends the request with the amount of payment specified to the oracle
-    // (results will arrive with the callback = later)
-    bytes32 queryId = sendChainlinkRequestTo(_oracleParams.oracle, req, _oracleParams.fee);
-    _pendingQueries[queryId] = policyId;
-  }
-
-  /**
-   * @dev Forces the resolution of the policy (without waiting Chainlink scheduled on creation)
-   * @param policyId The id of the policy previously created (in newPolicy)
-   */
-  function resolvePolicy(uint256 policyId)
-    external
-    onlyComponentRole(PRICER_ROLE)
-    returns (uint256)
-  {
-    PolicyData storage policy = _policies[policyId];
-    require(policy.expectedArrival != 0, "Policy not found!");
-    _chainlinkRequest(policyId, policy, 0);
-    return policyId;
-  }
-
-  function fulfill(bytes32 queryId, int256 actualArrivalDate)
-    public
-    recordChainlinkFulfillment(queryId)
-  {
-    uint256 policyId = _pendingQueries[queryId];
-    require(policyId != 0, "queryId not found!");
-    PolicyData storage policy = _policies[policyId];
-
-    if (actualArrivalDate == 0) {
-      if (block.timestamp > (policy.expectedArrival + policy.tolerance)) {
-        // Treat as arrived after tolerance
-        actualArrivalDate = int256(uint256((policy.expectedArrival + policy.tolerance) + 1));
-      } else {
-        // Not arrived yet
-        return;
-      }
-    }
-    bool customerWon = (actualArrivalDate <= 0 || // cancelled
-      uint256(actualArrivalDate) > uint256(policy.expectedArrival + policy.tolerance)); // arrived after tolerance
-
-    _policyPool.resolvePolicyFullPayout(policy.ensuroPolicy, customerWon);
-  }
-}

package/contracts/PolicyNFT.sol

@@ -1,96 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.2;
-
-import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
-import {ERC721Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC721/ERC721Upgradeable.sol";
-import {PausableUpgradeable} from "@openzeppelin/contracts-upgradeable/security/PausableUpgradeable.sol";
-import {IPolicyPool} from "./interfaces/IPolicyPool.sol";
-import {IERC721} from "@openzeppelin/contracts/token/ERC721/IERC721.sol";
-import {IPolicyNFT} from "./interfaces/IPolicyNFT.sol";
-
-/**
- * @title PolicyNFT - NFT that keeps track of issued policies and its owners
- * @dev Every time a new policy is accepted by the PolicyPool, a new NFT is minted generating a new
- *      policyId owned by the customer. Only the PolicyPool can mint NFTs.
- *      After creation, NFTs can be transferred in the ERC721 standard way and that changes the policy holder.
- * @custom:security-contact security@ensuro.co
- * @author Ensuro
- */
-contract PolicyNFT is UUPSUpgradeable, ERC721Upgradeable, PausableUpgradeable, IPolicyNFT {
-  bytes32 public constant GUARDIAN_ROLE = keccak256("GUARDIAN_ROLE");
-  bytes32 public constant LEVEL1_ROLE = keccak256("LEVEL1_ROLE");
-
-  IPolicyPool internal _policyPool;
-
-  modifier onlyPolicyPool() {
-    require(_msgSender() == address(_policyPool), "The caller must be the PolicyPool");
-    _;
-  }
-
-  modifier onlyPoolRole2(bytes32 role1, bytes32 role2) {
-    _policyPool.config().checkRole2(role1, role2, msg.sender);
-    _;
-  }
-
-  modifier onlyPoolRole(bytes32 role) {
-    _policyPool.config().checkRole(role, msg.sender);
-    _;
-  }
-
-  function initialize(
-    string memory name_,
-    string memory symbol_,
-    IPolicyPool policyPool_
-  ) public initializer {
-    __UUPSUpgradeable_init();
-    __Pausable_init();
-    __ERC721_init(name_, symbol_);
-    __PolicyNFT_init_unchained(policyPool_);
-  }
-
-  // solhint-disable-next-line func-name-mixedcase
-  function __PolicyNFT_init_unchained(IPolicyPool policyPool_) internal initializer {
-    _policyPool = policyPool_;
-  }
-
-  // solhint-disable-next-line no-empty-blocks
-  function _authorizeUpgrade(address) internal override onlyPoolRole2(GUARDIAN_ROLE, LEVEL1_ROLE) {}
-
-  function pause() public onlyPoolRole(GUARDIAN_ROLE) {
-    _pause();
-  }
-
-  function unpause() public onlyPoolRole2(GUARDIAN_ROLE, LEVEL1_ROLE) {
-    _unpause();
-  }
-
-  /**
-   * @dev This function can be called only once in contract's lifetime. It links the NFT with the
-   *      PolicyPool contract. It's called in PolicyPool initialization.
-   */
-  function connect() external override {
-    require(
-      address(_policyPool) == address(0) || address(_policyPool) == _msgSender(),
-      "PolicyPool already connected"
-    );
-    _policyPool = IPolicyPool(_msgSender());
-    // Not possible to do this validation because connect is called in _policyPool initialize :'(
-    // require(_policyPool.policyNFT() == address(this), "PolicyPool not connected to this config");
-  }
-
-  function policyPool() external view returns (IPolicyPool) {
-    return _policyPool;
-  }
-
-  function safeMint(address to, uint256 policyId) external override onlyPolicyPool whenNotPaused {
-    _safeMint(to, policyId, "");
-  }
-
-  function _beforeTokenTransfer(
-    address from,
-    address to,
-    uint256 tokenId
-  ) internal override whenNotPaused {
-    super._beforeTokenTransfer(from, to, tokenId);
-  }
-}

package/contracts/PolicyPoolConfig.sol

@@ -1,204 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.0;
-
-import {AccessControlUpgradeable} from "@openzeppelin/contracts-upgradeable/access/AccessControlUpgradeable.sol";
-import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
-import {UUPSUpgradeable} from "@openzeppelin/contracts-upgradeable/proxy/utils/UUPSUpgradeable.sol";
-import {IPolicyPoolConfig} from "./interfaces/IPolicyPoolConfig.sol";
-import {IPolicyPool} from "./interfaces/IPolicyPool.sol";
-import {IRiskModule} from "./interfaces/IRiskModule.sol";
-import {ILPWhitelist} from "./interfaces/ILPWhitelist.sol";
-import {IPolicyPoolComponent} from "./interfaces/IPolicyPoolComponent.sol";
-import {WadRayMath} from "./WadRayMath.sol";
-
-/**
- * @title PolicyPoolConfig - Protocol access roles and other settings/components
- * @dev Contract that holds the access roles for PolicyPool and other components of the protocol.
- * @custom:security-contact security@ensuro.co
- * @author Ensuro
- */
-contract PolicyPoolConfig is
-  Initializable,
-  AccessControlUpgradeable,
-  UUPSUpgradeable,
-  IPolicyPoolConfig
-{
-  using WadRayMath for uint256;
-
-  // Core governance roles
-  bytes32 public constant GUARDIAN_ROLE = keccak256("GUARDIAN_ROLE");
-  bytes32 public constant LEVEL1_ROLE = keccak256("LEVEL1_ROLE");
-  bytes32 public constant LEVEL2_ROLE = keccak256("LEVEL2_ROLE");
-  bytes32 public constant LEVEL3_ROLE = keccak256("LEVEL3_ROLE");
-
-  uint256 public constant L2_RM_LIMIT = 5e16; // 5% in WAD
-
-  address internal _treasury; // address of Ensuro treasury
-  IPolicyPool internal _policyPool;
-  ILPWhitelist internal _lpWhitelist; // Contract that handles whitelisting of Liquidity Providers
-
-  mapping(IRiskModule => RiskModuleStatus) private _riskModules;
-
-  event ComponentChanged(IPolicyPoolConfig.GovernanceActions indexed action, address value);
-
-  modifier onlyRole2(bytes32 role1, bytes32 role2) {
-    if (!hasRole(role1, _msgSender())) _checkRole(role2, _msgSender());
-    _;
-  }
-
-  modifier onlyRole3(
-    bytes32 role1,
-    bytes32 role2,
-    bytes32 role3
-  ) {
-    if (!hasRole(role1, _msgSender()) && !hasRole(role2, _msgSender())) {
-      _checkRole(role3, _msgSender());
-    }
-    _;
-  }
-
-  function initialize(IPolicyPool policyPool_, address treasury_) public initializer {
-    __AccessControl_init();
-    __UUPSUpgradeable_init();
-    __PolicyPoolConfig_init_unchained(policyPool_, treasury_);
-  }
-
-  // solhint-disable-next-line func-name-mixedcase
-  function __PolicyPoolConfig_init_unchained(IPolicyPool policyPool_, address treasury_)
-    internal
-    initializer
-  {
-    _setupRole(DEFAULT_ADMIN_ROLE, msg.sender);
-    _policyPool = policyPool_;
-    _treasury = treasury_;
-  }
-
-  /**
-   * @dev This function can be called only once in contract's lifetime. It links the PolicyPoolConfig with the
-   *      PolicyPool contract. It's called in PolicyPool initialization.
-   */
-  function connect() external override {
-    require(
-      address(_policyPool) == address(0) || address(_policyPool) == _msgSender(),
-      "PolicyPool already connected"
-    );
-    _policyPool = IPolicyPool(_msgSender());
-    // Not possible to do this validation because connect is called in _policyPool initialize :'(
-    // require(_policyPool.config() == this, "PolicyPool not connected to this config");
-  }
-
-  function policyPool() external view returns (IPolicyPool) {
-    return _policyPool;
-  }
-
-  // solhint-disable-next-line no-empty-blocks
-  function _authorizeUpgrade(address) internal override onlyRole2(GUARDIAN_ROLE, LEVEL1_ROLE) {}
-
-  function getComponentRole(address component, bytes32 role) public pure returns (bytes32) {
-    return bytes32(bytes20(component)) ^ role;
-  }
-
-  function checkComponentRole(
-    address component,
-    bytes32 role,
-    address account
-  ) external view override {
-    _checkRole(getComponentRole(component, role), account);
-  }
-
-  function grantComponentRole(
-    address component,
-    bytes32 role,
-    address account
-  ) external onlyRole(getRoleAdmin(getComponentRole(component, role))) {
-    _grantRole(getComponentRole(component, role), account);
-  }
-
-  function checkRole(bytes32 role, address account) external view override {
-    _checkRole(role, account);
-  }
-
-  function checkRole2(
-    bytes32 role1,
-    bytes32 role2,
-    address account
-  ) external view override {
-    if (!hasRole(role1, account)) _checkRole(role2, account);
-  }
-
-  function setTreasury(address treasury_) external onlyRole(LEVEL1_ROLE) {
-    _treasury = treasury_;
-    emit ComponentChanged(GovernanceActions.setTreasury, _treasury);
-  }
-
-  function treasury() external view override returns (address) {
-    return _treasury;
-  }
-
-  function setLPWhitelist(ILPWhitelist lpWhitelist_)
-    external
-    onlyRole2(GUARDIAN_ROLE, LEVEL1_ROLE)
-  {
-    require(
-      address(lpWhitelist_) == address(0) ||
-        IPolicyPoolComponent(address(lpWhitelist_)).policyPool() == _policyPool,
-      "Component not linked to this PolicyPool"
-    );
-    _lpWhitelist = lpWhitelist_;
-    emit ComponentChanged(GovernanceActions.setLPWhitelist, address(_lpWhitelist));
-  }
-
-  function lpWhitelist() external view override returns (ILPWhitelist) {
-    return _lpWhitelist;
-  }
-
-  function addRiskModule(IRiskModule riskModule) external onlyRole(LEVEL1_ROLE) {
-    require(
-      _riskModules[riskModule] == RiskModuleStatus.inactive,
-      "Risk Module already in the pool"
-    );
-    require(address(riskModule) != address(0), "riskModule can't be zero");
-    require(
-      IPolicyPoolComponent(address(riskModule)).policyPool() == _policyPool,
-      "RiskModule not linked to this pool"
-    );
-    _riskModules[riskModule] = RiskModuleStatus.active;
-    emit RiskModuleStatusChanged(riskModule, RiskModuleStatus.active);
-  }
-
-  function removeRiskModule(IRiskModule riskModule) external onlyRole(LEVEL2_ROLE) {
-    require(_riskModules[riskModule] != RiskModuleStatus.inactive, "Risk Module not found");
-    require(riskModule.activeExposure() == 0, "Can't remove a module with active policies");
-    delete _riskModules[riskModule];
-    emit RiskModuleStatusChanged(riskModule, RiskModuleStatus.inactive);
-  }
-
-  function changeRiskModuleStatus(IRiskModule riskModule, RiskModuleStatus newStatus)
-    external
-    onlyRole2(GUARDIAN_ROLE, LEVEL1_ROLE)
-  {
-    require(_riskModules[riskModule] != RiskModuleStatus.inactive, "Risk Module not found");
-    require(
-      newStatus != RiskModuleStatus.suspended || hasRole(GUARDIAN_ROLE, msg.sender),
-      "Only GUARDIAN can suspend modules"
-    );
-    // To activate LEVEL1 required or LEVEL2 if <5% of total liquidity
-    require(hasRole(LEVEL1_ROLE, msg.sender), "Only LEVEL1 can activate modules");
-    // Anyone (LEVEL1, GUARDIAN) can deprecate
-    _riskModules[riskModule] = newStatus;
-    emit RiskModuleStatusChanged(riskModule, newStatus);
-  }
-
-  function checkAcceptsNewPolicy(IRiskModule riskModule) external view override {
-    RiskModuleStatus rmStatus = _riskModules[riskModule];
-    require(rmStatus == RiskModuleStatus.active, "RM module not found or not active");
-  }
-
-  function checkAcceptsResolvePolicy(IRiskModule riskModule) external view override {
-    RiskModuleStatus rmStatus = _riskModules[riskModule];
-    require(
-      rmStatus == RiskModuleStatus.active || rmStatus == RiskModuleStatus.deprecated,
-      "Module must be active or deprecated to process resolutions"
-    );
-  }
-}

package/contracts/WadRayMath.sol

@@ -1,135 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.0;
-
-/**
- * @title WadRayMath library
- * @author Aave / Ensuro
- * @dev Provides mul and div function for wads (decimal numbers with 18 digits precision) and rays
- *      (decimals with 27 digits)
- * @custom:security-contact security@ensuro.co
- **/
-
-library WadRayMath {
-  uint256 internal constant WAD = 1e18;
-  uint256 internal constant HALF_WAD = WAD / 2;
-
-  uint256 internal constant RAY = 1e27;
-  uint256 internal constant HALF_RAY = RAY / 2;
-
-  uint256 internal constant WAD_RAY_RATIO = 1e9;
-
-  /**
-   * @return One ray, 1e27
-   **/
-  function ray() internal pure returns (uint256) {
-    return RAY;
-  }
-
-  /**
-   * @return One wad, 1e18
-   **/
-
-  function wad() internal pure returns (uint256) {
-    return WAD;
-  }
-
-  /**
-   * @return Half ray, 1e27/2
-   **/
-  function halfRay() internal pure returns (uint256) {
-    return HALF_RAY;
-  }
-
-  /**
-   * @return Half ray, 1e18/2
-   **/
-  function halfWad() internal pure returns (uint256) {
-    return HALF_WAD;
-  }
-
-  /**
-   * @dev Multiplies two wad, rounding half up to the nearest wad
-   * @param a Wad
-   * @param b Wad
-   * @return The result of a*b, in wad
-   **/
-  function wadMul(uint256 a, uint256 b) internal pure returns (uint256) {
-    if (a == 0 || b == 0) {
-      return 0;
-    }
-
-    require(a <= (type(uint256).max - HALF_WAD) / b, "wadMul: Math Multiplication Overflow");
-
-    return (a * b + HALF_WAD) / WAD;
-  }
-
-  /**
-   * @dev Divides two wad, rounding half up to the nearest wad
-   * @param a Wad
-   * @param b Wad
-   * @return The result of a/b, in wad
-   **/
-  function wadDiv(uint256 a, uint256 b) internal pure returns (uint256) {
-    require(b != 0, "wadDiv: Division by zero");
-    uint256 halfB = b / 2;
-
-    require(a <= (type(uint256).max - halfB) / WAD, "wadDiv: Math Multiplication Overflow");
-
-    return (a * WAD + halfB) / b;
-  }
-
-  /**
-   * @dev Multiplies two ray, rounding half up to the nearest ray
-   * @param a Ray
-   * @param b Ray
-   * @return The result of a*b, in ray
-   **/
-  function rayMul(uint256 a, uint256 b) internal pure returns (uint256) {
-    if (a == 0 || b == 0) {
-      return 0;
-    }
-
-    require(a <= (type(uint256).max - HALF_RAY) / b, "rayMul: Math Multiplication Overflow");
-
-    return (a * b + HALF_RAY) / RAY;
-  }
-
-  /**
-   * @dev Divides two ray, rounding half up to the nearest ray
-   * @param a Ray
-   * @param b Ray
-   * @return The result of a/b, in ray
-   **/
-  function rayDiv(uint256 a, uint256 b) internal pure returns (uint256) {
-    require(b != 0, "rayDiv: Division by zero");
-    uint256 halfB = b / 2;
-
-    require(a <= (type(uint256).max - halfB) / RAY, "rayDiv: Math Multiplication Overflow");
-
-    return (a * RAY + halfB) / b;
-  }
-
-  /**
-   * @dev Casts ray down to wad
-   * @param a Ray
-   * @return a casted to wad, rounded half up to the nearest wad
-   **/
-  function rayToWad(uint256 a) internal pure returns (uint256) {
-    uint256 halfRatio = WAD_RAY_RATIO / 2;
-    uint256 result = halfRatio + a;
-    require(result >= halfRatio, "rayToWad: Math Addition Overflow");
-
-    return result / WAD_RAY_RATIO;
-  }
-
-  /**
-   * @dev Converts wad up to ray
-   * @param a Wad
-   * @return a converted in ray
-   **/
-  function wadToRay(uint256 a) internal pure returns (uint256) {
-    uint256 result = a * WAD_RAY_RATIO;
-    require(result / WAD_RAY_RATIO == a, "wadToRad: Math Multiplication Overflow");
-    return result;
-  }
-}