@bananapus/core-v6 0.0.37 → 0.0.39

package/test/units/static/JBDirectory/TestSetTerminalsOf.sol

@@ -1,137 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {StdStorage, stdStorage} from "forge-std/StdStorage.sol";
-import {JBDirectory} from "../../../../src/JBDirectory.sol";
-import {JBPermissioned} from "../../../../src/abstract/JBPermissioned.sol";
-import {IJBDirectory} from "../../../../src/interfaces/IJBDirectory.sol";
-import {IJBDirectoryAccessControl} from "../../../../src/interfaces/IJBDirectoryAccessControl.sol";
-import {IJBPermissions} from "../../../../src/interfaces/IJBPermissions.sol";
-import {IJBTerminal} from "../../../../src/interfaces/IJBTerminal.sol";
-import {JBPermissionIds} from "@bananapus/permission-ids-v6/src/JBPermissionIds.sol";
-import {IERC721} from "@openzeppelin/contracts/token/ERC721/IERC721.sol";
-import {IERC165} from "@openzeppelin/contracts/utils/introspection/ERC165.sol";
-import {JBDirectorySetup} from "./JBDirectorySetup.sol";
-
-contract TestSetTerminalsOf_Local is JBDirectorySetup {
-    using stdStorage for StdStorage;
-
-    IJBTerminal _terminalToAdd = IJBTerminal(makeAddr("newTerminal"));
-    address _mockController = makeAddr("controller");
-    address _token = makeAddr("newToken");
-
-    function setUp() public {
-        super.directorySetup();
-    }
-
-    modifier whenCallerHasPermission() {
-        // mock ownerOf call
-        bytes memory _ownerOfCall = abi.encodeCall(IERC721.ownerOf, (1));
-        bytes memory _ownerData = abi.encode(address(this));
-
-        mockExpect(address(projects), _ownerOfCall, _ownerData);
-        _;
-    }
-
-    modifier givenSetTerminalsAllowed() {
-        // it should revert with revert SET_TERMINALS_NOT_ALLOWED()
-        stdstore.target(address(_directory)).sig("controllerOf(uint256)").with_key(1).depth(0)
-            .checked_write(_mockController);
-
-        // mock erc165 call
-        bytes memory _supportCall =
-            abi.encodeCall(IERC165.supportsInterface, (type(IJBDirectoryAccessControl).interfaceId));
-        bytes memory _supportReturned = abi.encode(true);
-
-        mockExpect(address(_mockController), _supportCall, _supportReturned);
-
-        // mock setTerminalsAllowed call
-        bytes memory _allowedCall = abi.encodeCall(IJBDirectoryAccessControl.setTerminalsAllowed, (1));
-        bytes memory _allowedReturn = abi.encode(true);
-
-        mockExpect(address(_mockController), _allowedCall, _allowedReturn);
-        _;
-    }
-
-    function test_GivenNotSetTerminalsAllowed() external whenCallerHasPermission {
-        // it should revert with revert SET_TERMINALS_NOT_ALLOWED()
-        stdstore.target(address(_directory)).sig("controllerOf(uint256)").with_key(1).depth(0)
-            .checked_write(_mockController);
-
-        // mock erc165 call
-        bytes memory _supportCall =
-            abi.encodeCall(IERC165.supportsInterface, (type(IJBDirectoryAccessControl).interfaceId));
-        bytes memory _supportReturned = abi.encode(true);
-
-        mockExpect(address(_mockController), _supportCall, _supportReturned);
-
-        // mock setTerminalsAllowed call
-        bytes memory _allowedCall = abi.encodeCall(IJBDirectoryAccessControl.setTerminalsAllowed, (1));
-        bytes memory _allowedReturn = abi.encode(false);
-
-        mockExpect(address(_mockController), _allowedCall, _allowedReturn);
-
-        // needed for the call
-        IJBTerminal[] memory _terminals = new IJBTerminal[](1);
-        _terminals[0] = _terminalToAdd;
-
-        vm.expectRevert(abi.encodeWithSelector(JBDirectory.JBDirectory_SetTerminalsNotAllowed.selector, 1));
-        _directory.setTerminalsOf(1, _terminals);
-    }
-
-    function test_WhenCallerHasNoPermission() external {
-        // it should revert with UNAUTHORIZED()
-        // mock ownerOf call
-        bytes memory _ownerOfCall = abi.encodeCall(IERC721.ownerOf, (1));
-        address _ownerData = address(1);
-
-        mockExpect(address(projects), _ownerOfCall, abi.encode(_ownerData));
-
-        // mock first permissions call
-        bytes memory _permissionsCall = abi.encodeCall(
-            IJBPermissions.hasPermission, (address(this), address(1), 1, JBPermissionIds.SET_TERMINALS, true, true)
-        );
-        bytes memory _permissionsReturned = abi.encode(false);
-
-        mockExpect(address(permissions), _permissionsCall, _permissionsReturned);
-
-        // needed for the call
-        IJBTerminal[] memory _terminals = new IJBTerminal[](1);
-        _terminals[0] = _terminalToAdd;
-
-        vm.expectRevert(
-            abi.encodeWithSelector(
-                JBPermissioned.JBPermissioned_Unauthorized.selector,
-                _ownerData,
-                address(this),
-                1,
-                JBPermissionIds.SET_TERMINALS
-            )
-        );
-        _directory.setTerminalsOf(1, _terminals);
-    }
-
-    function test_GivenDuplicateTerminalsWereAdded() external whenCallerHasPermission givenSetTerminalsAllowed {
-        // it should revert with DUPLICATE_TERMINALS()
-        // needed for the call
-        IJBTerminal[] memory _terminals = new IJBTerminal[](2);
-        _terminals[0] = _terminalToAdd;
-        _terminals[1] = _terminalToAdd;
-
-        vm.expectRevert(abi.encodeWithSelector(JBDirectory.JBDirectory_DuplicateTerminals.selector, _terminalToAdd));
-        _directory.setTerminalsOf(1, _terminals);
-    }
-
-    function test_GivenDuplicateTerminalsWereNotAdded() external whenCallerHasPermission givenSetTerminalsAllowed {
-        // it should set terminals and emit SetTerminals
-
-        // needed for the call
-        IJBTerminal[] memory _terminals = new IJBTerminal[](1);
-        _terminals[0] = _terminalToAdd;
-
-        vm.expectEmit();
-        emit IJBDirectory.SetTerminals(1, _terminals, address(this));
-
-        _directory.setTerminalsOf(1, _terminals);
-    }
-}

