@bananapus/core-v6 0.0.1

package/test/TestJBERC20Inheritance.sol

@@ -0,0 +1,91 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.23;
+
+import /* {*} from */ "./helpers/TestBaseWorkflow.sol";
+
+import {ERC20Votes} from "../src/JBERC20.sol";
+
+contract JBERC20Inheritance_Local is JBERC20, TestBaseWorkflow {
+    /// This test is to verify that the inheritance order of JBERC20 is correct and that it calls the
+    /// `ERC20Votes._update()`
+    /// forge-config: default.allow_internal_expect_revert = true
+    function test_votesUpdate() public {
+        uint256 _max = _maxSupply();
+        vm.expectRevert(abi.encodeWithSelector(ERC20Votes.ERC20ExceededSafeSupply.selector, _max + 1, _max));
+
+        _update(address(0), address(100), _max + 1);
+    }
+
+    // This test checks that voting power gets accounted for.
+    function test_votesUpdateOnTransfer() public {
+        JBRulesetMetadata memory _metadata = JBRulesetMetadata({
+            reservedPercent: 0,
+            cashOutTaxRate: 0,
+            baseCurrency: uint32(uint160(JBConstants.NATIVE_TOKEN)),
+            pausePay: false,
+            pauseCreditTransfers: false,
+            allowOwnerMinting: true,
+            allowSetCustomToken: false,
+            allowTerminalMigration: false,
+            allowSetTerminals: false,
+            ownerMustSendPayouts: false,
+            allowSetController: false,
+            allowAddAccountingContext: true,
+            allowAddPriceFeed: false,
+            holdFees: false,
+            useTotalSurplusForCashOuts: false,
+            useDataHookForPay: true,
+            useDataHookForCashOut: true,
+            dataHook: address(0),
+            metadata: 0
+        });
+        address _projectOwner = multisig();
+        address _recipient = address(200);
+        uint256 _amount = 10 ether;
+
+        // Package up ruleset configuration.
+        JBRulesetConfig[] memory _rulesetConfig = new JBRulesetConfig[](1);
+        _rulesetConfig[0].mustStartAtOrAfter = 0;
+        _rulesetConfig[0].duration = 0;
+        _rulesetConfig[0].weight = 0;
+        _rulesetConfig[0].weightCutPercent = 0;
+        _rulesetConfig[0].approvalHook = IJBRulesetApprovalHook(address(0));
+        _rulesetConfig[0].metadata = _metadata;
+        _rulesetConfig[0].splitGroups = new JBSplitGroup[](0);
+        _rulesetConfig[0].fundAccessLimitGroups = new JBFundAccessLimitGroup[](0);
+
+        // Package up terminal configuration.
+        JBTerminalConfig[] memory _terminalConfigurations = new JBTerminalConfig[](1);
+        JBAccountingContext[] memory _tokensToAccept = new JBAccountingContext[](1);
+        _tokensToAccept[0] = JBAccountingContext({
+            token: JBConstants.NATIVE_TOKEN, decimals: 18, currency: uint32(uint160(JBConstants.NATIVE_TOKEN))
+        });
+        _terminalConfigurations[0] =
+            JBTerminalConfig({terminal: jbMultiTerminal(), accountingContextsToAccept: _tokensToAccept});
+
+        uint256 projectId = jbController()
+            .launchProjectFor({
+                owner: _projectOwner,
+                projectUri: "myIPFSHash",
+                rulesetConfigurations: _rulesetConfig,
+                terminalConfigurations: _terminalConfigurations,
+                memo: ""
+            });
+
+        // Configure a token.
+        vm.prank(_projectOwner);
+        IJBToken _token = jbController().deployERC20For(projectId, "TestToken", "TEST", bytes32(0));
+
+        // Have the user delegate to themselves.
+        vm.prank(_recipient);
+        ERC20Votes(address(_token)).delegate(_recipient);
+
+        // Mint tokens to the user, check that the balance is correct.
+        vm.startPrank(_projectOwner);
+        jbController().mintTokensOf(projectId, _amount, _recipient, "", false);
+        assertEq(_token.balanceOf(_recipient), _amount);
+
+        // Assert that the user received the voting power as expected.
+        assertEq(ERC20Votes(address(_token)).getVotes(_recipient), _amount);
+    }
+}

