@ensuro/core 1.2.7 → 2.0.0-beta10

package/contracts/dependencies/ChainlinkClientUpgradeable.sol

@@ -1,371 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity ^0.8.0;
-
-import {Chainlink} from "@chainlink/contracts/src/v0.8/Chainlink.sol";
-import {ENSInterface} from "@chainlink/contracts/src/v0.8/interfaces/ENSInterface.sol";
-import {LinkTokenInterface} from "@chainlink/contracts/src/v0.8/interfaces/LinkTokenInterface.sol";
-import {OperatorInterface} from "@chainlink/contracts/src/v0.8/interfaces/OperatorInterface.sol";
-import {PointerInterface} from "@chainlink/contracts/src/v0.8/interfaces/PointerInterface.sol";
-import {ENSResolver as ENSResolver_Chainlink} from "@chainlink/contracts/src/v0.8/vendor/ENSResolver.sol";
-import {Initializable} from "@openzeppelin/contracts-upgradeable/proxy/utils/Initializable.sol";
-
-/**
- * @title The ChainlinkClient contract in upgradeable version
- * @dev Changes to make it compatible with OZ UUPS proxies
- * @notice Contract writers can inherit this contract in order to create requests for the
- * Chainlink network
- */
-contract ChainlinkClientUpgradeable is Initializable {
-  using Chainlink for Chainlink.Request;
-
-  uint256 constant internal LINK_DIVISIBILITY = 10**18;
-  uint256 constant private AMOUNT_OVERRIDE = 0;
-  address constant private SENDER_OVERRIDE = address(0);
-  uint256 constant private ORACLE_ARGS_VERSION = 1;
-  uint256 constant private OPERATOR_ARGS_VERSION = 2;
-  bytes32 constant private ENS_TOKEN_SUBNAME = keccak256("link");
-  bytes32 constant private ENS_ORACLE_SUBNAME = keccak256("oracle");
-  address constant private LINK_TOKEN_POINTER = 0xC89bD4E1632D3A43CB03AAAd5262cbe4038Bc571;
-
-  ENSInterface private ens;
-  bytes32 private ensNode;
-  LinkTokenInterface private link;
-  OperatorInterface private oracle;
-  uint256 private requestCount;
-  mapping(bytes32 => address) private pendingRequests;
-
-  event ChainlinkRequested(
-    bytes32 indexed id
-  );
-  event ChainlinkFulfilled(
-    bytes32 indexed id
-  );
-  event ChainlinkCancelled(
-    bytes32 indexed id
-  );
-
-  function __ChainlinkClient_init() internal initializer {
-    requestCount = 1;
-  }
-
-  /**
-   * @notice Creates a request that can hold additional parameters
-   * @param specId The Job Specification ID that the request will be created for
-   * @param callbackAddress The callback address that the response will be sent to
-   * @param callbackFunctionSignature The callback function signature to use for the callback address
-   * @return A Chainlink Request struct in memory
-   */
-  function buildChainlinkRequest(
-    bytes32 specId,
-    address callbackAddress,
-    bytes4 callbackFunctionSignature
-  )
-    internal
-    pure
-    returns (
-      Chainlink.Request memory
-    )
-  {
-    Chainlink.Request memory req;
-    return req.initialize(specId, callbackAddress, callbackFunctionSignature);
-  }
-
-  /**
-   * @notice Creates a Chainlink request to the stored oracle address
-   * @dev Calls `chainlinkRequestTo` with the stored oracle address
-   * @param req The initialized Chainlink Request
-   * @param payment The amount of LINK to send for the request
-   * @return requestId The request ID
-   */
-  function sendChainlinkRequest(
-    Chainlink.Request memory req,
-    uint256 payment
-  )
-    internal
-    returns (
-      bytes32
-    )
-  {
-    return sendChainlinkRequestTo(address(oracle), req, payment);
-  }
-
-  /**
-   * @notice Creates a Chainlink request to the specified oracle address
-   * @dev Generates and stores a request ID, increments the local nonce, and uses `transferAndCall` to
-   * send LINK which creates a request on the target oracle contract.
-   * Emits ChainlinkRequested event.
-   * @param oracleAddress The address of the oracle for the request
-   * @param req The initialized Chainlink Request
-   * @param payment The amount of LINK to send for the request
-   * @return requestId The request ID
-   */
-  function sendChainlinkRequestTo(
-    address oracleAddress,
-    Chainlink.Request memory req,
-    uint256 payment
-  )
-    internal
-    returns (
-      bytes32 requestId
-    )
-  {
-    return rawRequest(oracleAddress, req, payment, ORACLE_ARGS_VERSION, oracle.oracleRequest.selector);
-  }
-
-  /**
-   * @notice Creates a Chainlink request to the stored oracle address
-   * @dev This function supports multi-word response
-   * @dev Calls `requestOracleDataFrom` with the stored oracle address
-   * @param req The initialized Chainlink Request
-   * @param payment The amount of LINK to send for the request
-   * @return requestId The request ID
-   */
-  function requestOracleData(
-    Chainlink.Request memory req,
-    uint256 payment
-  )
-    internal
-    returns (
-      bytes32
-    )
-  {
-    return requestOracleDataFrom(address(oracle), req, payment);
-  }
-
-  /**
-   * @notice Creates a Chainlink request to the specified oracle address
-   * @dev This function supports multi-word response
-   * @dev Generates and stores a request ID, increments the local nonce, and uses `transferAndCall` to
-   * send LINK which creates a request on the target oracle contract.
-   * Emits ChainlinkRequested event.
-   * @param oracleAddress The address of the oracle for the request
-   * @param req The initialized Chainlink Request
-   * @param payment The amount of LINK to send for the request
-   * @return requestId The request ID
-   */
-  function requestOracleDataFrom(
-    address oracleAddress,
-    Chainlink.Request memory req,
-    uint256 payment
-  )
-    internal
-    returns (
-      bytes32 requestId
-    )
-  {
-    return rawRequest(oracleAddress, req, payment, OPERATOR_ARGS_VERSION, oracle.requestOracleData.selector);
-  }
-
-  /**
-   * @notice Make a request to an oracle
-   * @param oracleAddress The address of the oracle for the request
-   * @param req The initialized Chainlink Request
-   * @param payment The amount of LINK to send for the request
-   * @param argsVersion The version of data support (single word, multi word)
-   * @return requestId The request ID
-   */
-  function rawRequest(
-    address oracleAddress,
-    Chainlink.Request memory req,
-    uint256 payment,
-    uint256 argsVersion,
-    bytes4 funcSelector
-  )
-    private
-    returns (
-      bytes32 requestId
-    )
-  {
-    requestId = keccak256(abi.encodePacked(this, requestCount));
-    req.nonce = requestCount;
-    pendingRequests[requestId] = oracleAddress;
-    emit ChainlinkRequested(requestId);
-    bytes memory encodedData = abi.encodeWithSelector(
-      funcSelector,
-      SENDER_OVERRIDE, // Sender value - overridden by onTokenTransfer by the requesting contract's address
-      AMOUNT_OVERRIDE, // Amount value - overridden by onTokenTransfer by the actual amount of LINK sent
-      req.id,
-      req.callbackAddress,
-      req.callbackFunctionId,
-      req.nonce,
-      argsVersion,
-      req.buf.buf);
-    require(link.transferAndCall(oracleAddress, payment, encodedData), "unable to transferAndCall to oracle");
-    requestCount += 1;
-  }
-
-  /**
-   * @notice Allows a request to be cancelled if it has not been fulfilled
-   * @dev Requires keeping track of the expiration value emitted from the oracle contract.
-   * Deletes the request from the `pendingRequests` mapping.
-   * Emits ChainlinkCancelled event.
-   * @param requestId The request ID
-   * @param payment The amount of LINK sent for the request
-   * @param callbackFunc The callback function specified for the request
-   * @param expiration The time of the expiration for the request
-   */
-  function cancelChainlinkRequest(
-    bytes32 requestId,
-    uint256 payment,
-    bytes4 callbackFunc,
-    uint256 expiration
-  )
-    internal
-  {
-    OperatorInterface requested = OperatorInterface(pendingRequests[requestId]);
-    delete pendingRequests[requestId];
-    emit ChainlinkCancelled(requestId);
-    requested.cancelOracleRequest(requestId, payment, callbackFunc, expiration);
-  }
-
-  /**
-   * @notice Sets the stored oracle address
-   * @param oracleAddress The address of the oracle contract
-   */
-  function setChainlinkOracle(
-    address oracleAddress
-  )
-    internal
-  {
-    oracle = OperatorInterface(oracleAddress);
-  }
-
-  /**
-   * @notice Sets the LINK token address
-   * @param linkAddress The address of the LINK token contract
-   */
-  function setChainlinkToken(
-    address linkAddress
-  )
-    internal
-  {
-    link = LinkTokenInterface(linkAddress);
-  }
-
-  /**
-   * @notice Sets the Chainlink token address for the public
-   * network as given by the Pointer contract
-   */
-  function setPublicChainlinkToken()
-    internal
-  {
-    setChainlinkToken(PointerInterface(LINK_TOKEN_POINTER).getAddress());
-  }
-
-  /**
-   * @notice Retrieves the stored address of the LINK token
-   * @return The address of the LINK token
-   */
-  function chainlinkTokenAddress()
-    internal
-    view
-    returns (
-      address
-    )
-  {
-    return address(link);
-  }
-
-  /**
-   * @notice Retrieves the stored address of the oracle contract
-   * @return The address of the oracle contract
-   */
-  function chainlinkOracleAddress()
-    internal
-    view
-    returns (
-      address
-    )
-  {
-    return address(oracle);
-  }
-
-  /**
-   * @notice Allows for a request which was created on another contract to be fulfilled
-   * on this contract
-   * @param oracleAddress The address of the oracle contract that will fulfill the request
-   * @param requestId The request ID used for the response
-   */
-  function addChainlinkExternalRequest(
-    address oracleAddress,
-    bytes32 requestId
-  )
-    internal
-    notPendingRequest(requestId)
-  {
-    pendingRequests[requestId] = oracleAddress;
-  }
-
-  /**
-   * @notice Sets the stored oracle and LINK token contracts with the addresses resolved by ENS
-   * @dev Accounts for subnodes having different resolvers
-   * @param ensAddress The address of the ENS contract
-   * @param node The ENS node hash
-   */
-  function useChainlinkWithENS(
-    address ensAddress,
-    bytes32 node
-  )
-    internal
-  {
-    ens = ENSInterface(ensAddress);
-    ensNode = node;
-    bytes32 linkSubnode = keccak256(abi.encodePacked(ensNode, ENS_TOKEN_SUBNAME));
-    ENSResolver_Chainlink resolver = ENSResolver_Chainlink(ens.resolver(linkSubnode));
-    setChainlinkToken(resolver.addr(linkSubnode));
-    updateChainlinkOracleWithENS();
-  }
-
-  /**
-   * @notice Sets the stored oracle contract with the address resolved by ENS
-   * @dev This may be called on its own as long as `useChainlinkWithENS` has been called previously
-   */
-  function updateChainlinkOracleWithENS()
-    internal
-  {
-    bytes32 oracleSubnode = keccak256(abi.encodePacked(ensNode, ENS_ORACLE_SUBNAME));
-    ENSResolver_Chainlink resolver = ENSResolver_Chainlink(ens.resolver(oracleSubnode));
-    setChainlinkOracle(resolver.addr(oracleSubnode));
-  }
-
-  /**
-   * @notice Ensures that the fulfillment is valid for this contract
-   * @dev Use if the contract developer prefers methods instead of modifiers for validation
-   * @param requestId The request ID for fulfillment
-   */
-  function validateChainlinkCallback(
-    bytes32 requestId
-  )
-    internal
-    recordChainlinkFulfillment(requestId)
-    // solhint-disable-next-line no-empty-blocks
-  {}
-
-  /**
-   * @dev Reverts if the sender is not the oracle of the request.
-   * Emits ChainlinkFulfilled event.
-   * @param requestId The request ID for fulfillment
-   */
-  modifier recordChainlinkFulfillment(
-    bytes32 requestId
-  )
-  {
-    require(msg.sender == pendingRequests[requestId],
-            "Source must be the oracle of the request");
-    delete pendingRequests[requestId];
-    emit ChainlinkFulfilled(requestId);
-    _;
-  }
-
-  /**
-   * @dev Reverts if the request is already pending
-   * @param requestId The request ID for fulfillment
-   */
-  modifier notPendingRequest(
-    bytes32 requestId
-  )
-  {
-    require(pendingRequests[requestId] == address(0), "Request is already pending");
-    _;
-  }
-}

