@cpp.js/package-gdal 1.0.0-beta.23 → 2.0.0-beta.1

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindODBC.cmake

@@ -1,258 +0,0 @@
-# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
-# file Copyright.txt or https://cmake.org/licensing for details.
-
-#[=======================================================================[.rst:
-FindODBC
---------
-
-Find an Open Database Connectivity (ODBC) include directory and library.
-
-On Windows, when building with Visual Studio, this module assumes the ODBC
-library is provided by the available Windows SDK.
-
-On Unix, this module allows to search for ODBC library provided by
-unixODBC or iODBC implementations of ODBC API.
-This module reads hint about location of the config program:
-
-.. variable:: ODBC_CONFIG
-
-  Location of odbc_config or iodbc-config program
-
-Otherwise, this module tries to find the config program,
-first from unixODBC, then from iODBC.
-If no config program found, this module searches for ODBC header
-and library in list of known locations.
-
-Imported targets
-^^^^^^^^^^^^^^^^
-
-This module defines the following :prop_tgt:`IMPORTED` targets:
-
-.. variable:: ODBC::ODBC
-
-  Imported target for using the ODBC library, if found.
-
-Result variables
-^^^^^^^^^^^^^^^^
-
-.. variable:: ODBC_FOUND
-
-  Set to true if ODBC library found, otherwise false or undefined.
-
-.. variable:: ODBC_INCLUDE_DIRS
-
-  Paths to include directories listed in one variable for use by ODBC client.
-  May be empty on Windows, where the include directory corresponding to the
-  expected Windows SDK is already available in the compilation environment.
-
-.. variable:: ODBC_LIBRARIES
-
-  Paths to libraries to linked against to use ODBC.
-  May just a library name on Windows, where the library directory corresponding
-  to the expected Windows SDK is already available in the compilation environment.
-
-.. variable:: ODBC_CONFIG
-
-  Path to unixODBC or iODBC config program, if found or specified.
-
-Cache variables
-^^^^^^^^^^^^^^^
-
-For users who wish to edit and control the module behavior, this module
-reads hints about search locations from the following variables:
-
-.. variable:: ODBC_INCLUDE_DIR
-
-  Path to ODBC include directory with ``sql.h`` header.
-
-.. variable:: ODBC_LIBRARY
-
-  Path to ODBC library to be linked.
-
-These variables should not be used directly by project code.
-
-Limitations
-^^^^^^^^^^^
-
-On Windows, this module does not search for iODBC.
-On Unix, there is no way to prefer unixODBC over iODBC, or vice versa,
-other than providing the config program location using the ``ODBC_CONFIG``.
-This module does not allow to search for a specific ODBC driver.
-
-#]=======================================================================]
-
-# Define lists used internally
-set(_odbc_include_paths)
-set(_odbc_lib_paths)
-set(_odbc_lib_names)
-set(_odbc_required_libs_names)
-
-### Try Windows Kits ##########################################################
-if(WIN32)
-  # List names of ODBC libraries on Windows
-  if(NOT MINGW AND NOT CYGWIN)
-    set(ODBC_LIBRARY odbc32.lib)
-  endif()
-  set(_odbc_lib_names odbc32;)
-
-  # List additional libraries required to use ODBC library
-  if(MSVC OR CMAKE_CXX_COMPILER_ID MATCHES "Intel")
-    set(_odbc_required_libs_names odbccp32;ws2_32)
-  elseif(MINGW)
-    set(_odbc_required_libs_names odbccp32)
-  endif()
-endif()
-
-### Try unixODBC or iODBC config program ######################################
-if (UNIX)
-  find_program(ODBC_CONFIG
-    NAMES odbc_config iodbc-config
-    DOC "Path to unixODBC or iODBC config program")
-  mark_as_advanced(ODBC_CONFIG)
-endif()
-
-if (UNIX AND ODBC_CONFIG)
-  # unixODBC and iODBC accept unified command line options
-  execute_process(COMMAND ${ODBC_CONFIG} --cflags
-    OUTPUT_VARIABLE _cflags OUTPUT_STRIP_TRAILING_WHITESPACE)
-  execute_process(COMMAND ${ODBC_CONFIG} --libs
-    OUTPUT_VARIABLE _libs OUTPUT_STRIP_TRAILING_WHITESPACE)
-
-  # Collect paths of include directories from CFLAGS
-  separate_arguments(_cflags NATIVE_COMMAND "${_cflags}")
-  foreach(arg IN LISTS _cflags)
-    if("${arg}" MATCHES "^-I(.*)$")
-      list(APPEND _odbc_include_paths "${CMAKE_MATCH_1}")
-    endif()
-  endforeach()
-  unset(_cflags)
-
-  # Collect paths of library names and directories from LIBS
-  separate_arguments(_libs NATIVE_COMMAND "${_libs}")
-  foreach(arg IN LISTS _libs)
-    if("${arg}" MATCHES "^-L(.*)$")
-      list(APPEND _odbc_lib_paths "${CMAKE_MATCH_1}")
-    elseif("${arg}" MATCHES "^-l(.*)$")
-      set(_lib_name ${CMAKE_MATCH_1})
-      string(REGEX MATCH "odbc" _is_odbc ${_lib_name})
-      if(_is_odbc)
-        list(APPEND _odbc_lib_names ${_lib_name})
-      else()
-        list(APPEND _odbc_required_libs_names ${_lib_name})
-      endif()
-      unset(_lib_name)
-    endif()
-  endforeach()
-  unset(_libs)
-endif()
-
-### Try unixODBC or iODBC in include/lib filesystems ##########################
-if (UNIX AND NOT ODBC_CONFIG)
-  # List names of both ODBC libraries, unixODBC and iODBC
-  set(_odbc_lib_names odbc;iodbc;unixodbc;)
-endif()
-
-### Find include directories ##################################################
-find_path(ODBC_INCLUDE_DIR
-  NAMES sql.h
-  PATHS ${_odbc_include_paths})
-
-if(NOT ODBC_INCLUDE_DIR AND WIN32)
-  set(ODBC_INCLUDE_DIR "")
-endif()
-
-### Find libraries ############################################################
-
-  find_library(ODBC_LIBRARY
-    NAMES ${_odbc_lib_names}
-    PATHS ${_odbc_lib_paths}
-    PATH_SUFFIXES odbc)
-
-  foreach(_lib IN LISTS _odbc_required_libs_names)
-    find_library(_lib_path
-      NAMES ${_lib}
-      PATHS ${_odbc_lib_paths} # system parths or collected from ODBC_CONFIG
-      PATH_SUFFIXES odbc)
-    if(_lib_path)
-      list(APPEND _odbc_required_libs_paths ${_lib_path})
-    endif()
-    unset(_lib_path CACHE)
-  endforeach()
-
-
-# Unset internal lists as no longer used
-unset(_odbc_include_paths)
-unset(_odbc_lib_paths)
-unset(_odbc_lib_names)
-unset(_odbc_required_libs_names)
-
-### Set result variables ######################################################
-set(_odbc_required_vars ODBC_LIBRARY)
-if(NOT WIN32)
-  list(APPEND _odbc_required_vars ODBC_INCLUDE_DIR)
-endif()
-
-
-foreach(component IN LISTS ODBC_FIND_COMPONENTS)
-  set(ODBC_${component}_FOUND FALSE)
-endforeach()
-
-if(ODBCINST IN_LIST ODBC_FIND_COMPONENTS)
-  find_library(ODBC_ODBCINST_LIBRARY
-               NAMES odbcinst
-               PATHS ${_odbc_lib_paths})
-  mark_as_advanced(ODBC_ODBCINST_LIBRARY)
-  if(ODBC_ODBCINST_LIBRARY)
-    set(ODBC_ODBCINST_FOUND TRUE)
-  endif()
-endif()
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(ODBC
-                                  REQUIRED_VARS ${_odbc_required_vars}
-                                  HANDLE_COMPONENTS)
-
-unset(_odbc_required_vars)
-
-mark_as_advanced(ODBC_LIBRARY ODBC_INCLUDE_DIR)
-
-if(MSVC)
-  # legacy_stdio_definitions.lib : https://connect.microsoft.com/VisualStudio/feedback/details/1134693/vs-2015-ctp-5-c-vsnwprintf-s-and-other-functions-are-not-exported-in-appcrt140-dll-breaking-linkage-of-static-libraries
-  list(APPEND _odbc_required_libs_paths "legacy_stdio_definitions.lib;odbccp32.lib")
-endif()
-
-set(ODBC_INCLUDE_DIRS ${ODBC_INCLUDE_DIR})
-list(APPEND ODBC_LIBRARIES ${ODBC_LIBRARY})
-list(APPEND ODBC_LIBRARIES ${_odbc_required_libs_paths})
-set(ODBC_ODBCINST_LIBRARIES ${ODBC_ODBCINST_LIBRARY})
-
-### Import targets ############################################################
-if(ODBC_FOUND)
-  if(NOT TARGET ODBC::ODBC)
-    if(IS_ABSOLUTE "${ODBC_LIBRARY}")
-      add_library(ODBC::ODBC UNKNOWN IMPORTED)
-      set_target_properties(ODBC::ODBC PROPERTIES
-        IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-        IMPORTED_LOCATION "${ODBC_LIBRARY}")
-    else()
-      add_library(ODBC::ODBC INTERFACE IMPORTED)
-      set_target_properties(ODBC::ODBC PROPERTIES
-        IMPORTED_LIBNAME "${ODBC_LIBRARY}")
-    endif()
-    set_target_properties(ODBC::ODBC PROPERTIES
-      INTERFACE_INCLUDE_DIRECTORIES "${ODBC_INCLUDE_DIR}")
-
-    if(_odbc_required_libs_paths)
-      set_property(TARGET ODBC::ODBC APPEND PROPERTY
-        INTERFACE_LINK_LIBRARIES "${_odbc_required_libs_paths}")
-    endif()
-    if(ODBCINST IN_LIST ODBC_FIND_COMPONENTS)
-      add_library(ODBC::ODBCINST UNKNOWN IMPORTED)
-      set_target_properties(ODBC::ODBCINST PROPERTIES
-                            IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                            IMPORTED_LOCATION ${ODBC_ODBCINST_LIBRARY})
-    endif()
-  endif()
-endif()
-
-unset(_odbc_required_libs_paths)

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindODBCCPP.cmake

