@bananapus/suckers-v6 0.0.1

package/src/JBSuckerRegistry.sol

@@ -0,0 +1,262 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.23;
+
+import {JBPermissioned} from "@bananapus/core-v6/src/abstract/JBPermissioned.sol";
+import {IJBDirectory} from "@bananapus/core-v6/src/interfaces/IJBDirectory.sol";
+import {IJBController} from "@bananapus/core-v6/src/interfaces/IJBController.sol";
+import {IJBPermissions} from "@bananapus/core-v6/src/interfaces/IJBPermissions.sol";
+import {IJBProjects} from "@bananapus/core-v6/src/interfaces/IJBProjects.sol";
+import {JBRuleset} from "@bananapus/core-v6/src/structs/JBRuleset.sol";
+import {JBRulesetMetadata} from "@bananapus/core-v6/src/structs/JBRulesetMetadata.sol";
+import {JBPermissionIds} from "@bananapus/permission-ids-v6/src/JBPermissionIds.sol";
+import {Ownable} from "@openzeppelin/contracts/access/Ownable.sol";
+import {EnumerableMap} from "@openzeppelin/contracts/utils/structs/EnumerableMap.sol";
+import {ERC2771Context} from "@openzeppelin/contracts/metatx/ERC2771Context.sol";
+import {Context} from "@openzeppelin/contracts/utils/Context.sol";
+
+import {IJBSucker} from "./interfaces/IJBSucker.sol";
+import {IJBSuckerDeployer} from "./interfaces/IJBSuckerDeployer.sol";
+import {IJBSuckerRegistry} from "./interfaces/IJBSuckerRegistry.sol";
+import {JBSuckerDeployerConfig} from "./structs/JBSuckerDeployerConfig.sol";
+import {JBSuckersPair} from "./structs/JBSuckersPair.sol";
+import {JBSuckerState} from "./enums/JBSuckerState.sol";
+
+contract JBSuckerRegistry is ERC2771Context, Ownable, JBPermissioned, IJBSuckerRegistry {
+    using EnumerableMap for EnumerableMap.AddressToUintMap;
+
+    //*********************************************************************//
+    // --------------------------- custom errors ------------------------- //
+    //*********************************************************************//
+
+    error JBSuckerRegistry_InvalidDeployer(IJBSuckerDeployer deployer);
+    error JBSuckerRegistry_SuckerDoesNotBelongToProject(uint256 projectId, address sucker);
+    error JBSuckerRegistry_SuckerIsNotDeprecated(address sucker, JBSuckerState suckerState);
+
+    //*********************************************************************//
+    // ------------------------- internal constants ----------------------- //
+    //*********************************************************************//
+
+    /// @notice A constant indicating that this sucker exists and belongs to a specific project.
+    uint256 internal constant _SUCKER_EXISTS = 1;
+
+    //*********************************************************************//
+    // --------------- public immutable stored properties ---------------- //
+    //*********************************************************************//
+
+    /// @notice The juicebox directory.
+    IJBDirectory public immutable override DIRECTORY;
+
+    /// @notice A contract which mints ERC-721s that represent project ownership and transfers.
+    IJBProjects public immutable override PROJECTS;
+
+    //*********************************************************************//
+    // --------------------- public stored properties -------------------- //
+    //*********************************************************************//
+
+    /// @notice Tracks whether the specified sucker deployer is approved by this registry.
+    /// @custom:member deployer The address of the deployer to check.
+    mapping(address deployer => bool) public override suckerDeployerIsAllowed;
+
+    //*********************************************************************//
+    // --------------------- internal stored properties ------------------- //
+    //*********************************************************************//
+
+    /// @notice Tracks the suckers for the specified project.
+    mapping(uint256 => EnumerableMap.AddressToUintMap) internal _suckersOf;
+
+    //*********************************************************************//
+    // -------------------------- constructor ---------------------------- //
+    //*********************************************************************//
+
+    /// @param directory The juicebox directory.
+    /// @param permissions A contract storing permissions.
+    /// @param initialOwner The initial owner of this contract.
+    constructor(
+        IJBDirectory directory,
+        IJBPermissions permissions,
+        address initialOwner,
+        address trustedForwarder
+    )
+        ERC2771Context(trustedForwarder)
+        JBPermissioned(permissions)
+        Ownable(initialOwner)
+    {
+        DIRECTORY = directory;
+        PROJECTS = directory.PROJECTS();
+    }
+
+    //*********************************************************************//
+    // ------------------------- external views -------------------------- //
+    //*********************************************************************//
+
+    /// @notice Returns true if the specified sucker belongs to the specified project, and was deployed through this
+    /// registry.
+    /// @param projectId The ID of the project to check for.
+    /// @param addr The address of the sucker to check.
+    /// @return flag A flag indicating if the sucker belongs to the project, and was deployed through this registry.
+    function isSuckerOf(uint256 projectId, address addr) external view override returns (bool) {
+        (bool exists, uint256 val) = _suckersOf[projectId].tryGet(addr);
+        return exists && val == _SUCKER_EXISTS;
+    }
+
+    /// @notice Helper function for retrieving the projects suckers and their metadata.
+    /// @param projectId The ID of the project to get the suckers of.
+    /// @return pairs The pairs of suckers and their metadata.
+    function suckerPairsOf(uint256 projectId) external view override returns (JBSuckersPair[] memory pairs) {
+        // Get the suckers of the project.
+        address[] memory suckers = _suckersOf[projectId].keys();
+
+        // Initialize the array of pairs.
+        pairs = new JBSuckersPair[](suckers.length);
+
+        // Populate the array of pairs.
+        for (uint256 i; i < suckers.length; i++) {
+            // Get the sucker being iterated over.
+            IJBSucker sucker = IJBSucker(suckers[i]);
+
+            // slither-disable-next-line calls-loop
+            pairs[i] =
+                JBSuckersPair({local: address(sucker), remote: sucker.peer(), remoteChainId: sucker.peerChainId()});
+        }
+    }
+
+    /// @notice Gets all of the specified project's suckers which were deployed through this registry.
+    /// @param projectId The ID of the project to get the suckers of.
+    /// @return suckers The addresses of the suckers.
+    function suckersOf(uint256 projectId) external view override returns (address[] memory) {
+        return _suckersOf[projectId].keys();
+    }
+
+    //*********************************************************************//
+    // ------------------------ internal views --------------------------- //
+    //*********************************************************************//
+
+    /// @notice The calldata. Preferred to use over `msg.data`.
+    /// @return calldata The `msg.data` of this call.
+    function _msgData() internal view override(ERC2771Context, Context) returns (bytes calldata) {
+        return ERC2771Context._msgData();
+    }
+
+    /// @notice The message's sender. Preferred to use over `msg.sender`.
+    /// @return sender The address which sent this call.
+    function _msgSender() internal view override(ERC2771Context, Context) returns (address sender) {
+        return ERC2771Context._msgSender();
+    }
+
+    /// @dev ERC-2771 specifies the context as being a single address (20 bytes).
+    function _contextSuffixLength() internal view virtual override(ERC2771Context, Context) returns (uint256) {
+        return ERC2771Context._contextSuffixLength();
+    }
+
+    //*********************************************************************//
+    // ---------------------- external transactions ---------------------- //
+    //*********************************************************************//
+
+    /// @notice Adds a suckers deployer to the allowlist.
+    /// @dev Can only be called by this contract's owner (initially project ID 1, or JuiceboxDAO).
+    /// @param deployer The address of the deployer to add.
+    function allowSuckerDeployer(address deployer) public override onlyOwner {
+        suckerDeployerIsAllowed[deployer] = true;
+        emit SuckerDeployerAllowed({deployer: deployer, caller: _msgSender()});
+    }
+
+    /// @notice Adds multiple suckers deployer to the allowlist.
+    /// @dev Can only be called by this contract's owner (initially project ID 1, or JuiceboxDAO).
+    /// @param deployers The address of the deployer to add.
+    function allowSuckerDeployers(address[] calldata deployers) public override onlyOwner {
+        // Iterate through the deployers and allow them.
+        for (uint256 i; i < deployers.length; i++) {
+            // Get the deployer being iterated over.
+            address deployer = deployers[i];
+
+            // Allow the deployer.
+            suckerDeployerIsAllowed[deployer] = true;
+            emit SuckerDeployerAllowed({deployer: deployer, caller: _msgSender()});
+        }
+    }
+
+    /// @notice Deploy one or more suckers for the specified project.
+    /// @dev The caller must be the project's owner or have `JBPermissionIds.DEPLOY_SUCKERS` from the project's owner.
+    /// @param projectId The ID of the project to deploy suckers for.
+    /// @param salt The salt used to deploy the contract. For the suckers to be peers, this must be the same value on
+    /// each chain where suckers are deployed.
+    /// @param configurations The sucker deployer configs to use to deploy the suckers.
+    /// @return suckers The addresses of the deployed suckers.
+    function deploySuckersFor(
+        uint256 projectId,
+        bytes32 salt,
+        JBSuckerDeployerConfig[] calldata configurations
+    )
+        public
+        override
+        returns (address[] memory suckers)
+    {
+        _requirePermissionFrom({
+            account: PROJECTS.ownerOf(projectId), projectId: projectId, permissionId: JBPermissionIds.DEPLOY_SUCKERS
+        });
+
+        // Create an array to store the suckers as they are deployed.
+        suckers = new address[](configurations.length);
+
+        // Calculate the salt using the sender's address and the provided `salt`.
+        // This means that for suckers to be peers, the sender has to be the same on each chain.
+        salt = keccak256(abi.encode(_msgSender(), salt));
+
+        // Iterate through the configurations and deploy the suckers.
+        for (uint256 i; i < configurations.length; i++) {
+            // Get the configuration being iterated over.
+            JBSuckerDeployerConfig memory configuration = configurations[i];
+
+            // Make sure the deployer is allowed.
+            if (!suckerDeployerIsAllowed[address(configuration.deployer)]) {
+                revert JBSuckerRegistry_InvalidDeployer(configuration.deployer);
+            }
+
+            // Create the sucker.
+            // slither-disable-next-line reentrancy-event,calls-loop
+            IJBSucker sucker = configuration.deployer.createForSender({localProjectId: projectId, salt: salt});
+            suckers[i] = address(sucker);
+
+            // Store the sucker as being deployed for this project.
+            // slither-disable-next-line unused-return
+            _suckersOf[projectId].set({key: address(sucker), value: _SUCKER_EXISTS});
+
+            // Map the tokens for the sucker.
+            // slither-disable-next-line reentrancy-events,calls-loop
+            sucker.mapTokens(configuration.mappings);
+            emit SuckerDeployedFor({
+                projectId: projectId, sucker: address(sucker), configuration: configuration, caller: _msgSender()
+            });
+        }
+    }
+
+    /// @notice Lets anyone remove a deprecated sucker from a project.
+    /// @param projectId The ID of the project to remove the sucker from.
+    /// @param sucker The address of the deprecated sucker to remove.
+    function removeDeprecatedSucker(uint256 projectId, address sucker) public override {
+        // Sanity check, make sure that the sucker does actually belong to the project.
+        (bool belongsToProject, uint256 val) = _suckersOf[projectId].tryGet(sucker);
+        if (!belongsToProject || val != _SUCKER_EXISTS) {
+            revert JBSuckerRegistry_SuckerDoesNotBelongToProject(projectId, address(sucker));
+        }
+
+        // Check if the sucker is deprecated.
+        JBSuckerState state = IJBSucker(sucker).state();
+        if (state != JBSuckerState.DEPRECATED) {
+            revert JBSuckerRegistry_SuckerIsNotDeprecated(address(sucker), state);
+        }
+
+        // Remove the sucker from the registry.
+        // slither-disable-next-line unused-return
+        _suckersOf[projectId].remove(address(sucker));
+        emit SuckerDeprecated({projectId: projectId, sucker: address(sucker), caller: _msgSender()});
+    }
+
+    /// @notice Removes a sucker deployer from the allowlist.
+    /// @dev Can only be called by this contract's owner (initially project ID 1, or JuiceboxDAO).
+    /// @param deployer The address of the deployer to remove.
+    function removeSuckerDeployer(address deployer) public override onlyOwner {
+        suckerDeployerIsAllowed[deployer] = false;
+        emit SuckerDeployerRemoved({deployer: deployer, caller: _msgSender()});
+    }
+}