package/contracts/extras/IPriceRiskModule.sol

@@ -1,41 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.0;
-
-import {IRiskModule} from "../../interfaces/IRiskModule.sol";
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-
-/**
- * @title IPriceRiskModule interface
- * @dev Interface for price risk module
- * @author Ensuro
- */
-interface IPriceRiskModule is IRiskModule {
-  /**
-   * @dev Returns the premium and lossProb of the policy
-   * @param triggerPrice Price of the asset_ that will trigger the policy (expressed in _currency)
-   * @param lower If true -> triggers if the price is lower, If false -> triggers if the price is higher
-   * @param payout Expressed in policyPool.currency()
-   * @param expiration Expiration of the policy
-   * @return premium Premium that needs to be paid
-   * @return lossProb Probability of paying the maximum payout
-   */
-  function pricePolicy(
-    uint256 triggerPrice,
-    bool lower,
-    uint256 payout,
-    uint40 expiration
-  ) external view returns (uint256 premium, uint256 lossProb);
-
-  function newPolicy(
-    uint256 triggerPrice,
-    bool lower,
-    uint256 payout,
-    uint40 expiration
-  ) external returns (uint256);
-
-  function triggerPolicy(uint256 policyId) external;
-
-  function referenceCurrency() external view returns (IERC20Metadata);
-
-  function asset() external view returns (IERC20Metadata);
-}

