@artblocks/contracts 1.2.0 → 1.3.0

package/contracts/web3call/Web3Call.sol

@@ -0,0 +1,25 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {IWeb3Call} from "../interfaces/v0.8.x/IWeb3Call.sol";
+
+import {ERC165} from "@openzeppelin-5.0/contracts/utils/introspection/ERC165.sol";
+
+/**
+ * @title Abstract Web3Call contract
+ * @author Art Blocks Inc.
+ * @notice This abstract can be inherited by any contract that wants to implement the Web3Call interface.
+ * It indicates support for the IWeb3Call interface via ERC165 interface detection, and ensures that all
+ * child contracts implement the required IWeb3Call functions.
+ */
+abstract contract Web3Call is IWeb3Call, ERC165 {
+    function supportsInterface(
+        bytes4 interfaceId
+    ) public view override returns (bool) {
+        return
+            interfaceId == type(IWeb3Call).interfaceId ||
+            super.supportsInterface(interfaceId);
+    }
+}

package/contracts/web3call/augment-hooks/AbstractPMPAugmentHook.sol

@@ -0,0 +1,46 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {IPMPAugmentHook} from "../../interfaces/v0.8.x/IPMPAugmentHook.sol";
+import {IWeb3Call} from "../../interfaces/v0.8.x/IWeb3Call.sol";
+
+import {ERC165} from "@openzeppelin-5.0/contracts/utils/introspection/ERC165.sol";
+import {IERC165} from "@openzeppelin-5.0/contracts/interfaces/IERC165.sol";
+
+/**
+ * @title Abstract Web3Call contract
+ * @author Art Blocks Inc.
+ * @notice This abstract can be inherited by any contract that wants to implement the Web3Call interface.
+ * It indicates support for the IWeb3Call interface via ERC165 interface detection, and ensures that all
+ * child contracts implement the required IWeb3Call functions.
+ */
+abstract contract AbstractPMPAugmentHook is IPMPAugmentHook, ERC165 {
+    /**
+     * @notice Augment the token parameters for a given token.
+     * @dev This hook is called when a token's PMPs are read.
+     * @dev This must return all desired tokenParams, not just additional data.
+     * @param coreContract The address of the core contract to call.
+     * @param tokenId The tokenId of the token to get data for.
+     * @param tokenParams The token parameters for the queried token.
+     * @return augmentedTokenParams The augmented token parameters.
+     */
+    function onTokenPMPReadAugmentation(
+        address coreContract,
+        uint256 tokenId,
+        IWeb3Call.TokenParam[] calldata tokenParams
+    )
+        external
+        view
+        virtual
+        returns (IWeb3Call.TokenParam[] memory augmentedTokenParams);
+
+    function supportsInterface(
+        bytes4 interfaceId
+    ) public view override(ERC165, IERC165) returns (bool) {
+        return
+            interfaceId == type(IPMPAugmentHook).interfaceId ||
+            super.supportsInterface(interfaceId);
+    }
+}

package/contracts/web3call/augment-hooks/InjectBaseGasFee.sol

@@ -0,0 +1,57 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {AbstractPMPAugmentHook} from "./AbstractPMPAugmentHook.sol";
+
+import {IWeb3Call} from "../../interfaces/v0.8.x/IWeb3Call.sol";
+import {Strings} from "@openzeppelin-5.0/contracts/utils/Strings.sol";
+
+/**
+ * @title InjectBaseGasFee
+ * @author Art Blocks Inc.
+ * @notice This hook injects the base gas fee into a tokens PMPs.
+ */
+contract InjectBaseGasFee is AbstractPMPAugmentHook {
+    using Strings for uint256;
+
+    /**
+     * @notice Augment the token parameters for a given token.
+     * Appends the base gas fee into a tokens PMPs.
+     * @dev This hook is called when a token's PMPs are read.
+     * @dev This must return all desired tokenParams, not just additional data.
+     * @param tokenParams The token parameters for the queried token.
+     * @return augmentedTokenParams The augmented token parameters.
+     */
+    function onTokenPMPReadAugmentation(
+        address /* coreContract */,
+        uint256 /* tokenId */,
+        IWeb3Call.TokenParam[] calldata tokenParams
+    )
+        external
+        view
+        override
+        returns (IWeb3Call.TokenParam[] memory augmentedTokenParams)
+    {
+        // create a new tokenParam array with one extra element
+        uint256 originalLength = tokenParams.length;
+        uint256 newLength = originalLength + 1;
+        augmentedTokenParams = new IWeb3Call.TokenParam[](newLength);
+
+        // copy the original tokenParams into the new array
+        for (uint256 i = 0; i < originalLength; i++) {
+            augmentedTokenParams[i] = tokenParams[i];
+        }
+
+        // get + inject the base gas fee into the new array
+        uint256 blockBaseFee = block.basefee;
+        augmentedTokenParams[originalLength] = IWeb3Call.TokenParam({
+            key: "baseGasFee",
+            value: blockBaseFee.toString()
+        });
+
+        // return the augmented tokenParams
+        return augmentedTokenParams;
+    }
+}

