@cpp.js/package-gdal 1.0.0 → 2.0.0-beta.2

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindJSONC.cmake

@@ -1,47 +0,0 @@
-# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
-# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
-
-#.rst
-# FindJSONC
-# ~~~~~~~~~
-# Copyright (C) 2017-2018, Hiroshi Miura
-# Copyright (c) 2012, Dmitry Baryshnikov <polimax at mail.ru>
-#
-# CMake module to search for jsonc library
-#
-# If it's found it sets JSONC_FOUND to TRUE
-# and following variables are set:
-#    JSONC_INCLUDE_DIR
-#    JSONC_LIBRARY
-
-find_package(PkgConfig QUIET)
-if(PKG_CONFIG_FOUND)
-  pkg_check_modules(PC_JSONC QUIET json-c)
-endif()
-
-find_path(JSONC_INCLUDE_DIR
-          NAMES json.h
-          HINTS ${PC_JSONC_INCLUDE_DIRS}
-                ${JSONC_ROOT}/include
-          PATH_SUFFIXES json-c json)
-find_library(JSONC_LIBRARY
-             NAMES json-c json
-             HINTS ${PC_JSONC_LIBRARY_DIRS}
-                   ${JSONC_ROOT}/lib)
-mark_as_advanced(JSONC_LIBRARY JSONC_INCLUDE_DIR)
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(JSONC DEFAULT_MSG JSONC_LIBRARY JSONC_INCLUDE_DIR)
-
-if(JSONC_FOUND)
-  set(JSONC_INCLUDE_DIRS ${JSONC_INCLUDE_DIR})
-  set(JSONC_LIBRARIES ${JSONC_LIBRARY})
-  set(JSONC_TARGET JSONC::JSONC)
-  if(NOT TARGET ${JSONC_TARGET})
-      add_library(${JSONC_TARGET} UNKNOWN IMPORTED)
-      set_target_properties(${JSONC_TARGET} PROPERTIES
-                            INTERFACE_INCLUDE_DIRECTORIES "${JSONC_INCLUDE_DIRS}"
-                            IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                            IMPORTED_LOCATION "${JSONC_LIBRARY}")
-  endif()
-endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindKDU.cmake