package/src/deployers/JBArbitrumSuckerDeployer.sol

@@ -0,0 +1,86 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.23;
+
+import "./JBSuckerDeployer.sol";
+import "../interfaces/IJBArbitrumSuckerDeployer.sol";
+
+import {JBArbitrumSucker} from "../JBArbitrumSucker.sol";
+import {JBLayer} from "../enums/JBLayer.sol";
+import {IArbGatewayRouter} from "../interfaces/IArbGatewayRouter.sol";
+import {ARBAddresses} from "../libraries/ARBAddresses.sol";
+import {ARBChains} from "../libraries/ARBChains.sol";
+
+/// @notice An `IJBSuckerDeployer` implementation to deploy `JBArbitrumSucker` contracts.
+contract JBArbitrumSuckerDeployer is JBSuckerDeployer, IJBArbitrumSuckerDeployer {
+    //*********************************************************************//
+    // ---------------------- public stored properties ------------------- //
+    //*********************************************************************//
+
+    /// @notice The layer that this contract is on.
+    JBLayer public arbLayer;
+
+    /// @notice The inbox used to send messages between the local and remote sucker.
+    IInbox public override arbInbox;
+
+    /// @notice The gateway router for the specific chain
+    IArbGatewayRouter public override arbGatewayRouter;
+
+    //*********************************************************************//
+    // ---------------------------- constructor -------------------------- //
+    //*********************************************************************//
+
+    /// @param directory The directory of terminals and controllers for projects.
+    /// @param permissions The permissions contract for the deployer.
+    /// @param tokens The contract that manages token minting and burning.
+    /// @param configurator The address of the configurator.
+    constructor(
+        IJBDirectory directory,
+        IJBPermissions permissions,
+        IJBTokens tokens,
+        address configurator,
+        address trustedForwarder
+    )
+        JBSuckerDeployer(directory, permissions, tokens, configurator, trustedForwarder)
+    {}
+
+    //*********************************************************************//
+    // ------------------------ internal views --------------------------- //
+    //*********************************************************************//
+
+    /// @notice Check if the layer specific configuration is set or not. Used as a sanity check.
+    function _layerSpecificConfigurationIsSet() internal view override returns (bool) {
+        // We don't check arbLayer here because JBLayer.L1 == 0 which is the default/unset value.
+        // Since all fields are set atomically in setChainSpecificConstants, checking inbox + gateway is sufficient.
+        return address(arbInbox) != address(0) && address(arbGatewayRouter) != address(0);
+    }
+
+    //*********************************************************************//
+    // --------------------- external transactions ----------------------- //
+    //*********************************************************************//
+
+    /// @notice Handles some layer specific configuration that can't be done in the constructor otherwise deployment
+    /// addresses would change.
+    /// @param layer The Arbitrum layer (L1 or L2).
+    /// @param inbox The Arbitrum inbox on this layer.
+    /// @param gatewayRouter The Arbitrum gateway router on this layer.
+    function setChainSpecificConstants(JBLayer layer, IInbox inbox, IArbGatewayRouter gatewayRouter) external {
+        if (_layerSpecificConfigurationIsSet()) {
+            revert JBSuckerDeployer_AlreadyConfigured();
+        }
+
+        if (_msgSender() != LAYER_SPECIFIC_CONFIGURATOR) {
+            revert JBSuckerDeployer_Unauthorized(_msgSender(), LAYER_SPECIFIC_CONFIGURATOR);
+        }
+
+        // Configure these layer specific properties.
+        // This is done in a separate call to make the deployment code chain agnostic.
+        arbLayer = layer;
+        arbInbox = inbox;
+        arbGatewayRouter = gatewayRouter;
+
+        // Make sure the layer specific configuration is properly configured.
+        if (!_layerSpecificConfigurationIsSet()) {
+            revert JBSuckerDeployer_InvalidLayerSpecificConfiguration();
+        }
+    }
+}