package/contracts/web3call/augment-hooks/InjectChromieSquiggleFloorPrice.sol

@@ -0,0 +1,103 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {AbstractPMPAugmentHook} from "./AbstractPMPAugmentHook.sol";
+
+import {IWeb3Call} from "../../interfaces/v0.8.x/IWeb3Call.sol";
+import {Strings} from "@openzeppelin-5.0/contracts/utils/Strings.sol";
+
+// @dev This is a simplified interface for the Uniswap V2 Pair contract.
+interface IUniswapV2Pair {
+    function getReserves()
+        external
+        view
+        returns (uint112 reserve0, uint112 reserve1, uint32 blockTimestampLast);
+
+    function token0() external view returns (address);
+
+    function token1() external view returns (address);
+}
+
+/**
+ * @title InjectChromieSquiggleFloorPrice
+ * @author Art Blocks Inc.
+ * @notice This hook appends the floor price of Chromie Squiggle, in wei, to a tokens PMPs.
+ */
+contract InjectChromieSquiggleFloorPrice is AbstractPMPAugmentHook {
+    using Strings for uint256;
+
+    address public immutable nftxVaultPoolSquiggleWeth;
+
+    /**
+     * @notice Constructor.
+     * @param _nftxVaultPoolSquiggleWeth The address of the NFTX vault for Chromie Squiggle.
+     * For mainnet, this is 0x698AbbBC986C59D02941E18BC96fe2396493339B
+     */
+    constructor(address _nftxVaultPoolSquiggleWeth) {
+        nftxVaultPoolSquiggleWeth = _nftxVaultPoolSquiggleWeth;
+    }
+
+    /**
+     * @notice Augment the token parameters for a given token.
+     * Appends the spot price of Chromie Squiggle in WETH, based on the NFTX vault pool.
+     * @dev This hook is called when a token's PMPs are read.
+     * @dev This must return all desired tokenParams, not just additional data.
+     * @param tokenParams The token parameters for the queried token.
+     * @return augmentedTokenParams The augmented token parameters.
+     */
+    function onTokenPMPReadAugmentation(
+        address /* coreContract */,
+        uint256 /* tokenId */,
+        IWeb3Call.TokenParam[] calldata tokenParams
+    )
+        external
+        view
+        override
+        returns (IWeb3Call.TokenParam[] memory augmentedTokenParams)
+    {
+        // create a new tokenParam array with one extra element
+        uint256 originalLength = tokenParams.length;
+        uint256 newLength = originalLength + 1;
+        augmentedTokenParams = new IWeb3Call.TokenParam[](newLength);
+
+        // copy the original tokenParams into the new array
+        for (uint256 i = 0; i < originalLength; i++) {
+            augmentedTokenParams[i] = tokenParams[i];
+        }
+
+        // get + inject the floor price of Chromie Squiggle
+        uint256 floorPriceChromieSquiggle = _getSquiggleFloorPriceInWETH();
+
+        augmentedTokenParams[originalLength] = IWeb3Call.TokenParam({
+            key: "floorPriceChromieSquiggle",
+            value: floorPriceChromieSquiggle.toString()
+        });
+
+        // return the augmented tokenParams
+        return augmentedTokenParams;
+    }
+
+    function _getSquiggleFloorPriceInWETH()
+        internal
+        view
+        returns (uint256 priceInWei)
+    {
+        IUniswapV2Pair pair = IUniswapV2Pair(nftxVaultPoolSquiggleWeth);
+
+        (uint112 reserve0, uint112 reserve1, ) = pair.getReserves();
+        address token0 = pair.token0(); // expected to be SQGL
+
+        // Price of 1 SquiggleVault token in WETH = reserve1 / reserve0
+        // We'll scale result to return value in wei (1e18)
+
+        if (token0 == 0x8d137e3337eb1B58A222Fef2B2Cc7C423903d9cf) {
+            // token0 is SQGL, token1 is WETH
+            priceInWei = (uint256(reserve1) * 1e18) / reserve0;
+        } else {
+            // token1 is SQGL, token0 is WETH
+            priceInWei = (uint256(reserve0) * 1e18) / reserve1;
+        }
+    }
+}

