@artblocks/contracts 1.3.1 → 1.4.0

package/contracts/interfaces/v0.8.x/ISRHooks.sol

@@ -0,0 +1,229 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Creatd By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+/**
+ * @title ISRHooks
+ * @author Art Blocks Inc.
+ * @notice This interface defines the custom events and functions for the SRHooks contract.
+ * It does not include any of the IPMPV0 events, which are indexed separately.
+ */
+interface ISRHooks {
+    /**
+     * @notice Emitted when the contract is initialized
+     * @param coreContractAddress The address of the core contract.
+     * @param coreProjectId The project ID of the core contract.
+     */
+    event SRHooksInitialized(
+        address coreContractAddress,
+        uint256 coreProjectId
+    );
+
+    /**
+     * @notice Emitted when the tokens sending to a token are updated
+     * @param coreContract The address of the core contract.
+     * @param tokenId The ID of the token.
+     * @param tokensSendingTo The tokens sending to the token.
+     */
+    event TokenSendingToUpdated(
+        address indexed coreContract,
+        uint256 indexed tokenId,
+        uint16[] tokensSendingTo
+    );
+
+    /**
+     * @notice Emitted when the tokens sending to a token are updated
+     * @param coreContract The address of the core contract.
+     * @param tokenId The ID of the token.
+     * @param tokensReceivingFrom The tokens receiving from the token.
+     */
+    event TokenReceivingFromUpdated(
+        address indexed coreContract,
+        uint256 indexed tokenId,
+        uint16[] tokensReceivingFrom
+    );
+
+    /**
+     * @notice Struct for the token metadata calldata.
+     * @param updateImage Whether to update the image data.
+     * @param imageDataCompressed The compressed image data.
+     * @param updateSound Whether to update the sound data.
+     * @param soundDataCompressed The compressed sound data.
+     */
+    struct TokenMetadataCalldata {
+        bool updateImage; // true if updating the image data
+        bytes imageDataCompressed; // non-empty if updating the image data
+        bool updateSound; // true if updating the sound data
+        bytes soundDataCompressed; // may be empty to clear the sound data, non-empty if setting the sound data
+    }
+
+    /**
+     * @notice Struct for the token metadata view.
+     * @param imageDataCompressed The compressed image data.
+     * @param imageVersion The version of the image data.
+     * @param soundDataCompressed The compressed sound data.
+     * @param soundVersion The version of the sound data.
+     */
+    struct TokenMetadataView {
+        bytes imageDataCompressed;
+        uint16 imageVersion;
+        bytes soundDataCompressed;
+        uint16 soundVersion;
+    }
+
+    struct TokenLiveData {
+        uint256 tokenNumber;
+        address ownerAddress;
+        bytes imageDataCompressed;
+        bytes soundDataCompressed;
+        string ownerEnsName;
+    }
+
+    // enum for the different possible states of a token's SR configuration
+    enum SendStates {
+        Neutral,
+        SendGeneral,
+        SendTo
+    }
+
+    enum ReceiveStates {
+        Neutral,
+        ReceiveGeneral,
+        ReceiveFrom,
+        ReceiveTo
+    }
+
+    /**
+     * @notice Updates the state and metadata for a given token.
+     * Reverts if the token number is invalid or the msg.sender is not owner or valid delegate.xyz V2 of token owner.
+     * Reverts if invalid configuration is provided.
+     * Includes two boolean flags to update the send and receive states and token metadata separately, in a single function call.
+     * Never allows updating to a slot that is invalid.
+     * @param tokenNumber The token number to update.
+     * @param updateSendState Whether to update the send state.
+     * @param sendState The new send state. Valid values are SendGeneral, SendTo, Neutral.
+     * @param tokensSendingTo Tokens to send this token to. Only non-empty iff updateSendState is true and sendState is SendTo.
+     * Duplicates are automatically deduplicated when calculating dilution rates.
+     * @param updateReceiveState Whether to update the receive state.
+     * @param receiveState The new receive state. Valid values are ReceiveGeneral, ReceiveFrom, Neutral.
+     * @param tokensReceivingFrom Tokens this token is open to receive from. Only non-empty iff updateReceiveState is true and receiveState is ReceiveFrom.
+     * Duplicates and self-referential entries are automatically filtered in getLiveData results.
+     * @param updateTokenMetadata Whether to update the token metadata.
+     * @param updatedActiveSlot The new active slot. If updating token metadata, this is the new active slot.
+     * @param tokenMetadataCalldata The new token metadata. If updating token metadata, this is the new token metadata at the updated active slot. Only non-empty iff updateTokenMetadata is true.
+     */
+    function updateTokenStateAndMetadata(
+        uint256 tokenNumber,
+        bool updateSendState,
+        SendStates sendState,
+        uint16[] memory tokensSendingTo,
+        bool updateReceiveState,
+        ReceiveStates receiveState,
+        uint16[] memory tokensReceivingFrom,
+        bool updateTokenMetadata,
+        uint256 updatedActiveSlot,
+        TokenMetadataCalldata memory tokenMetadataCalldata
+    ) external;
+
+    /**
+     * @notice Gets the live data for a given token.
+     * @param tokenNumber The token number to get the live data for.
+     * @param blockNumber The block number to get the live data for. Must be in latest 256 blocks.
+     * @param maxReceive The maximum number of tokens to receive, in each array of receivedTokensGeneral and receivedTokensTo.
+     * maxReceive must be less than or equal to MAX_RECEIVE_RATE_PER_BLOCK.
+     * Treats block number of 0 as latest completed block.
+     * Reverts if block number is in future - need block hash to be defined.
+     * NOTE: Each array of receivedTokensGeneral and receivedTokensTo has a maximum length of maxReceive,
+     * but their combined length may be greater than maxReceive. The art script should handle this by
+     * deterministically shuffling/sampling from the arrays if desired.
+     * WARNING: This function is designed for off-chain view calls only and may exceed block gas limits in cases where
+     * a token has many senders or is receiving from many tokens. It is not intended to be called within transactions.
+     * WARNING: Self-referential SendGeneral and SendTo tokens may be included in the results.
+     * @return sendState The send state of the token.
+     * @return receiveState The receive state of the token.
+     * @return receivedTokensGeneral The received tokens general of the token.
+     * @return receivedTokensTo The received tokens to of the token.
+     * @return numSendGeneral The number of tokens in the send general pool.
+     * @return numReceiveGeneral The number of tokens in the receive general pool.
+     * @return numSendingToMe The number of tokens sending to me.
+     * @return usedBlockNumber The block number used to generate the random numbers.
+     */
+    function getLiveData(
+        uint256 tokenNumber,
+        uint256 blockNumber,
+        uint256 maxReceive
+    )
+        external
+        view
+        returns (
+            SendStates sendState,
+            ReceiveStates receiveState,
+            TokenLiveData[] memory receivedTokensGeneral,
+            TokenLiveData[] memory receivedTokensTo,
+            uint256 numSendGeneral,
+            uint256 numReceiveGeneral,
+            uint256 numSendingToMe,
+            uint256 usedBlockNumber
+        );
+
+    /**
+     * @notice Gets the state of the general pools.
+     * @return sendGeneralTokensLength The length of the send general tokens.
+     * @return receiveGeneralTokensLength The length of the receive general tokens.
+     */
+    function getGeneralPoolState()
+        external
+        view
+        returns (
+            uint256 sendGeneralTokensLength,
+            uint256 receiveGeneralTokensLength
+        );
+
+    /**
+     * @notice Gets the state of a given token.
+     * @param tokenNumber The token number to get the state for.
+     * @return sendState The send state.
+     * @return receiveState The receive state.
+     * @return tokensSendingTo The tokens sending to the token.
+     * @return tokensReceivingFrom The tokens receiving from the token.
+     * @return activeSlot The active slot.
+     * @return activeSlotTokenMetadata The token metadata at the active slot.
+     * @return ownerAddress The address of the token owner.
+     */
+    function getTokenState(
+        uint256 tokenNumber
+    )
+        external
+        view
+        returns (
+            SendStates sendState,
+            ReceiveStates receiveState,
+            uint16[] memory tokensSendingTo,
+            uint16[] memory tokensReceivingFrom,
+            uint256 activeSlot,
+            TokenMetadataView memory activeSlotTokenMetadata,
+            address ownerAddress
+        );
+
+    /**
+     * @notice Gets the token metadata at a given slot.
+     * @param tokenNumber The token number to get the token metadata for.
+     * @param slot The slot to get the token metadata for.
+     * @return tokenMetadata The token metadata at the given slot.
+     */
+    function getTokenMetadataAtSlot(
+        uint256 tokenNumber,
+        uint256 slot
+    ) external view returns (TokenMetadataView memory tokenMetadata);
+
+    /**
+     * @notice Gets the tokens sending to a given token.
+     * WARNING: This function is unbounded in gas cost, and is designed to be used by view accessors only. Use with caution.
+     * @param tokenNumber The token number to get the tokens sending to for.
+     * @return tokensSendingTo The token numbers sending to the given token.
+     */
+    function getTokensSendingToToken(
+        uint256 tokenNumber
+    ) external view returns (uint256[] memory tokensSendingTo);
+}