@@ -1,72 +0,0 @@
-# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
-# file COPYING-CMAKE-SCRIPTS or https://cmake.org/licensing for details.
-
-#[=======================================================================[.rst:
-FindODBCCPP
---------------
-
-Find the odbc-cpp-wrapper includes and library.
-
-IMPORTED Targets
-^^^^^^^^^^^^^^^^
-
-This module defines :prop_tgt:`IMPORTED` target ``ODBCCPP::ODBCCPP``, if
-the odbc-cpp-wrapper has been found.
-
-Result Variables
-^^^^^^^^^^^^^^^^
-
-This module defines the following variables:
-
-::
-
-  ODBCCPP_INCLUDE_DIRS - where to find the odbc-cpp-wrapper headers.
-  ODBCCPP_LIBRARIES    - List of libraries when using the odbc-cpp-wrapper.
-  ODBCCPP_FOUND        - True if the odbc-cpp-wrapper found.
-
-#]=======================================================================]
-
-if(NOT ODBCCPP_INCLUDE_DIR)
-  find_path(ODBCCPP_INCLUDE_DIR odbc/Environment.h
-    PATHS
-     /usr/include
-     /usr/local/include
-     c:/msys/local/include
-     "$ENV{LIB_DIR}/include"
-     "$ENV{INCLUDE}"
-     "$ENV{ODBCCPP_PATH}/include")
-endif(NOT ODBCCPP_INCLUDE_DIR)
-
-if(NOT ODBCCPP_LIBRARY)
-  find_library(ODBCCPP_LIBRARY odbccpp
-    PATHS
-     /usr/lib
-     /usr/local/lib
-     c:/msys/local/lib
-     "$ENV{LIB_DIR}/lib"
-     "$ENV{LIB}"
-     "$ENV{ODBCCPP_PATH}/lib")
-endif(NOT ODBCCPP_LIBRARY)
-
-if(ODBCCPP_INCLUDE_DIR AND ODBCCPP_LIBRARY)
-   set(ODBCCPP_FOUND TRUE)
-endif(ODBCCPP_INCLUDE_DIR AND ODBCCPP_LIBRARY)
-
-mark_as_advanced(ODBCCPP_LIBRARY ODBCCPP_INCLUDE_DIR)
-
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(ODBCCPP
-                                  FOUND_VAR ODBCCPP_FOUND
-                                  REQUIRED_VARS ODBCCPP_LIBRARY ODBCCPP_INCLUDE_DIR)
-
-if(ODBCCPP_FOUND)
-  set(ODBCCPP_INCLUDE_DIRS ${ODBCCPP_INCLUDE_DIR})
-  set(ODBCCPP_LIBRARIES ${ODBCCPP_LIBRARY})
-  if(NOT TARGET ODBCCPP::ODBCCPP)
-      add_library(ODBCCPP::ODBCCPP UNKNOWN IMPORTED)
-      set_target_properties(ODBCCPP::ODBCCPP PROPERTIES
-                            INTERFACE_INCLUDE_DIRECTORIES "${ODBCCPP_INCLUDE_DIRS}"
-                            IMPORTED_LINK_INTERFACE_LANGUAGES "CXX"
-                            IMPORTED_LOCATION "${ODBCCPP_LIBRARY}")
-  endif()
-endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindOGDI.cmake