package/contracts/web3call/augment-hooks/InjectIsNounsDaoMember.sol

@@ -0,0 +1,66 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {AbstractPMPAugmentHook} from "./AbstractPMPAugmentHook.sol";
+
+import {IWeb3Call} from "../../interfaces/v0.8.x/IWeb3Call.sol";
+import {IERC721} from "@openzeppelin-5.0/contracts/interfaces/IERC721.sol";
+import {IERC20} from "@openzeppelin-5.0/contracts/interfaces/IERC20.sol";
+import {Strings} from "@openzeppelin-5.0/contracts/utils/Strings.sol";
+
+/**
+ * @title InjectIsNounsDaoMember
+ * @author Art Blocks Inc.
+ * @notice This hook injects if the token's owner is a member of the Nouns DAO.
+ */
+contract InjectIsNounsDaoMember is AbstractPMPAugmentHook {
+    address public constant nounsTokenAddress =
+        0x9C8fF314C9Bc7F6e59A9d9225Fb22946427eDC03;
+
+    /**
+     * @notice Augment the token parameters for a given token.
+     * Appends if the token's owner is a member of the Nouns DAO into a tokens PMPs,
+     * i.e. if the token's owner has a Noun in their wallet.
+     * @dev This hook is called when a token's PMPs are read.
+     * @dev This must return all desired tokenParams, not just additional data.
+     * @param coreContract The address of the core contract to call.
+     * @param tokenId The tokenId of the token to get data for.
+     * @param tokenParams The token parameters for the queried token.
+     * @return augmentedTokenParams The augmented token parameters.
+     */
+    function onTokenPMPReadAugmentation(
+        address coreContract,
+        uint256 tokenId,
+        IWeb3Call.TokenParam[] calldata tokenParams
+    )
+        external
+        view
+        override
+        returns (IWeb3Call.TokenParam[] memory augmentedTokenParams)
+    {
+        // create a new tokenParam array with one extra element
+        uint256 originalLength = tokenParams.length;
+        uint256 newLength = originalLength + 1;
+        augmentedTokenParams = new IWeb3Call.TokenParam[](newLength);
+
+        // copy the original tokenParams into the new array
+        for (uint256 i = 0; i < originalLength; i++) {
+            augmentedTokenParams[i] = tokenParams[i];
+        }
+
+        // get + inject the token owner's nouns dao membership status
+        address tokenOwner = IERC721(coreContract).ownerOf(tokenId);
+        bool isNounsDaoMember = IERC20(nounsTokenAddress).balanceOf(
+            tokenOwner
+        ) > 0;
+        augmentedTokenParams[originalLength] = IWeb3Call.TokenParam({
+            key: "isNounsDaoMember",
+            value: isNounsDaoMember ? "true" : "false"
+        });
+
+        // return the augmented tokenParams
+        return augmentedTokenParams;
+    }
+}

package/contracts/web3call/augment-hooks/InjectIsProjectFullyMinted.sol