package/test/units/static/JBERC20/JBERC20Setup.sol

@@ -1,34 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {Clones} from "@openzeppelin/contracts/proxy/Clones.sol";
-import {JBERC20} from "../../../../src/JBERC20.sol";
-import {IJBPermissions} from "../../../../src/interfaces/IJBPermissions.sol";
-import {IJBProjects} from "../../../../src/interfaces/IJBProjects.sol";
-import {IJBToken} from "../../../../src/interfaces/IJBToken.sol";
-import {JBTest} from "../../../helpers/JBTest.sol";
-
-/*
-Contract that deploys a target contract with other mock contracts to satisfy the constructor.
-Tests relative to this contract will be dependent on mock calls/emits and stdStorage.
-*/
-contract JBERC20Setup is JBTest {
-    // Mocks
-    address _tokens = makeAddr("tokens");
-    IJBProjects _projects = IJBProjects(makeAddr("projects"));
-    IJBPermissions _permissions = IJBPermissions(makeAddr("permissions"));
-
-    // Implementation (constructor sets _name = "invalid", cannot be initialized)
-    IJBToken public _implementation;
-
-    // Target Contract (clone with empty _name, can be initialized)
-    IJBToken public _erc20;
-
-    function erc20Setup() public virtual {
-        // Deploy the implementation with immutable permissions and projects
-        _implementation = new JBERC20(_permissions, _projects);
-
-        // Clone it — clones start with empty storage, so initialize() works
-        _erc20 = IJBToken(Clones.clone(address(_implementation)));
-    }
-}

package/test/units/static/JBERC20/SigUtils.sol

