@buildautomaton/cli 0.1.54 → 0.1.55

package/dist/migrations/004_code_nav_symbol_index.sql

@@ -0,0 +1,23 @@
+CREATE TABLE IF NOT EXISTS symbol_index_parent_path (
+  id INTEGER PRIMARY KEY AUTOINCREMENT,
+  path TEXT NOT NULL UNIQUE,
+  path_hash TEXT NOT NULL,
+  updated_at TEXT NOT NULL
+);
+
+CREATE TABLE IF NOT EXISTS symbol_index_tag (
+  parent_id INTEGER NOT NULL,
+  file_path TEXT NOT NULL,
+  name TEXT NOT NULL,
+  role TEXT NOT NULL,
+  kind TEXT NOT NULL,
+  start_line INTEGER NOT NULL,
+  start_column INTEGER NOT NULL,
+  end_line INTEGER NOT NULL,
+  end_column INTEGER NOT NULL,
+  PRIMARY KEY (parent_id, file_path, start_line, start_column, role, kind, name),
+  FOREIGN KEY (parent_id) REFERENCES symbol_index_parent_path(id) ON DELETE CASCADE
+);
+
+CREATE INDEX IF NOT EXISTS idx_symbol_index_tag_parent_name ON symbol_index_tag(parent_id, name);
+CREATE INDEX IF NOT EXISTS idx_symbol_index_tag_parent_file ON symbol_index_tag(parent_id, file_path);

package/dist/migrations/005_code_nav_index_version.sql

@@ -0,0 +1 @@
+ALTER TABLE symbol_index_parent_path ADD COLUMN index_version INTEGER NOT NULL DEFAULT 1;

package/dist/migrations/006_drop_cache_tables.sql

@@ -0,0 +1,5 @@
+DROP INDEX IF EXISTS idx_file_index_child_path_parent;
+DROP TABLE IF EXISTS file_index_child_path;
+DROP TABLE IF EXISTS file_index_parent_path;
+DROP INDEX IF EXISTS idx_file_index_path_cwd;
+DROP TABLE IF EXISTS file_index_path;

package/dist/tree-sitter/tree-sitter-c/tags.scm

@@ -0,0 +1,32 @@
+(struct_specifier name: (type_identifier) @name body:(_)) @definition.class
+
+(declaration type: (union_specifier name: (type_identifier) @name)) @definition.class
+
+(function_declarator declarator: (identifier) @name) @definition.function
+
+(type_definition declarator: (type_identifier) @name) @definition.type
+
+(enum_specifier name: (type_identifier) @name) @definition.type
+
+(parameter_declaration
+  declarator: (identifier) @name) @definition.parameter
+
+(declaration
+  declarator: (init_declarator
+    declarator: (identifier) @name)) @definition.variable
+
+(preproc_include
+  path: (string_literal) @name) @reference.module
+
+(call_expression
+  function: (identifier) @name) @reference.call
+
+(type_identifier) @name @reference.type
+
+[
+  (binary_expression left: (identifier) @name)
+  (binary_expression right: (identifier) @name)
+  (return_statement (identifier) @name)
+  (argument_list (identifier) @name)
+  (assignment_expression right: (identifier) @name)
+] @reference.variable

package/dist/tree-sitter/tree-sitter-cpp/tags.scm