package/contracts/extras/PriceRiskModule.sol

@@ -1,243 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.0;
-
-import {SafeERC20} from "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-import {IPolicyPool} from "../../interfaces/IPolicyPool.sol";
-import {IPolicyPoolConfig} from "../../interfaces/IPolicyPoolConfig.sol";
-import {RiskModule} from "../RiskModule.sol";
-import {Policy} from "../Policy.sol";
-import {WadRayMath} from "../WadRayMath.sol";
-import {IPriceRiskModule} from "./IPriceRiskModule.sol";
-
-/**
- * @title PriceRiskModule
- * @dev Risk Module that triggers the payout if the price of an asset is lower or higher than trigger price
- * @custom:security-contact security@ensuro.co
- * @author Ensuro
- */
-contract PriceRiskModule is RiskModule, IPriceRiskModule {
-  using SafeERC20 for IERC20Metadata;
-  using WadRayMath for uint256;
-
-  bytes32 public constant CUSTOMER_ROLE = keccak256("CUSTOMER_ROLE");
-  bytes32 public constant PRICER_ROLE = keccak256("PRICER_ROLE");
-
-  uint8 public constant PRICE_SLOTS = 30;
-
-  /// @custom:oz-upgrades-unsafe-allow state-variable-immutable
-  IERC20Metadata internal immutable _asset;
-  /// @custom:oz-upgrades-unsafe-allow state-variable-immutable
-  IERC20Metadata internal immutable _referenceCurrency;
-  /// @custom:oz-upgrades-unsafe-allow state-variable-immutable
-  uint256 internal immutable _slotSize;
-
-  struct PolicyData {
-    Policy.PolicyData ensuroPolicy;
-    uint256 triggerPrice;
-    bool lower; // If true -> triggers if the price is lower, If false -> triggers if the price is higher
-  }
-
-  mapping(uint256 => PolicyData) internal _policies;
-
-  // Duration (in hours) of the protection * (1 if lower else -1) => cummulative density function
-  //   [0] = prob of ([0, infinite%)
-  //   [1] = prob of ([1, infinite%)
-  //   ...
-  //   [PRICE_SLOTS - 1] = prob of ([PRICE_SLOTS - 1, -infinite%)
-  mapping(int40 => uint256[PRICE_SLOTS]) internal _cdf;
-
-  uint96 internal _internalId;
-
-  event NewPricePolicy(
-    address indexed customer,
-    uint256 policyId,
-    uint256 triggerPrice,
-    bool lower
-  );
-
-  /**
-   * @dev Constructs the LiquidationProtectionRiskModule
-   * @param policyPool_ The policyPool
-   * @param asset_ Address of the asset which price want to protect
-   * @param referenceCurrency_ Address of the comparison asset (price will be price(asset)/price(currency))
-   * @param slotSize_ Size of each percentage slot in the pdf function (in wad)
-   */
-  /// @custom:oz-upgrades-unsafe-allow constructor
-  constructor(
-    IPolicyPool policyPool_,
-    IERC20Metadata asset_,
-    IERC20Metadata referenceCurrency_,
-    uint256 slotSize_
-  ) RiskModule(policyPool_) {
-    _asset = asset_;
-    _referenceCurrency = referenceCurrency_;
-    _slotSize = slotSize_;
-  }
-
-  /**
-   * @dev Initializes the RiskModule
-   * @param name_ Name of the Risk Module
-   * @param scrPercentage_ Solvency Capital Requirement percentage, to calculate
-   *                       capital requirement as % of (payout - premium)  (in ray)
-   * @param ensuroFee_ % of premium that will go for Ensuro treasury (in ray)
-   * @param scrInterestRate_ cost of capital (in ray)
-   * @param maxScrPerPolicy_ Max SCR to be allocated to this module (in wad)
-   * @param scrLimit_ Max SCR to be allocated to this module (in wad)
-   * @param wallet_ Address of the RiskModule provider
-   */
-  function initialize(
-    string memory name_,
-    uint256 scrPercentage_,
-    uint256 ensuroFee_,
-    uint256 scrInterestRate_,
-    uint256 maxScrPerPolicy_,
-    uint256 scrLimit_,
-    address wallet_
-  ) public initializer {
-    __RiskModule_init(
-      name_,
-      scrPercentage_,
-      ensuroFee_,
-      scrInterestRate_,
-      maxScrPerPolicy_,
-      scrLimit_,
-      wallet_
-    );
-    _internalId = 1;
-  }
-
-  function _getCurrentPrice() internal view returns (uint256) {
-    uint256 ret = policyPool().config().exchange().convert(
-      address(_asset),
-      address(_referenceCurrency),
-      10**_asset.decimals()
-    );
-    require(ret != 0, "Price not available");
-    return ret;
-  }
-
-  /**
-   * @dev Returns the premium and lossProb of the policy
-   * @param triggerPrice Price of the asset_ that will trigger the policy (expressed in _referenceCurrency)
-   * @param lower If true -> triggers if the price is lower, If false -> triggers if the price is higher
-   * @param payout Expressed in policyPool.currency()
-   * @param expiration Expiration of the policy
-   * @return premium Premium that needs to be paid
-   * @return lossProb Probability of paying the maximum payout
-   */
-  function pricePolicy(
-    uint256 triggerPrice,
-    bool lower,
-    uint256 payout,
-    uint40 expiration
-  ) public view override returns (uint256 premium, uint256 lossProb) {
-    uint256 currentPrice = _getCurrentPrice();
-    require(
-      (lower && currentPrice > triggerPrice) || (!lower && currentPrice < triggerPrice),
-      "Price already at trigger value"
-    );
-    lossProb = _computeLossProb(currentPrice, triggerPrice, expiration - uint40(block.timestamp));
-    if (lossProb == 0) return (0, 0);
-    premium = getMinimumPremium(payout, lossProb, expiration); // TODO: extra fee for RiskModule?
-    return (premium, lossProb);
-  }
-
-  function _computeLossProb(
-    uint256 currentPrice,
-    uint256 triggerPrice,
-    uint40 duration
-  ) internal view returns (uint256) {
-    uint256[PRICE_SLOTS] storage pdf = _cdf[
-      int40((duration + 1800) / 3600) * (currentPrice > triggerPrice ? int40(1) : int40(-1))
-    ];
-    uint256 priceJump;
-    uint256 decimalConv = 10**(18 - _referenceCurrency.decimals());
-    // Calculate the jump percentage as integer with simetric rounding
-    if (currentPrice > triggerPrice) {
-      priceJump =
-        WadRayMath.wad() -
-        (triggerPrice * decimalConv).wadDiv(currentPrice * decimalConv);
-    } else {
-      priceJump =
-        (triggerPrice * decimalConv).wadDiv(currentPrice * decimalConv) -
-        WadRayMath.wad();
-    }
-
-    uint8 downPerc = uint8((priceJump + _slotSize / 2) / _slotSize);
-
-    if (downPerc >= PRICE_SLOTS) {
-      return pdf[PRICE_SLOTS - 1];
-    } else {
-      return pdf[downPerc];
-    }
-  }
-
-  function newPolicy(
-    uint256 triggerPrice,
-    bool lower,
-    uint256 payout,
-    uint40 expiration
-  ) external override returns (uint256) {
-    (uint256 premium, uint256 lossProb) = pricePolicy(triggerPrice, lower, payout, expiration);
-    require(premium > 0, "Either duration or percentage jump not supported");
-
-    uint256 policyId = (uint256(uint160(address(this))) << 96) + _internalId;
-    PolicyData storage priceRiskPolicy = _policies[policyId];
-    address customer = _msgSender();
-    priceRiskPolicy.ensuroPolicy = _newPolicy(
-      payout,
-      premium,
-      lossProb,
-      expiration,
-      customer,
-      _internalId
-    );
-    _internalId += 1;
-    priceRiskPolicy.triggerPrice = triggerPrice;
-    priceRiskPolicy.lower = lower;
-    emit NewPricePolicy(customer, policyId, triggerPrice, lower);
-    return policyId;
-  }
-
-  function triggerPolicy(uint256 policyId) external override whenNotPaused {
-    PolicyData storage policy = _policies[policyId];
-    uint256 currentPrice = _getCurrentPrice();
-    require(
-      !policy.lower || currentPrice <= policy.triggerPrice,
-      "Condition not met CurrentPrice > triggerPrice"
-    );
-    require(
-      policy.lower || currentPrice >= policy.triggerPrice,
-      "Condition not met CurrentPrice < triggerPrice"
-    );
-
-    _policyPool.resolvePolicy(policy.ensuroPolicy, policy.ensuroPolicy.payout);
-  }
-
-  /**
-   * @dev Sets the probability distribution for a given duration
-   * @param duration Duration of the policy in hours (simetric rounding) positive if probability of lower price
-   *                 negative if probability of higher price
-   * @param cdf Array where cdf[i] = prob of price lower/higher than i% of current price
-   */
-  function setCDF(int40 duration, uint256[PRICE_SLOTS] calldata cdf)
-    external
-    onlyRole(PRICER_ROLE)
-    whenNotPaused
-  {
-    _cdf[duration] = cdf;
-  }
-
-  function getCDF(int40 duration) external view returns (uint256[PRICE_SLOTS] memory) {
-    return _cdf[duration];
-  }
-
-  function referenceCurrency() external view override returns (IERC20Metadata) {
-    return _referenceCurrency;
-  }
-
-  function asset() external view override returns (IERC20Metadata) {
-    return _asset;
-  }
-}

package/contracts/upgraded/IPolicyNFTv1.sol

@@ -1,15 +0,0 @@
-// SPDX-License-Identifier: Apache-2.0
-pragma solidity ^0.8.0;
-
-import {IERC721Upgradeable} from "@openzeppelin/contracts-upgradeable/token/ERC721/IERC721Upgradeable.sol";
-
-/**
- * @title IPolicyNFT interface
- * @dev Interface for mintable NFT token that returns tokenId
- * @author Ensuro
- */
-interface IPolicyNFTv1 is IERC721Upgradeable {
-  function safeMint(address to) external returns (uint256);
-
-  function connect() external;
-}