package/contracts/interfaces/v0.8.x/ISeaDropShimForContract.sol

@@ -10,10 +10,4 @@ interface ISeaDropShimForContract {
      * @param nftContract The address of the NFT contract that this shim contract is compatible with
      */
     event SeaDropShimForContract(address nftContract);
-
-    /**
-     * @dev Emit event when the local max supply is updated
-     * @param newLocalMaxSupply The new local max supply
-     */
-    event LocalMaxSupplyUpdated(uint256 newLocalMaxSupply);
 }

package/contracts/interfaces/v0.8.x/ISharedMinterTieredAllowV0.sol

@@ -0,0 +1,69 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+/**
+ * @title This interface adds support for tiered allowlist pricing.
+ * @notice Intended for shared minters that expose both a public price and a
+ * privileged allowlist price, and that can resolve the effective price for a
+ * given wallet.
+ * @author Art Blocks Inc.
+ */
+interface ISharedMinterTieredAllowV0 {
+    /**
+     * @notice Gets if price is configured, allowlist price of minting a token
+     * on project `projectId`, and currency symbol and address to be used as
+     * payment.
+     * @param projectId Project ID to get allowlist price information for
+     * @param coreContract Contract address of the core contract
+     * @return isConfigured true only if prices have been configured on this
+     * minter
+     * @return tokenPriceInWei current allowlist price of token on this minter
+     * @return currencySymbol currency symbol for purchases of project on this
+     * minter
+     * @return currencyAddress currency address for purchases of project on
+     * this minter
+     */
+    function getAllowlistPriceInfo(
+        uint256 projectId,
+        address coreContract
+    )
+        external
+        view
+        returns (
+            bool isConfigured,
+            uint256 tokenPriceInWei,
+            string memory currencySymbol,
+            address currencyAddress
+        );
+
+    /**
+     * @notice Returns the effective price for a given wallet address on
+     * project `projectId`. If the wallet is allowlisted, returns the
+     * allowlist price; otherwise returns the public price.
+     * @param projectId Project ID to get price information for
+     * @param coreContract Contract address of the core contract
+     * @param wallet Address to check the effective price for
+     * @return isConfigured true only if prices have been configured for the
+     * project
+     * @return tokenPriceInWei effective price per token for the given wallet
+     * @return currencySymbol currency symbol for purchases of project on this
+     * minter
+     * @return currencyAddress currency address for purchases of project on
+     * this minter
+     */
+    function getPriceInfoForAddress(
+        uint256 projectId,
+        address coreContract,
+        address wallet
+    )
+        external
+        view
+        returns (
+            bool isConfigured,
+            uint256 tokenPriceInWei,
+            string memory currencySymbol,
+            address currencyAddress
+        );
+}