@@ -1,36 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-contract SigUtils {
-    // forge-lint: disable-next-line(mixed-case-variable)
-    bytes32 internal DOMAIN_SEPARATOR;
-
-    // forge-lint: disable-next-line(mixed-case-variable)
-    constructor(bytes32 _DOMAIN_SEPARATOR) {
-        DOMAIN_SEPARATOR = _DOMAIN_SEPARATOR;
-    }
-
-    // keccak256("Permit(address owner,address spender,uint256 value,uint256 nonce,uint256 deadline)");
-    bytes32 private constant PERMIT_TYPEHASH =
-        keccak256("Permit(address owner,address spender,uint256 value,uint256 nonce,uint256 deadline)");
-
-    struct Permit {
-        address owner;
-        address spender;
-        uint256 value;
-        uint256 nonce;
-        uint256 deadline;
-    }
-
-    // computes the hash of a permit
-    function getStructHash(Permit memory _permit) internal pure returns (bytes32) {
-        return keccak256(
-            abi.encode(PERMIT_TYPEHASH, _permit.owner, _permit.spender, _permit.value, _permit.nonce, _permit.deadline)
-        );
-    }
-
-    // computes the hash of the fully encoded EIP-712 message for the domain, which can be used to recover the signer
-    function getTypedDataHash(Permit memory _permit) public view returns (bytes32) {
-        return keccak256(abi.encodePacked("\x19\x01", DOMAIN_SEPARATOR, getStructHash(_permit)));
-    }
-}

package/test/units/static/JBERC20/TestInitialize.sol

@@ -1,60 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-import {JBERC20} from "../../../../src/JBERC20.sol";
-import {JBERC20Setup} from "./JBERC20Setup.sol";
-
-contract TestInitialize_Local is JBERC20Setup {
-    string _name = "Nana";
-    string _symbol = "NANA";
-
-    function setUp() public {
-        super.erc20Setup();
-    }
-
-    function test_ImplementationCannotBeInitialized() external {
-        // The implementation has _name = "invalid" set in constructor, so initialize() must revert.
-        vm.expectRevert(JBERC20.JBERC20_AlreadyInitialized.selector);
-        _implementation.initialize(_name, _symbol, _tokens);
-    }
-
-    function test_WhenANameIsAlreadySet() external {
-        // it will revert
-
-        _erc20.initialize(_name, _symbol, _tokens);
-
-        // ensure TOKENS is set
-        address setTokens = address(JBERC20(address(_erc20)).TOKENS());
-        assertEq(setTokens, _tokens);
-
-        // will fail as internal name is no longer zero length
-        vm.expectRevert();
-        _erc20.initialize(_name, _symbol, _tokens);
-    }
-
-    function test_WhenName_EQNothing() external {
-        // it will revert
-
-        // will fail as internal name is no longer than zero length
-        vm.expectRevert();
-        _erc20.initialize("", _symbol, _tokens);
-    }
-
-    function test_WhenNameIsValidAndNotAlreadySet() external {
-        // it will set the name, symbol, and store references
-
-        _erc20.initialize(_name, _symbol, _tokens);
-
-        // ensure TOKENS is set
-        address setTokens = address(JBERC20(address(_erc20)).TOKENS());
-        assertEq(setTokens, _tokens);
-
-        // name is set
-        string memory _setName = IERC20Metadata(address(_erc20)).name();
-        string memory _setSymbol = IERC20Metadata(address(_erc20)).symbol();
-
-        assertEq(_setName, _name);
-        assertEq(_setSymbol, _symbol);
-    }
-}

package/test/units/static/JBERC20/TestName.sol

@@ -1,30 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-import {JBERC20Setup} from "./JBERC20Setup.sol";
-
-contract TestName_Local is JBERC20Setup {
-    IERC20Metadata _token;
-
-    function setUp() public {
-        super.erc20Setup();
-
-        _token = IERC20Metadata(address(_erc20));
-    }
-
-    function test_WhenANameIsSet() external {
-        // it will return the name
-        _erc20.initialize("NANAPUS", "NANA", _tokens);
-
-        string memory _setName = _token.name();
-        assertEq(_setName, "NANAPUS");
-    }
-
-    function test_WhenANameIsNotSet() external view {
-        // it will return an empty string
-
-        string memory _storedName = _token.name();
-        assertEq(_storedName, "");
-    }
-}