@@ -1,105 +0,0 @@
-# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
-# file Copyright.txt or https://cmake.org/licensing for details.
-
-#.rst:
-# FindKDU
-# -----------
-#
-# CMake module to search for KAKADU library
-#
-# Copyright (C) 2017-2018, Hiroshi Miura
-#
-# If it's found it sets KDU_FOUND to TRUE
-# and following variables are set:
-#    KDU_INCLUDE_DIRS
-#    KDU_LIBRARIES
-# and it defines the KDU::KDU target
-
-macro(find_kdu_libs_from_makefiles)
-    # first argument = platform
-    # second argument = library extension (without .)
-    file(READ "${KDU_ROOT}/coresys/make/Makefile-${ARGV0}" CORESYS_MAKEFILE_CONTENTS)
-    string(REGEX REPLACE ".*SHARED_LIB_NAME[ \t]*=[ \t]*([^.]*)(\.${ARGV1}).*" "\\1\\2" KDU_SHARED_LIB_NAME ${CORESYS_MAKEFILE_CONTENTS})
-    file(READ "${KDU_ROOT}/managed/make/Makefile-${ARGV0}" MANAGED_MAKEFILE_CONTENTS)
-    string(REGEX REPLACE ".*AUX_SHARED_LIB_NAME[ \t]*=[ \t]*([^.]*)(\.${ARGV1}).*" "\\1\\2" KDU_AUX_SHARED_LIB_NAME ${MANAGED_MAKEFILE_CONTENTS})
-
-    string(REGEX REPLACE "libkdu_v([0-9])([0-9A-F])R\.${ARGV1}" "\\1" KDU_MAJOR_VERSION "${KDU_SHARED_LIB_NAME}")
-    string(REGEX REPLACE "libkdu_v([0-9])([0-9A-F])R\.${ARGV1}" "\\2" KDU_MINOR_VERSION "${KDU_SHARED_LIB_NAME}")
-    if( KDU_MINOR_VERSION STREQUAL "A" )
-        set(KDU_MINOR_VERSION 10)
-    endif()
-    set(KDU_VERSION_VAR "${KDU_MAJOR_VERSION}.${KDU_MINOR_VERSION}")
-
-    find_library(KDU_LIBRARY ${KDU_SHARED_LIB_NAME}
-                 PATH ${KDU_ROOT}/lib/${ARGV0})
-    find_library(KDU_AUX_LIBRARY ${KDU_AUX_SHARED_LIB_NAME}
-                 PATH ${KDU_ROOT}/lib/${ARGV0})
-endmacro()
-
-set(KDU_VERSION_VAR "")
-if(KDU_ROOT AND EXISTS "${KDU_ROOT}/coresys")
-    if("${CMAKE_SYSTEM_PROCESSOR}" MATCHES "x86_64" AND "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
-        find_kdu_libs_from_makefiles("Linux-x86-64-gcc" "so")
-
-    elseif("${CMAKE_SYSTEM_PROCESSOR}" MATCHES "aarch64" AND "${CMAKE_SYSTEM_NAME}" STREQUAL "Linux")
-        find_kdu_libs_from_makefiles("Linux-arm-64-gcc" "so")
-
-    elseif("${CMAKE_SYSTEM_PROCESSOR}" MATCHES "x86_64" AND "${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
-        find_kdu_libs_from_makefiles("Mac-x86-64-gcc" "so")
-
-    elseif("${CMAKE_SYSTEM_PROCESSOR}" MATCHES "arm64" AND "${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
-        find_kdu_libs_from_makefiles("Mac-arm-64-gcc" "so")
-
-    elseif("${CMAKE_SYSTEM_PROCESSOR}" MATCHES "x86_64" AND "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows" AND MINGW)
-        find_kdu_libs_from_makefiles("Mingw-x86-64-gcc" "dll")
-
-    elseif("${CMAKE_SYSTEM_PROCESSOR}" MATCHES "AMD64" AND "${CMAKE_SYSTEM_NAME}" STREQUAL "Windows" AND MSVC)
-        file(READ "${KDU_ROOT}/coresys/coresys_2019.vcxproj" CORESYS_MAKEFILE_CONTENTS)
-        string(REGEX REPLACE [[.*<ImportLibrary>([^l]*)(lib_x64\\)([^R]*R)(\.lib).*]] "\\1\\2\\3\\4" KDU_SHARED_LIB_NAME ${CORESYS_MAKEFILE_CONTENTS})
-        file(READ "${KDU_ROOT}/managed/kdu_aux/kdu_aux_2019.vcxproj" MANAGED_MAKEFILE_CONTENTS)
-        string(REGEX REPLACE [[.*<ImportLibrary>([^l]*)(lib_x64\\)([^R]*R)(\.lib).*]] "\\1\\2\\3\\4" KDU_AUX_SHARED_LIB_NAME ${MANAGED_MAKEFILE_CONTENTS})
-
-        find_library(KDU_LIBRARY ${KDU_SHARED_LIB_NAME}
-                     PATH ${KDU_ROOT})
-
-        find_library(KDU_AUX_LIBRARY ${KDU_AUX_SHARED_LIB_NAME}
-                     PATH ${KDU_ROOT})
-    endif()
-endif()
-
-find_path(KDU_INCLUDE_DIR coresys/common/kdu_elementary.h
-          PATH ${KDU_ROOT})
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(KDU
-                                  REQUIRED_VARS KDU_INCLUDE_DIR KDU_LIBRARY KDU_AUX_LIBRARY
-                                  VERSION_VAR KDU_VERSION_VAR)
-mark_as_advanced(KDU_INCLUDE_DIR KDU_LIBRARY KDU_AUX_LIBRARY)
-
-if(KDU_FOUND)
-    set(KDU_INCLUDE_DIRS ${KDU_INCLUDE_DIR})
-    set(KDU_LIBRARIES ${KDU_LIBRARY} ${KDU_AUX_LIBRARY})
-    if(NOT TARGET KDU::KDU)
-        add_library(KDU::KDU_MAIN UNKNOWN IMPORTED)
-        set_target_properties(KDU::KDU_MAIN PROPERTIES
-                            INTERFACE_INCLUDE_DIRECTORIES "${KDU_INCLUDE_DIR}/coresys/common"
-                            IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                            IMPORTED_LOCATION "${KDU_LIBRARY}")
-
-        add_library(KDU::KDU_AUX UNKNOWN IMPORTED)
-        set_target_properties(KDU::KDU_AUX PROPERTIES
-                            INTERFACE_INCLUDE_DIRECTORIES "${KDU_INCLUDE_DIR}/apps/compressed_io;${KDU_INCLUDE_DIR}/apps/jp2;${KDU_INCLUDE_DIR}/apps/image;${KDU_INCLUDE_DIR}/apps/args;${KDU_INCLUDE_DIR}/apps/support;${KDU_INCLUDE_DIR}/apps/kdu_compress"
-                            IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                            IMPORTED_LOCATION "${KDU_AUX_LIBRARY}")
-
-        add_library(KDU::KDU INTERFACE IMPORTED)
-        set_target_properties(KDU::KDU PROPERTIES
-                              INTERFACE_INCLUDE_DIRECTORIES "${KDU_INCLUDE_DIR}/coresys/common;${KDU_INCLUDE_DIR}/apps/compressed_io;${KDU_INCLUDE_DIR}/apps/jp2;${KDU_INCLUDE_DIR}/apps/image;${KDU_INCLUDE_DIR}/apps/args;${KDU_INCLUDE_DIR}/apps/support;${KDU_INCLUDE_DIR}/apps/kdu_compress"
-                              INTERFACE_LINK_LIBRARIES "KDU::KDU_MAIN;KDU::KDU_AUX")
-        if( DEFINED KDU_MAJOR_VERSION AND ${KDU_MAJOR_VERSION}.${KDU_MINOR_VERSION} VERSION_LESS 7.5 )
-            set_property(TARGET KDU::KDU
-                         APPEND PROPERTY
-                         INTERFACE_COMPILE_DEFINITIONS "KDU_MAJOR_VERSION=${KDU_MAJOR_VERSION};KDU_MINOR_VERSION=${KDU_MINOR_VERSION}")
-        endif()
-    endif()
-endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindLERC.cmake

@@ -1,46 +0,0 @@
-# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
-# file Copyright.txt or https://cmake.org/licensing for details.
-
-#[=======================================================================[.rst:
-FindLERC
---------
-
-The following vars are set if LERC is found.
-
-.. variable:: LERC_FOUND
-
-  True if found, otherwise all other vars are undefined
-
-.. variable:: LERC_INCLUDE_DIR
-
-  The include dir for main *.h files
-
-.. variable:: LERC_LIBRARY
-
-  The library file
-
-#]=======================================================================]
-
-
-include(FindPackageHandleStandardArgs)
-
-find_path(LERC_INCLUDE_DIR NAMES Lerc_c_api.h)
-find_library(LERC_LIBRARY NAMES Lerc lerc)
-
-mark_as_advanced(LERC_INCLUDE_DIR LERC_LIBRARY)
-find_package_handle_standard_args(LERC
-                                  FOUND_VAR LERC_FOUND
-                                  REQUIRED_VARS LERC_LIBRARY LERC_INCLUDE_DIR)
-
-if(LERC_FOUND)
-    set(LERC_LIBRARIES ${LERC_LIBRARY})
-    set(LERC_INCLUDE_DIRS ${LERC_INCLUDE_DIR})
-
-    if(NOT TARGET LERC::LERC)
-        add_library(LERC::LERC UNKNOWN IMPORTED)
-        set_target_properties(LERC::LERC PROPERTIES
-                              INTERFACE_INCLUDE_DIRECTORIES "${LERC_INCLUDE_DIR}"
-                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                              IMPORTED_LOCATION "${LERC_LIBRARY}")
-    endif()
-endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindLURATECH.cmake

@@ -1,35 +0,0 @@
-# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
-# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
-
-# - Try to find the LURATECH library
-#
-# Once done this will define
-#
-#  LURATECH_FOUND - System has Luratech
-#  LURATECH_INCLUDE_DIR - The Luratech include directory
-#  LURATECH_LIBRARIES - The libraries needed to use Luratech
-
-find_path(LURATECH_INCLUDE_DIR lwf_jp2.h HINTS ${LURATECH_ROOT}/include)
-
-find_library(LURATECH_LIBRARY NAMES _lwf_jp2 lwf_jp2 PATH_SUFFIXES library HINTS ${LURATECH_ROOT}/library)
-
-mark_as_advanced(LURATECH_INCLUDE_DIR LURATECH_LIBRARY)
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(LURATECH
-                                  FOUND_VAR LURATECH_FOUND
-                                  REQUIRED_VARS LURATECH_LIBRARY LURATECH_INCLUDE_DIR
-                                  VERSION_VAR LURATECH_VERSION_STRING
-)
-
-if(LURATECH_FOUND)
-    set(LURATECH_LIBRARIES "${LURATECH_LIBRARY}")
-    set(LURATECH_INCLUDE_DIRS "${LURATECH_INCLUDE_DIR}")
-    if(NOT TARGET LURATECH::LURATECH)
-        add_library(LURATECH::LURATECH UNKNOWN IMPORTED)
-        set_target_properties(LURATECH::LURATECH PROPERTIES
-                              INTERFACE_INCLUDE_DIRECTORIES "${LURATECH_INCLUDE_DIRS}"
-                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                              IMPORTED_LOCATION "${LURATECH_LIBRARIES}")
-    endif()
-endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindLZ4.cmake

@@ -1,130 +0,0 @@
-# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
-# file Copyright.txt or https://cmake.org/licensing for details.
-
-#[=======================================================================[.rst:
-FindLZ4
--------
-
-Find the LZ4 include directory and library.
-
-Use this module by invoking find_package with the form::
-
-.. code-block:: cmake
-
-  find_package(LZ4
-    [version]              # Minimum version e.g. 1.8.0
-    [REQUIRED]             # Fail with error if LZ4 is not found
-  )
-
-Imported targets
-^^^^^^^^^^^^^^^^
-
-This module defines the following :prop_tgt:`IMPORTED` targets:
-
-.. variable:: LZ4::LZ4
-
-  Imported target for using the LZ4 library, if found.
-
-Result variables
-^^^^^^^^^^^^^^^^
-
-.. variable:: LZ4_FOUND
-
-  Set to true if LZ4 library found, otherwise false or undefined.
-
-.. variable:: LZ4_INCLUDE_DIRS
-
-  Paths to include directories listed in one variable for use by LZ4 client.
-
-.. variable:: LZ4_LIBRARIES
-
-  Paths to libraries to linked against to use LZ4.
-
-.. variable:: LZ4_VERSION
-
-  The version string of LZ4 found.
-
-Cache variables
-^^^^^^^^^^^^^^^
-
-For users who wish to edit and control the module behavior, this module
-reads hints about search locations from the following variables::
-
-.. variable:: LZ4_INCLUDE_DIR
-
-  Path to LZ4 include directory with ``lz4.h`` header.
-
-.. variable:: LZ4_LIBRARY
-
-  Path to LZ4 library to be linked.
-
-NOTE: The variables above should not usually be used in CMakeLists.txt files!
-
-#]=======================================================================]
-
-### Find library ##############################################################
-
-if(NOT LZ4_LIBRARY)
-  find_library(LZ4_LIBRARY_RELEASE NAMES lz4 liblz4)
-  find_library(LZ4_LIBRARY_DEBUG NAMES lz4d)
-
-  include(SelectLibraryConfigurations)
-  select_library_configurations(LZ4)
-else()
-  file(TO_CMAKE_PATH "${LZ4_LIBRARY}" LZ4_LIBRARY)
-endif()
-
-### Find include directory ####################################################
-find_path(LZ4_INCLUDE_DIR NAMES lz4.h)
-
-if(LZ4_INCLUDE_DIR AND EXISTS "${LZ4_INCLUDE_DIR}/lz4.h")
-    file(STRINGS "${LZ4_INCLUDE_DIR}/lz4.h" _lz4_h_contents
-      REGEX "#define LZ4_VERSION_[A-Z]+[ ]+[0-9]+")
-    string(REGEX REPLACE "#define LZ4_VERSION_MAJOR[ ]+([0-9]+).+" "\\1"
-      LZ4_VERSION_MAJOR "${_lz4_h_contents}")
-    string(REGEX REPLACE ".+#define LZ4_VERSION_MINOR[ ]+([0-9]+).+" "\\1"
-      LZ4_VERSION_MINOR "${_lz4_h_contents}")
-    string(REGEX REPLACE ".+#define LZ4_VERSION_RELEASE[ ]+([0-9]+).*" "\\1"
-      LZ4_VERSION_RELEASE "${_lz4_h_contents}")
-    set(LZ4_VERSION "${LZ4_VERSION_MAJOR}.${LZ4_VERSION_MINOR}.${LZ4_VERSION_RELEASE}")
-    unset(_lz4_h_contents)
-endif()
-
-### Set result variables ######################################################
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(LZ4 DEFAULT_MSG
-    LZ4_LIBRARY LZ4_INCLUDE_DIR LZ4_VERSION)
-
-mark_as_advanced(LZ4_INCLUDE_DIR LZ4_LIBRARY)
-
-set(LZ4_LIBRARIES ${LZ4_LIBRARY})
-set(LZ4_INCLUDE_DIRS ${LZ4_INCLUDE_DIR})
-
-### Import targets ############################################################
-if(LZ4_FOUND)
-  if(NOT TARGET LZ4::LZ4)
-    add_library(LZ4::LZ4 UNKNOWN IMPORTED)
-    set_target_properties(LZ4::LZ4 PROPERTIES
-      IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-      INTERFACE_INCLUDE_DIRECTORIES "${LZ4_INCLUDE_DIR}")
-
-    if(LZ4_LIBRARY_RELEASE)
-      set_property(TARGET LZ4::LZ4 APPEND PROPERTY
-        IMPORTED_CONFIGURATIONS RELEASE)
-      set_target_properties(LZ4::LZ4 PROPERTIES
-        IMPORTED_LOCATION_RELEASE "${LZ4_LIBRARY_RELEASE}")
-      endif()
-
-    if(LZ4_LIBRARY_DEBUG)
-      set_property(TARGET LZ4::LZ4 APPEND PROPERTY
-        IMPORTED_CONFIGURATIONS DEBUG)
-      set_target_properties(LZ4::LZ4 PROPERTIES
-        IMPORTED_LOCATION_DEBUG "${LZ4_LIBRARY_DEBUG}")
-    endif()
-
-    if(NOT LZ4_LIBRARY_RELEASE AND NOT LZ4_LIBRARY_DEBUG)
-      set_property(TARGET LZ4::LZ4 APPEND PROPERTY
-        IMPORTED_LOCATION "${LZ4_LIBRARY}")
-    endif()
-  endif()
-endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindLibKML.cmake

@@ -1,131 +0,0 @@
-# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
-# file Copyright.txt or https://cmake.org/licensing for details.
-
-#[=======================================================================[.rst:
-FindLibKML
-----------
-
-Find the LibKML headers and libraries.
-
-This module accept optional COMPONENTS to check supported sub modules::
-
-    LIBKML_BASE_LIBRARY
-    LIBKML_DOM_LIBRARY
-    LIBKML_ENGINE_LIBRARY
-    LIBKML_CONVENIENCE_LIBRARY
-    LIBKML_XSD_LIBRARY
-
-
-IMPORTED Targets
-^^^^^^^^^^^^^^^^
-
-This module defines :prop_tgt:`IMPORTED` target ``LIBKML::LibKML``, if found.
-
-Result Variables
-^^^^^^^^^^^^^^^^
-
-This module defines the following variables:
-
-``LIBKML_FOUND``
-  True if libkml found.
-
-``LIBKML_INCLUDE_DIRS``
-  where to find header files.
-
-``LIBKML_LIBRARIES``
-  List of libraries when using libkml.
-
-``LIBKML_VERSION_STRING``
-  The version of libkml found.
-#]=======================================================================]
-
-find_package(PkgConfig QUIET)
-if(PKG_CONFIG_FOUND)
-  pkg_check_modules(PC_LIBKML QUIET libkml)
-  if(PC_LIBKML_VERSION)
-  endif()
-endif()
-
-find_path(LIBKML_INCLUDE_DIR
-          NAMES kml/engine.h kml/dom.h
-          HINTS ${PC_LIBKML_INCLUDE_DIRS})
-mark_as_advanced(LIBKML_INCLUDE_DIR)
-
-find_library(LIBKML_BASE_LIBRARY
-             NAMES kmlbase libkmlbase
-             HINTS ${PC_LIBKML_LIBRARY_DIRS} )
-mark_as_advanced(LIBKML_BASE_LIBRARY)
-
-set(libkml_known_components DOM CONVENIENCE ENGINE REGIONATOR)
-foreach(_comp IN LISTS libkml_known_components)
-  if(${_comp} IN_LIST LibKML_FIND_COMPONENTS)
-    string(TOLOWER ${_comp} _name)
-    find_library(LIBKML_${_comp}_LIBRARY
-                 NAMES kml${_name} libkml${_name}
-                 HINTS ${PC_LIBKML_LIBRARY_DIRS} )
-    mark_as_advanced(LIBKML_${_comp}_LIBRARY)
-  endif()
-endforeach()
-
-set(libkml_helpers MINIZIP URIPARSER)
-foreach(_helper IN LISTS libkml_helpers)
-  string(TOLOWER ${_helper} _name)
-  find_library(LIBKML_${_helper}_LIBRARY
-               NAMES ${_name} lib${_name}
-               HINTS ${PC_LIBKML_LIBRARY_DIRS} )
-  mark_as_advanced(LIBKML_${_helper}_LIBRARY)
-endforeach()
-
-if(LIBKML_INCLUDE_DIR AND NOT LIBKML_VERSION)
-  file(STRINGS ${LIBKML_INCLUDE_DIR}/kml/base/version.h libkml_version_h_string
-       REGEX "^#define[\t ]+LIBKML_(MAJOR|MINOR|MICRO)_VERSION[\t ]+[0-9]+")
-  string(REGEX REPLACE ".*LIBKML_MAJOR_VERSION[\t ]+([0-9]+).*" "\\1" LIBKML_VERSION_MAJOR "${libkml_version_h_string}")
-  string(REGEX REPLACE ".*LIBKML_MINOR_VERSION[\t ]+([0-9]+).*" "\\1" LIBKML_VERSION_MINOR "${libkml_version_h_string}")
-  string(REGEX REPLACE ".*LIBKML_MICRO_VERSION[\t ]+([0-9]+).*" "\\1" LIBKML_VERSION_MICRO "${libkml_version_h_string}")
-  set(LIBKML_VERSION_STRING "${LIBKML_VERSION_MAJOR}.${LIBKML_VERSION_MINOR}.${LIBKML_VERSION_MICRO}")
-endif()
-
-set(libkml_required_vars LIBKML_BASE_LIBRARY LIBKML_INCLUDE_DIR)
-foreach(_comp IN LISTS LibKML_FIND_COMPONENTS)
-  set(libkml_required_vars ${libkml_required_vars} "LIBKML_${_comp}_LIBRARY")
-endforeach()
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(LibKML
-                                  FOUND_VAR LIBKML_FOUND
-                                  REQUIRED_VARS ${libkml_required_vars}
-                                  VERSION_VAR LIBKML_VERSION_STRING)
-
-if(LIBKML_FOUND)
-  set(LIBKML_INCLUDE_DIRS "${LIBKML_INCLUDE_DIR}")
-  set(LIBKML_LIBRARIES "${LIBKML_BASE_LIBRARY}")
-  if(NOT TARGET LIBKML::LibKML)
-    add_library(LIBKML::LibKML UNKNOWN IMPORTED)
-    set_target_properties(LIBKML::LibKML PROPERTIES
-                          INTERFACE_INCLUDE_DIRECTORIES "${LIBKML_INCLUDE_DIR}"
-                          IMPORTED_LINK_INTERFACE_LANGUAGES "C++"
-                          IMPORTED_LOCATION "${LIBKML_BASE_LIBRARY}")
-  endif()
-  foreach(_comp IN LISTS libkml_known_components)
-    if(${_comp} IN_LIST LibKML_FIND_COMPONENTS)
-      list(APPEND LIBKML_LIBRARIES "${LIBKML_${_comp}_LIBRARY}")
-      if(NOT TARGET LIBKML::${_comp})
-        add_library(LIBKML::${_comp} UNKNOWN IMPORTED)
-        set_target_properties(LIBKML::${_comp} PROPERTIES
-                              IMPORTED_LINK_INTERFACE_LANGUAGES "C++"
-                              IMPORTED_LOCATION "${LIBKML_${_comp}_LIBRARY}")
-      endif()
-    endif()
-  endforeach()
-  foreach(_helper IN LISTS libkml_helpers)
-    if(LIBKML_${_helper}_LIBRARY)
-      list(APPEND LIBKML_LIBRARIES "${LIBKML_${_helper}_LIBRARY}")
-      if(NOT TARGET LIBKML::${_helper})
-        add_library(LIBKML::${_helper} UNKNOWN IMPORTED)
-        set_target_properties(LIBKML::${_helper} PROPERTIES
-                              IMPORTED_LINK_INTERFACE_LANGUAGES "C++"
-                              IMPORTED_LOCATION "${LIBKML_${_helper}_LIBRARY}")
-      endif()
-    endif()
-  endforeach()
-endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindMONGOCXX.cmake

@@ -1,56 +0,0 @@
-# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
-# file Copyright.txt or https://cmake.org/licensing for details.
-
-#.rst:
-# FindMONGOCXX
-# -----------
-#
-# Find the MONGOCXX library
-#
-# Once done this will define
-#
-#  MONGOCXX_FOUND - System has MONGOCXX
-#  MONGOCXX_INCLUDE_DIR - The MONGOCXX include directory
-#  MONGOCXX_LIBRARIES - The libraries needed to use MONGOCXX
-
-find_package(PkgConfig QUIET)
-if(PKG_CONFIG_FOUND)
-    pkg_check_modules(PC_MONGOCXX QUIET libmongocxx)
-    set(MONGOCXX_VERSION_STRING ${PC_MONGOCXX_VERSION})
-endif()
-
-find_path(MONGOCXX_INCLUDE_DIR mongocxx/client.hpp
-          HINTS ${PC_MONGOCXX_INCLUDE_DIRS}
-          PATH_SUFFIXES mongocxx/v_noabi)
-find_path(BSONCXX_INCLUDE_DIR bsoncxx/config/version.hpp
-          HINTS ${PC_MONGOCXX_INCLUDE_DIRS}
-          PATH_SUFFIXES bsoncxx/v_noabi)
-find_library(MONGOCXX_LIBRARY NAMES mongocxx
-             HINTS ${PC_MONGOCXX_LIBRARY_DIRS})
-find_library(BSONCXX_LIBRARY NAMES bsoncxx
-             HINTS ${PC_MONGOCXX_LIBRARY_DIRS})
-mark_as_advanced(MONGOCXX_INCLUDE_DIR BSONCXX_INCLUDE_DIR MONGOCXX_LIBRARY BSONCXX_LIBRARY)
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(MONGOCXX
-                                  REQUIRED_VARS MONGOCXX_INCLUDE_DIR BSONCXX_INCLUDE_DIR MONGOCXX_LIBRARY BSONCXX_LIBRARY
-                                  VERSION_VAR MONGOCXX_VERSION_STRING)
-
-if(MONGOCXX_FOUND)
-    set(MONGOCXX_LIBRARIES "${MONGOCXX_LIBRARY}" "${BSONCXX_LIBRARY}")
-    set(MONGOCXX_INCLUDE_DIRS "${MONGOCXX_INCLUDE_DIR}" "${BSONCXX_INCLUDE_DIR}")
-    if(NOT TARGET MONGOCXX::MONGOCXX)
-        add_library(MONGOCXX::MONGOCXX UNKNOWN IMPORTED)
-        set_target_properties(MONGOCXX::MONGOCXX PROPERTIES
-                              INTERFACE_INCLUDE_DIRECTORIES "${MONGOCXX_INCLUDE_DIR}"
-                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                              IMPORTED_LOCATION "${MONGOCXX_LIBRARY}")
-    endif()
-    if(NOT TARGET MONGOCXX::BSONCXX)
-        add_library(MONGOCXX::BSONCXX UNKNOWN IMPORTED)
-        set_target_properties(MONGOCXX::BSONCXX PROPERTIES
-                              INTERFACE_INCLUDE_DIRECTORIES "${BSONCXX_INCLUDE_DIR}"
-                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                              IMPORTED_LOCATION "${BSONCXX_LIBRARY}")
-    endif()
-endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindMRSID.cmake

@@ -1,66 +0,0 @@
-# Distributed under the GDAL/OGR MIT style License.  See accompanying
-# file LICENSE.TXT.
-
-#[=======================================================================[.rst:
-configure
----------
-
-#]=======================================================================]
-# Find the MRSID library - Multi-resolution Seamless Image Database.
-#
-# Copyright (C) 2017,2018 Hiroshi Miura
-# Copyright (c) 2015 NextGIS <info@nextgis.com>
-#
-# Sets
-#   MRSID_FOUND.
-#   MRSID_INCLUDE_DIRS
-#   MRSID_LIBRARIES
-#
-
-find_path(MRSID_INCLUDE_DIR NAMES lt_base.h)
-
-if( MRSID_INCLUDE_DIR )
-  find_library( MRSID_LIBRARY NAMES lti_dsdk ltidsdk)
-endif()
-
-if(MRSID_INCLUDE_DIR AND MRSID_LIBRARY)
-  set(MAJOR_VERSION 0)
-  set(MINOR_VERSION 0)
-  set(SRV_VERSION 0)
-  set(BLD_VERSION 0)
-  if(EXISTS "${MRSID_INCLUDE_DIR}/lti_version.h")
-    file(READ "${MRSID_INCLUDE_DIR}/lti_version.h" VERSION_H_CONTENTS)
-    string(REGEX MATCH "LTI_SDK_MAJOR[ \t]+([0-9]+)"
-      MAJOR_VERSION ${VERSION_H_CONTENTS})
-    string (REGEX MATCH "([0-9]+)"
-      MAJOR_VERSION ${MAJOR_VERSION})
-    string(REGEX MATCH "LTI_SDK_MINOR[ \t]+([0-9]+)"
-      MINOR_VERSION ${VERSION_H_CONTENTS})
-    string (REGEX MATCH "([0-9]+)"
-      MINOR_VERSION ${MINOR_VERSION})
-    string(REGEX MATCH "LTI_SDK_REV[ \t]+([0-9]+)"
-      REV_VERSION ${VERSION_H_CONTENTS})
-    string (REGEX MATCH "([0-9]+)"
-      REV_VERSION ${REV_VERSION})
-    unset(VERSION_H_CONTENTS)
-  endif()
-  set(MRSID_VERSION_STRING "${MAJOR_VERSION}.${MINOR_VERSION}.${REV_VERSION}")
-endif()
-mark_as_advanced(MRSID_INCLUDE_DIR MRSID_LIBRARY MRSID_VERSION_STRING)
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(MRSID FOUND_VAR MRSID_FOUND
-                                  REQUIRED_VARS MRSID_LIBRARY MRSID_INCLUDE_DIR
-                                  VERSION_VAR MRSID_VERSION_STRING)
-
-# Copy the results to the output variables.
-if(MRSID_FOUND)
-  set(MRSID_LIBRARIES ${MRSID_LIBRARY})
-  set(MRSID_INCLUDE_DIRS ${MRSID_INCLUDE_DIR})
-  if(NOT TARGET MRSID::MRSID)
-    add_library(MRSID::MRSID UNKNOWN IMPORTED)
-    set_target_properties(MRSID::MRSID PROPERTIES
-                          INTERFACE_INCLUDE_DIRECTORIES "${MRSID_INCLUDE_DIR}"
-                          IMPORTED_LOCATION "${MRSID_LIBRARY}")
-  endif()
-endif()