package/contracts/interfaces/v0.8.x/ITransferHook.sol

@@ -0,0 +1,48 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {IERC165} from "@openzeppelin-5.0/contracts/interfaces/IERC165.sol";
+
+/**
+ * @title Transfer hook interface for Art Blocks V3 Engine cores.
+ * @author Art Blocks Inc.
+ * @notice Invoked by a core after a token's ownership has been updated (mint
+ * or transfer). A reverting hook aborts the entire mint or transfer.
+ * Implementations MUST authenticate `msg.sender` as the expected core; the
+ * core passes `coreContract` for convenience when one hook serves many cores.
+ * Inheriting `AbstractTransferHook` is the recommended way to satisfy both
+ * that requirement and the ERC-165 requirement below.
+ * @dev A core will not accept a hook unless it ERC-165-advertises this
+ * interface. The ERC-165 interface ID is `0x6344b0e2`, which is
+ * `type(ITransferHook).interfaceId` — the selector of `onTokenTransfer`
+ * alone. Solidity excludes inherited interface functions (here, `IERC165`)
+ * from that XOR, so implementers hardcoding the value must use `0x6344b0e2`
+ * and not XOR in `IERC165`'s `0x01ffc9a7`.
+ */
+interface ITransferHook is IERC165 {
+    /**
+     * @notice Execution logic to be executed after a token's ownership updates.
+     * @dev Called after the ERC-721 ownership write. On mint, called after the
+     * token hash seed is assigned. Reverting aborts the mint or transfer.
+     * @dev The calling core blocks reentrant mints and transfers for the
+     * duration of this call, on every project of that core. Implementations
+     * must not attempt to mint or transfer on the calling core.
+     * @param coreContract The core contract that performed the ownership update.
+     * Also equal to `msg.sender` when called by a conforming core.
+     * @param tokenId The token whose ownership changed.
+     * @param from Previous owner. `address(0)` on mint.
+     * @param to New owner. `address(0)` on burn (cores do not currently burn).
+     * @param operator For transfers, the ERC-721 operator (`_msgSender()`).
+     * For mint, the `_by` address passed to `mint_Ecf` (the initiating user,
+     * not the minter contract).
+     */
+    function onTokenTransfer(
+        address coreContract,
+        uint256 tokenId,
+        address from,
+        address to,
+        address operator
+    ) external;
+}

package/contracts/libs/v0.8.x/DependencyRegistryStorageLib.sol