package/test/units/static/JBERC20/TestNonces.sol

@@ -1,62 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {IERC20Permit} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Permit.sol";
-import {JBERC20Setup} from "./JBERC20Setup.sol";
-import {SigUtils} from "./SigUtils.sol";
-
-contract TestNonces_Local is JBERC20Setup {
-    address _user = makeAddr("user");
-    IERC20Permit _token;
-    SigUtils sigUtils;
-
-    // forge-lint: disable-next-line(screaming-snake-case-immutable)
-    bytes32 private immutable _hashedName = keccak256(bytes("JBToken"));
-    // forge-lint: disable-next-line(screaming-snake-case-immutable)
-    bytes32 private immutable _hashedVersion = keccak256(bytes("1"));
-
-    bytes32 _domain;
-
-    bytes32 private constant TYPE_HASH =
-        keccak256("EIP712Domain(string name,string version,uint256 chainId,address verifyingContract)");
-
-    function setUp() public {
-        super.erc20Setup();
-
-        _token = IERC20Permit(address(_erc20));
-        _domain = keccak256(abi.encode(TYPE_HASH, _hashedName, _hashedVersion, block.chainid, address(_token)));
-        sigUtils = new SigUtils(_domain);
-    }
-
-    function test_WhenAUserHasNotCalledPermit() external view {
-        // it will return zero
-
-        uint256 _nonce = _token.nonces(_user);
-
-        assertEq(_nonce, 0);
-    }
-
-    function test_WhenAUserHasCalledPermit() external {
-        // it will return a nonce GT zero
-
-        (address holder, uint256 holderPk) = makeAddrAndKey("hodler");
-
-        SigUtils.Permit memory permit = SigUtils.Permit({
-            owner: holder,
-            spender: address(this),
-            value: 1,
-            nonce: _token.nonces(holder),
-            deadline: block.timestamp + 1 days
-        });
-
-        bytes32 digest = sigUtils.getTypedDataHash(permit);
-
-        (uint8 v, bytes32 r, bytes32 s) = vm.sign(holderPk, digest);
-
-        vm.prank(holder);
-        _token.permit(holder, address(this), 1, block.timestamp + 1 days, v, r, s);
-
-        uint256 _nonce = _token.nonces(holder);
-        assertEq(_nonce, 1);
-    }
-}

package/test/units/static/JBERC20/TestSymbol.sol

@@ -1,31 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {IERC20Metadata} from "@openzeppelin/contracts/token/ERC20/extensions/IERC20Metadata.sol";
-import {JBERC20Setup} from "./JBERC20Setup.sol";
-
-contract TestSymbol_Local is JBERC20Setup {
-    IERC20Metadata _token;
-
-    function setUp() public {
-        super.erc20Setup();
-
-        _token = IERC20Metadata(address(_erc20));
-    }
-
-    function test_WhenASymbolIsSet() external {
-        // it will return a non-empty string
-
-        _erc20.initialize("NANAPUS", "NANA", _tokens);
-
-        string memory _setSymbol = _token.symbol();
-        assertEq(_setSymbol, "NANA");
-    }
-
-    function test_WhenASymbolIsNotSet() external view {
-        // it will return an empty string
-
-        string memory _setSymbol = _token.symbol();
-        assertEq(_setSymbol, "");
-    }
-}

package/test/units/static/JBFeelessAdresses/JBFeelessSetup.sol

@@ -1,22 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {JBFeelessAddresses} from "../../../../src/JBFeelessAddresses.sol";
-import {IJBFeelessAddresses} from "../../../../src/interfaces/IJBFeelessAddresses.sol";
-import {JBTest} from "../../../helpers/JBTest.sol";
-
-/*
-Contract that deploys a target contract with other mock contracts to satisfy the constructor.
-Tests relative to this contract will be dependent on mock calls/emits and stdStorage.
-*/
-contract JBFeelessSetup is JBTest {
-    address _owner = makeAddr("owner");
-
-    // Target Contract
-    IJBFeelessAddresses public _feelessAddresses;
-
-    function feelessAddressesSetup() public virtual {
-        // Instantiate the contract being tested
-        _feelessAddresses = new JBFeelessAddresses(_owner);
-    }
-}