@@ -1,63 +0,0 @@
-# FindOGDI
-# ~~~~~~~~~
-#
-# Copyright (c) 2017, Hiroshi Miura <miurahr@linux.com>
-# Redistribution and use is allowed according to the terms of the BSD license.
-# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
-#
-# If it's found it sets OGDI_FOUND to TRUE
-# and following variables are set:
-#    OGDI_INCLUDE_DIRS
-#    OGDI_LIBRARIES
-#    OGDI_VERSION
-#
-
-find_package(PkgConfig QUIET)
-if(PKG_CONFIG_FOUND)
-  pkg_check_modules(PC_OGDI QUIET ogdi)
-  set(OGDI_VERSION_STRING ${PC_OGDI_VERSION})
-  set(OGDI_INCLUDE_DIRS ${PC_OGDI_INCLUDE_DIRS})
-endif()
-
-find_path(OGDI_INCLUDE_DIR ecs.h
-          HINTS ${PC_OGDI_INCLUDE_DIRS}
-          PATH_SUFFIXES ogdi)
-mark_as_advanced(OGDI_INCLUDE_DIR)
-
-find_library(OGDI_LIBRARY NAMES ogdi libogdi)
-mark_as_advanced(OGDI_LIBRARY)
-
-if(OGDI_INCLUDE_DIR AND OGDI_LIBRARY)
-  find_program(OGDI_CONFIG_EXE ogdi-config)
-  mark_as_advanced(OGDI_CONFIG_EXE)
-  execute_process(COMMAND ${OGDI_CONFIG_EXE} --version
-    OUTPUT_VARIABLE OGDI_VERSION
-    OUTPUT_STRIP_TRAILING_WHITESPACE
-    )
-  execute_process(COMMAND ${OGDI_CONFIG_EXE} --cflags
-    OUTPUT_VARIABLE _cflags OUTPUT_STRIP_TRAILING_WHITESPACE
-    )
-  # Collect paths of include directories from CFLAGS
-  separate_arguments(_cflags NATIVE_COMMAND "${_cflags}")
-  foreach(arg IN LISTS _cflags)
-    if("${arg}" MATCHES "^-I(.*)$")
-      list(APPEND OGDI_INCLUDE_DIRS "${CMAKE_MATCH_1}")
-    endif()
-  endforeach()
-  unset(_cflags)
-endif()
-
-find_package_handle_standard_args(OGDI REQUIRED_VARS OGDI_LIBRARY OGDI_INCLUDE_DIRS
-                                  VERSION_VAR OGDI_VERSION)
-
-if(OGDI_FOUND)
-    set(OGDI_LIBRARIES ${OGDI_LIBRARY})
-    set(OGDI_INCLUDE_DIRS ${OGDI_INCLUDE_DIRS})
-    if(NOT TARGET OGDI::OGDI)
-        add_library(OGDI::OGDI UNKNOWN IMPORTED)
-        set_target_properties(OGDI::OGDI PROPERTIES
-                              INTERFACE_INCLUDE_DIRECTORIES "${OGDI_INCLUDE_DIRS}"
-                              IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                              IMPORTED_LOCATION "${OGDI_LIBRARY}")
-    endif()
-endif()

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindOpenCAD.cmake