package/src/deployers/JBBaseSuckerDeployer.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.23;
+
+import "./JBOptimismSuckerDeployer.sol";
+import "../JBBaseSucker.sol";
+
+// Exact same as JBOptimismSuckerDeployer, we do this so we get a seperate artifact for Base.
+contract JBBaseSuckerDeployer is JBOptimismSuckerDeployer {
+    //*********************************************************************//
+    // ---------------------------- constructor -------------------------- //
+    //*********************************************************************//
+
+    /// @param directory The directory of terminals and controllers for projects.
+    /// @param permissions The permissions contract for the deployer.
+    /// @param tokens The contract that manages token minting and burning.
+    /// @param configurator The address of the configurator.
+    constructor(
+        IJBDirectory directory,
+        IJBPermissions permissions,
+        IJBTokens tokens,
+        address configurator,
+        address trustedForwarder
+    )
+        JBOptimismSuckerDeployer(directory, permissions, tokens, configurator, trustedForwarder)
+    {}
+}

package/src/deployers/JBCCIPSuckerDeployer.sol

@@ -0,0 +1,88 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.23;
+
+import "./JBSuckerDeployer.sol";
+import "../interfaces/IJBArbitrumSuckerDeployer.sol";
+
+import {JBCCIPSucker} from "../JBCCIPSucker.sol";
+import {JBAddToBalanceMode} from "../enums/JBAddToBalanceMode.sol";
+import {IJBSucker} from "./../interfaces/IJBSucker.sol";
+import {IJBSuckerDeployer} from "./../interfaces/IJBSuckerDeployer.sol";
+import {IJBCCIPSuckerDeployer} from "./../interfaces/IJBCCIPSuckerDeployer.sol";
+import {ICCIPRouter} from "src/interfaces/ICCIPRouter.sol";
+import {CCIPHelper} from "src/libraries/CCIPHelper.sol";
+
+/// @notice An `IJBSuckerDeployer` implementation to deploy contracts.
+contract JBCCIPSuckerDeployer is JBSuckerDeployer, IJBCCIPSuckerDeployer {
+    error JBCCIPSuckerDeployer_InvalidCCIPRouter(address router);
+
+    //*********************************************************************//
+    // ---------------------- public stored properties ------------------- //
+    //*********************************************************************//
+
+    /// @notice Store the remote chain id
+    uint256 public ccipRemoteChainId;
+
+    /// @notice The remote chain selector target of all sucker deployed by this contract.
+    uint64 public ccipRemoteChainSelector;
+
+    /// @notice Store the address of the CCIP router for this chain.
+    ICCIPRouter public ccipRouter;
+
+    //*********************************************************************//
+    // ---------------------------- constructor -------------------------- //
+    //*********************************************************************//
+
+    /// @param directory The directory of terminals and controllers for projects.
+    /// @param permissions The permissions contract for the deployer.
+    /// @param tokens The contract that manages token minting and burning.
+    /// @param configurator The address of the configurator.
+    constructor(
+        IJBDirectory directory,
+        IJBPermissions permissions,
+        IJBTokens tokens,
+        address configurator,
+        address trustedForwarder
+    )
+        JBSuckerDeployer(directory, permissions, tokens, configurator, trustedForwarder)
+    {}
+
+    //*********************************************************************//
+    // ------------------------ internal views --------------------------- //
+    //*********************************************************************//
+
+    /// @notice Check if the layer specific configuration is set or not. Used as a sanity check.
+    function _layerSpecificConfigurationIsSet() internal view override returns (bool) {
+        return ccipRemoteChainId != 0 && ccipRemoteChainSelector != 0 && address(ccipRouter) != address(0);
+    }
+
+    //*********************************************************************//
+    // --------------------- external transactions ----------------------- //
+    //*********************************************************************//
+
+    /// @notice handles some layer specific configuration that can't be done in the constructor otherwise deployment
+    /// addresses would change.
+    /// @param remoteChainId The remote chain id.
+    /// @param remoteChainSelector The CCIP remote chain selector.
+    /// @param router The CCIP router for this chain.
+    function setChainSpecificConstants(uint256 remoteChainId, uint64 remoteChainSelector, ICCIPRouter router) external {
+        if (_layerSpecificConfigurationIsSet()) {
+            revert JBSuckerDeployer_AlreadyConfigured();
+        }
+
+        if (_msgSender() != LAYER_SPECIFIC_CONFIGURATOR) {
+            revert JBSuckerDeployer_Unauthorized(_msgSender(), LAYER_SPECIFIC_CONFIGURATOR);
+        }
+
+        ccipRemoteChainId = remoteChainId;
+        ccipRemoteChainSelector = remoteChainSelector;
+        ccipRouter = router;
+
+        // Make sure the layer specific configuration is properly configured.
+        if (!_layerSpecificConfigurationIsSet()) {
+            revert JBSuckerDeployer_InvalidLayerSpecificConfiguration();
+        }
+
+        emit CCIPConstantsSet(address(ccipRouter), ccipRemoteChainId, ccipRemoteChainSelector, _msgSender());
+    }
+}

