@bloxchain/contracts 1.0.0-alpha.6 → 1.0.0

package/core/research/FactoryBlox/FactoryBlox.sol

@@ -1,346 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.33;
-
-import "@openzeppelin/contracts/proxy/Clones.sol";
-import "@openzeppelin/contracts/utils/introspection/ERC165Checker.sol";
-import "@openzeppelin/contracts/utils/structs/EnumerableSet.sol";
-import "../../execution/GuardController.sol";
-import "../../access/RuntimeRBAC.sol";
-import "../../security/SecureOwnable.sol";
-import "../../base/interface/IBaseStateMachine.sol";
-import "../../lib/EngineBlox.sol";
-import "../ICopyable.sol";
-import "../../lib/interfaces/IDefinition.sol";
-import "../../lib/interfaces/IEventForwarder.sol";
-import "../../lib/utils/SharedValidation.sol";
-import "./FactoryBloxDefinitions.sol";
-
-/**
- * @title FactoryBlox
- * @dev CopyBlox-style blox factory with RBAC and GuardController like AccountBlox
- *
- * Combines:
- * - GuardController: Execution workflows and time-locked transactions
- * - RuntimeRBAC: Runtime role creation and management
- * - SecureOwnable: Secure ownership transfer and management
- * - Clone factory: Clone blox contracts (EIP-1167) with RBAC-protected cloneBlox
- * - IEventForwarder: Centralize events from clones
- *
- * Only wallets with clone permission (OWNER_ROLE by default; custom roles via RuntimeRBAC)
- * can call cloneBlox. Clones are initialized with eventForwarder set to this contract.
- * When initData is non-empty, the implementation must support ICopyable and is initialized
- * via initializeWithData; otherwise initialize(address,address,address,uint256,address) is used.
- *
- * clonesWhitelist: lightweight set of trusted blox implementation addresses. Only addresses in the
- * whitelist can be cloned via cloneBlox, giving certainty about deploying the same contract.
- * addToWhitelist and removeFromWhitelist are controller-only (macro + _validateExecuteBySelf).
- */
-contract FactoryBlox is GuardController, RuntimeRBAC, SecureOwnable, IEventForwarder {
-    using Clones for address;
-    using ERC165Checker for address;
-    using EnumerableSet for EnumerableSet.AddressSet;
-
-    /// @dev Reverted when a cloneBlox request-with-payment has payment details that do not match clonePrice
-    error ClonePriceMismatch();
-
-    EnumerableSet.AddressSet private _clones;
-    /// @dev Trusted blox implementation addresses; only these can be cloned via cloneBlox
-    EnumerableSet.AddressSet private _clonesWhitelist;
-    /// @notice Whitelist entry containing implementation address and its configured clone price
-    struct CloneWhitelistEntry {
-        address bloxImplementation;
-        EngineBlox.PaymentDetails price;
-    }
-
-    /// @dev Per-implementation clone pricing configuration
-    mapping(address => EngineBlox.PaymentDetails) private _clonePrices;
-
-    /**
-     * @notice Initializer for FactoryBlox
-     */
-    function initialize(
-        address initialOwner,
-        address broadcaster,
-        address recovery,
-        uint256 timeLockPeriodSec,
-        address eventForwarder
-    ) public virtual override(GuardController, RuntimeRBAC, SecureOwnable) initializer {
-        GuardController.initialize(initialOwner, broadcaster, recovery, timeLockPeriodSec, eventForwarder);
-        RuntimeRBAC.initialize(initialOwner, broadcaster, recovery, timeLockPeriodSec, eventForwarder);
-        SecureOwnable.initialize(initialOwner, broadcaster, recovery, timeLockPeriodSec, eventForwarder);
-
-        IDefinition.RolePermission memory factoryPermissions = FactoryBloxDefinitions.getRolePermissions();
-        _loadDefinitions(
-            FactoryBloxDefinitions.getFunctionSchemas(),
-            factoryPermissions.roleHashes,
-            factoryPermissions.functionPermissions,
-            true
-        );
-
-        // Register macro selectors so controller can target address(this) for time-lock/meta-tx execution
-        _addMacroSelector(FactoryBloxDefinitions.CLONE_BLOX_SELECTOR);
-        _addMacroSelector(FactoryBloxDefinitions.ADD_TO_WHITELIST_SELECTOR);
-        _addMacroSelector(FactoryBloxDefinitions.REMOVE_FROM_WHITELIST_SELECTOR);
-
-        // Allow cloning this factory's implementation (or proxy) by default
-        _clonesWhitelist.add(address(this));
-    }
-
-    function supportsInterface(bytes4 interfaceId)
-        public
-        view
-        virtual
-        override(GuardController, RuntimeRBAC, SecureOwnable)
-        returns (bool)
-    {
-        return interfaceId == type(IEventForwarder).interfaceId
-            || GuardController.supportsInterface(interfaceId)
-            || RuntimeRBAC.supportsInterface(interfaceId)
-            || SecureOwnable.supportsInterface(interfaceId);
-    }
-
-    /**
-     * @notice Clone a blox contract (RBAC-protected). Caller must have clone permission (e.g. OWNER_ROLE).
-     * @param initData When non-empty, target must implement ICopyable and is initialized via initializeWithData; otherwise standard initialize(...) is used.
-     */
-    function cloneBlox(
-        address bloxAddress,
-        address initialOwner,
-        address broadcaster,
-        address recovery,
-        uint256 timeLockPeriodSec,
-        bytes calldata initData
-    ) external nonReentrant returns (address cloneAddress) {
-        _validateExecuteBySelf();
-        _validateBloxImplementation(bloxAddress);
-
-        if (initData.length > 0 && !bloxAddress.supportsInterface(type(ICopyable).interfaceId)) {
-            revert SharedValidation.InvalidOperation(bloxAddress);
-        }
-        if (!_clonesWhitelist.contains(bloxAddress)) {
-            revert SharedValidation.InvalidOperation(bloxAddress);
-        }
-
-        cloneAddress = Clones.clone(bloxAddress);
-        address eventForwarder = address(this);
-        bool success;
-
-        if (initData.length > 0) {
-            success = _initializeCloneWithData(
-                cloneAddress,
-                initialOwner,
-                broadcaster,
-                recovery,
-                timeLockPeriodSec,
-                eventForwarder,
-                initData
-            );
-        } else {
-            success = _initializeClone(
-                cloneAddress,
-                initialOwner,
-                broadcaster,
-                recovery,
-                timeLockPeriodSec,
-                eventForwarder
-            );
-        }
-
-        if (!success) revert SharedValidation.OperationFailed();
-
-        _clones.add(cloneAddress);
-        _logComponentEvent(abi.encode(bloxAddress, cloneAddress, initialOwner, _clones.length()));
-        return cloneAddress;
-    }
-
-    /**
-     * @notice Add a trusted blox implementation to the whitelist with an associated clone price.
-     *         Only callable by the controller (macro + _validateExecuteBySelf).
-     * @param bloxImplementation Address of the blox implementation contract (must be IBaseStateMachine, not zero, not this).
-     * @param price Per-clone payment configuration for this implementation.
-     */
-    function addToWhitelist(address bloxImplementation, EngineBlox.PaymentDetails calldata price) external nonReentrant {
-        _validateExecuteBySelf();
-        _validateBloxImplementation(bloxImplementation);  
-        if (_clonesWhitelist.add(bloxImplementation)) {
-            _clonePrices[bloxImplementation] = price;
-            _logComponentEvent(
-                abi.encode(
-                    bloxImplementation,
-                    price.recipient,
-                    price.nativeTokenAmount,
-                    price.erc20TokenAddress,
-                    price.erc20TokenAmount
-                )
-            );
-        }
-    }
-
-    /**
-     * @notice Remove a blox implementation from the whitelist. Only callable by the controller (macro + _validateExecuteBySelf).
-     * @param bloxImplementation Address to remove from the whitelist.
-     */
-    function removeFromWhitelist(address bloxImplementation) external nonReentrant {
-        _validateExecuteBySelf();
-        if (_clonesWhitelist.remove(bloxImplementation)) {
-            // Clear any configured price for the removed implementation
-            delete _clonePrices[bloxImplementation];
-            _logComponentEvent(abi.encode(bloxImplementation));
-        }
-    }
-
-    /**
-     * @dev Validates that an address is a deployed contract implementing IBaseStateMachine.
-     */
-    function _validateBloxImplementation(address bloxAddress) internal view {
-        if (!bloxAddress.supportsInterface(type(IBaseStateMachine).interfaceId)) {
-            revert SharedValidation.InvalidOperation(bloxAddress);
-        }
-    }
-
-    function _initializeClone(
-        address cloneAddress,
-        address initialOwner,
-        address broadcaster,
-        address recovery,
-        uint256 timeLockPeriodSec,
-        address eventForwarder
-    ) internal returns (bool) {
-        (bool success, ) = cloneAddress.call(
-            abi.encodeWithSignature(
-                "initialize(address,address,address,uint256,address)",
-                initialOwner,
-                broadcaster,
-                recovery,
-                timeLockPeriodSec,
-                eventForwarder
-            )
-        );
-        return success;
-    }
-
-    function _initializeCloneWithData(
-        address cloneAddress,
-        address initialOwner,
-        address broadcaster,
-        address recovery,
-        uint256 timeLockPeriodSec,
-        address eventForwarder,
-        bytes calldata initData
-    ) internal returns (bool) {
-        (bool success, ) = cloneAddress.call(
-            abi.encodeWithSignature(
-                "initializeWithData(address,address,address,uint256,address,bytes)",
-                initialOwner,
-                broadcaster,
-                recovery,
-                timeLockPeriodSec,
-                eventForwarder,
-                initData
-            )
-        );
-        return success;
-    }
-
-    function getCloneAtIndex(uint256 index) external view returns (address) {
-        return _clones.at(index);
-    }
-
-    function isClone(address cloneAddress) external view returns (bool) {
-        return _clones.contains(cloneAddress);
-    }
-
-    function getClonesCount() external view returns (uint256) {
-        return _clones.length();
-    }
-
-    function getWhitelistCount() external view returns (uint256) {
-        return _clonesWhitelist.length();
-    }
-
-    // function getWhitelistAtIndex(uint256 index) external view returns (address) {
-    //     return _clonesWhitelist.at(index);
-    // }
-
-    function isWhitelisted(address bloxImplementation) external view returns (bool) {
-        return _clonesWhitelist.contains(bloxImplementation);
-    }
-
-    // /**
-    //  * @notice Returns the configured clone price for a given blox implementation.
-    //  * @dev Zero-valued fields indicate no explicit pricing (free clone) for this implementation.
-    //  */
-    // function getClonePrice(address bloxImplementation) external view returns (EngineBlox.PaymentDetails memory) {
-    //     return _clonePrices[bloxImplementation];
-    // }
-
-    /**
-     * @notice Returns whitelist entry (implementation + price) at a given index.
-     */
-    function getWhitelistEntryAtIndex(uint256 index) external view returns (CloneWhitelistEntry memory) {
-        address bloxImplementation = _clonesWhitelist.at(index);
-        return CloneWhitelistEntry({ bloxImplementation: bloxImplementation, price: _clonePrices[bloxImplementation] });
-    }
-
-    /**
-     * @dev Post-action hook: when cloneBlox was requested with payment, verify the tx payment matches
-     *      the configured per-implementation clone price. Ensures the requestor did not alter the payment
-     *      (e.g. recipient or amounts). Only runs when TxStatus is COMPLETED (e.g. not on cancellation
-     *      or failed execution).
-     */
-    function _postActionHook(EngineBlox.TxRecord memory txRecord) internal virtual override {
-        if (txRecord.params.executionSelector != FactoryBloxDefinitions.CLONE_BLOX_SELECTOR) {
-            return;
-        }
-        if (txRecord.status != EngineBlox.TxStatus.COMPLETED) {
-            return;
-        }
-
-        // Decode the blox implementation address from execution params:
-        // cloneBlox(address bloxAddress, address initialOwner, address broadcaster, address recovery, uint256 timeLockPeriodSec, bytes initData)
-        (address bloxImplementation, , , , , ) = abi.decode(
-            txRecord.params.executionParams,
-            (address, address, address, address, uint256, bytes)
-        );
-
-        EngineBlox.PaymentDetails memory expectedPrice = _clonePrices[bloxImplementation];
-        EngineBlox.PaymentDetails memory payment = txRecord.payment;
-
-        if (
-            payment.recipient != expectedPrice.recipient
-            || payment.nativeTokenAmount != expectedPrice.nativeTokenAmount
-            || payment.erc20TokenAddress != expectedPrice.erc20TokenAddress
-            || payment.erc20TokenAmount != expectedPrice.erc20TokenAmount
-        ) {
-            revert ClonePriceMismatch();
-        }
-    }
-
-    function forwardTxEvent(
-        uint256 txId,
-        bytes4 functionSelector,
-        EngineBlox.TxStatus status,
-        address requester,
-        address target,
-        bytes32 operationType
-    ) external override {
-        if (!_clones.contains(msg.sender)) revert SharedValidation.NoPermission(msg.sender);
-
-        _logComponentEvent(abi.encode(msg.sender, txId, functionSelector, status, requester, target, operationType));
-
-        address eventForwarder = _secureState.eventForwarder;
-        if (eventForwarder != address(0) && eventForwarder != address(this)) {
-            try IEventForwarder(eventForwarder).forwardTxEvent(
-                txId, functionSelector, status, requester, target, operationType
-            ) {} catch {}
-        }
-    }
-
-    receive() external payable {}
-
-    fallback() external payable {
-        revert SharedValidation.NotSupported();
-    }
-
-    uint256[50] private __gap;
-}