@@ -4,6 +4,7 @@ pragma solidity ^0.8.19;
 import "../../interfaces/v0.8.x/IAdminACLV0.sol";
 import "../../interfaces/v0.8.x/ICoreRegistryV1.sol";
 import "../../interfaces/v0.8.x/IUniversalBytecodeStorageReader.sol";
+import {IDependencyRegistryV0} from "../../interfaces/v0.8.x/IDependencyRegistryV0.sol";
 import "@openzeppelin-4.7/contracts/utils/structs/EnumerableSet.sol";
 
 /**
@@ -51,6 +52,17 @@ library DependencyRegistryStorageLib {
         uint24 additionalRepositoryCount;
         // count of scripts that make up the dependency, if the dependency is available on-chain
         uint24 scriptCount;
+        // @dev fields below are appended for the generator's rendering directives, and are
+        // safe to append because Dependency is only ever used as a mapping value.
+        // canvas tag requirement for the dependency
+        IDependencyRegistryV0.CanvasTagType canvasTagType;
+        // how a project's script must be injected into generated HTML
+        IDependencyRegistryV0.ProjectScriptTagType projectScriptTagType;
+        // whether the dependency's own script is an ES module, and therefore must be exposed to
+        // project scripts via an import map rather than loaded with a plain `<script src>` tag
+        bool loadAsModule;
+        // `type` attribute used when projectScriptTagType is SpecialType; empty otherwise
+        string projectScriptSpecialType;
     }
 
     /**

package/contracts/libs/v0.8.x/ENSLib.sol

@@ -0,0 +1,85 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+/**
+ * @title IUniversalResolver
+ * @notice Minimal ENS Universal Resolver interface for reverse resolution
+ * @dev See https://docs.ens.domains/resolvers/universal#reverse-resolution
+ */
+interface IUniversalResolver {
+    function reverse(
+        bytes calldata lookupAddress,
+        uint256 coinType
+    )
+        external
+        view
+        returns (
+            string memory primary,
+            address resolver,
+            address reverseResolver
+        );
+}
+
+/**
+ * @title ENS Library
+ * @notice This library provides helper functions for ENS name resolution
+ * using the ENS Universal Resolver following ENS best practices.
+ * @author Art Blocks Inc.
+ * @dev This library uses the Universal Resolver's reverse() function which
+ * performs both reverse lookup AND forward verification in a single call.
+ * For an address to have a valid ENS name returned by this library, the owner
+ * must set up a reverse record (reverse lookup) by calling setName() on the
+ * reverse registrar. This is OPTIONAL and must be done by the address owner
+ * on-chain. If not set, the library returns an empty string.
+ *
+ * References:
+ * - Universal Resolver: https://docs.ens.domains/resolvers/universal
+ * - Reverse Resolution: https://docs.ens.domains/resolvers/universal#reverse-resolution
+ */
+library ENSLib {
+    /// @notice ENS Universal Resolver deployment address (same on mainnet and testnets)
+    /// @dev This is a proxy contract owned by ENS DAO
+    /// See: https://docs.ens.domains/resolvers/universal
+    address internal constant UNIVERSAL_RESOLVER_ADDRESS =
+        0xeEeEEEeE14D718C2B47D9923Deab1335E144EeEe;
+
+    /// @notice Coin type for Ethereum (used in reverse resolution)
+    /// @dev See ENSIP-9 for multichain address resolution
+    uint256 internal constant COIN_TYPE_ETH = 60;
+
+    /**
+     * @notice Resolves an ENS name for a given address using the Universal Resolver.
+     * @dev Uses the ENS Universal Resolver's reverse() function which internally:
+     * 1. Performs reverse lookup to get the name claimed by the address
+     * 2. Verifies forward resolution to ensure the name actually resolves back to the address
+     *
+     * This provides protection against spoofing in a single call.
+     *
+     * NOTE: For an address to have a valid ENS name returned by this function, the owner must:
+     * - Set up a reverse record (reverse lookup) by calling setName() on the reverse registrar
+     * - This is OPTIONAL and must be done by the address owner on-chain
+     * - If not set, this function returns an empty string
+     *
+     * @param ownerAddress The address to resolve the ENS name for.
+     * @return ensName The ENS name for the address, or empty string if not found/invalid.
+     */
+    function getEnsName(
+        address ownerAddress
+    ) internal view returns (string memory) {
+        // Call the Universal Resolver's reverse function
+        // The reverse function internally performs both reverse lookup and forward verification
+        try
+            IUniversalResolver(UNIVERSAL_RESOLVER_ADDRESS).reverse(
+                abi.encodePacked(ownerAddress),
+                COIN_TYPE_ETH
+            )
+        returns (string memory primary, address, address) {
+            return primary;
+        } catch {
+            // If any error occurs (no reverse record, forward mismatch, etc.), return empty string
+            return "";
+        }
+    }
+}