@@ -0,0 +1,73 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {AbstractPMPAugmentHook} from "./AbstractPMPAugmentHook.sol";
+
+import {ABHelpers} from "../../libs/v0.8.x/ABHelpers.sol";
+
+import {IWeb3Call} from "../../interfaces/v0.8.x/IWeb3Call.sol";
+import {IERC721} from "@openzeppelin-5.0/contracts/interfaces/IERC721.sol";
+import {IGenArt721CoreContractV3_Base} from "../../interfaces/v0.8.x/IGenArt721CoreContractV3_Base.sol";
+import {Strings} from "@openzeppelin-5.0/contracts/utils/Strings.sol";
+
+/**
+ * @title InjectIsProjectFullyMinted
+ * @author Art Blocks Inc.
+ * @notice This hook injects if a project is fully minted.
+ */
+contract InjectIsProjectFullyMinted is AbstractPMPAugmentHook {
+    using Strings for address;
+
+    /**
+     * @notice Augment the token parameters for a given token.
+     * Appends if a project is fully minted into a tokens PMPs.
+     * @dev This hook is called when a token's PMPs are read.
+     * @dev This must return all desired tokenParams, not just additional data.
+     * @param coreContract The address of the core contract to call.
+     * @param tokenId The tokenId of the token to get data for.
+     * @param tokenParams The token parameters for the queried token.
+     * @return augmentedTokenParams The augmented token parameters.
+     */
+    function onTokenPMPReadAugmentation(
+        address coreContract,
+        uint256 tokenId,
+        IWeb3Call.TokenParam[] calldata tokenParams
+    )
+        external
+        view
+        override
+        returns (IWeb3Call.TokenParam[] memory augmentedTokenParams)
+    {
+        // create a new tokenParam array with one extra element
+        uint256 originalLength = tokenParams.length;
+        uint256 newLength = originalLength + 1;
+        augmentedTokenParams = new IWeb3Call.TokenParam[](newLength);
+
+        // copy the original tokenParams into the new array
+        for (uint256 i = 0; i < originalLength; i++) {
+            augmentedTokenParams[i] = tokenParams[i];
+        }
+
+        // get + inject the token owner into the new array
+        uint256 projectId = ABHelpers.tokenIdToProjectId(tokenId);
+        (
+            uint256 invocations,
+            uint256 maxInvocations,
+            ,
+            ,
+            ,
+
+        ) = IGenArt721CoreContractV3_Base(coreContract).projectStateData(
+                projectId
+            );
+        augmentedTokenParams[originalLength] = IWeb3Call.TokenParam({
+            key: "isProjectFullyMinted",
+            value: invocations == maxInvocations ? "true" : "false"
+        });
+
+        // return the augmented tokenParams
+        return augmentedTokenParams;
+    }
+}

package/contracts/web3call/augment-hooks/InjectPolyptychTokenHash.sol

@@ -0,0 +1,88 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {AbstractPMPAugmentHook} from "./AbstractPMPAugmentHook.sol";
+import {ABHelpers} from "../../libs/v0.8.x/ABHelpers.sol";
+
+import {IWeb3Call} from "../../interfaces/v0.8.x/IWeb3Call.sol";
+import {IGenArt721CoreContractV3_Base} from "../../interfaces/v0.8.x/IGenArt721CoreContractV3_Base.sol";
+
+import {Strings} from "@openzeppelin-5.0/contracts/utils/Strings.sol";
+
+/**
+ * @title InjectPolyptychTokenHash
+ * @author Art Blocks Inc.
+ * @notice This hook injects the hash of a token on a different project into a tokens PMPs.
+ */
+contract InjectPolyptychTokenHash is AbstractPMPAugmentHook {
+    using Strings for uint256;
+
+    /**
+     * @notice The projectId of the project to inject the hash from.
+     */
+    uint256 public immutable sourceProjectId;
+    /**
+     * @notice the core contract address of the project to inject the hash from.
+     */
+    address public immutable sourceCoreContract;
+
+    /**
+     * @notice Constructor.
+     * @param _sourceCoreContract The address of the core contract to inject the hash from.
+     * @param _sourceProjectId The projectId of the project to inject the hash from.
+     */
+    constructor(address _sourceCoreContract, uint256 _sourceProjectId) {
+        sourceCoreContract = _sourceCoreContract;
+        sourceProjectId = _sourceProjectId;
+    }
+
+    /**
+     * @notice Augment the token parameters for a given token.
+     * Appends the hash of a token on a different project into a tokens PMPs.
+     * @dev This hook is called when a token's PMPs are read.
+     * @dev This must return all desired tokenParams, not just additional data.
+     * @param tokenId The tokenId of the token to get data for.
+     * @param tokenParams The token parameters for the queried token.
+     * @return augmentedTokenParams The augmented token parameters.
+     */
+    function onTokenPMPReadAugmentation(
+        address /* coreContract */,
+        uint256 tokenId,
+        IWeb3Call.TokenParam[] calldata tokenParams
+    )
+        external
+        view
+        override
+        returns (IWeb3Call.TokenParam[] memory augmentedTokenParams)
+    {
+        // create a new tokenParam array with one extra element
+        uint256 originalLength = tokenParams.length;
+        uint256 newLength = originalLength + 1;
+        augmentedTokenParams = new IWeb3Call.TokenParam[](newLength);
+
+        // copy the original tokenParams into the new array
+        for (uint256 i = 0; i < originalLength; i++) {
+            augmentedTokenParams[i] = tokenParams[i];
+        }
+
+        // get + inject the source token hash into the new array
+        uint256 tokenNumber = ABHelpers.tokenIdToTokenNumber(tokenId);
+        uint256 sourceTokenId = ABHelpers.tokenIdFromProjectIdAndTokenNumber({
+            projectId: sourceProjectId,
+            tokenNumber: tokenNumber
+        });
+        bytes32 sourceTokenHash = IGenArt721CoreContractV3_Base(
+            sourceCoreContract
+        ).tokenIdToHash(sourceTokenId);
+
+        augmentedTokenParams[originalLength] = IWeb3Call.TokenParam({
+            key: "sourceTokenHash",
+            value: uint256(sourceTokenHash).toHexString()
+        });
+
+        // return the augmented tokenParams
+        return augmentedTokenParams;
+    }
+}