package/src/deployers/JBOptimismSuckerDeployer.sol

@@ -0,0 +1,82 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.23;
+
+import "./JBSuckerDeployer.sol";
+import "../interfaces/IJBArbitrumSuckerDeployer.sol";
+
+import {JBOptimismSucker} from "../JBOptimismSucker.sol";
+import {JBAddToBalanceMode} from "../enums/JBAddToBalanceMode.sol";
+import {IJBOpSuckerDeployer} from "./../interfaces/IJBOpSuckerDeployer.sol";
+import {IJBSuckerDeployer} from "./../interfaces/IJBSuckerDeployer.sol";
+import {IOPMessenger} from "../interfaces/IOPMessenger.sol";
+import {IOPStandardBridge} from "../interfaces/IOPStandardBridge.sol";
+
+/// @notice An `IJBSuckerDeployer` implementation to deploy `JBOptimismSucker` contracts.
+contract JBOptimismSuckerDeployer is JBSuckerDeployer, IJBOpSuckerDeployer {
+    //*********************************************************************//
+    // ---------------------- public stored properties ------------------- //
+    //*********************************************************************//
+
+    /// @notice The messenger used to send messages between the local and remote sucker.
+    IOPMessenger public override opMessenger;
+
+    /// @notice The bridge used to bridge tokens between the local and remote chain.
+    IOPStandardBridge public override opBridge;
+
+    //*********************************************************************//
+    // ---------------------------- constructor -------------------------- //
+    //*********************************************************************//
+
+    /// @param directory The directory of terminals and controllers for projects.
+    /// @param permissions The permissions contract for the deployer.
+    /// @param tokens The contract that manages token minting and burning.
+    /// @param configurator The address of the configurator.
+    constructor(
+        IJBDirectory directory,
+        IJBPermissions permissions,
+        IJBTokens tokens,
+        address configurator,
+        address trustedForwarder
+    )
+        JBSuckerDeployer(directory, permissions, tokens, configurator, trustedForwarder)
+    {}
+
+    //*********************************************************************//
+    // ------------------------ internal views --------------------------- //
+    //*********************************************************************//
+
+    /// @notice Check if the layer specific configuration is set or not. Used as a sanity check.
+    function _layerSpecificConfigurationIsSet() internal view override returns (bool) {
+        // Use && (not ||) so the post-set check in setChainSpecificConstants rejects partial configurations
+        // where only one of messenger/bridge is provided. Both are required for the sucker to function.
+        return address(opMessenger) != address(0) && address(opBridge) != address(0);
+    }
+
+    //*********************************************************************//
+    // --------------------- external transactions ----------------------- //
+    //*********************************************************************//
+
+    /// @notice Handles some layer specific configuration that can't be done in the constructor otherwise deployment
+    /// addresses would change.
+    /// @param messenger The OPMessenger on this layer.
+    /// @param bridge The OPStandardBridge on this layer.
+    function setChainSpecificConstants(IOPMessenger messenger, IOPStandardBridge bridge) external {
+        if (_layerSpecificConfigurationIsSet()) {
+            revert JBSuckerDeployer_AlreadyConfigured();
+        }
+
+        if (_msgSender() != LAYER_SPECIFIC_CONFIGURATOR) {
+            revert JBSuckerDeployer_Unauthorized(_msgSender(), LAYER_SPECIFIC_CONFIGURATOR);
+        }
+
+        // Configure these layer specific properties.
+        // This is done in a separate call to make the deployment code chain agnostic.
+        opMessenger = messenger;
+        opBridge = bridge;
+
+        // Make sure the layer specific configuration is properly configured.
+        if (!_layerSpecificConfigurationIsSet()) {
+            revert JBSuckerDeployer_InvalidLayerSpecificConfiguration();
+        }
+    }
+}