@@ -1,96 +0,0 @@
-# Find opencad
-# ~~~~~~~~~
-# Copyright (c) 2016, Dmitry Baryshnikov <polimax at mail.ru>
-# Redistribution and use is allowed according to the terms of the BSD license.
-# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
-#
-# CMake module to search for opencad library
-#
-# If it's found it sets OPENCAD_FOUND to TRUE
-# and following variables are set:
-#    OPENCAD_INCLUDE_DIR
-#    OPENCAD_LIBRARY
-
-# FIND_PATH and FIND_LIBRARY normally search standard locations
-# before the specified paths. To search non-standard paths first,
-# FIND_* is invoked first with specified paths and NO_DEFAULT_PATH
-# and then again with no specified paths to search the default
-# locations. When an earlier FIND_* succeeds, subsequent FIND_*s
-# searching for the same item do nothing. 
-
-# try to use framework on mac
-# want clean framework path, not unix compatibility path
-# Try to use OSGeo4W installation
-IF(WIN32)
-    SET(OPENCAD_OSGEO4W_HOME "C:/OSGeo4W") 
-
-    IF($ENV{OSGEO4W_HOME})
-        SET(OPENCAD_OSGEO4W_HOME "$ENV{OSGEO4W_HOME}") 
-    ENDIF()
-ENDIF(WIN32)
-
-FIND_PATH(OPENCAD_INCLUDE_DIR opencad.h
-    PATHS ${OPENCAD_OSGEO4W_HOME}/include
-    PATH_SUFFIXES opencad
-    DOC "Path to OPENCAD library include directory")
-
-SET(OPENCAD_NAMES ${OPENCAD_NAMES} opencad opencad_i)
-FIND_LIBRARY(OPENCAD_LIBRARY
-    NAMES ${OPENCAD_NAMES}
-    PATHS ${OPENCAD_OSGEO4W_HOME}/lib
-    DOC "Path to OPENCAD library file")
-
-if(OPENCAD_INCLUDE_DIR)
-    set(OPENCAD_VERSION_MAJOR 0)
-    set(OPENCAD_VERSION_MINOR 0)
-    set(OPENCAD_VERSION_PATCH 0)
-    set(OPENCAD_VERSION_NAME "EARLY RELEASE")
-
-    if(EXISTS "${OPENCAD_INCLUDE_DIR}/opencad.h")
-        file(READ "${OPENCAD_INCLUDE_DIR}/opencad.h" OPENCAD_API_H_CONTENTS)
-        string(REGEX MATCH "OCAD_VERSION_MAJOR[ \t]+([0-9]+)"
-          OPENCAD_VERSION_MAJOR ${OPENCAD_API_H_CONTENTS})
-        string (REGEX MATCH "([0-9]+)"
-          OPENCAD_VERSION_MAJOR ${OPENCAD_VERSION_MAJOR})
-        string(REGEX MATCH "OCAD_VERSION_MINOR[ \t]+([0-9]+)"
-          OPENCAD_VERSION_MINOR ${OPENCAD_API_H_CONTENTS})
-        string (REGEX MATCH "([0-9]+)"
-          OPENCAD_VERSION_MINOR ${OPENCAD_VERSION_MINOR})
-
-        string(REGEX MATCH "OCAD_VERSION_REV[ \t]+([0-9]+)"
-          OPENCAD_VERSION_PATCH ${OPENCAD_API_H_CONTENTS})
-        string (REGEX MATCH "([0-9]+)"
-          OPENCAD_VERSION_PATCH ${OPENCAD_VERSION_PATCH})
-
-        unset(OPENCAD_API_H_CONTENTS)
-    endif()
-      
-    set(OPENCAD_VERSION_STRING "${OPENCAD_VERSION_MAJOR}.${OPENCAD_VERSION_MINOR}.${OPENCAD_VERSION_PATCH}")   
-endif ()    
-         
-# Handle the QUIETLY and REQUIRED arguments and set SPATIALINDEX_FOUND to TRUE
-# if all listed variables are TRUE
-include(FindPackageHandleStandardArgs)
-find_package_handle_standard_args(OpenCAD
-                                  FOUND_VAR OPENCAD_FOUND
-                                  REQUIRED_VARS OPENCAD_LIBRARY OPENCAD_INCLUDE_DIR 
-                                  VERSION_VAR OPENCAD_VERSION_STRING)
-
-IF(OPENCAD_FOUND)
-  set(OPENCAD_LIBRARIES ${OPENCAD_LIBRARY})
-  set(OPENCAD_INCLUDE_DIRS ${OPENCAD_INCLUDE_DIR})
-  if(NOT TARGET OpenCAD::opencad)
-      add_library(OpenCAD::opencad UNKNOWN IMPORTED)
-      set_target_properties(OpenCAD::opencad PROPERTIES
-                            INTERFACE_INCLUDE_DIRECTORIES "${OPENCAD_INCLUDE_DIR}"
-                            IMPORTED_LINK_INTERFACE_LANGUAGES C
-                            IMPORTED_LOCATION "${OPENCAD_LIBRARY}")
-  endif()
-ENDIF()
-
-# Hide internal variables
-mark_as_advanced(
-  OPENCAD_INCLUDE_DIR
-  OPENCAD_LIBRARY)
-
-#======================

