@bananapus/721-hook-v6 0.0.1

package/src/abstract/JB721Hook.sol

@@ -0,0 +1,279 @@
+// SPDX-License-Identifier: MIT
+pragma solidity 0.8.23;
+
+import {IJBCashOutHook} from "@bananapus/core-v6/src/interfaces/IJBCashOutHook.sol";
+import {IJBDirectory} from "@bananapus/core-v6/src/interfaces/IJBDirectory.sol";
+import {IJBPayHook} from "@bananapus/core-v6/src/interfaces/IJBPayHook.sol";
+import {IJBRulesetDataHook} from "@bananapus/core-v6/src/interfaces/IJBRulesetDataHook.sol";
+import {IJBTerminal} from "@bananapus/core-v6/src/interfaces/IJBTerminal.sol";
+import {JBConstants} from "@bananapus/core-v6/src/libraries/JBConstants.sol";
+import {JBMetadataResolver} from "@bananapus/core-v6/src/libraries/JBMetadataResolver.sol";
+import {JBAfterPayRecordedContext} from "@bananapus/core-v6/src/structs/JBAfterPayRecordedContext.sol";
+import {JBAfterCashOutRecordedContext} from "@bananapus/core-v6/src/structs/JBAfterCashOutRecordedContext.sol";
+import {JBBeforePayRecordedContext} from "@bananapus/core-v6/src/structs/JBBeforePayRecordedContext.sol";
+import {JBBeforeCashOutRecordedContext} from "@bananapus/core-v6/src/structs/JBBeforeCashOutRecordedContext.sol";
+import {JBCashOutHookSpecification} from "@bananapus/core-v6/src/structs/JBCashOutHookSpecification.sol";
+import {JBPayHookSpecification} from "@bananapus/core-v6/src/structs/JBPayHookSpecification.sol";
+import {JBRuleset} from "@bananapus/core-v6/src/structs/JBRuleset.sol";
+import {IERC2981} from "@openzeppelin/contracts/interfaces/IERC2981.sol";
+import {IERC165} from "@openzeppelin/contracts/utils/introspection/IERC165.sol";
+import {mulDiv} from "@prb/math/src/Common.sol";
+
+import {ERC721} from "./ERC721.sol";
+import {IJB721Hook} from "../interfaces/IJB721Hook.sol";
+
+/// @title JB721Hook
+/// @notice When a project which uses this hook is paid, this hook may mint NFTs to the payer, depending on this hook's
+/// setup, the amount paid, and information specified by the payer. The project's owner can enable NFT cash outs.
+/// through this hook, allowing the NFT holders to burn their NFTs to reclaim funds from the project (in proportion to
+/// the NFT's price).
+abstract contract JB721Hook is ERC721, IJB721Hook {
+    //*********************************************************************//
+    // --------------------------- custom errors ------------------------- //
+    //*********************************************************************//
+
+    error JB721Hook_InvalidCashOut();
+    error JB721Hook_InvalidPay();
+    error JB721Hook_UnauthorizedToken(uint256 tokenId, address holder);
+    error JB721Hook_UnexpectedTokenCashedOut();
+
+    //*********************************************************************//
+    // --------------- public immutable stored properties ---------------- //
+    //*********************************************************************//
+
+    /// @notice The directory of terminals and controllers for projects.
+    IJBDirectory public immutable override DIRECTORY;
+
+    /// @notice The ID used when parsing metadata.
+    address public immutable override METADATA_ID_TARGET;
+
+    //*********************************************************************//
+    // -------------------- public stored properties --------------------- //
+    //*********************************************************************//
+
+    /// @notice The ID of the project that this contract is associated with.
+    uint256 public override PROJECT_ID;
+
+    //*********************************************************************//
+    // -------------------------- constructor ---------------------------- //
+    //*********************************************************************//
+
+    /// @param directory A directory of terminals and controllers for projects.
+    constructor(IJBDirectory directory) {
+        DIRECTORY = directory;
+        // Store the address of the original hook deploy. Clones will each use the address of the instance they're based
+        // on.
+        METADATA_ID_TARGET = address(this);
+    }
+
+    //*********************************************************************//
+    // ------------------------- external views -------------------------- //
+    //*********************************************************************//
+
+    /// @notice The data calculated before a payment is recorded in the terminal store. This data is provided to the
+    /// terminal's `pay(...)` transaction.
+    /// @dev Sets this contract as the pay hook. Part of `IJBRulesetDataHook`.
+    /// @param context The payment context passed to this contract by the `pay(...)` function.
+    /// @return weight The new `weight` to use, overriding the ruleset's `weight`.
+    /// @return hookSpecifications The amount and data to send to pay hooks (this contract) instead of adding to the
+    /// terminal's balance.
+    function beforePayRecordedWith(JBBeforePayRecordedContext calldata context)
+        public
+        view
+        virtual
+        override
+        returns (uint256 weight, JBPayHookSpecification[] memory hookSpecifications)
+    {
+        // Forward the received weight and memo, and use this contract as the only pay hook.
+        weight = context.weight;
+        hookSpecifications = new JBPayHookSpecification[](1);
+        hookSpecifications[0] = JBPayHookSpecification({hook: this, amount: 0, metadata: bytes("")});
+    }
+
+    /// @notice The data calculated before a cash out is recorded in the terminal store. This data is provided to the
+    /// terminal's `cashOutTokensOf(...)` transaction.
+    /// @dev Sets this contract as the cash out hook. Part of `IJBRulesetDataHook`.
+    /// @dev This function is used for NFT cash outs, and will only be called if the project's ruleset has
+    /// `useDataHookForCashOut` set to `true`.
+    /// @param context The cash out context passed to this contract by the `cashOutTokensOf(...)` function.
+    /// @return cashOutTaxRate The cash out tax rate influencing the reclaim amount.
+    /// @return cashOutCount The amount of tokens that should be considered cashed out.
+    /// @return totalSupply The total amount of tokens that are considered to be existing.
+    /// @return hookSpecifications The amount and data to send to cash out hooks (this contract) instead of returning to
+    /// the beneficiary.
+    function beforeCashOutRecordedWith(JBBeforeCashOutRecordedContext calldata context)
+        public
+        view
+        virtual
+        override
+        returns (
+            uint256 cashOutTaxRate,
+            uint256 cashOutCount,
+            uint256 totalSupply,
+            JBCashOutHookSpecification[] memory hookSpecifications
+        )
+    {
+        // Make sure (fungible) project tokens aren't also being cashed out.
+        if (context.cashOutCount > 0) revert JB721Hook_UnexpectedTokenCashedOut();
+
+        // Fetch the cash out hook metadata using the corresponding metadata ID.
+        (bool metadataExists, bytes memory metadata) = JBMetadataResolver.getDataFor({
+            id: JBMetadataResolver.getId({purpose: "cashOut", target: METADATA_ID_TARGET}), metadata: context.metadata
+        });
+
+        // Use this contract as the only cash out hook.
+        hookSpecifications = new JBCashOutHookSpecification[](1);
+        hookSpecifications[0] = JBCashOutHookSpecification({hook: this, amount: 0, metadata: bytes("")});
+
+        uint256[] memory decodedTokenIds;
+
+        // Decode the metadata.
+        if (metadataExists) decodedTokenIds = abi.decode(metadata, (uint256[]));
+
+        // Use the cash out weight of the provided 721s.
+        cashOutCount = cashOutWeightOf({tokenIds: decodedTokenIds, context: context});
+
+        // Use the total cash out weight of the 721s.
+        totalSupply = totalCashOutWeight(context);
+
+        // Use the cash out tax rate from the context.
+        cashOutTaxRate = context.cashOutTaxRate;
+    }
+
+    /// @notice Required by the IJBRulesetDataHook interfaces. Return false to not leak any permissions.
+    function hasMintPermissionFor(uint256, JBRuleset memory, address) external pure returns (bool) {
+        return false;
+    }
+
+    //*********************************************************************//
+    // -------------------------- public views --------------------------- //
+    //*********************************************************************//
+
+    /// @notice Returns the cumulative cash out weight of the specified token IDs relative to the
+    /// `totalCashOutWeight`.
+    /// @param tokenIds The NFT token IDs to calculate the cumulative cash out weight of.
+    /// @param context The cash out context passed to this contract by the `cashOutTokensOf(...)` function.
+    /// @return The cumulative cash out weight of the specified token IDs.
+    function cashOutWeightOf(
+        uint256[] memory tokenIds,
+        JBBeforeCashOutRecordedContext calldata context
+    )
+        public
+        view
+        virtual
+        returns (uint256)
+    {
+        tokenIds; // Prevents unused var compiler and natspec complaints.
+        context; // Prevents unused var compiler and natspec complaints.
+        return 0;
+    }
+
+    /// @notice Indicates if this contract adheres to the specified interface.
+    /// @dev See {IERC165-supportsInterface}.
+    /// @param interfaceId The ID of the interface to check for adherence to.
+    function supportsInterface(bytes4 interfaceId) public view virtual override(ERC721, IERC165) returns (bool) {
+        return interfaceId == type(IJB721Hook).interfaceId || interfaceId == type(IJBRulesetDataHook).interfaceId
+            || interfaceId == type(IJBPayHook).interfaceId || interfaceId == type(IJBCashOutHook).interfaceId
+            || interfaceId == type(IERC2981).interfaceId || super.supportsInterface(interfaceId);
+    }
+
+    /// @notice Calculates the cumulative cash out weight of all NFT token IDs.
+    /// @param context The cash out context passed to this contract by the `cashOutTokensOf(...)` function.
+    /// @return The total cumulative cash out weight of all NFT token IDs.
+    function totalCashOutWeight(JBBeforeCashOutRecordedContext calldata context) public view virtual returns (uint256) {
+        context; // Prevents unused var compiler and natspec complaints.
+        return 0;
+    }
+
+    //*********************************************************************//
+    // ---------------------- external transactions ---------------------- //
+    //*********************************************************************//
+
+    /// @notice Mints one or more NFTs to the `context.beneficiary` upon payment if conditions are met. Part of
+    /// `IJBPayHook`.
+    /// @dev Reverts if the calling contract is not one of the project's terminals.
+    /// @param context The payment context passed in by the terminal.
+    // slither-disable-next-line locked-ether
+    function afterPayRecordedWith(JBAfterPayRecordedContext calldata context) external payable virtual override {
+        uint256 projectId = PROJECT_ID;
+
+        // Make sure the caller is a terminal of the project, and that the call is being made on behalf of an
+        // interaction with the correct project.
+        if (
+            msg.value != 0 || !DIRECTORY.isTerminalOf({projectId: projectId, terminal: IJBTerminal(msg.sender)})
+                || context.projectId != projectId
+        ) revert JB721Hook_InvalidPay();
+
+        // Process the payment.
+        _processPayment(context);
+    }
+
+    /// @notice Burns the specified NFTs upon token holder cash out, reclaiming funds from the project's balance for
+    /// `context.beneficiary`. Part of `IJBCashOutHook`.
+    /// @dev Reverts if the calling contract is not one of the project's terminals.
+    /// @param context The cash out context passed in by the terminal.
+    // slither-disable-next-line locked-ether
+    function afterCashOutRecordedWith(JBAfterCashOutRecordedContext calldata context)
+        external
+        payable
+        virtual
+        override
+    {
+        // Keep a reference to the project ID.
+        uint256 projectId = PROJECT_ID;
+
+        // Make sure the caller is a terminal of the project, and that the call is being made on behalf of an
+        // interaction with the correct project.
+        if (
+            msg.value != 0 || !DIRECTORY.isTerminalOf({projectId: projectId, terminal: IJBTerminal(msg.sender)})
+                || context.projectId != projectId
+        ) revert JB721Hook_InvalidCashOut();
+
+        // Fetch the cash out hook metadata using the corresponding metadata ID.
+        (bool metadataExists, bytes memory metadata) = JBMetadataResolver.getDataFor({
+            id: JBMetadataResolver.getId({purpose: "cashOut", target: METADATA_ID_TARGET}),
+            metadata: context.cashOutMetadata
+        });
+
+        uint256[] memory decodedTokenIds;
+
+        // Decode the metadata.
+        if (metadataExists) decodedTokenIds = abi.decode(metadata, (uint256[]));
+
+        // Iterate through the NFTs, burning them if the owner is correct.
+        for (uint256 i; i < decodedTokenIds.length; i++) {
+            // Set the current NFT's token ID.
+            uint256 tokenId = decodedTokenIds[i];
+
+            // Make sure the token's owner is correct.
+            if (_ownerOf(tokenId) != context.holder) revert JB721Hook_UnauthorizedToken(tokenId, context.holder);
+
+            // Burn the token.
+            _burn(tokenId);
+        }
+
+        // Call the hook.
+        _didBurn(decodedTokenIds);
+    }
+
+    //*********************************************************************//
+    // ---------------------- internal transactions ---------------------- //
+    //*********************************************************************//
+
+    /// @notice Initializes the contract by associating it with a project and adding ERC721 details.
+    /// @param projectId The ID of the project that this contract is associated with.
+    /// @param name The name of the NFT collection.
+    /// @param symbol The symbol representing the NFT collection.
+    function _initialize(uint256 projectId, string memory name, string memory symbol) internal {
+        ERC721._initialize({name_: name, symbol_: symbol});
+        PROJECT_ID = projectId;
+    }
+
+    /// @notice Executes after NFTs have been burned via cash out.
+    /// @param tokenIds The token IDs of the NFTs that were burned.
+    function _didBurn(uint256[] memory tokenIds) internal virtual;
+
+    /// @notice Process a received payment.
+    /// @param context The payment context passed in by the terminal.
+    function _processPayment(JBAfterPayRecordedContext calldata context) internal virtual;
+}

