@cloudnux/cli 0.1.0

package/.deploy/aws/http/main.tf

@@ -0,0 +1,35 @@
+data "aws_apigatewayv2_api" "this" {
+  api_id = var.api_gateway_id
+}
+
+resource "aws_apigatewayv2_route" "this" {
+  for_each = var.entrypoints
+
+  api_id    = var.api_gateway_id
+  route_key = "${upper(each.value.method)} ${each.value.path}"
+
+  authorization_type = try(each.value.authorization_type, "NONE")
+  authorizer_id      = try(each.value.authorizer_id, null)
+
+  operation_name = each.key
+  target         = "integrations/${aws_apigatewayv2_integration.this[each.key].id}"
+}
+
+resource "aws_apigatewayv2_integration" "this" {
+  for_each = var.entrypoints
+
+  api_id      = var.api_gateway_id
+  description = try(each.value.description, null)
+
+  integration_type   = "AWS_PROXY"
+  integration_method = "POST"
+  integration_uri    = var.lambda_arn
+  connection_type    = "INTERNET"
+
+  payload_format_version = "2.0"
+  timeout_milliseconds   = try(each.value.timeout, null)
+
+  lifecycle {
+    create_before_destroy = true
+  }
+}

package/.deploy/aws/http/variables.tf

@@ -0,0 +1,22 @@
+variable "entrypoints" {
+  type = map(object({
+    description        = string
+    method             = string
+    path               = string
+    timeout            = optional(number, 29000)
+    authorization_type = optional(string, "NONE")
+    authorizer_id      = optional(string)
+  }))
+}
+
+variable "lambda_name" {
+  type = string
+}
+
+variable "lambda_arn" {
+  type = string
+}
+
+variable "api_gateway_id" {
+  type = string
+}

package/.deploy/aws/scheduler/main.tf

@@ -0,0 +1,47 @@
+data "aws_iam_role" "eventbridge_role" {
+  name = "eventbridge_execution_role"
+}
+
+resource "aws_scheduler_schedule_group" "this" {
+
+  name = var.component
+
+  lifecycle {
+    create_before_destroy = true
+  }
+}
+
+
+resource "aws_scheduler_schedule" "this" {
+  for_each = var.schedules
+
+  name        = each.value.name
+  description = try(each.value.description, null)
+  group_name  = aws_scheduler_schedule_group.this.name
+
+  schedule_expression          = each.value.pattern
+  schedule_expression_timezone = try(each.value.timezone, "UTC")
+
+  state = try(each.value.state, "ENABLED")
+
+  flexible_time_window {
+    maximum_window_in_minutes = lookup(each.value, "maximum_window_in_minutes", null)
+    mode                      = lookup(each.value, "use_flexible_time_window", false) ? "FLEXIBLE" : "OFF"
+  }
+
+  target {
+    arn      = var.target_arn
+    role_arn = data.aws_iam_role.eventbridge_role.arn
+
+    dynamic "retry_policy" {
+      for_each = lookup(each.value, "retry_policy", null) != null ? [
+        each.value.retry_policy
+      ] : []
+
+      content {
+        maximum_event_age_in_seconds = retry_policy.value.maximum_event_age_in_seconds
+        maximum_retry_attempts       = retry_policy.value.maximum_retry_attempts
+      }
+    }
+  }
+}

package/.deploy/aws/scheduler/variables.tf

@@ -0,0 +1,21 @@
+variable "schedules" {
+  description = "A map of objects with EventBridge Schedule definitions."
+  type = map(object({
+    name                      = string
+    pattern                   = string
+    description               = optional(string)
+    timezone                  = optional(string, "Europe/Stockholm")
+    state                     = optional(string, "ENABLED")
+    use_flexible_time_window  = optional(bool, false)
+    maximum_window_in_minutes = optional(number)
+  }))
+}
+variable "component" {
+  description = "The name of the component."
+  type        = string
+}
+
+variable "target_arn" {
+  description = "The ARN of the Lambda function."
+  type        = string
+}

package/.deploy/aws/sqs/main.tf

@@ -0,0 +1,38 @@
+# SQS Trigger Module - main.tf
+
+data "aws_sqs_queue" "this" {
+  for_each = var.event_sources
+  name     = each.value.queue_name
+}
+
+data "aws_sqs_queue" "dlq" {
+  for_each = var.event_sources
+  name     = "${each.value.queue_name}-dlq"
+}
+
+resource "aws_lambda_event_source_mapping" "sqs" {
+  for_each = var.event_sources
+
+  event_source_arn = data.aws_sqs_queue.this[each.key].arn
+  function_name    = var.lambda_name
+  enabled          = try(each.value.enabled, true)
+
+  # SQS specific configurations
+  batch_size                         = try(each.value.batch_size, 10)
+  maximum_batching_window_in_seconds = try(each.value.maximum_batching_window_in_seconds, null)
+
+  lifecycle {
+    create_before_destroy = true
+  }
+}
+
+# # Grant Lambda permission to be invoked by SQS
+# resource "aws_lambda_permission" "allow_sqs" {
+#   for_each = var.event_sources
+
+#   statement_id  = "AllowExecutionFromSQS-${each.key}"
+#   action        = "lambda:InvokeFunction"
+#   function_name = var.lambda_name
+#   principal     = "sqs.amazonaws.com"
+#   source_arn    = data.aws_sqs_queue.this[each.key].arn
+# }

package/.deploy/aws/sqs/variables.tf

@@ -0,0 +1,27 @@
+variable "event_sources" {
+  description = "Map of SQS event source configurations"
+  type = map(object({
+    queue_name                         = string
+    enabled                            = optional(bool, true)
+    batch_size                         = optional(number, 10)
+    maximum_batching_window_in_seconds = optional(number)
+    function_response_types            = optional(list(string))
+
+    # Scaling configuration
+    scaling_config = optional(object({
+      maximum_concurrency = number
+    }))
+  }))
+
+  validation {
+    condition = alltrue([
+      for k, v in var.event_sources : v.batch_size >= 1 && v.batch_size <= 10000
+    ])
+    error_message = "Batch size must be between 1 and 10000."
+  }
+}
+
+variable "lambda_name" {
+  description = "Name of the Lambda function"
+  type        = string
+}

package/dist/cli.d.ts

@@ -0,0 +1,2 @@
+
+export {  }