@crossbind/port-gdal-linuxmusl 0.0.0-bootstrap.0 → 2.0.0-beta.63

package/dist/prebuilt/linuxmusl-arm64-mt-release/lib/cmake/gdal/packages/FindQHULL.cmake

@@ -0,0 +1,44 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst
+# Find QHULL library
+# ~~~~~~~~~
+#
+# Copyright (c) 2017,2018, Hiroshi Miura <miurahr@linux.com>
+#
+# Input variables:
+#    QHULL_PACKAGE_NAME: name (or list of names) of the pkg-config package, typically qhull_r or qhullstatic_r
+#
+# If it's found it sets QHULL_FOUND to TRUE
+# and following variables are set:
+#    QHULL_INCLUDE_DIR
+#    QHULL_LIBRARY
+#
+
+set(QHULL_PACKAGE_NAME "qhull_r;qhullstatic_r" CACHE STRING "Names of the pkg-config package, typically qhull_r or qhullstatic_r")
+mark_as_advanced(QHULL_PACKAGE_NAME)
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+    pkg_search_module(PC_QHULL QUIET ${QHULL_PACKAGE_NAME})
+endif()
+
+find_path(QHULL_INCLUDE_DIR libqhull_r/libqhull_r.h
+          HINTS ${PC_QHULL_INCLUDE_DIRS})
+
+if(PC_QHULL_FOUND)
+  set(_library_name "${PC_QHULL_LIBRARIES}")
+else()
+  set(_library_name qhull_r qhullstatic_r)
+endif()
+find_library(QHULL_LIBRARY NAMES ${_library_name}
+             NAMES_PER_DIR
+             HINTS ${PC_QHULL_LIBRARY_DIRS})
+unset(_library_name)
+
+mark_as_advanced(QHULL_INCLUDE_DIR QHULL_LIBRARY)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(QHULL
+    REQUIRED_VARS QHULL_LIBRARY QHULL_INCLUDE_DIR)

package/dist/prebuilt/linuxmusl-arm64-mt-release/lib/cmake/gdal/packages/FindRASTERLITE2.cmake