package/test/TestLaunchProject.sol

@@ -0,0 +1,176 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.6;
+
+import /* {*} from */ "./helpers/TestBaseWorkflow.sol";
+
+// Projects can be launched.
+contract TestLaunchProject_Local is TestBaseWorkflow {
+    IJBController private _controller;
+    JBRulesetMetadata private _metadata;
+    IJBTerminal private _terminal;
+    IJBRulesets private _rulesets;
+
+    address private _projectOwner;
+
+    function setUp() public override {
+        super.setUp();
+
+        _projectOwner = multisig();
+        _terminal = jbMultiTerminal();
+        _controller = jbController();
+        _rulesets = jbRulesets();
+
+        _metadata = JBRulesetMetadata({
+            reservedPercent: 0,
+            cashOutTaxRate: 0,
+            baseCurrency: uint32(uint160(JBConstants.NATIVE_TOKEN)),
+            pausePay: false,
+            pauseCreditTransfers: false,
+            allowOwnerMinting: false,
+            allowSetCustomToken: false,
+            allowTerminalMigration: false,
+            allowSetTerminals: false,
+            ownerMustSendPayouts: false,
+            allowSetController: false,
+            allowAddAccountingContext: true,
+            allowAddPriceFeed: false,
+            holdFees: false,
+            useTotalSurplusForCashOuts: false,
+            useDataHookForPay: false,
+            useDataHookForCashOut: false,
+            dataHook: address(0),
+            metadata: 0
+        });
+    }
+
+    function equals(JBRuleset memory queued, JBRuleset memory stored) internal pure returns (bool) {
+        // Just compare the output of hashing all fields packed.
+        return (keccak256(
+                    abi.encodePacked(
+                        queued.cycleNumber,
+                        queued.id,
+                        queued.basedOnId,
+                        queued.start,
+                        queued.duration,
+                        queued.weight,
+                        queued.weightCutPercent,
+                        queued.approvalHook,
+                        queued.metadata
+                    )
+                )
+                == keccak256(
+                    abi.encodePacked(
+                        stored.cycleNumber,
+                        stored.id,
+                        stored.basedOnId,
+                        stored.start,
+                        stored.duration,
+                        stored.weight,
+                        stored.weightCutPercent,
+                        stored.approvalHook,
+                        stored.metadata
+                    )
+                ));
+    }
+
+    function testLaunchProject() public {
+        // Package up ruleset configuration.
+        JBRulesetConfig[] memory _rulesetConfig = new JBRulesetConfig[](1);
+        _rulesetConfig[0].mustStartAtOrAfter = 0;
+        _rulesetConfig[0].duration = 0;
+        _rulesetConfig[0].weight = 0;
+        _rulesetConfig[0].weightCutPercent = 0;
+        _rulesetConfig[0].approvalHook = IJBRulesetApprovalHook(address(0));
+        _rulesetConfig[0].metadata = _metadata;
+        _rulesetConfig[0].splitGroups = new JBSplitGroup[](0);
+        _rulesetConfig[0].fundAccessLimitGroups = new JBFundAccessLimitGroup[](0);
+
+        // Package up terminal configuration.
+        JBTerminalConfig[] memory _terminalConfigurations = new JBTerminalConfig[](1);
+        JBAccountingContext[] memory _tokensToAccept = new JBAccountingContext[](1);
+        _tokensToAccept[0] = JBAccountingContext({
+            token: JBConstants.NATIVE_TOKEN, decimals: 18, currency: uint32(uint160(JBConstants.NATIVE_TOKEN))
+        });
+        _terminalConfigurations[0] =
+            JBTerminalConfig({terminal: _terminal, accountingContextsToAccept: _tokensToAccept});
+
+        uint256 projectId = _controller.launchProjectFor({
+            owner: _projectOwner,
+            projectUri: "myIPFSHash",
+            rulesetConfigurations: _rulesetConfig,
+            terminalConfigurations: _terminalConfigurations,
+            memo: ""
+        });
+
+        // Get a reference to the first ruleset.
+        JBRuleset memory ruleset = _rulesets.currentOf(projectId);
+
+        // Reference queued attributes for sake of comparison.
+        JBRuleset memory queued = JBRuleset({
+            cycleNumber: 1,
+            id: uint48(block.timestamp),
+            basedOnId: 0,
+            start: uint48(block.timestamp),
+            duration: 0,
+            weight: 0,
+            weightCutPercent: 0,
+            approvalHook: IJBRulesetApprovalHook(address(0)),
+            metadata: ruleset.metadata
+        });
+
+        bool same = equals(queued, ruleset);
+
+        assertEq(same, true);
+    }
+
+    function testLaunchProjectFuzzWeight(uint112 _weight) public {
+        uint256 _projectId;
+
+        // Package up ruleset configuration.
+        JBRulesetConfig[] memory _rulesetConfig = new JBRulesetConfig[](1);
+        _rulesetConfig[0].mustStartAtOrAfter = 0;
+        _rulesetConfig[0].duration = 14;
+        _rulesetConfig[0].weight = _weight;
+        _rulesetConfig[0].weightCutPercent = 450_000_000;
+        _rulesetConfig[0].approvalHook = IJBRulesetApprovalHook(address(0));
+        _rulesetConfig[0].metadata = _metadata;
+        _rulesetConfig[0].splitGroups = new JBSplitGroup[](0);
+        _rulesetConfig[0].fundAccessLimitGroups = new JBFundAccessLimitGroup[](0);
+
+        // Package up terminal configuration.
+        JBTerminalConfig[] memory _terminalConfigurations = new JBTerminalConfig[](1);
+        JBAccountingContext[] memory _tokensToAccept = new JBAccountingContext[](1);
+        _tokensToAccept[0] = JBAccountingContext({
+            token: JBConstants.NATIVE_TOKEN, decimals: 18, currency: uint32(uint160(JBConstants.NATIVE_TOKEN))
+        });
+        _terminalConfigurations[0] =
+            JBTerminalConfig({terminal: _terminal, accountingContextsToAccept: _tokensToAccept});
+
+        _projectId = _controller.launchProjectFor({
+            owner: _projectOwner,
+            projectUri: "myIPFSHash",
+            rulesetConfigurations: _rulesetConfig,
+            terminalConfigurations: _terminalConfigurations,
+            memo: ""
+        });
+
+        JBRuleset memory ruleset = _rulesets.currentOf(_projectId);
+
+        // Reference queued attributes for sake of comparison.
+        JBRuleset memory queued = JBRuleset({
+            cycleNumber: 1,
+            id: uint48(block.timestamp),
+            basedOnId: 0,
+            start: uint48(block.timestamp),
+            duration: _rulesetConfig[0].duration,
+            weight: _weight,
+            weightCutPercent: _rulesetConfig[0].weightCutPercent,
+            approvalHook: _rulesetConfig[0].approvalHook,
+            metadata: ruleset.metadata
+        });
+
+        bool same = equals(queued, ruleset);
+
+        assertEq(same, true);
+    }
+}