package/contracts/web3call/augment-hooks/InjectTokenHashSeed.sol

@@ -0,0 +1,62 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {AbstractPMPAugmentHook} from "./AbstractPMPAugmentHook.sol";
+
+import {IWeb3Call} from "../../interfaces/v0.8.x/IWeb3Call.sol";
+import {IGenArt721CoreContractExposesHashSeed} from "../../interfaces/v0.8.x/IGenArt721CoreContractExposesHashSeed.sol";
+import {Strings} from "@openzeppelin-5.0/contracts/utils/Strings.sol";
+
+/**
+ * @title InjectTokenHashSeed
+ * @author Art Blocks Inc.
+ * @notice This hook injects the token hash seed into a tokens PMPs.
+ */
+contract InjectTokenHashSeed is AbstractPMPAugmentHook {
+    using Strings for uint256;
+
+    /**
+     * @notice Augment the token parameters for a given token.
+     * Appends a token's hash seed into a tokens PMPs.
+     * @dev This hook is called when a token's PMPs are read.
+     * @dev This must return all desired tokenParams, not just additional data.
+     * @param coreContract The address of the core contract to call.
+     * @param tokenId The tokenId of the token to get data for.
+     * @param tokenParams The token parameters for the queried token.
+     * @return augmentedTokenParams The augmented token parameters.
+     */
+    function onTokenPMPReadAugmentation(
+        address coreContract,
+        uint256 tokenId,
+        IWeb3Call.TokenParam[] calldata tokenParams
+    )
+        external
+        view
+        override
+        returns (IWeb3Call.TokenParam[] memory augmentedTokenParams)
+    {
+        // create a new tokenParam array with one extra element
+        uint256 originalLength = tokenParams.length;
+        uint256 newLength = originalLength + 1;
+        augmentedTokenParams = new IWeb3Call.TokenParam[](newLength);
+
+        // copy the original tokenParams into the new array
+        for (uint256 i = 0; i < originalLength; i++) {
+            augmentedTokenParams[i] = tokenParams[i];
+        }
+
+        // get + inject the token hash seed into the new array
+        bytes12 tokenHashSeed = IGenArt721CoreContractExposesHashSeed(
+            coreContract
+        ).tokenIdToHashSeed(tokenId);
+        augmentedTokenParams[originalLength] = IWeb3Call.TokenParam({
+            key: "tokenHashSeed",
+            value: uint256(bytes32(tokenHashSeed)).toHexString()
+        });
+
+        // return the augmented tokenParams
+        return augmentedTokenParams;
+    }
+}

package/contracts/web3call/augment-hooks/InjectTokenOwner.sol