package/test/units/static/JBFeelessAdresses/TestInterfaces.sol

@@ -1,30 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {IJBFeelessAddresses} from "../../../../src/interfaces/IJBFeelessAddresses.sol";
-import {IERC165} from "@openzeppelin/contracts/utils/introspection/ERC165.sol";
-import {JBFeelessSetup} from "./JBFeelessSetup.sol";
-
-contract TestSupportsInterface_Local is JBFeelessSetup {
-    function setUp() public {
-        super.feelessAddressesSetup();
-    }
-
-    function test_WhenItSupportsEitherIJBFeelessAddressesOrIERC165() external view {
-        // it should return true
-        bool result1 = IERC165(address(_feelessAddresses)).supportsInterface(type(IJBFeelessAddresses).interfaceId);
-        assertEq(result1, true);
-
-        bool result2 = IERC165(address(_feelessAddresses)).supportsInterface(type(IERC165).interfaceId);
-        assertEq(result2, true);
-    }
-
-    function test_WhenAskedIfSupportsNonIJBFeelessAddressesOrIERC165() external view {
-        // it should return false
-        bool result1 = IERC165(address(_feelessAddresses)).supportsInterface(0x12345678);
-        assertEq(result1, false);
-
-        bool result2 = IERC165(address(_feelessAddresses)).supportsInterface(0x12345679);
-        assertEq(result2, false);
-    }
-}

package/test/units/static/JBFeelessAdresses/TestSetFeelessAddress.sol

@@ -1,35 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {IJBFeelessAddresses} from "../../../../src/interfaces/IJBFeelessAddresses.sol";
-import {JBFeelessSetup} from "./JBFeelessSetup.sol";
-
-contract TestSetFeelessAddress_Local is JBFeelessSetup {
-    address _feeLess = makeAddr("something");
-
-    function setUp() public {
-        super.feelessAddressesSetup();
-    }
-
-    function test_WhenCallerIsOwner() external {
-        // it should set isFeeless and emit SetFeelessAddress
-        vm.expectEmit();
-        emit IJBFeelessAddresses.SetFeelessAddress(_feeLess, true, address(_owner));
-
-        vm.prank(_owner);
-        _feelessAddresses.setFeelessAddress(_feeLess, true);
-
-        bool result = _feelessAddresses.isFeeless(_feeLess);
-        assertEq(result, true);
-    }
-
-    function test_RevertIf_RevertWhen_CallerIsNotOwner() external {
-        address _multisig = makeAddr("multisig");
-        vm.prank(_multisig);
-        // it should revert  0x7FA9385bE102ac3EAc297483Dd6233D62b3e1496
-        bytes4 selector = bytes4(keccak256("OwnableUnauthorizedAccount(address)"));
-        bytes memory expectedError = abi.encodeWithSelector(selector, _multisig);
-        vm.expectRevert(expectedError);
-        _feelessAddresses.setFeelessAddress(_feeLess, true);
-    }
-}

package/test/units/static/JBFees/TestFeesFuzz.sol