package/core/research/FactoryBlox/FactoryBloxDefinitions.sol

@@ -1,143 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.33;
-
-import "@openzeppelin/contracts/utils/introspection/IERC165.sol";
-import "../../lib/EngineBlox.sol";
-import "../../lib/interfaces/IDefinition.sol";
-
-/**
- * @title FactoryBloxDefinitions
- * @dev Library containing definitions for FactoryBlox cloneBlox, whitelist, pricing, and macro registration.
- *
- * Registers cloneBlox, whitelist (addToWhitelist, removeFromWhitelist), and pricing (setClonePrice)
- * function schemas. OWNER_ROLE gets EXECUTE_TIME_DELAY_REQUEST so requests go via the controller.
- * All four are macro selectors so the controller can target address(this).
- */
-library FactoryBloxDefinitions {
-    bytes32 public constant CLONE_OPERATION = keccak256("CLONE_OPERATION");
-    bytes32 public constant WHITELIST_OPERATION = keccak256("WHITELIST_OPERATION");
-    bytes32 public constant CLONE_PRICE_OPERATION = keccak256("CLONE_PRICE_OPERATION");
-
-    /// @dev Macro selectors (allowed to target address(this) for GuardController execution)
-    bytes4 public constant CLONE_BLOX_SELECTOR =
-        bytes4(keccak256("cloneBlox(address,address,address,address,uint256,bytes)"));
-    // addToWhitelist(address,(address,uint256,address,uint256))
-    bytes4 public constant ADD_TO_WHITELIST_SELECTOR =
-        bytes4(keccak256("addToWhitelist(address,(address,uint256,address,uint256))"));
-    bytes4 public constant REMOVE_FROM_WHITELIST_SELECTOR = bytes4(keccak256("removeFromWhitelist(address)"));
-    // setClonePrice(address,(address,uint256,address,uint256))
-    bytes4 public constant SET_CLONE_PRICE_SELECTOR =
-        bytes4(keccak256("setClonePrice(address,(address,uint256,address,uint256))"));
-
-    function getFunctionSchemas() public pure returns (EngineBlox.FunctionSchema[] memory) {
-        EngineBlox.FunctionSchema[] memory schemas = new EngineBlox.FunctionSchema[](4);
-
-        EngineBlox.TxAction[] memory timeDelayRequestActions = new EngineBlox.TxAction[](1);
-        timeDelayRequestActions[0] = EngineBlox.TxAction.EXECUTE_TIME_DELAY_REQUEST;
-
-        bytes4[] memory cloneHandlers = new bytes4[](1);
-        cloneHandlers[0] = CLONE_BLOX_SELECTOR;
-        schemas[0] = EngineBlox.FunctionSchema({
-            functionSignature: "cloneBlox(address,address,address,address,uint256,bytes)",
-            functionSelector: CLONE_BLOX_SELECTOR,
-            operationType: CLONE_OPERATION,
-            operationName: "CLONE_OPERATION",
-            supportedActionsBitmap: EngineBlox.createBitmapFromActions(timeDelayRequestActions),
-            isProtected: true,
-            handlerForSelectors: cloneHandlers
-        });
-
-        bytes4[] memory addWhitelistHandlers = new bytes4[](1);
-        addWhitelistHandlers[0] = ADD_TO_WHITELIST_SELECTOR;
-        schemas[1] = EngineBlox.FunctionSchema({
-            functionSignature: "addToWhitelist(address,(address,uint256,address,uint256))",
-            functionSelector: ADD_TO_WHITELIST_SELECTOR,
-            operationType: WHITELIST_OPERATION,
-            operationName: "WHITELIST_OPERATION",
-            supportedActionsBitmap: EngineBlox.createBitmapFromActions(timeDelayRequestActions),
-            isProtected: true,
-            handlerForSelectors: addWhitelistHandlers
-        });
-
-        bytes4[] memory removeWhitelistHandlers = new bytes4[](1);
-        removeWhitelistHandlers[0] = REMOVE_FROM_WHITELIST_SELECTOR;
-        schemas[2] = EngineBlox.FunctionSchema({
-            functionSignature: "removeFromWhitelist(address)",
-            functionSelector: REMOVE_FROM_WHITELIST_SELECTOR,
-            operationType: WHITELIST_OPERATION,
-            operationName: "WHITELIST_OPERATION",
-            supportedActionsBitmap: EngineBlox.createBitmapFromActions(timeDelayRequestActions),
-            isProtected: true,
-            handlerForSelectors: removeWhitelistHandlers
-        });
-
-        // Schema 3: setClonePrice (per-implementation pricing configuration for cloneBlox)
-        bytes4[] memory setClonePriceHandlers = new bytes4[](1);
-        setClonePriceHandlers[0] = SET_CLONE_PRICE_SELECTOR;
-        schemas[3] = EngineBlox.FunctionSchema({
-            functionSignature: "setClonePrice(address,(address,uint256,address,uint256))",
-            functionSelector: SET_CLONE_PRICE_SELECTOR,
-            operationType: CLONE_PRICE_OPERATION,
-            operationName: "CLONE_PRICE_OPERATION",
-            supportedActionsBitmap: EngineBlox.createBitmapFromActions(timeDelayRequestActions),
-            isProtected: true,
-            handlerForSelectors: setClonePriceHandlers
-        });
-
-        return schemas;
-    }
-
-    function getRolePermissions() public pure returns (IDefinition.RolePermission memory) {
-        bytes32[] memory roleHashes = new bytes32[](4);
-        EngineBlox.FunctionPermission[] memory functionPermissions = new EngineBlox.FunctionPermission[](4);
-
-        EngineBlox.TxAction[] memory ownerRequestActions = new EngineBlox.TxAction[](1);
-        ownerRequestActions[0] = EngineBlox.TxAction.EXECUTE_TIME_DELAY_REQUEST;
-
-        roleHashes[0] = EngineBlox.OWNER_ROLE;
-        bytes4[] memory cloneHandlers = new bytes4[](1);
-        cloneHandlers[0] = CLONE_BLOX_SELECTOR;
-        functionPermissions[0] = EngineBlox.FunctionPermission({
-            functionSelector: CLONE_BLOX_SELECTOR,
-            grantedActionsBitmap: EngineBlox.createBitmapFromActions(ownerRequestActions),
-            handlerForSelectors: cloneHandlers
-        });
-
-        roleHashes[1] = EngineBlox.OWNER_ROLE;
-        bytes4[] memory addWhitelistHandlers = new bytes4[](1);
-        addWhitelistHandlers[0] = ADD_TO_WHITELIST_SELECTOR;
-        functionPermissions[1] = EngineBlox.FunctionPermission({
-            functionSelector: ADD_TO_WHITELIST_SELECTOR,
-            grantedActionsBitmap: EngineBlox.createBitmapFromActions(ownerRequestActions),
-            handlerForSelectors: addWhitelistHandlers
-        });
-
-        roleHashes[2] = EngineBlox.OWNER_ROLE;
-        bytes4[] memory removeWhitelistHandlers = new bytes4[](1);
-        removeWhitelistHandlers[0] = REMOVE_FROM_WHITELIST_SELECTOR;
-        functionPermissions[2] = EngineBlox.FunctionPermission({
-            functionSelector: REMOVE_FROM_WHITELIST_SELECTOR,
-            grantedActionsBitmap: EngineBlox.createBitmapFromActions(ownerRequestActions),
-            handlerForSelectors: removeWhitelistHandlers
-        });
-
-        // Owner: setClonePrice
-        roleHashes[3] = EngineBlox.OWNER_ROLE;
-        bytes4[] memory setClonePriceHandlers = new bytes4[](1);
-        setClonePriceHandlers[0] = SET_CLONE_PRICE_SELECTOR;
-        functionPermissions[3] = EngineBlox.FunctionPermission({
-            functionSelector: SET_CLONE_PRICE_SELECTOR,
-            grantedActionsBitmap: EngineBlox.createBitmapFromActions(ownerRequestActions),
-            handlerForSelectors: setClonePriceHandlers
-        });
-
-        return IDefinition.RolePermission({
-            roleHashes: roleHashes,
-            functionPermissions: functionPermissions
-        });
-    }
-
-    function supportsInterface(bytes4 interfaceId) external pure returns (bool) {
-        return interfaceId == type(IERC165).interfaceId || interfaceId == type(IDefinition).interfaceId;
-    }
-}