@@ -0,0 +1,60 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {AbstractPMPAugmentHook} from "./AbstractPMPAugmentHook.sol";
+
+import {IWeb3Call} from "../../interfaces/v0.8.x/IWeb3Call.sol";
+import {IERC721} from "@openzeppelin-5.0/contracts/interfaces/IERC721.sol";
+import {Strings} from "@openzeppelin-5.0/contracts/utils/Strings.sol";
+
+/**
+ * @title InjectTokenOwner
+ * @author Art Blocks Inc.
+ * @notice This hook injects the token owner's address into a tokens PMPs.
+ */
+contract InjectTokenOwner is AbstractPMPAugmentHook {
+    using Strings for address;
+
+    /**
+     * @notice Augment the token parameters for a given token.
+     * Appends the token owner's address into a tokens PMPs.
+     * @dev This hook is called when a token's PMPs are read.
+     * @dev This must return all desired tokenParams, not just additional data.
+     * @param coreContract The address of the core contract to call.
+     * @param tokenId The tokenId of the token to get data for.
+     * @param tokenParams The token parameters for the queried token.
+     * @return augmentedTokenParams The augmented token parameters.
+     */
+    function onTokenPMPReadAugmentation(
+        address coreContract,
+        uint256 tokenId,
+        IWeb3Call.TokenParam[] calldata tokenParams
+    )
+        external
+        view
+        override
+        returns (IWeb3Call.TokenParam[] memory augmentedTokenParams)
+    {
+        // create a new tokenParam array with one extra element
+        uint256 originalLength = tokenParams.length;
+        uint256 newLength = originalLength + 1;
+        augmentedTokenParams = new IWeb3Call.TokenParam[](newLength);
+
+        // copy the original tokenParams into the new array
+        for (uint256 i = 0; i < originalLength; i++) {
+            augmentedTokenParams[i] = tokenParams[i];
+        }
+
+        // get + inject the token owner into the new array
+        address tokenOwner = IERC721(coreContract).ownerOf(tokenId);
+        augmentedTokenParams[originalLength] = IWeb3Call.TokenParam({
+            key: "tokenOwner",
+            value: tokenOwner.toHexString()
+        });
+
+        // return the augmented tokenParams
+        return augmentedTokenParams;
+    }
+}

package/contracts/web3call/augment-hooks/InjectTokenOwnerEthBalance.sol

@@ -0,0 +1,61 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {AbstractPMPAugmentHook} from "./AbstractPMPAugmentHook.sol";
+
+import {IWeb3Call} from "../../interfaces/v0.8.x/IWeb3Call.sol";
+import {IERC721} from "@openzeppelin-5.0/contracts/interfaces/IERC721.sol";
+import {Strings} from "@openzeppelin-5.0/contracts/utils/Strings.sol";
+
+/**
+ * @title InjectTokenOwnerEthBalance
+ * @author Art Blocks Inc.
+ * @notice This hook appends the token owner's ETH balance, in wei, to a tokens PMPs.
+ */
+contract InjectTokenOwnerEthBalance is AbstractPMPAugmentHook {
+    using Strings for uint256;
+
+    /**
+     * @notice Augment the token parameters for a given token.
+     * Appends the token owner's ETH balance into a tokens PMPs.
+     * @dev This hook is called when a token's PMPs are read.
+     * @dev This must return all desired tokenParams, not just additional data.
+     * @param coreContract The address of the core contract to call.
+     * @param tokenId The tokenId of the token to get data for.
+     * @param tokenParams The token parameters for the queried token.
+     * @return augmentedTokenParams The augmented token parameters.
+     */
+    function onTokenPMPReadAugmentation(
+        address coreContract,
+        uint256 tokenId,
+        IWeb3Call.TokenParam[] calldata tokenParams
+    )
+        external
+        view
+        override
+        returns (IWeb3Call.TokenParam[] memory augmentedTokenParams)
+    {
+        // create a new tokenParam array with one extra element
+        uint256 originalLength = tokenParams.length;
+        uint256 newLength = originalLength + 1;
+        augmentedTokenParams = new IWeb3Call.TokenParam[](newLength);
+
+        // copy the original tokenParams into the new array
+        for (uint256 i = 0; i < originalLength; i++) {
+            augmentedTokenParams[i] = tokenParams[i];
+        }
+
+        // get + inject the token owner into the new array
+        address tokenOwner = IERC721(coreContract).ownerOf(tokenId);
+        uint256 tokenOwnerEthBalanceInWei = address(tokenOwner).balance;
+        augmentedTokenParams[originalLength] = IWeb3Call.TokenParam({
+            key: "tokenOwnerEthBalance",
+            value: tokenOwnerEthBalanceInWei.toString()
+        });
+
+        // return the augmented tokenParams
+        return augmentedTokenParams;
+    }
+}