@@ -0,0 +1,85 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindRASTERLITE2
+--------------
+
+CMake module to search for RasterLite2 library
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``RASTERLITE2::RASTERLITE2``, if
+RasterLite2 has been found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+``RASTERLITE2_FOUND``
+  True if RasterLite2 found.
+
+``RASTERLITE2_INCLUDE_DIRS``
+  where to find rasterlite2, etc.
+
+``RASTERLITE2_LIBRARIES``
+  List of libraries when using RasterLite2.
+
+``RASTERLITE2_VERSION_STRING``
+  The version of RasterLite2 found.
+#]=======================================================================]
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+    pkg_check_modules(PC_RASTERLITE2 QUIET rasterlite2)
+    set(RASTERLITE2_VERSION_STRING ${PC_RASTERLITE2_VERSION})
+endif()
+
+find_path(RASTERLITE2_INCLUDE_DIR
+          NAMES rasterlite2/rasterlite2.h
+          HINTS ${RASTERLITE2_ROOT} ${PC_RASTERLITE2_INCLUDE_DIRS}
+          PATH_SUFFIXES include)
+find_library(RASTERLITE2_LIBRARY
+             NAMES rasterlite2
+             HINTS ${RASTERLITE2_ROOT} ${PC_RASTERLITE2_LIBRARY_DIRS}
+             PATH_SUFFIXES lib)
+mark_as_advanced(RASTERLITE2_LIBRARY RASTERLITE2_INCLUDE_DIR)
+
+if(NOT RASTERLITE2_VERSION_STRING AND RASTERLITE2_INCLUDE_DIR AND RASTERLITE2_LIBRARY)
+  include(CMakePushCheckState)
+  cmake_push_check_state(RESET)
+  file(WRITE "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/get_rasterlite2_version.c"
+          "#include <stdio.h>\n#include \"rasterlite2/rasterlite2.h\"\n
+          int main(int argc, void *argv) { const char *version = rl2_version(); printf(\"%s\", version); }\n")
+  set(CMAKE_REQUIRED_INCLUDES "${RASTERLITE2_INCLUDE_DIR}")
+  try_run(RL2_EXITCODE RL2_COMPILED ${PROJECT_BINARY_DIR} ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/get_rasterlite2_version.c
+      LINK_LIBRARIES  ${RASTERLITE2_LIBRARY}
+      CMAKE_FLAGS "-DCMAKE_SKIP_RPATH:BOOL=${CMAKE_SKIP_RPATH}" "-DINCLUDE_DIRECTORIES:STRING=${RASTERLITE2_INCLUDE_DIR}"
+      RUN_OUTPUT_VARIABLE RL2_OUTPUT)
+  if(RL2_COMPILED AND RL2_EXITCODE EQUAL 0)
+    set(RASTERLITE2_VERSION_STRING "${RL2_OUTPUT}")
+  endif()
+  unset(RL2_EXITCODE)
+  unset(RL2_COMPILED)
+  unset(RL2_OUTPUT)
+  cmake_pop_check_state()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(RASTERLITE2
+                                  FOUND_VAR RASTERLITE2_FOUND
+                                  REQUIRED_VARS RASTERLITE2_LIBRARY RASTERLITE2_INCLUDE_DIR
+                                  VERSION_VAR RASTERLITE2_VERSION_STRING)
+if(RASTERLITE2_FOUND)
+    set(RASTERLITE2_LIBRARIES "${RASTERLITE2_LIBRARY}")
+    set(RASTERLITE2_INCLUDE_DIRS "${RASTERLITE2_INCLUDE_DIR}")
+    if(NOT TARGET RASTERLITE2::RASTERLITE2)
+        add_library(RASTERLITE2::RASTERLITE2 UNKNOWN IMPORTED)
+        set_target_properties(RASTERLITE2::RASTERLITE2 PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${RASTERLITE2_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${RASTERLITE2_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/linuxmusl-arm64-mt-release/lib/cmake/gdal/packages/FindSFCGAL.cmake

@@ -0,0 +1,87 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst
+# FindSFCGAL
+# ~~~~~~~~~
+# Copyright (C) 2017-2018, Hiroshi Miura
+#
+
+find_program(SFCGAL_CONFIG sfcgal-config DOC "SFCGAL config command")
+mark_as_advanced(SFCGAL_CONFIG)
+
+if(SFCGAL_CONFIG)
+    execute_process(COMMAND ${SFCGAL_CONFIG} --prefix
+                    OUTPUT_VARIABLE SC_SFCGAL_PREFIX
+                    ERROR_QUIET
+                    OUTPUT_STRIP_TRAILING_WHITESPACE)
+    execute_process(COMMAND ${SFCGAL_CONFIG} --version
+                    OUTPUT_VARIABLE SC_SFCGAL_VERSION_STRING
+                    ERROR_QUIET
+                    OUTPUT_STRIP_TRAILING_WHITESPACE)
+    execute_process(COMMAND ${SFCGAL_CONFIG} --ldflags
+                    OUTPUT_VARIABLE SC_SFCGAL_LDFLAGS
+                    ERROR_QUIET
+                    OUTPUT_STRIP_TRAILING_WHITESPACE)
+    string(REGEX REPLACE "^-L(.*)$" "\\1" SC_SFCGAL_LIBDIR "${SC_SFCGAL_LDFLAGS}")
+    if(SC_SFCGAL_VERSION_STRING)
+        set(SFCGAL_VERSION_STRING ${SC_SFCGAL_VERSION_STRING})
+    endif()
+endif()
+
+find_path(SFCGAL_INCLUDE_DIR SFCGAL/Kernel.h
+          HINTS ${SC_SFCGAL_PREFIX}
+          PATHS ${SFCGAL_ROOT}
+          PATH_SUFFIXES include Include
+          )
+
+if(SFCGAL_INCLUDE_DIR)
+    if(NOT SFCGAL_VERSION_STRING)
+        if(EXISTS "${SFCGAL_INCLUDE_DIR}/SFCGAL/version.h")
+            file(STRINGS "${SFCGAL_INCLUDE_DIR}/SFCGAL/version.h" sfcgal_version_str REGEX "^#define[\t ]+SFCGAL_VERSION[\t ]+\".*\"")
+            string(REGEX REPLACE "^#define[\t ]+SFCGAL_VERSION[\t ]+\"([^\"]*)\".*" "\\1" SFCGAL_VERSION_STRING "${sfcgal_version_str}")
+            if(${SFCGAL_VERSION_STRING} MATCHES "[0-9]+\\.[0-9]+\\.[0-9]+")
+                string(REGEX REPLACE "^([0-9]+)\\.[0-9]+\\.[0-9]+" "\\1" SFCGAL_VERSION_MAJOR "${SFCGAL_VERSION_STRING}")
+                string(REGEX REPLACE "^[0-9]+\\.([0-9])+\\.[0-9]+" "\\1" SFCGAL_VERSION_MINOR "${SFCGAL_VERSION_STRING}")
+                string(REGEX REPLACE "^[0-9]+\\.[0-9]+\\.([0-9]+)" "\\1" SFCGAL_VERSION_PATCH "${SFCGAL_VERSION_STRING}")
+            else()
+                message(WARNING "SFCGAL_VERSION (${SFCGAL_VERSION_STRING}) doesn't match *.*.* form")
+            endif()
+            unset(sfcgal_version_str)
+        else()
+            message(WARNING "Failed toget SFCGAL version, header file not found.")
+        endif()
+    endif()
+endif()
+
+find_library(SFCGAL_LIBRARY_RELEASE NAMES SFCGAL
+             HINTS ${SC_SFCGAL_LIBDIR}
+             PATHS ${SFCGAL_ROOT}
+             PATH_SUFFIXES lib Lib
+             )
+find_library(SFCGAL_LIBRARY_DEBUG NAMES SFCGALd
+             HINTS ${SC_SFCGAL_LIBDIR}
+             PATHS ${SFCGAL_ROOT}
+             PATH_SUFFIXES lib Lib
+             )
+include(SelectLibraryConfigurations)
+select_library_configurations(SFCGAL)
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(SFCGAL
+                                  FOUND_VAR SFCGAL_FOUND
+                                  REQUIRED_VARS SFCGAL_LIBRARY SFCGAL_INCLUDE_DIR
+                                  VERSION_VAR SFCGAL_VERSION_STRING
+                                  )
+mark_as_advanced(SFCGAL_INCLUDE_DIR SFCGAL_LIBRARY)
+
+if(SFCGAL_FOUND)
+    set(SFCGAL_LIBRARIES ${SFCGAL_LIBRARY})
+    set(SFCGAL_INCLUDE_DIRS "${SFCGAL_INCLUDE_DIR}")
+    if(NOT TARGET SFCGAL::SFCGAL)
+        add_library(SFCGAL::SFCGAL UNKNOWN IMPORTED)
+        set_target_properties(SFCGAL::SFCGAL PROPERTIES
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${SFCGAL_LIBRARY}"
+                              INTERFACE_INCLUDE_DIRECTORIES "${SFCGAL_INCLUDE_DIR}")
+    endif()
+endif()

package/dist/prebuilt/linuxmusl-arm64-mt-release/lib/cmake/gdal/packages/FindSPATIALITE.cmake

@@ -0,0 +1,74 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file Copyright.txt or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindSPATIALITE
+--------------
+
+CMake module to search for SpatiaLite library
+
+IMPORTED Targets
+^^^^^^^^^^^^^^^^
+
+This module defines :prop_tgt:`IMPORTED` target ``SPATIALITE::SPATIALITE``, if
+Spatialite has been found.
+
+Result Variables
+^^^^^^^^^^^^^^^^
+
+This module defines the following variables:
+
+``SPATIALITE_FOUND``
+  True if Spatialite found.
+
+``SPATIALITE_INCLUDE_DIRS``
+  where to find Spatialite.h, etc.
+
+``SPATIALITE_LIBRARIES``
+  List of libraries when using Spatialite.
+
+``SPATIALITE_VERSION_STRING``
+  The version of Spatialite found.
+#]=======================================================================]
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+    pkg_check_modules(PC_SPATIALITE QUIET spatialite)
+    set(SPATIALITE_VERSION_STRING ${PC_SPATIALITE_VERSION})
+endif()
+
+find_path(SPATIALITE_INCLUDE_DIR
+          NAMES spatialite.h
+          HINTS ${SPATIALITE_ROOT} ${PC_SPATIALITE_INCLUDE_DIRS}
+          PATH_SUFFIXES include)
+find_library(SPATIALITE_LIBRARY
+             NAMES spatialite_i spatialite
+             NAMES_PER_DIR
+             HINTS ${SPATIALITE_ROOT} ${PC_SPATIALITE_LIBRARY_DIRS}
+             PATH_SUFFIXES lib)
+mark_as_advanced(SPATIALITE_LIBRARY SPATIALITE_INCLUDE_DIR)
+
+if(SPATIALITE_LIBRARY AND SPATIALITE_INCLUDE_DIR
+   AND NOT SPATIALITE_VERSION_STRING)
+    file(STRINGS "${SPATIALITE_INCLUDE_DIR}/spatialite.h" _spatialite_h_ver
+         REGEX "^[ \t]version[ \t]([0-9]+\\.[0-9]+)[,.].*")
+    string(REGEX REPLACE "[ \t]version[ \t]([0-9]+\\.[0-9]+)[,.].*" "\\1" _spatialite_h_ver "${_spatialite_h_ver}")
+    set(SPATIALITE_VERSION_STRING "${_spatialite_h_ver}")
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(SPATIALITE
+                                  FOUND_VAR SPATIALITE_FOUND
+                                  REQUIRED_VARS SPATIALITE_LIBRARY SPATIALITE_INCLUDE_DIR
+                                  VERSION_VAR SPATIALITE_VERSION_STRING)
+if(SPATIALITE_FOUND)
+    set(SPATIALITE_LIBRARIES "${SPATIALITE_LIBRARY}")
+    set(SPATIALITE_INCLUDE_DIRS "${SPATIALITE_INCLUDE_DIR}")
+    if(NOT TARGET SPATIALITE::SPATIALITE)
+        add_library(SPATIALITE::SPATIALITE UNKNOWN IMPORTED)
+        set_target_properties(SPATIALITE::SPATIALITE PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${SPATIALITE_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                              IMPORTED_LOCATION "${SPATIALITE_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/linuxmusl-arm64-mt-release/lib/cmake/gdal/packages/FindSQLite3.cmake

@@ -0,0 +1,208 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#[=======================================================================[.rst:
+FindSQLite3
+-----------
+Find the SQLite libraries, v3
+IMPORTED targets
+^^^^^^^^^^^^^^^^
+This module defines the following :prop_tgt:`IMPORTED` target:
+``SQLite3::SQLite3``
+Result variables
+^^^^^^^^^^^^^^^^
+This module will set the following variables if found:
+``SQLite3_INCLUDE_DIRS``
+  where to find sqlite3.h, etc.
+``SQLite3_LIBRARIES``
+  the libraries to link against to use SQLite3.
+``SQLite3_VERSION``
+  version of the SQLite3 library found
+``SQLite3_FOUND``
+  TRUE if found
+
+  Copyright (c) 2008 Andreas Schneider <mail@cynapses.org>
+  Copyright (c) 2016 NextGIS <info@nextgis.com>
+  Copyright (c) 2018,2021 Hiroshi Miura
+  Copyright (c) 2019 Chuck Atkins
+#]=======================================================================]
+include (CMakePushCheckState)
+# Accept upper case variant for SQLite3_INCLUDE_DIR
+if(SQLITE3_INCLUDE_DIR)
+  if(SQLite3_INCLUDE_DIR AND NOT "${SQLite3_INCLUDE_DIR}" STREQUAL "${SQLITE3_INCLUDE_DIR}")
+    message(FATAL_ERROR "Both SQLite3_INCLUDE_DIR and SQLITE3_INCLUDE_DIR are defined, but not at same value")
+  endif()
+  set(SQLite3_INCLUDE_DIR "${SQLITE3_INCLUDE_DIR}" CACHE STRING "Path to a file" FORCE)
+  unset(SQLITE3_INCLUDE_DIR CACHE)
+endif()
+
+# Accept upper case variant for SQLite3_LIBRARY
+if(SQLITE3_LIBRARY)
+  if(SQLite3_LIBRARY AND NOT "${SQLite3_LIBRARY}" STREQUAL "${SQLITE3_LIBRARY}")
+    message(FATAL_ERROR "Both SQLite3_LIBRARY and SQLITE3_LIBRARY are defined, but not at same value")
+  endif()
+  set(SQLite3_LIBRARY "${SQLITE3_LIBRARY}" CACHE FILEPATH "Path to a library" FORCE)
+  unset(SQLITE3_LIBRARY CACHE)
+endif()
+
+if(SQLite3_INCLUDE_DIR AND SQLite3_LIBRARY)
+  set(SQLite3_FIND_QUIETLY TRUE)
+else()
+  find_package(PkgConfig QUIET)
+  if(PKG_CONFIG_FOUND)
+      pkg_check_modules(PC_SQLITE3 QUIET sqlite3)
+  endif()
+
+  find_path(SQLite3_INCLUDE_DIR
+            NAMES  sqlite3.h
+            HINTS ${PC_SQLITE3_INCLUDE_DIRS})
+  find_library(SQLite3_LIBRARY
+               NAMES sqlite3 sqlite3_i
+               NAMES_PER_DIR
+               HINTS ${PC_SQLITE3_LIBRARY_DIRS})
+endif()
+
+# Extract version information from the header file
+if(SQLite3_INCLUDE_DIR)
+    file(STRINGS ${SQLite3_INCLUDE_DIR}/sqlite3.h _ver_line
+         REGEX "^#define SQLITE_VERSION  *\"[0-9]+\\.[0-9]+\\.[0-9]+\""
+         LIMIT_COUNT 1)
+    string(REGEX MATCH "[0-9]+\\.[0-9]+\\.[0-9]+"
+           SQLite3_VERSION "${_ver_line}")
+    unset(_ver_line)
+endif()
+
+if(SQLite3_INCLUDE_DIR AND SQLite3_LIBRARY)
+    include(CheckCSourceCompiles)
+    include(CheckCXXSourceCompiles)
+    include(CheckSymbolExists)
+    cmake_push_check_state(RESET)
+    # check column metadata
+    set(CMAKE_REQUIRED_INCLUDES ${SQLite3_INCLUDE_DIR})
+    if( ${SQLite3_LIBRARY} MATCHES "libsqlite3.a")
+      if(PC_SQLITE3_STATIC_LDFLAGS)
+        set(CMAKE_REQUIRED_LIBRARIES ${PC_SQLITE3_STATIC_LDFLAGS})
+      else()
+        # Manually try likely additional private libraries
+        set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY})
+        check_symbol_exists(sqlite3_open sqlite3.h SQLite3_HAS_OPEN)
+        if(NOT SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN CACHE)
+            set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY} -lz)
+            check_symbol_exists(sqlite3_open sqlite3.h SQLite3_HAS_OPEN)
+        endif()
+        if(NOT SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN CACHE)
+            set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY} -lm)
+            check_symbol_exists(sqlite3_open sqlite3.h SQLite3_HAS_OPEN)
+        endif()
+        if(NOT SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN CACHE)
+            set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY} -lz -lm)
+            check_symbol_exists(sqlite3_open sqlite3.h SQLite3_HAS_OPEN)
+        endif()
+        if(NOT SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN)
+            unset(SQLite3_HAS_OPEN CACHE)
+            set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY} -lz -lm -lpthread -ldl)
+            check_symbol_exists(sqlite3_open sqlite3.h SQLite3_HAS_OPEN)
+        endif()
+      endif()
+    else()
+        set(CMAKE_REQUIRED_LIBRARIES ${SQLite3_LIBRARY})
+    endif()
+
+    # Trick to force CMake to re-run if SQLite3_LIBRARY changes
+    # Useful in development situations when switching/refreshing the library
+    set_property(
+        DIRECTORY
+        APPEND
+        PROPERTY CMAKE_CONFIGURE_DEPENDS "${SQLite3_LIBRARY}"
+    )
+    # Invalidate cached variables if SQLite3_LIBRARY changes
+    file(TIMESTAMP "${SQLite3_LIBRARY}" SQLite3_LIBRARY_TIMESTAMP)
+    if( SQLite3_LIBRARY_TIMESTAMP_OLD_VAL AND
+        NOT "${SQLite3_LIBRARY_TIMESTAMP_OLD_VAL}" STREQUAL "${SQLite3_LIBRARY_TIMESTAMP}")
+        get_cmake_property(_cache_variables CACHE_VARIABLES)
+        foreach(opt IN LISTS _cache_variables)
+            if ("${opt}" MATCHES "SQLite3_HAS_")
+                message(STATUS "Invalidating ${opt}")
+                unset(${opt} CACHE)
+            endif()
+        endforeach()
+    endif()
+    set(SQLite3_LIBRARY_TIMESTAMP_OLD_VAL "${SQLite3_LIBRARY_TIMESTAMP}" CACHE INTERNAL "Old value of option SQLite3_LIBRARY_TIMESTAMP")
+
+    check_symbol_exists(sqlite3_mutex_alloc sqlite3.h SQLite3_HAS_MUTEX_ALLOC)
+    check_symbol_exists(sqlite3_column_table_name sqlite3.h SQLite3_HAS_COLUMN_METADATA)
+    check_symbol_exists(sqlite3_rtree_query_callback sqlite3.h SQLite3_HAS_RTREE)
+    check_symbol_exists(sqlite3_load_extension sqlite3.h SQLite3_HAS_LOAD_EXTENSION)
+    # https://www.sqlite.org/compile.html recommends to build with -DSQLITE_OMIT_PROGRESS_CALLBACK
+    # "for applications that are able to use them"... This is sometimes wrongly
+    # understood as recommended in all situations.
+    check_symbol_exists(sqlite3_progress_handler sqlite3.h SQLite3_HAS_PROGRESS_HANDLER)
+
+    if (MSVC)
+        set(CMAKE_REQUIRED_FLAGS "/WX")
+      else ()
+        set(CMAKE_REQUIRED_FLAGS "-Werror")
+      endif ()
+    set(SQLITE3_AUTO_EXTENSION_CHECK
+        "#include <sqlite3.h>
+         int main(){
+          return sqlite3_auto_extension ((void (*)(void)) 0);
+         }")
+    if(CMAKE_C_COMPILER_LOADED)
+        check_c_source_compiles("${SQLITE3_AUTO_EXTENSION_CHECK}" SQLite3_HAS_NON_DEPRECATED_AUTO_EXTENSION)
+    elseif(CMAKE_CXX_COMPILER_LOADED)
+        check_cxx_source_compiles("${SQLITE3_AUTO_EXTENSION_CHECK}" SQLite3_HAS_NON_DEPRECATED_AUTO_EXTENSION)
+    else()
+        message(AUTHOR_WARNING "C and CXX languages not enabled: Skipping detection of sqlite3_auto_extension.")
+    endif()
+    cmake_pop_check_state()
+endif()
+mark_as_advanced(SQLite3_LIBRARY SQLite3_INCLUDE_DIR SQLite3_HAS_COLUMN_METADATA SQLite3_HAS_RTREE SQLite3_HAS_LOAD_EXTENSION)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(SQLite3
+                                  FOUND_VAR SQLite3_FOUND
+                                  REQUIRED_VARS SQLite3_LIBRARY SQLite3_INCLUDE_DIR
+                                  VERSION_VAR SQLite3_VERSION)
+
+if(SQLite3_FOUND)
+  set(SQLite3_LIBRARIES ${SQLite3_LIBRARY})
+  set(SQLite3_INCLUDE_DIRS ${SQLite3_INCLUDE_DIR})
+  if(NOT TARGET SQLite3::SQLite3)
+    add_library(SQLite3::SQLite3 UNKNOWN IMPORTED)
+    set_target_properties(SQLite3::SQLite3 PROPERTIES
+                          INTERFACE_INCLUDE_DIRECTORIES "${SQLite3_INCLUDE_DIRS}"
+                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
+                          IMPORTED_LOCATION "${SQLite3_LIBRARY}")
+    if(SQLite3_HAS_COLUMN_METADATA)
+        set_property(TARGET SQLite3::SQLite3 APPEND PROPERTY
+                     INTERFACE_COMPILE_DEFINITIONS "SQLite3_HAS_COLUMN_METADATA")
+    endif()
+    if(SQLite3_HAS_RTREE)
+        set_property(TARGET SQLite3::SQLite3 APPEND PROPERTY
+                     INTERFACE_COMPILE_DEFINITIONS "SQLite3_HAS_RTREE")
+    endif()
+  endif()
+
+  # Alias SQLite3::SQLite3 to SQLite::SQLite3 since that's what PROJ will
+  # expect (when static linking PROJ)
+  if(NOT TARGET SQLite::SQLite3)
+    get_target_property(IS_SQLITE3_IMPORTED SQLite3::SQLite3 IMPORTED)
+    if(IS_SQLITE3_IMPORTED AND CMAKE_VERSION VERSION_LESS "3.18")
+        set_target_properties(SQLite3::SQLite3 PROPERTIES IMPORTED_GLOBAL TRUE)
+        message(DEPRECATION "If your project consumes GDAL as a subdirectory \
+          and also uses either the SQLite3::SQLite3 or SQLite::SQLite3 target, \
+          make sure you have your own call to find_package.\nThese targets \
+          will no longer be available to the global CMake scope once GDAL bumps to CMake v3.18+.")
+    endif()
+    add_library(SQLite::SQLite3 ALIAS SQLite3::SQLite3)
+  endif()
+
+endif()

package/dist/prebuilt/linuxmusl-arm64-mt-release/lib/cmake/gdal/packages/FindShapelib.cmake

@@ -0,0 +1,69 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst:
+# FindShapelib
+# -----------
+#
+# Copyright (c) 2018, Hiroshi Miura <miurahr@linux.com>
+#
+
+find_package(PkgConfig QUIET)
+if(PKG_CONFIG_FOUND)
+    pkg_check_modules(PC_Shapelib QUIET shapelib)
+endif()
+
+find_path(Shapelib_INCLUDE_DIR
+          NAMES shapefil.h
+          HINTS ${PC_Shapelib_INCLUDE_DIRS})
+
+if(Shapelib_INCLUDE_DIR)
+    if(PC_Shapelib_VERSION)
+        set(Shapelib_VERSION ${PC_Shapelib_VERSION})
+    else()
+        file(READ ${Shapelib_INCLUDE_DIR}/shapefil.h _shapefil_h_contents)
+        string(REGEX MATCH "Id: shapefil.h,v ([0-9.]+)" Shapelib_H_VERSION "${_shapefil_h_contents}")
+        string(REGEX MATCH "([0-9].[0-9][0-9])" Shapelib_H_VERSION "${Shapelib_H_VERSION}")
+        # shapefil.h 1.26 = release 1.2.10
+        # shapefil.h 1.52 = release 1.3.0
+        # shapefil.h 1.55 = release 1.4.0, 1.4.1
+        if(Shapelib_H_VERSION VERSION_LESS 1.26)
+            message(WARNING "Shapelib version detection failed")
+        elseif(Shapelib_H_VERSION VERSION_LESS 1.52)
+            set(Shapelib_VERSION 1.2.10)
+        elseif(Shapelib_H_VERSION VERSION_LESS 1.55)
+            set(Shapelib_VERSION 1.3.0)
+        else()
+            set(Shapelib_VERSION 1.4.0)
+        endif()
+    endif()
+endif()
+
+if(MSVC)
+    set(Shapelib_LIBNAME shapelib)
+else()
+    set(Shapelib_LIBNAME shp)
+endif()
+
+find_library(Shapelib_LIBRARY NAMES ${Shapelib_LIBNAME})
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Shapelib
+                                  FOUND_VAR Shapelib_FOUND
+                                  REQUIRED_VARS Shapelib_INCLUDE_DIR Shapelib_LIBRARY
+                                  VERSION_VAR Shapelib_VERSION
+)
+
+mark_as_advanced(Shapelib_INCLUDE_DIR Shapelib_LIBRARY)
+
+if(Shapelib_FOUND)
+    set(Shapelib_INCLUDE_DIRS "${Shapelib_INCLUDE_DIR}")
+    set(Shapelib_LIBRARIES "${Shapelib_LIBRARY}")
+    if(NOT TARGET SHAPELIB::shp)
+        add_library(SHAPELIB::shp UNKNOWN IMPORTED)
+        set_target_properties(SHAPELIB::shp PROPERTIES
+                              INTERFACE_INCLUDE_DIRECTORIES "${Shapelib_INCLUDE_DIR}"
+                              IMPORTED_LINK_INTERFACE_LANGUAGES C
+                              IMPORTED_LOCATION "${Shapelib_LIBRARY}")
+    endif()
+endif()

package/dist/prebuilt/linuxmusl-arm64-mt-release/lib/cmake/gdal/packages/FindSpatialindex.cmake

@@ -0,0 +1,18 @@
+# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
+# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
+
+#.rst
+# - Find Spatialindex
+#
+# Once run this will define:
+#
+# SPATIALINDEX_FOUND       = system has Spatialindex lib
+# SPATIALINDEX_LIBRARY     = full path to the Spatialindex library
+# SPATIALINDEX_INCLUDE_DIR = where to find headers
+#
+
+find_path(SPATIALINDEX_INCLUDE_DIR NAMES SpatialIndex.h PATH_SUFFIXES spatialindex)
+find_library(SPATIALINDEX_LIBRARY NAMES spatialindex_i spatialindex NAMES_PER_DIR)
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(Spatialindex FOUND_VAR SPATIALINDEX_FOUND
+                                  REQUIRED_VARS SPATIALINDEX_LIBRARY MYSQL_SPATIALINDEX_DIR)