package/test/TestMetaTx.sol

@@ -0,0 +1,203 @@
+// SPDX-License-Identifier: MIT
+pragma solidity >=0.8.6;
+
+import /* {*} from */ "./helpers/TestBaseWorkflow.sol";
+import {ERC2771Forwarder} from "@openzeppelin/contracts/metatx/ERC2771Forwarder.sol";
+import {ERC2771ForwarderMock, ForwardRequest} from "./mock/ERC2771ForwarderMock.sol";
+
+contract TestMetaTx_Local is TestBaseWorkflow {
+    uint112 private constant _WEIGHT = 1000 * 10 ** 18;
+
+    IJBController private _controller;
+    IJBMultiTerminal private _terminal;
+    JBTokens private _tokens;
+    ERC2771ForwarderMock internal _erc2771Forwarder = ERC2771ForwarderMock(address(123_456));
+    address private _projectOwner;
+
+    uint256 _projectId;
+
+    // Meta Tx guys
+    uint256 internal _signerPrivateKey;
+    uint256 internal _relayerPrivateKey;
+    address internal _signer;
+    address internal _relayer;
+
+    // utility function - setUp() is below
+    function _forgeRequestData(
+        uint256 value,
+        uint256 nonce,
+        uint48 deadline,
+        bytes memory data,
+        address target
+    )
+        private
+        view
+        returns (ERC2771Forwarder.ForwardRequestData memory)
+    {
+        ForwardRequest memory request = ForwardRequest({
+            from: _signer, to: address(target), value: value, gas: 300_000, nonce: nonce, deadline: deadline, data: data
+        });
+
+        bytes32 digest = _erc2771Forwarder.structHash(request);
+        (uint8 v, bytes32 r, bytes32 s) = vm.sign(_signerPrivateKey, digest);
+        bytes memory signature = abi.encodePacked(r, s, v);
+
+        return ERC2771Forwarder.ForwardRequestData({
+            from: request.from,
+            to: request.to,
+            value: request.value,
+            gas: request.gas,
+            deadline: request.deadline,
+            data: request.data,
+            signature: signature
+        });
+    }
+
+    function setUp() public override {
+        super.setUp();
+
+        _controller = jbController();
+        _tokens = jbTokens();
+        _terminal = jbMultiTerminal();
+
+        // Deploy forwarder
+        deployCodeTo("ERC2771ForwarderMock.sol", abi.encode("ERC2771Forwarder"), address(123_456));
+
+        _signerPrivateKey = 0xA11CE;
+        _relayerPrivateKey = 0xB0B;
+
+        _signer = vm.addr(_signerPrivateKey);
+        _relayer = vm.addr(_relayerPrivateKey);
+
+        // In case we need to test access control
+        _projectOwner = _signer;
+
+        JBRulesetMetadata memory _metadata = JBRulesetMetadata({
+            reservedPercent: 0,
+            cashOutTaxRate: 0,
+            baseCurrency: uint32(uint160(JBConstants.NATIVE_TOKEN)),
+            pausePay: false,
+            pauseCreditTransfers: false,
+            allowOwnerMinting: true,
+            allowSetCustomToken: true,
+            allowTerminalMigration: false,
+            allowSetTerminals: false,
+            ownerMustSendPayouts: false,
+            allowSetController: false,
+            allowAddAccountingContext: true,
+            allowAddPriceFeed: false,
+            holdFees: false,
+            useTotalSurplusForCashOuts: false,
+            useDataHookForPay: false,
+            useDataHookForCashOut: false,
+            dataHook: address(0),
+            metadata: 0
+        });
+
+        // Package up cycle config.
+        JBRulesetConfig[] memory _rulesetConfig = new JBRulesetConfig[](1);
+        _rulesetConfig[0].mustStartAtOrAfter = 0;
+        _rulesetConfig[0].duration = 0;
+        _rulesetConfig[0].weight = _WEIGHT;
+        _rulesetConfig[0].weightCutPercent = 0;
+        _rulesetConfig[0].approvalHook = IJBRulesetApprovalHook(address(0));
+        _rulesetConfig[0].metadata = _metadata;
+        _rulesetConfig[0].splitGroups = new JBSplitGroup[](0);
+        _rulesetConfig[0].fundAccessLimitGroups = new JBFundAccessLimitGroup[](0);
+
+        JBTerminalConfig[] memory _terminalConfigurations = new JBTerminalConfig[](1);
+        JBAccountingContext[] memory _tokensToAccept = new JBAccountingContext[](1);
+        _tokensToAccept[0] = JBAccountingContext({
+            token: JBConstants.NATIVE_TOKEN, decimals: 18, currency: uint32(uint160(JBConstants.NATIVE_TOKEN))
+        });
+        _terminalConfigurations[0] =
+            JBTerminalConfig({terminal: _terminal, accountingContextsToAccept: _tokensToAccept});
+
+        // First project for fee collection
+        _controller.launchProjectFor({
+            owner: _projectOwner,
+            projectUri: "myIPFSHash",
+            rulesetConfigurations: _rulesetConfig,
+            terminalConfigurations: _terminalConfigurations,
+            memo: ""
+        });
+
+        _projectId = _controller.launchProjectFor({
+            owner: _projectOwner,
+            projectUri: "myIPFSHash",
+            rulesetConfigurations: _rulesetConfig,
+            terminalConfigurations: _terminalConfigurations,
+            memo: ""
+        });
+    }
+
+    function testForwarderDeployed() public view {
+        // Check: forwarder deployed to address
+        assertEq(_erc2771Forwarder.deployed(), true);
+    }
+
+    function testMetaPayAndMetaCashOut() public {
+        // Setup: pay amounts, set balances
+        uint256 _payAmount = 1 ether;
+        vm.deal(_relayer, 1 ether);
+
+        // Setup: meta tx data
+        bytes memory _data = abi.encodeWithSelector(
+            IJBTerminal.pay.selector,
+            _projectId,
+            JBConstants.NATIVE_TOKEN,
+            _payAmount,
+            _signer,
+            0, // minReturnedTokens
+            "Take my money!", // memo
+            "" // metadata, empty bytes
+        );
+
+        // Setup: forwarder request data
+        ERC2771Forwarder.ForwardRequestData memory requestData = _forgeRequestData({
+            value: _payAmount, nonce: 0, deadline: uint48(block.timestamp + 1), data: _data, target: address(_terminal)
+        });
+
+        // Send: "Meta Tx" (signed by _signer) from relayer to our trusted forwarder
+        vm.prank(_relayer);
+        _erc2771Forwarder.execute{value: _payAmount}(requestData);
+
+        // Check: Ensure balance left the relayer (sponsor)
+        assertEq(_relayer.balance, 0);
+
+        // Check: Ensure terminal has ETH from meta tx
+        assertEq(address(_terminal).balance, 1 ether);
+
+        // Check: Ensure the beneficiary (signer) has a balance of tokens.
+        uint256 _beneficiaryTokenBalance = UD60x18unwrap(UD60x18mul(UD60x18wrap(_payAmount), UD60x18wrap(_WEIGHT)));
+        assertEq(_tokens.totalBalanceOf(_signer, _projectId), _beneficiaryTokenBalance);
+
+        // Setup 2: meta tx data for cash outs
+        bytes memory _data2 = abi.encodeWithSelector(
+            IJBCashOutTerminal.cashOutTokensOf.selector,
+            _signer,
+            _projectId,
+            _beneficiaryTokenBalance,
+            JBConstants.NATIVE_TOKEN,
+            0, // minReturnedTokens
+            payable(_signer),
+            "Gimme my money!", // memo
+            "" // metadata, empty bytes
+        );
+
+        // Setup 2: forwarder request data with incremented nonce for cash out tx
+        ERC2771Forwarder.ForwardRequestData memory requestData2 = _forgeRequestData({
+            value: 0, nonce: 1, deadline: uint48(block.timestamp + 1), data: _data2, target: address(_terminal)
+        });
+
+        // Setup 2: Give relayer some gas gas gasssss
+        vm.deal(_relayer, 1 ether);
+
+        // Send 2 : "Meta Tx #2" (signed by _signer) from relayer to our trusted forwarder
+        vm.prank(_relayer);
+        _erc2771Forwarder.execute{value: 0}(requestData2);
+
+        // Check 2: original signer has ETH back
+        assertEq(_signer.balance, 1 ether);
+    }
+}