@@ -0,0 +1,51 @@
+(struct_specifier name: (type_identifier) @name body:(_)) @definition.class
+
+(declaration type: (union_specifier name: (type_identifier) @name)) @definition.class
+
+(function_declarator declarator: (identifier) @name) @definition.function
+
+(function_declarator declarator: (field_identifier) @name) @definition.function
+
+(function_declarator declarator: (qualified_identifier scope: (namespace_identifier) @local.scope name: (identifier) @name)) @definition.method
+
+(type_definition declarator: (type_identifier) @name) @definition.type
+
+(enum_specifier name: (type_identifier) @name) @definition.type
+
+(class_specifier name: (type_identifier) @name) @definition.class
+
+(type_parameter_declaration
+  (type_parameter
+    name: (type_identifier) @name)) @definition.type
+
+(template_type_parameter
+  name: (type_identifier) @name) @definition.type
+
+(parameter_declaration
+  declarator: (identifier) @name) @definition.parameter
+
+(declaration
+  declarator: (init_declarator
+    declarator: (identifier) @name)) @definition.variable
+
+(preproc_include
+  path: (string_literal) @name) @reference.module
+
+(namespace_definition
+  name: (namespace_identifier) @name) @definition.module
+
+(call_expression
+  function: (identifier) @name) @reference.call
+
+(type_identifier) @name @reference.type
+
+(template_argument
+  (type_identifier) @name) @reference.type
+
+[
+  (binary_expression left: (identifier) @name)
+  (binary_expression right: (identifier) @name)
+  (return_statement (identifier) @name)
+  (argument_list (identifier) @name)
+  (assignment_expression right: (identifier) @name)
+] @reference.variable

package/dist/tree-sitter/tree-sitter-go/tags.scm