@@ -1,79 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {JBConstants} from "../../../../src/libraries/JBConstants.sol";
-import {JBTest} from "../../../helpers/JBTest.sol";
-import {JBFees} from "../../../../src/libraries/JBFees.sol";
-
-/// @notice Fuzz tests for the JBFees library.
-contract TestFeesFuzz_Local is JBTest {
-    function setUp() external {}
-
-    /// @notice feeAmountFrom with feePercent=0 returns 0.
-    function testFuzz_feeAmountFrom_zeroPercent(uint256 amount) external pure {
-        amount = bound(amount, 0, type(uint128).max);
-        uint256 fee = JBFees.feeAmountFrom(amount, 0);
-        assertEq(fee, 0, "fee with 0% should be 0");
-    }
-
-    /// @notice feeAmountFrom with amount=0 returns 0.
-    function testFuzz_feeAmountFrom_zeroAmount(uint256 feePercent) external pure {
-        feePercent = bound(feePercent, 0, JBConstants.MAX_FEE);
-        uint256 fee = JBFees.feeAmountFrom(0, feePercent);
-        assertEq(fee, 0, "fee on 0 amount should be 0");
-    }
-
-    /// @notice fee + remainder == amount (conservation).
-    /// @dev feeAmountFrom(amount, percent) + (amount - feeAmountFrom(amount, percent)) == amount
-    function testFuzz_feeAmountFrom_conservation(uint256 amount, uint256 feePercent) external pure {
-        amount = bound(amount, 0, type(uint128).max);
-        feePercent = bound(feePercent, 0, JBConstants.MAX_FEE);
-
-        uint256 fee = JBFees.feeAmountFrom(amount, feePercent);
-        uint256 remainder = amount - fee;
-
-        assertEq(fee + remainder, amount, "fee + remainder must equal amount");
-        assertLe(fee, amount, "fee must not exceed amount");
-    }
-
-    /// @notice fee is monotonically increasing with amount (for fixed percent).
-    function testFuzz_feeAmountFrom_monotonic(uint256 amount1, uint256 amount2, uint256 feePercent) external pure {
-        amount1 = bound(amount1, 0, type(uint64).max);
-        amount2 = bound(amount2, amount1, type(uint64).max);
-        feePercent = bound(feePercent, 0, JBConstants.MAX_FEE);
-
-        uint256 fee1 = JBFees.feeAmountFrom(amount1, feePercent);
-        uint256 fee2 = JBFees.feeAmountFrom(amount2, feePercent);
-
-        assertLe(fee1, fee2, "fee should be monotonically increasing with amount");
-    }
-
-    /// @notice feeAmountFrom and feeAmountResultingIn are directionally consistent.
-    /// @dev feeAmountResultingIn(afterFee, percent) >= fee from feeAmountFrom.
-    ///      The reverse operation should always produce a fee that covers the forward fee.
-    function testFuzz_feeSymmetry(uint256 amount, uint256 feePercent) external pure {
-        amount = bound(amount, 1, type(uint64).max);
-        feePercent = bound(feePercent, 1, JBConstants.MAX_FEE - 1); // Avoid 0% and 100%
-
-        // Forward: calculate fee from amount
-        uint256 fee = JBFees.feeAmountFrom(amount, feePercent);
-        uint256 afterFee = amount - fee;
-
-        // Reverse: from afterFee, what fee would produce afterFee as the result?
-        uint256 reverseFee = JBFees.feeAmountResultingIn(afterFee, feePercent);
-
-        // The reverse fee should always be >= the forward fee (it rounds up to ensure
-        // the total with fee >= the original amount).
-        assertGe(reverseFee, fee, "reverse fee should be >= forward fee");
-
-        // And the total should be >= the original amount (reverse is conservative)
-        assertGe(reverseFee + afterFee, amount, "reverse fee + afterFee should be >= amount");
-    }
-
-    /// @notice feeAmountFrom with MAX_FEE returns the full amount.
-    function testFuzz_feeAmountFrom_maxPercent(uint256 amount) external pure {
-        amount = bound(amount, 0, type(uint128).max);
-        uint256 fee = JBFees.feeAmountFrom(amount, JBConstants.MAX_FEE);
-        assertEq(fee, amount, "fee at MAX_FEE should equal amount");
-    }
-}

package/test/units/static/JBFixedPointNumber/TestAdjustDecimals.sol

@@ -1,16 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {JBTest} from "../../../helpers/JBTest.sol";
-import {JBFixedPointNumber} from "../../../../src/libraries/JBFixedPointNumber.sol";
-
-contract TestAdjustDecimals_Local is JBTest {
-    function setUp() external {}
-
-    function testWhenTargetEqDecimals() external pure {
-        // it will return the value parameter provided
-
-        uint256 returned = JBFixedPointNumber.adjustDecimals(1e18, 6, 6);
-        assertEq(returned, 1e18);
-    }
-}

package/test/units/static/JBFixedPointNumber/TestAdjustDecimalsFuzz.sol