package/src/interfaces/IJB721Hook.sol

@@ -0,0 +1,21 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {IJBCashOutHook} from "@bananapus/core-v6/src/interfaces/IJBCashOutHook.sol";
+import {IJBDirectory} from "@bananapus/core-v6/src/interfaces/IJBDirectory.sol";
+import {IJBPayHook} from "@bananapus/core-v6/src/interfaces/IJBPayHook.sol";
+import {IJBRulesetDataHook} from "@bananapus/core-v6/src/interfaces/IJBRulesetDataHook.sol";
+
+interface IJB721Hook is IJBRulesetDataHook, IJBPayHook, IJBCashOutHook {
+    /// @notice The directory of terminals and controllers for projects.
+    /// @return The directory contract.
+    function DIRECTORY() external view returns (IJBDirectory);
+
+    /// @notice The ID used when parsing metadata.
+    /// @return The address of the metadata ID target.
+    function METADATA_ID_TARGET() external view returns (address);
+
+    /// @notice The ID of the project that this contract is associated with.
+    /// @return The project ID.
+    function PROJECT_ID() external view returns (uint256);
+}

package/src/interfaces/IJB721TiersHook.sol

@@ -0,0 +1,135 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {IJBPrices} from "@bananapus/core-v6/src/interfaces/IJBPrices.sol";
+import {IJBRulesets} from "@bananapus/core-v6/src/interfaces/IJBRulesets.sol";
+
+import {IJB721Hook} from "./IJB721Hook.sol";
+import {IJB721TiersHookStore} from "./IJB721TiersHookStore.sol";
+import {IJB721TokenUriResolver} from "./IJB721TokenUriResolver.sol";
+import {JB721InitTiersConfig} from "../structs/JB721InitTiersConfig.sol";
+import {JB721TierConfig} from "../structs/JB721TierConfig.sol";
+import {JB721TiersHookFlags} from "../structs/JB721TiersHookFlags.sol";
+import {JB721TiersMintReservesConfig} from "../structs/JB721TiersMintReservesConfig.sol";
+import {JB721TiersSetDiscountPercentConfig} from "../structs/JB721TiersSetDiscountPercentConfig.sol";
+
+interface IJB721TiersHook is IJB721Hook {
+    event AddPayCredits(
+        uint256 indexed amount, uint256 indexed newTotalCredits, address indexed account, address caller
+    );
+    event AddTier(uint256 indexed tierId, JB721TierConfig tier, address caller);
+    event Mint(
+        uint256 indexed tokenId,
+        uint256 indexed tierId,
+        address indexed beneficiary,
+        uint256 totalAmountPaid,
+        address caller
+    );
+    event MintReservedNft(uint256 indexed tokenId, uint256 indexed tierId, address indexed beneficiary, address caller);
+    event RemoveTier(uint256 indexed tierId, address caller);
+    event SetBaseUri(string indexed baseUri, address caller);
+    event SetContractUri(string indexed uri, address caller);
+    event SetDiscountPercent(uint256 indexed tierId, uint256 discountPercent, address caller);
+    event SetEncodedIPFSUri(uint256 indexed tierId, bytes32 encodedUri, address caller);
+    event SetTokenUriResolver(IJB721TokenUriResolver indexed resolver, address caller);
+    event UsePayCredits(
+        uint256 indexed amount, uint256 indexed newTotalCredits, address indexed account, address caller
+    );
+
+    /// @notice The contract storing and managing project rulesets.
+    /// @return The rulesets contract.
+    function RULESETS() external view returns (IJBRulesets);
+
+    /// @notice The contract that stores and manages data for this contract's NFTs.
+    /// @return The store contract.
+    function STORE() external view returns (IJB721TiersHookStore);
+
+    /// @notice The base URI for the NFT `tokenUris`.
+    /// @return The base URI string.
+    function baseURI() external view returns (string memory);
+
+    /// @notice This contract's metadata URI.
+    /// @return The contract URI string.
+    function contractURI() external view returns (string memory);
+
+    /// @notice The first owner of an NFT.
+    /// @param tokenId The token ID of the NFT to get the first owner of.
+    /// @return The address of the NFT's first owner.
+    function firstOwnerOf(uint256 tokenId) external view returns (address);
+
+    /// @notice The amount of NFT credits the address has.
+    /// @param addr The address to get the NFT credits balance of.
+    /// @return The amount of credits the address has.
+    function payCreditsOf(address addr) external view returns (uint256);
+
+    /// @notice Context for the pricing of this hook's tiers.
+    /// @return currency The currency used for tier prices.
+    /// @return decimals The amount of decimals being used in tier prices.
+    /// @return prices The prices contract used to resolve the value of payments in other currencies.
+    function pricingContext() external view returns (uint256 currency, uint256 decimals, IJBPrices prices);
+
+    /// @notice Add or remove tiers.
+    /// @param tiersToAdd The tiers to add, as an array of `JB721TierConfig` structs.
+    /// @param tierIdsToRemove The tiers to remove, as an array of tier IDs.
+    function adjustTiers(JB721TierConfig[] calldata tiersToAdd, uint256[] calldata tierIdsToRemove) external;
+
+    /// @notice Initializes a cloned copy of the original `JB721TiersHook` contract.
+    /// @param projectId The ID of the project this hook is associated with.
+    /// @param name The name of the NFT collection.
+    /// @param symbol The symbol representing the NFT collection.
+    /// @param baseUri The URI to use as a base for full NFT `tokenUri`s.
+    /// @param tokenUriResolver An optional contract responsible for resolving the token URI for each NFT.
+    /// @param contractUri A URI where this contract's metadata can be found.
+    /// @param tiersConfig The NFT tiers and pricing context to initialize the hook with.
+    /// @param flags A set of additional options which dictate how the hook behaves.
+    function initialize(
+        uint256 projectId,
+        string memory name,
+        string memory symbol,
+        string memory baseUri,
+        IJB721TokenUriResolver tokenUriResolver,
+        string memory contractUri,
+        JB721InitTiersConfig memory tiersConfig,
+        JB721TiersHookFlags memory flags
+    )
+        external;
+
+    /// @notice Set the discount percent for a tier.
+    /// @param tierId The ID of the tier to set the discount of.
+    /// @param discountPercent The discount percent to set.
+    function setDiscountPercentOf(uint256 tierId, uint256 discountPercent) external;
+
+    /// @notice Set the discount percent for multiple tiers.
+    /// @param configs The configs to set the discount percent for.
+    function setDiscountPercentsOf(JB721TiersSetDiscountPercentConfig[] calldata configs) external;
+
+    /// @notice Manually mint NFTs from the provided tiers.
+    /// @param tierIds The IDs of the tiers to mint from.
+    /// @param beneficiary The address to mint to.
+    /// @return tokenIds The IDs of the newly minted tokens.
+    function mintFor(uint16[] calldata tierIds, address beneficiary) external returns (uint256[] memory tokenIds);
+
+    /// @notice Mint pending reserved NFTs based on the provided information.
+    /// @param reserveMintConfigs Contains information about how many reserved tokens to mint for each tier.
+    function mintPendingReservesFor(JB721TiersMintReservesConfig[] calldata reserveMintConfigs) external;
+
+    /// @notice Mint pending reserved NFTs for a specific tier.
+    /// @param tierId The ID of the tier to mint reserved NFTs from.
+    /// @param count The number of reserved NFTs to mint.
+    function mintPendingReservesFor(uint256 tierId, uint256 count) external;
+
+    /// @notice Update this hook's URI metadata properties.
+    /// @param baseUri The new base URI.
+    /// @param contractUri The new contract URI.
+    /// @param tokenUriResolver The new URI resolver.
+    /// @param encodedIPFSUriTierId The ID of the tier to set the encoded IPFS URI of.
+    /// @param encodedIPFSUri The encoded IPFS URI to set.
+    function setMetadata(
+        string calldata baseUri,
+        string calldata contractUri,
+        IJB721TokenUriResolver tokenUriResolver,
+        uint256 encodedIPFSUriTierId,
+        bytes32 encodedIPFSUri
+    )
+        external;
+}