@@ -0,0 +1,64 @@
+(
+  (comment)* @doc
+  .
+  (function_declaration
+    name: (identifier) @name) @definition.function
+  (#strip! @doc "^//\\s*")
+  (#set-adjacent! @doc @definition.function)
+)
+
+(
+  (comment)* @doc
+  .
+  (method_declaration
+    name: (field_identifier) @name) @definition.method
+  (#strip! @doc "^//\\s*")
+  (#set-adjacent! @doc @definition.method)
+)
+
+(type_spec
+  name: (type_identifier) @name) @definition.type
+
+(type_parameter_declaration
+  (type_identifier) @name) @definition.type
+
+(type_identifier) @name @reference.type
+
+(call_expression
+  function: [
+    (identifier) @name
+    (parenthesized_expression (identifier) @name)
+  ]) @reference.call
+
+(import_declaration
+  (import_spec
+    path: (interpreted_string_literal) @name)) @reference.module
+
+(import_declaration
+  (import_spec
+    name: (package_identifier) @name)) @reference.import
+
+(var_declaration
+  (var_spec
+    name: (identifier) @name)) @definition.variable
+
+(const_declaration
+  (const_spec
+    name: (identifier) @name)) @definition.constant
+
+(short_var_declaration
+  left: (expression_list (identifier) @name)) @definition.variable
+
+(parameter_declaration
+  (identifier) @name) @definition.parameter
+
+[
+  (binary_expression left: (identifier) @name)
+  (binary_expression right: (identifier) @name)
+  (return_statement (identifier) @name)
+  (argument_list (identifier) @name)
+  (assignment_statement left: (expression_list (identifier) @name))
+  (inc_statement (identifier) @name)
+  (dec_statement (identifier) @name)
+  (range_clause left: (expression_list (identifier) @name))
+] @reference.variable

package/dist/tree-sitter/tree-sitter-java/tags.scm

@@ -0,0 +1,52 @@
+(class_declaration
+  name: (identifier) @name) @definition.class
+
+(method_declaration
+  name: (identifier) @name) @definition.method
+
+(formal_parameters
+  (formal_parameter
+    name: (identifier) @name)) @definition.parameter
+
+(local_variable_declaration
+  declarator: (variable_declarator
+    name: (identifier) @name)) @definition.variable
+
+(field_declaration
+  declarator: (variable_declarator
+    name: (identifier) @name)) @definition.variable
+
+(interface_declaration
+  name: (identifier) @name) @definition.interface
+
+(type_parameter
+  (type_identifier) @name) @definition.type
+
+(import_declaration
+  (scoped_identifier) @name) @reference.import
+
+(import_declaration
+  (identifier) @name) @reference.import
+
+(method_invocation
+  name: (identifier) @name
+  arguments: (argument_list)) @reference.call
+
+(type_list
+  (type_identifier) @name) @reference.implementation
+
+(object_creation_expression
+  type: (type_identifier) @name) @reference.class
+
+(superclass (type_identifier) @name) @reference.class
+
+(type_identifier) @name @reference.type
+
+[
+  (assignment_expression left: (identifier) @name)
+  (assignment_expression right: (identifier) @name)
+  (return_statement (identifier) @name)
+  (argument_list (identifier) @name)
+  (binary_expression left: (identifier) @name)
+  (binary_expression right: (identifier) @name)
+] @reference.variable

package/dist/tree-sitter/tree-sitter-javascript/tags.scm

@@ -0,0 +1,143 @@
+(
+  (comment)* @doc
+  .
+  (method_definition
+    name: (property_identifier) @name) @definition.method
+  (#not-eq? @name "constructor")
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.method)
+)
+
+(
+  (comment)* @doc
+  .
+  [
+    (class
+      name: (_) @name)
+    (class_declaration
+      name: (_) @name)
+  ] @definition.class
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.class)
+)
+
+(
+  (comment)* @doc
+  .
+  [
+    (function_expression
+      name: (identifier) @name)
+    (function_declaration
+      name: (identifier) @name)
+    (generator_function
+      name: (identifier) @name)
+    (generator_function_declaration
+      name: (identifier) @name)
+  ] @definition.function
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.function)
+)
+
+(
+  (comment)* @doc
+  .
+  (lexical_declaration
+    (variable_declarator
+      name: (identifier) @name
+      value: [(arrow_function) (function_expression)]) @definition.function)
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.function)
+)
+
+(
+  (comment)* @doc
+  .
+  (variable_declaration
+    (variable_declarator
+      name: (identifier) @name
+      value: [(arrow_function) (function_expression)]) @definition.function)
+  (#strip! @doc "^[\\s\\*/]+|^[\\s\\*/]$")
+  (#select-adjacent! @doc @definition.function)
+)
+
+(assignment_expression
+  left: [
+    (identifier) @name
+  ]
+  right: [(arrow_function) (function_expression)]
+) @definition.function
+
+(pair
+  key: (property_identifier) @name
+  value: [(arrow_function) (function_expression)]) @definition.function
+
+(lexical_declaration
+  (variable_declarator
+    name: (identifier) @name)) @definition.variable
+
+(variable_declaration
+  (variable_declarator
+    name: (identifier) @name)) @definition.variable
+
+(formal_parameters
+  (identifier) @name) @definition.parameter
+
+(
+  (call_expression
+    function: (identifier) @name) @reference.call
+  (#not-match? @name "^(require)$")
+)
+
+(new_expression
+  constructor: (_) @name) @reference.class
+
+(import_statement
+  source: (string
+    (string_fragment) @name)) @reference.module
+
+(import_clause
+  (identifier) @name) @reference.import
+
+(namespace_import
+  (identifier) @name) @reference.import
+
+(import_specifier
+  name: (identifier) @name) @reference.import
+
+(import_specifier
+  alias: (identifier) @name) @reference.import
+
+(export_statement
+  source: (string
+    (string_fragment) @name)) @reference.module
+
+[
+  (binary_expression left: (identifier) @name)
+  (binary_expression right: (identifier) @name)
+  (unary_expression (identifier) @name)
+  (return_statement (identifier) @name)
+  (array (identifier) @name)
+  (arguments (identifier) @name)
+  (variable_declarator value: (identifier) @name)
+  (assignment_expression right: (identifier) @name)
+  (pair value: (identifier) @name)
+  (await_expression (identifier) @name)
+  (yield_expression (identifier) @name)
+  (subscript_expression object: (identifier) @name)
+  (shorthand_property_identifier) @name
+  (ternary_expression condition: (identifier) @name)
+  (ternary_expression consequence: (identifier) @name)
+  (ternary_expression alternative: (identifier) @name)
+  (template_substitution (identifier) @name)
+] @reference.variable
+
+(export_statement value: (assignment_expression left: (identifier) @name right: ([
+ (number)
+ (string)
+ (identifier)
+ (undefined)
+ (null)
+ (new_expression)
+ (binary_expression)
+ (call_expression)
+]))) @definition.constant

package/dist/tree-sitter/tree-sitter-python/tags.scm

@@ -0,0 +1,39 @@
+(module (expression_statement (assignment left: (identifier) @name) @definition.constant))
+
+(class_definition
+  name: (identifier) @name) @definition.class
+
+(function_definition
+  name: (identifier) @name) @definition.function
+
+(parameters
+  (identifier) @name) @definition.parameter
+
+(assignment
+  left: (identifier) @name) @definition.variable
+
+(import_statement
+  name: (dotted_name) @name) @reference.module
+
+(import_from_statement
+  module_name: (dotted_name) @name) @reference.module
+
+(import_from_statement
+  name: (dotted_name) @name) @reference.import
+
+(call
+  function: (identifier) @name) @reference.call
+
+[
+  (binary_operator left: (identifier) @name)
+  (binary_operator right: (identifier) @name)
+  (return_statement (identifier) @name)
+  (argument_list (identifier) @name)
+  (assignment right: (identifier) @name)
+  (subscript value: (identifier) @name)
+  (comparison_operator (identifier) @name)
+  (conditional_expression (identifier) @name)
+] @reference.variable
+
+(type
+  (identifier) @name) @reference.type

package/dist/tree-sitter/tree-sitter-ruby/tags.scm

@@ -0,0 +1,73 @@
+(
+  (comment)* @doc
+  .
+  [
+    (method
+      name: (_) @name) @definition.method
+    (singleton_method
+      name: (_) @name) @definition.method
+  ]
+  (#strip! @doc "^#\\s*")
+  (#select-adjacent! @doc @definition.method)
+)
+
+(alias
+  name: (_) @name) @definition.method
+
+(setter
+  (identifier) @ignore)
+
+(
+  (comment)* @doc
+  .
+  [
+    (class
+      name: [
+        (constant) @name
+        (scope_resolution
+          name: (_) @name)
+      ]) @definition.class
+    (singleton_class
+      value: [
+        (constant) @name
+        (scope_resolution
+          name: (_) @name)
+      ]) @definition.class
+  ]
+  (#strip! @doc "^#\\s*")
+  (#select-adjacent! @doc @definition.class)
+)
+
+(
+  (module
+    name: [
+      (constant) @name
+      (scope_resolution
+        name: (_) @name)
+    ]) @definition.module
+)
+
+(call method: (identifier) @name) @reference.call
+
+(
+  [(identifier) (constant)] @name @reference.call
+  (#is-not? local)
+  (#not-match? @name "^(lambda|load|require|require_relative|__FILE__|__LINE__)$")
+)
+
+(call
+  arguments: (argument_list (identifier) @name)) @reference.variable
+
+(assignment
+  left: (identifier) @name) @definition.variable
+
+(parameters
+  (identifier) @name) @definition.parameter
+
+[
+  (binary left: (identifier) @name)
+  (binary right: (identifier) @name)
+  (return (identifier) @name)
+  (unless (identifier) @name)
+  (if (identifier) @name)
+] @reference.variable

package/dist/tree-sitter/tree-sitter-rust/tags.scm

@@ -0,0 +1,71 @@
+(struct_item
+  name: (type_identifier) @name) @definition.class
+
+(enum_item
+  name: (type_identifier) @name) @definition.class
+
+(union_item
+  name: (type_identifier) @name) @definition.class
+
+(type_item
+  name: (type_identifier) @name) @definition.class
+
+(type_parameters
+  (type_parameter
+    name: (type_identifier) @name)) @definition.type
+
+(declaration_list
+  (function_item
+    name: (identifier) @name)) @definition.method
+
+(function_item
+  name: (identifier) @name) @definition.function
+
+(trait_item
+  name: (type_identifier) @name) @definition.interface
+
+(mod_item
+  name: (identifier) @name) @definition.module
+
+(macro_definition
+  name: (identifier) @name) @definition.macro
+
+(use_declaration
+  argument: (identifier) @name) @reference.import
+
+(use_declaration
+  argument: (scoped_identifier
+    name: (identifier) @name)) @reference.import
+
+(call_expression
+  function: (identifier) @name) @reference.call
+
+(macro_invocation
+  macro: (identifier) @name) @reference.call
+
+(impl_item
+  trait: (type_identifier) @name) @reference.implementation
+
+(impl_item
+  type: (type_identifier) @name
+  !trait) @reference.implementation
+
+(type_arguments
+  (type_identifier) @name) @reference.type
+
+(generic_type
+  type: (type_identifier) @name) @reference.type
+
+[
+  (binary_expression left: (identifier) @name)
+  (binary_expression right: (identifier) @name)
+  (unary_expression (identifier) @name)
+  (return_expression (identifier) @name)
+  (arguments (identifier) @name)
+  (assignment_expression left: (identifier) @name)
+  (let_declaration pattern: (identifier) @name)
+] @reference.variable
+
+(parameters
+  (parameter
+    pattern: (identifier) @name)) @definition.parameter

package/dist/tree-sitter/tree-sitter-typescript/tags.scm

@@ -0,0 +1,96 @@
+(function_signature
+  name: (identifier) @name) @definition.function
+
+(method_signature
+  name: (property_identifier) @name) @definition.method
+
+(abstract_method_signature
+  name: (property_identifier) @name) @definition.method
+
+(abstract_class_declaration
+  name: (type_identifier) @name) @definition.class
+
+(module
+  name: (identifier) @name) @definition.module
+
+(interface_declaration
+  name: (type_identifier) @name) @definition.interface
+
+(type_parameter
+  name: (type_identifier) @name) @definition.type
+
+(type_annotation
+  (type_identifier) @name) @reference.type
+
+(type_predicate
+  (identifier) @name) @reference.variable
+
+(new_expression
+  constructor: (identifier) @name) @reference.class
+
+(function_declaration
+  name: (identifier) @name) @definition.function
+
+(class_declaration
+  name: (type_identifier) @name) @definition.class
+
+(type_alias_declaration
+  name: (type_identifier) @name) @definition.type
+
+(enum_declaration
+  name: (identifier) @name) @definition.enum
+
+(lexical_declaration
+  (variable_declarator
+    name: (identifier) @name)) @definition.variable
+
+(variable_declaration
+  (variable_declarator
+    name: (identifier) @name)) @definition.variable
+
+(required_parameter
+  (identifier) @name) @definition.parameter
+
+(optional_parameter
+  (identifier) @name) @definition.parameter
+
+(call_expression
+  function: (identifier) @name) @reference.call
+
+(import_statement
+  source: (string
+    (string_fragment) @name)) @reference.module
+
+(import_clause
+  (identifier) @name) @reference.import
+
+(namespace_import
+  (identifier) @name) @reference.import
+
+(import_specifier
+  name: (identifier) @name) @reference.import
+
+(import_specifier
+  alias: (identifier) @name) @reference.import
+
+[
+  (binary_expression left: (identifier) @name)
+  (binary_expression right: (identifier) @name)
+  (unary_expression (identifier) @name)
+  (return_statement (identifier) @name)
+  (array (identifier) @name)
+  (arguments (identifier) @name)
+  (variable_declarator value: (identifier) @name)
+  (assignment_expression right: (identifier) @name)
+  (pair value: (identifier) @name)
+  (await_expression (identifier) @name)
+  (yield_expression (identifier) @name)
+  (subscript_expression object: (identifier) @name)
+  (shorthand_property_identifier) @name
+  (ternary_expression condition: (identifier) @name)
+  (ternary_expression consequence: (identifier) @name)
+  (ternary_expression alternative: (identifier) @name)
+  (template_substitution (identifier) @name)
+  (non_null_expression (identifier) @name)
+  (as_expression (identifier) @name)
+] @reference.variable