@@ -1,71 +0,0 @@
-// SPDX-License-Identifier: MIT
-pragma solidity 0.8.28;
-
-import {JBTest} from "../../../helpers/JBTest.sol";
-import {JBFixedPointNumber} from "../../../../src/libraries/JBFixedPointNumber.sol";
-
-/// @notice Fuzz tests for JBFixedPointNumber.adjustDecimals.
-contract TestAdjustDecimalsFuzz_Local is JBTest {
-    function setUp() external {}
-
-    /// @notice Same decimals returns the value unchanged.
-    function testFuzz_sameDecimals(uint256 value, uint8 decimals) external pure {
-        decimals = uint8(bound(uint256(decimals), 0, 36));
-        uint256 result = JBFixedPointNumber.adjustDecimals(value, decimals, decimals);
-        assertEq(result, value, "same decimals should return value unchanged");
-    }
-
-    /// @notice Scale up then down round-trip preserves value (modulo rounding loss).
-    function testFuzz_roundTrip_upThenDown(uint256 value, uint8 fromDecimals, uint8 toDecimals) external pure {
-        fromDecimals = uint8(bound(uint256(fromDecimals), 0, 18));
-        toDecimals = uint8(bound(uint256(toDecimals), fromDecimals, 36));
-
-        // Avoid overflow: value * 10^(toDecimals - fromDecimals) must fit in uint256
-        uint256 scaleFactor = 10 ** (toDecimals - fromDecimals);
-        if (scaleFactor > 0 && value > type(uint256).max / scaleFactor) return;
-
-        uint256 scaled = JBFixedPointNumber.adjustDecimals(value, fromDecimals, toDecimals);
-        uint256 restored = JBFixedPointNumber.adjustDecimals(scaled, toDecimals, fromDecimals);
-
-        assertEq(restored, value, "round trip (up then down) should restore original value");
-    }
-
-    /// @notice Scale down then up loses precision but never exceeds original.
-    function testFuzz_roundTrip_downThenUp(uint256 value, uint8 fromDecimals, uint8 toDecimals) external pure {
-        fromDecimals = uint8(bound(uint256(fromDecimals), 0, 36));
-        toDecimals = uint8(bound(uint256(toDecimals), 0, fromDecimals));
-
-        uint256 scaled = JBFixedPointNumber.adjustDecimals(value, fromDecimals, toDecimals);
-
-        // Scale back up
-        uint256 scaleFactor = 10 ** (fromDecimals - toDecimals);
-        if (scaleFactor > 0 && scaled > type(uint256).max / scaleFactor) return;
-
-        uint256 restored = JBFixedPointNumber.adjustDecimals(scaled, toDecimals, fromDecimals);
-
-        assertLe(restored, value, "round trip (down then up) should not exceed original");
-    }
-
-    /// @notice Scaling up increases value when decimals differ.
-    function testFuzz_scaleUp_increases(uint256 value, uint8 fromDecimals, uint8 toDecimals) external pure {
-        value = bound(value, 1, 1e36);
-        fromDecimals = uint8(bound(uint256(fromDecimals), 0, 18));
-        toDecimals = uint8(bound(uint256(toDecimals), fromDecimals + 1, 36));
-
-        uint256 result = JBFixedPointNumber.adjustDecimals(value, fromDecimals, toDecimals);
-        assertGt(result, value, "scaling up with more decimals should increase value");
-    }
-
-    /// @notice Scaling down returns zero for small values.
-    function testFuzz_scaleDown_smallValue(uint8 fromDecimals, uint8 toDecimals) external pure {
-        fromDecimals = uint8(bound(uint256(fromDecimals), 1, 36));
-        toDecimals = uint8(bound(uint256(toDecimals), 0, fromDecimals - 1));
-
-        uint256 scaleFactor = 10 ** (fromDecimals - toDecimals);
-        // Value smaller than the scale factor should round to 0
-        uint256 value = scaleFactor - 1;
-
-        uint256 result = JBFixedPointNumber.adjustDecimals(value, fromDecimals, toDecimals);
-        assertEq(result, 0, "value below scale factor should round to 0");
-    }
-}