package/src/interfaces/IJB721TiersHookDeployer.sol

@@ -0,0 +1,22 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {IJB721TiersHook} from "./IJB721TiersHook.sol";
+import {JBDeploy721TiersHookConfig} from "../structs/JBDeploy721TiersHookConfig.sol";
+
+interface IJB721TiersHookDeployer {
+    event HookDeployed(uint256 indexed projectId, IJB721TiersHook hook, address caller);
+
+    /// @notice Deploys a 721 tiers hook for the specified project.
+    /// @param projectId The ID of the project to deploy the hook for.
+    /// @param deployTiersHookConfig The config to deploy the hook with.
+    /// @param salt A salt to use for the deterministic deployment.
+    /// @return newHook The address of the newly deployed hook.
+    function deployHookFor(
+        uint256 projectId,
+        JBDeploy721TiersHookConfig memory deployTiersHookConfig,
+        bytes32 salt
+    )
+        external
+        returns (IJB721TiersHook newHook);
+}

package/src/interfaces/IJB721TiersHookProjectDeployer.sol

@@ -0,0 +1,76 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+import {IJBDirectory} from "@bananapus/core-v6/src/interfaces/IJBDirectory.sol";
+import {IJBController} from "@bananapus/core-v6/src/interfaces/IJBController.sol";
+
+import {IJB721TiersHook} from "./IJB721TiersHook.sol";
+import {IJB721TiersHookDeployer} from "./IJB721TiersHookDeployer.sol";
+import {JBDeploy721TiersHookConfig} from "../structs/JBDeploy721TiersHookConfig.sol";
+import {JBLaunchProjectConfig} from "../structs/JBLaunchProjectConfig.sol";
+import {JBLaunchRulesetsConfig} from "../structs/JBLaunchRulesetsConfig.sol";
+import {JBQueueRulesetsConfig} from "../structs/JBQueueRulesetsConfig.sol";
+
+interface IJB721TiersHookProjectDeployer {
+    /// @notice The directory of terminals and controllers for projects.
+    /// @return The directory contract.
+    function DIRECTORY() external view returns (IJBDirectory);
+
+    /// @notice The 721 tiers hook deployer.
+    /// @return The hook deployer contract.
+    function HOOK_DEPLOYER() external view returns (IJB721TiersHookDeployer);
+
+    /// @notice Launches a new project with a 721 tiers hook attached.
+    /// @param owner The address to set as the owner of the project.
+    /// @param deployTiersHookConfig Configuration which dictates the behavior of the 721 tiers hook.
+    /// @param launchProjectConfig Configuration which dictates the behavior of the project.
+    /// @param controller The controller that the project's rulesets will be queued with.
+    /// @param salt A salt to use for the deterministic deployment.
+    /// @return projectId The ID of the newly launched project.
+    /// @return hook The 721 tiers hook that was deployed for the project.
+    function launchProjectFor(
+        address owner,
+        JBDeploy721TiersHookConfig memory deployTiersHookConfig,
+        JBLaunchProjectConfig memory launchProjectConfig,
+        IJBController controller,
+        bytes32 salt
+    )
+        external
+        returns (uint256 projectId, IJB721TiersHook hook);
+
+    /// @notice Launches rulesets for a project with an attached 721 tiers hook.
+    /// @param projectId The ID of the project that rulesets are being launched for.
+    /// @param deployTiersHookConfig Configuration which dictates the behavior of the 721 tiers hook.
+    /// @param launchRulesetsConfig Configuration which dictates the project's new rulesets.
+    /// @param controller The controller that the project's rulesets will be queued with.
+    /// @param salt A salt to use for the deterministic deployment.
+    /// @return rulesetId The ID of the successfully created ruleset.
+    /// @return hook The 721 tiers hook that was deployed for the project.
+    function launchRulesetsFor(
+        uint256 projectId,
+        JBDeploy721TiersHookConfig memory deployTiersHookConfig,
+        JBLaunchRulesetsConfig memory launchRulesetsConfig,
+        IJBController controller,
+        bytes32 salt
+    )
+        external
+        returns (uint256 rulesetId, IJB721TiersHook hook);
+
+    /// @notice Queues rulesets for a project with an attached 721 tiers hook.
+    /// @param projectId The ID of the project that rulesets are being queued for.
+    /// @param deployTiersHookConfig Configuration which dictates the behavior of the 721 tiers hook.
+    /// @param queueRulesetsConfig Configuration which dictates the project's newly queued rulesets.
+    /// @param controller The controller that the project's rulesets will be queued with.
+    /// @param salt A salt to use for the deterministic deployment.
+    /// @return rulesetId The ID of the successfully created ruleset.
+    /// @return hook The 721 tiers hook that was deployed for the project.
+    function queueRulesetsOf(
+        uint256 projectId,
+        JBDeploy721TiersHookConfig memory deployTiersHookConfig,
+        JBQueueRulesetsConfig memory queueRulesetsConfig,
+        IJBController controller,
+        bytes32 salt
+    )
+        external
+        returns (uint256 rulesetId, IJB721TiersHook hook);
+}