package/core/research/erc1155-blox/ERC1155Blox.sol

@@ -1,169 +0,0 @@
-// SPDX-License-Identifier: MPL-2.0
-pragma solidity 0.8.33;
-
-// OpenZeppelin
-import "@openzeppelin/contracts-upgradeable/token/ERC1155/ERC1155Upgradeable.sol";
-import "@openzeppelin/contracts-upgradeable/token/ERC1155/extensions/ERC1155BurnableUpgradeable.sol";
-import "@openzeppelin/contracts/token/ERC1155/IERC1155.sol";
-import "@openzeppelin/contracts/utils/introspection/IERC165.sol";
-
-// Core
-import "../../security/SecureOwnable.sol";
-import "../../access/RuntimeRBAC.sol";
-import "../../execution/GuardController.sol";
-import "../../base/BaseStateMachine.sol";
-import "../../lib/interfaces/IDefinition.sol";
-import "./lib/definitions/ERC1155BloxDefinitions.sol";
-
-/**
- * @title ERC1155Blox
- * @dev ERC1155 multi-token (IERC1155) with SecureOwnable, RuntimeRBAC, and GuardController.
- * Exposes safeTransferFrom, safeBatchTransferFrom (callable only via GuardController), mint/mintBatch (via controller), and burn/burnBatch (via controller).
- * @custom:security-contact security@particlecrypto.com
- */
-contract ERC1155Blox is
-    IERC1155,
-    ERC1155Upgradeable,
-    ERC1155BurnableUpgradeable,
-    SecureOwnable,
-    RuntimeRBAC,
-    GuardController
-{
-    /// @custom:oz-upgrades-unsafe-allow constructor
-    constructor() {
-        _disableInitializers();
-    }
-
-    /**
-     * @dev Override to resolve diamond: SecureOwnable, RuntimeRBAC, GuardController all define initialize(5 params).
-     * Call this first, then initializeToken(uri) to set ERC1155 base URI.
-     */
-    function initialize(
-        address initialOwner,
-        address broadcaster,
-        address recovery,
-        uint256 timeLockPeriodSec,
-        address eventForwarder
-    ) public virtual override(GuardController, RuntimeRBAC, SecureOwnable) initializer {
-        GuardController.initialize(initialOwner, broadcaster, recovery, timeLockPeriodSec, eventForwarder);
-        RuntimeRBAC.initialize(initialOwner, broadcaster, recovery, timeLockPeriodSec, eventForwarder);
-        SecureOwnable.initialize(initialOwner, broadcaster, recovery, timeLockPeriodSec, eventForwarder);
-
-        IDefinition.RolePermission memory erc1155Permissions = ERC1155BloxDefinitions.getRolePermissions();
-        _loadDefinitions(
-            ERC1155BloxDefinitions.getFunctionSchemas(),
-            erc1155Permissions.roleHashes,
-            erc1155Permissions.functionPermissions,
-            true
-        );
-
-        _addMacroSelector(ERC1155BloxDefinitions.SAFE_TRANSFER_FROM_SELECTOR);
-        _addMacroSelector(ERC1155BloxDefinitions.SAFE_BATCH_TRANSFER_FROM_SELECTOR);
-        _addMacroSelector(ERC1155BloxDefinitions.MINT_SELECTOR);
-        _addMacroSelector(ERC1155BloxDefinitions.MINT_BATCH_SELECTOR);
-        _addMacroSelector(ERC1155BloxDefinitions.BURN_SELECTOR);
-        _addMacroSelector(ERC1155BloxDefinitions.BURN_BATCH_SELECTOR);
-    }
-
-    /**
-     * @notice Initialize the ERC1155 base URI. Call after initialize(5 params).
-     * @param uri_ Base URI for token metadata (e.g. https://example.com/{id}.json)
-     */
-    function initializeToken(string memory uri_) public reinitializer(2) {
-        __ERC1155_init(uri_);
-    }
-
-    /**
-     * @notice Safe transfer of token; callable only by this contract via GuardController
-     * @param from Sender address
-     * @param to Recipient address
-     * @param id Token type ID
-     * @param value Amount to transfer
-     * @param data Additional data for recipient hook
-     */
-    function safeTransferFrom(address from, address to, uint256 id, uint256 value, bytes memory data)
-        public
-        virtual
-        override(ERC1155Upgradeable, IERC1155)
-    {
-        _validateExecuteBySelf();
-        super.safeTransferFrom(from, to, id, value, data);
-    }
-
-    /**
-     * @notice Safe batch transfer; callable only by this contract via GuardController
-     * @param from Sender address
-     * @param to Recipient address
-     * @param ids Token type IDs
-     * @param values Amounts to transfer
-     * @param data Additional data for recipient hook
-     */
-    function safeBatchTransferFrom(address from, address to, uint256[] memory ids, uint256[] memory values, bytes memory data)
-        public
-        virtual
-        override(ERC1155Upgradeable, IERC1155)
-    {
-        _validateExecuteBySelf();
-        super.safeBatchTransferFrom(from, to, ids, values, data);
-    }
-
-    /**
-     * @notice Mint tokens to an account (callable only by this contract via GuardController)
-     * @param to Recipient address
-     * @param id Token type ID
-     * @param value Amount to mint
-     * @param data Additional data for recipient hook
-     */
-    function mint(address to, uint256 id, uint256 value, bytes memory data) external virtual {
-        _validateExecuteBySelf();
-        _mint(to, id, value, data);
-    }
-
-    /**
-     * @notice Mint batch of tokens (callable only by this contract via GuardController)
-     * @param to Recipient address
-     * @param ids Token type IDs
-     * @param values Amounts to mint
-     * @param data Additional data for recipient hook
-     */
-    function mintBatch(address to, uint256[] memory ids, uint256[] memory values, bytes memory data) external virtual {
-        _validateExecuteBySelf();
-        _mintBatch(to, ids, values, data);
-    }
-
-    /**
-     * @notice Burn tokens from an account (callable only by this contract via GuardController)
-     * @param account Account to burn from
-     * @param id Token type ID
-     * @param value Amount to burn
-     */
-    function burn(address account, uint256 id, uint256 value) public virtual override(ERC1155BurnableUpgradeable) {
-        _validateExecuteBySelf();
-        super.burn(account, id, value);
-    }
-
-    /**
-     * @notice Burn batch of tokens (callable only by this contract via GuardController)
-     * @param account Account to burn from
-     * @param ids Token type IDs
-     * @param values Amounts to burn
-     */
-    function burnBatch(address account, uint256[] memory ids, uint256[] memory values)
-        public
-        virtual
-        override(ERC1155BurnableUpgradeable)
-    {
-        _validateExecuteBySelf();
-        super.burnBatch(account, ids, values);
-    }
-
-    function supportsInterface(bytes4 interfaceId)
-        public
-        view
-        virtual
-        override(ERC1155Upgradeable, SecureOwnable, RuntimeRBAC, GuardController, IERC165)
-        returns (bool)
-    {
-        return interfaceId == type(IERC1155).interfaceId || super.supportsInterface(interfaceId) || GuardController.supportsInterface(interfaceId);
-    }
-}