package/dist/prebuilt/Emscripten-x86_64/lib/cmake/gdal/packages/FindOpenEXR.cmake

@@ -1,125 +0,0 @@
-# Distributed under the OSI-approved BSD 3-Clause License.  See accompanying
-# file Copyright.txt or https://cmake.org/licensing for details.
-
-#.rst:
-# FindOpenEXR
-# -----------
-#
-# CMake module to search for OpenEXR library
-#
-# Copyright (C) 2020, Hiroshi Miura
-#
-# If it's found it sets OpenEXR_FOUND to TRUE
-# and following variables are set:
-#    OpenEXR_INCLUDE_DIRS
-#    OpenEXR_LIBRARIES
-#
-
-if(OpenEXR_ROOT)
-  list(APPEND OpenEXR_INC_HINTS ${OpenEXR_ROOT}/include/OpenEXR)
-  list(APPEND OpenEXR_LIB_HINTS ${OpenEXR_ROOT}/lib)
-  list(APPEND CMAKE_PREFIX_PATH ${OpenEXR_ROOT})
-endif()
-
-if(Imath_ROOT)
-  list(APPEND Imath_INC_HINTS ${Imath_ROOT}/include/Imath)
-  list(APPEND Imath_LIB_HINTS ${Imath_ROOT}/lib)
-  list(APPEND CMAKE_PREFIX_PATH ${Imath_ROOT})
-endif()
-
-find_package(PkgConfig QUIET)
-if (PKG_CONFIG_FOUND)
-  pkg_check_modules(PC_OpenEXR QUIET OpenEXR)
-  if(PC_OpenEXR_FOUND)
-    list(APPEND OpenEXR_LIB_HINTS ${PC_OpenEXR_LIBRARY_DIRS})
-    list(APPEND OpenEXR_INC_HINTS ${PC_OpenEXR_INCLUDE_DIRS})
-    set(OpenEXR_VERSION_STRING ${PC_OpenEXR_VERSION})
-  endif()
-endif ()
-
-find_path(OpenEXR_INCLUDE_DIR
-          NAMES ImfVersion.h
-          HINTS ${OpenEXR_INC_HINTS}
-          PATH_SUFFIXES OpenEXR)
-find_path(Imath_INCLUDE_DIR
-          NAMES ImathMatrix.h
-          HINTS ${Imath_INC_HINTS} ${OpenEXR_INCLUDE_DIR}
-          PATH_SUFFIXES Imath)
-
-if(OpenEXR_INCLUDE_DIR AND NOT OpenEXR_VERSION_STRING)
-  # Fallback for PkgConfig not finding anything
-  file(READ ${OpenEXR_INCLUDE_DIR}/OpenEXRConfig.h txt)
-  string(REGEX MATCH "define[ \t]+OPENEXR_VERSION_STRING[ \t]+\"([0-9]+(.[0-9]+)?(.[0-9]+)?)\".*$" _ ${txt})
-  set(OpenEXR_VERSION_STRING ${CMAKE_MATCH_1})
-endif()
-
-if (OpenEXR_VERSION_STRING VERSION_GREATER_EQUAL 3.0)
-    find_library(OpenEXR_LIBRARY
-                 NAMES OpenEXR
-                 HINTS ${OpenEXR_LIB_HINTS})
-    find_library(OpenEXR_UTIL_LIBRARY
-                 NAMES OpenEXRUtil
-                 HINTS ${OpenEXR_LIB_HINTS})
-    find_library(OpenEXR_HALF_LIBRARY
-                 NAMES Imath
-                 HINTS ${Imath_LIB_HINTS})  #Imath is considered separate since v3
-    find_library(OpenEXR_IEX_LIBRARY
-                 NAMES Iex
-                 HINTS ${OpenEXR_LIB_HINTS})
-else()
-    find_library(OpenEXR_LIBRARY
-                 NAMES IlmImf
-                 HINTS ${OpenEXR_LIB_HINTS})
-    find_library(OpenEXR_UTIL_LIBRARY
-                 NAMES IlmImfUtil
-                 HINTS ${OpenEXR_LIB_HINTS})
-    find_library(OpenEXR_HALF_LIBRARY
-                 NAMES Half
-                 HINTS ${OpenEXR_LIB_HINTS})
-    find_library(OpenEXR_IEX_LIBRARY
-                 NAMES Iex
-                 HINTS ${OpenEXR_LIB_HINTS})
-endif()
-
-mark_as_advanced(OpenEXR_LIBRARY
-                 OpenEXR_UTIL_LIBRARY
-                 OpenEXR_HALF_LIBRARY
-                 OpenEXR_IEX_LIBRARY
-                 OpenEXR_INCLUDE_DIR
-                 Imath_INCLUDE_DIR)
-
-find_package_handle_standard_args(OpenEXR FOUND_VAR OpenEXR_FOUND
-                                  REQUIRED_VARS OpenEXR_LIBRARY
-                                                OpenEXR_UTIL_LIBRARY
-                                                OpenEXR_HALF_LIBRARY
-                                                OpenEXR_IEX_LIBRARY
-                                                OpenEXR_INCLUDE_DIR
-                                                Imath_INCLUDE_DIR
-                                  VERSION_VAR OpenEXR_VERSION_STRING)
-
-if (OpenEXR_FOUND)
-  set(OpenEXR_INCLUDE_DIRS ${OpenEXR_INCLUDE_DIR} ${Imath_INCLUDE_DIR})
-  set(OpenEXR_LIBRARIES ${OpenEXR_LIBRARY} ${OpenEXR_UTIL_LIBRARY} ${OpenEXR_HALF_LIBRARY} ${OpenEXR_IEX_LIBRARY})
-  if (NOT TARGET OpenEXR::OpenEXR)
-    add_library(OpenEXR::IlmImf UNKNOWN IMPORTED)
-    add_library(OpenEXR::IlmImfUtil UNKNOWN IMPORTED)
-    add_library(OpenEXR::Half UNKNOWN IMPORTED)
-    add_library(OpenEXR::Iex UNKNOWN IMPORTED)
-    set_target_properties(OpenEXR::IlmImf  PROPERTIES
-                          INTERFACE_INCLUDE_DIRECTORIES "${OpenEXR_INCLUDE_DIRS}"
-                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                          IMPORTED_LOCATION ${OpenEXR_LIBRARY})
-    set_target_properties(OpenEXR::IlmImfUtil PROPERTIES
-                          INTERFACE_INCLUDE_DIRECTORIES "${OpenEXR_INCLUDE_DIRS}"
-                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                          IMPORTED_LOCATION ${OpenEXR_UTIL_LIBRARY})
-    set_target_properties(OpenEXR::Half PROPERTIES
-                          INTERFACE_INCLUDE_DIRECTORIES "${OpenEXR_INCLUDE_DIRS}"
-                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                          IMPORTED_LOCATION ${OpenEXR_HALF_LIBRARY})
-    set_target_properties(OpenEXR::Iex PROPERTIES
-                          INTERFACE_INCLUDE_DIRECTORIES "${OpenEXR_INCLUDE_DIRS}"
-                          IMPORTED_LINK_INTERFACE_LANGUAGES "C"
-                          IMPORTED_LOCATION ${OpenEXR_IEX_LIBRARY})
-  endif ()
-endif ()