@artblocks/contracts 1.1.0 → 1.2.1

package/contracts/GenArt721CoreV3_Curated.sol

@@ -0,0 +1,133 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+pragma solidity 0.8.22;
+
+// Created By: Art Blocks Inc.
+
+import {GenArt721CoreV3_Engine} from "./engine/V3/GenArt721CoreV3_Engine.sol";
+import {EngineConfiguration} from "./interfaces/v0.8.x/IGenArt721CoreContractV3_Engine.sol";
+
+import "./libs/v0.8.x/Bytes32Strings.sol";
+
+/**
+ * @title Art Blocks Curated ERC-721 core contract, V3.2
+ * @author Art Blocks Inc.
+ * @notice This contract derives from the Art Blocks Engine contract and adds
+ * some functionality to support curation of projects by Art Blocks.
+ * It also performs initialization of the contract in the constructor, because
+ * the contract is not intended to use a clone proxy pattern, and is intended
+ * to be deployed without any required follow-on calls to initialize.
+ * ----------------------------------------------------------------------------
+ * See the Art Blocks Engine contract for additional applicable documentation.
+ */
+contract GenArt721CoreV3_Curated is GenArt721CoreV3_Engine {
+    using Bytes32Strings for bytes32;
+
+    /// override patch version of this core contract
+    // @dev this is a constant value that is used to override the inherited core version CORE_VERSION
+    bytes32 private constant _CORE_VERSION_OVERRIDE = "v3.2.6";
+
+    // @dev overridden core version is returned instead of the inherited core version
+    function coreVersion() external pure override returns (string memory) {
+        return _CORE_VERSION_OVERRIDE.toString();
+    }
+
+    /// metadata pointer to the previous associated Flagship Artblocks core contracts
+    // @dev not defined as constant because constant address arrays are not yet implemented in Solidity
+    address[] public PREVIOUS_ART_BLOCKS_CONTRACTS = [
+        0x059EDD72Cd353dF5106D2B9cC5ab83a52287aC3a,
+        0xa7d8d9ef8D8Ce8992Df33D8b8CF4Aebabd5bD270,
+        0x99a9B7c1116f9ceEB1652de04d5969CcE509B069
+    ];
+
+    /// Curation registry for Flagship projects, managed by Art Blocks
+    address public artblocksCurationRegistryAddress;
+
+    bool public constant IS_FLAGSHIP = true;
+
+    /**
+     * @notice Construct a new curated Art Blocks ERC-721 core contract.
+     * Performs all contract initialization in the constructor.
+     * @param engineConfiguration Configuration for the engine contract.
+     * note: parameter `engineConfiguration.newSuperAdminAddress` is not used or operated on in this contract.
+     * @param adminACLContract_ Address of the admin ACL contract.
+     * @param defaultBaseURIHost Default base URI host for token URIs, e.g. "https://token.artblocks.io/" for mainnet
+     * @param bytecodeStorageReaderContract_ Address of the bytecode storage reader contract to be used by this
+     * contract.
+     */
+    constructor(
+        EngineConfiguration memory engineConfiguration,
+        address adminACLContract_,
+        string memory defaultBaseURIHost,
+        address bytecodeStorageReaderContract_
+    ) GenArt721CoreV3_Engine() {
+        // input validation generally performed by the engine factory
+        _onlyNonZeroAddress(engineConfiguration.renderProviderAddress);
+        _onlyNonZeroAddress(engineConfiguration.randomizerContract);
+        _onlyNonZeroAddress(adminACLContract_);
+        _onlyNonZeroAddress(bytecodeStorageReaderContract_);
+        require(
+            bytes(defaultBaseURIHost).length > 0,
+            "GenArt721CoreV3_Curated: defaultBaseURIHost must be non-empty"
+        );
+
+        // input validation specific to the curated contract
+        require(
+            !engineConfiguration.autoApproveArtistSplitProposals,
+            "GenArt721CoreV3_Curated: autoApproveArtistSplitProposals must be false"
+        );
+        // @dev artblocks is listed as render provider, no party should be platform provider
+        require(
+            engineConfiguration.nullPlatformProvider,
+            "GenArt721CoreV3_Curated: nullPlatformProvider must be true"
+        );
+        require(
+            !engineConfiguration.allowArtistProjectActivation,
+            "GenArt721CoreV3_Curated: allowArtistProjectActivation must be false"
+        );
+        // @dev previous artblocks contracts exists, so only starting project ID > 0
+        require(
+            engineConfiguration.startingProjectId > 0,
+            "GenArt721CoreV3_Curated: startingProjectId must be greater than 0"
+        );
+
+        // initialize the contract
+        _initialize({
+            engineConfiguration: engineConfiguration,
+            adminACLContract_: adminACLContract_,
+            defaultBaseURIHost: defaultBaseURIHost,
+            bytecodeStorageReaderContract_: bytecodeStorageReaderContract_
+        });
+
+        // override default base URI to be curated format instead of Engine (no address required for curated)
+        _updateDefaultBaseURI(defaultBaseURIHost);
+    }
+
+    /**
+     * @notice Override of the Engine contract's initialize function.
+     * Immediately reverts, as initialization of this Curated contract is performed in the constructor.
+     */
+    function initialize(
+        EngineConfiguration memory /*engineConfiguration*/,
+        address /*adminACLContract_*/,
+        string memory /*defaultBaseURIHost*/,
+        address /*bytecodeStorageReaderContract_*/
+    ) external pure override {
+        // revert - initialization for this contract is performed in the constructor
+        // @dev note that the initialize function would revert without this override, but it is included for clarity
+        revert("GenArt721CoreV3_Curated: contract initialized in constructor");
+    }
+
+    /**
+     * @notice Updates reference to Art Blocks Curation Registry contract.
+     * @param _artblocksCurationRegistryAddress Address of Art Blocks Curation Registry contract.
+     */
+    function updateArtblocksCurationRegistryAddress(
+        address _artblocksCurationRegistryAddress
+    ) external {
+        _onlyAdminACL(this.updateArtblocksCurationRegistryAddress.selector);
+        artblocksCurationRegistryAddress = _artblocksCurationRegistryAddress;
+        emit ArtBlocksCurationRegistryContractUpdated(
+            _artblocksCurationRegistryAddress
+        );
+    }
+}

package/contracts/OwnedCreate2FactoryV0.sol

@@ -0,0 +1,173 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+// @dev fixed to specific solidity version for clarity and for more clear
+// source code verification purposes.
+pragma solidity 0.8.22;
+
+import {IOwnedCreate2FactoryV0} from "./interfaces/v0.8.x/IOwnedCreate2FactoryV0.sol";
+
+import "@openzeppelin-5.0/contracts/access/Ownable.sol";
+import {IERC20} from "@openzeppelin-5.0/contracts/token/ERC20/IERC20.sol";
+import {SafeERC20} from "@openzeppelin-5.0/contracts/token/ERC20/utils/SafeERC20.sol";
+import {Create2} from "@openzeppelin-5.0/contracts/utils/Create2.sol";
+
+/**
+ * @title OwnedCreate2FactoryV0
+ * @author Art Blocks Inc.
+ * @notice Owned, Create2 factory contract for deploying arbitrary contracts from a single wallet.
+ * This contract is intended to be used as a factory for deploying other contracts, while also allowing
+ * the owner to drain the contract's balance to a recipient address. The contract also provides a
+ * function to execute a batch of calls, which can be useful for interacting with contracts that
+ * might deem this contract eligible for airdrops, thereby avoiding loss of funds.
+ */
+contract OwnedCreate2FactoryV0 is Ownable, IOwnedCreate2FactoryV0 {
+    // public type
+    bytes32 public constant type_ = "OwnedCreate2FactoryV0";
+
+    /**
+     * Represents a generic call operation.
+     */
+    struct Call {
+        address to;
+        bytes data;
+    }
+
+    /**
+     * @notice creates this contract and deploys the curated contract
+     * @param owner_ address of the initial owner of this contract to execute all future calls
+     */
+    constructor(address owner_) Ownable(owner_) {
+        // input validation
+        // @dev Ownable enforces that the owner must be non-zero
+
+        // emit Deployed event
+        emit Deployed();
+    }
+
+    /**
+     * @notice Deploy a new contract using create2.
+     * Reverts if the initcode is empty.
+     * Reverts if not called by the owner.
+     * The address of the new contract is deterministic based on the salt and initcode, and may be obtained by calling
+     * the `predictDeterministicAddress` function.
+     * @param salt The salt to use for the deployment.
+     * @param initcode The initcode of the contract to deploy.
+     * @return newContract The address of the newly deployed contract.
+     */
+    function deployCreate2(
+        bytes32 salt,
+        bytes calldata initcode
+    ) external payable onlyOwner returns (address newContract) {
+        // input validation
+        // @dev Create2.deploy will revert if initcode is empty
+
+        // deploy contract
+        newContract = Create2.deploy({
+            amount: msg.value,
+            salt: salt,
+            bytecode: initcode
+        });
+
+        emit ContractCreated({newContract: newContract});
+        return newContract;
+    }
+
+    /**
+     * @dev This contract is not intended to hold funds. This function,
+     * `drainETH`, and `drainERC20` are implemented to prevent the loss
+     * of funds that might be sent to this contract inadvertently.
+     */
+    receive() external payable {}
+
+    /**
+     * @notice Drains the contract's balance to the `recipient`.
+     * @param recipient The address to send funds to.
+     * Only callable by the owner.
+     */
+    function drainETH(address payable recipient) external onlyOwner {
+        uint256 balance = address(this).balance;
+        if (balance > 0) {
+            (bool success, ) = recipient.call{value: balance}("");
+            require(success, "Payment failed");
+        }
+    }
+
+    /**
+     * @notice Drains the contract's balance of an input ERC20 token to
+     * the `recipient`.
+     * @param ERC20TokenAddress The address of the ERC20 token to withdraw.
+     * @param recipient The address to send ERC20 tokens to.
+     * Only callable by the owner.
+     */
+    function drainERC20(
+        address ERC20TokenAddress,
+        address recipient
+    ) external onlyOwner {
+        IERC20 token = IERC20(ERC20TokenAddress);
+        uint256 balance = token.balanceOf(address(this));
+        if (balance > 0) {
+            SafeERC20.safeTransfer({
+                token: token,
+                to: recipient,
+                value: balance
+            });
+        }
+    }
+
+    /**
+     * @notice Execute a batch of calls.
+     * @dev The calls are executed in order, reverting if any of them fails. Can
+     * only be called by the owner. It is safe to check ownership only once here
+     * because the owner status is only used to gate access to the function, not
+     * to validate each individual call. Even if ownership is transferred during
+     * the sequence of calls, it does not affect the execution logic or security,
+     * as ownership is solely used to prevent unauthorized use of this batch
+     * execution capability. This is particularly useful to safely interact
+     * with contracts or addresses that might deem this contract eligible for
+     * airdrops, thereby avoiding loss of funds.
+     * @param _calls The calls to execute
+     */
+    function execCalls(
+        Call[] calldata _calls
+    )
+        external
+        onlyOwner
+        returns (uint256 blockNumber, bytes[] memory returnData)
+    {
+        blockNumber = block.number;
+        uint256 length = _calls.length;
+        returnData = new bytes[](length);
+
+        for (uint256 i = 0; i < length; ++i) {
+            Call calldata calli = _calls[i];
+
+            // check for existence of code at the target address
+            if (calli.to.code.length == 0) {
+                // when the call is to an EOA, the calldata must be empty.
+                require(calli.data.length == 0, "Invalid call data");
+            }
+
+            (bool success, bytes memory data) = calli.to.call(calli.data);
+            require(success, string(data));
+            returnData[i] = data;
+        }
+    }
+
+    /**
+     * @dev Predict the deterministic address for a new deployment using create2.
+     * @param salt Salt used to deterministically deploy the clone.
+     * @param initcode The initcode of the contract to deploy.
+     */
+
+    function predictDeterministicAddress(
+        bytes32 salt,
+        bytes memory initcode
+    ) external view returns (address predicted) {
+        return
+            Create2.computeAddress({
+                salt: salt,
+                bytecodeHash: keccak256(initcode)
+            });
+    }
+}

package/contracts/{GenArt721CoreV3.sol → archive/GenArt721CoreV3.sol}

@@ -1,19 +1,19 @@
 // SPDX-License-Identifier: LGPL-3.0-only
-pragma solidity 0.8.19;
+pragma solidity 0.8.22;
 
 // Created By: Art Blocks Inc.
 
-import "./interfaces/v0.8.x/IRandomizer_V3CoreBase.sol";
-import "./interfaces/v0.8.x/IAdminACLV0.sol";
-import "./interfaces/v0.8.x/IGenArt721CoreContractV3.sol";
-import "./interfaces/v0.8.x/IGenArt721CoreContractExposesHashSeed.sol";
-import "./interfaces/v0.8.x/IManifold.sol";
+import "../interfaces/v0.8.x/IRandomizer_V3CoreBase.sol";
+import "../interfaces/v0.8.x/IAdminACLV0.sol";
+import "../interfaces/v0.8.x/IGenArt721CoreContractV3.sol";
+import "../interfaces/v0.8.x/IGenArt721CoreContractExposesHashSeed.sol";
+import "../interfaces/v0.8.x/IManifold.sol";
 
 import "@openzeppelin-4.7/contracts/utils/Strings.sol";
 import "@openzeppelin-4.7/contracts/access/Ownable.sol";
-import "./libs/v0.8.x/ERC721_PackedHashSeed.sol";
-import "./libs/v0.8.x/BytecodeStorageV1.sol";
-import "./libs/v0.8.x/Bytes32Strings.sol";
+import "../libs/v0.8.x/ERC721_PackedHashSeed.sol";
+import "../libs/v0.8.x/BytecodeStorageV1.sol";
+import "../libs/v0.8.x/Bytes32Strings.sol";
 
 /**
  * @title Art Blocks ERC-721 core contract, V3.
@@ -103,7 +103,7 @@ contract GenArt721CoreV3 is
     uint8 constant AT_CHARACTER_CODE = uint8(bytes1("@")); // 0x40
 
     // numeric constants
-    uint256 constant ART_BLOCKS_MAX_PRIMARY_SALES_PERCENTAGE = 25; // 25%
+    // max art blocks primary sales percentage is 100%
     uint256 constant ART_BLOCKS_MAX_SECONDARY_SALES_BPS = 10000; // 10_000 BPS = 100%
     uint256 constant ARTIST_MAX_SECONDARY_ROYALTY_PERCENTAGE = 95; // 95%
 
@@ -125,10 +125,13 @@ contract GenArt721CoreV3 is
     bytes32 constant FIELD_ARTBLOCKS_SECONDARY_SALES_ADDRESS =
         "artblocksSecondarySalesAddress";
     bytes32 constant FIELD_RANDOMIZER_ADDRESS = "randomizerAddress";
+    bytes32 constant FIELD_NEXT_CORE_CONTRACT = "nextCoreContract";
     bytes32 constant FIELD_ARTBLOCKS_CURATION_REGISTRY_ADDRESS =
         "curationRegistryAddress";
     bytes32 constant FIELD_ARTBLOCKS_DEPENDENCY_REGISTRY_ADDRESS =
         "dependencyRegistryAddress";
+    bytes32 constant FIELD_ARTBLOCKS_ON_CHAIN_GENERATOR_ADDRESS =
+        "onChainGeneratorAddress";
     bytes32 constant FIELD_ARTBLOCKS_PRIMARY_SALES_PERCENTAGE =
         "artblocksPrimaryPercentage";
     bytes32 constant FIELD_ARTBLOCKS_SECONDARY_SALES_BPS =
@@ -160,11 +163,15 @@ contract GenArt721CoreV3 is
     /// Art Blocks Project ID range: [3-373]
     address public constant ART_BLOCKS_ERC721TOKEN_ADDRESS_V1 =
         0xa7d8d9ef8D8Ce8992Df33D8b8CF4Aebabd5bD270;
+    /// pointer to next core contract associated with this contract
+    address public nextCoreContract;
 
     /// Curation registry managed by Art Blocks
     address public artblocksCurationRegistryAddress;
     /// Dependency registry managed by Art Blocks
     address public artblocksDependencyRegistryAddress;
+    /// On chain generator managed by Art Blocks
+    address public artblocksOnChainGeneratorAddress;
 
     /// current randomizer contract
     IRandomizer_V3CoreBase public randomizerContract;
@@ -484,6 +491,16 @@ contract GenArt721CoreV3 is
         Ownable.renounceOwnership();
     }
 
+    /**
+     * @notice Updates reference to next core contract, associated with this contract.
+     * @param _nextCoreContract Address of the next core contract
+     */
+    function updateNextCoreContract(address _nextCoreContract) external {
+        _onlyAdminACL(this.updateNextCoreContract.selector);
+        nextCoreContract = _nextCoreContract;
+        emit PlatformUpdated(FIELD_NEXT_CORE_CONTRACT);
+    }
+
     /**
      * @notice Updates reference to Art Blocks Curation Registry contract.
      * @param _artblocksCurationRegistryAddress Address of new Curation
@@ -512,6 +529,19 @@ contract GenArt721CoreV3 is
         emit PlatformUpdated(FIELD_ARTBLOCKS_DEPENDENCY_REGISTRY_ADDRESS);
     }
 
+    /**
+     * @notice Updates reference to Art Blocks On Chain Generator contract.
+     * @param _artblocksOnChainGeneratorAddress Address of new on chain generator.
+     */
+    function updateArtblocksOnChainGeneratorAddress(
+        address _artblocksOnChainGeneratorAddress
+    ) external {
+        _onlyAdminACL(this.updateArtblocksOnChainGeneratorAddress.selector);
+        _onlyNonZeroAddress(_artblocksOnChainGeneratorAddress);
+        artblocksOnChainGeneratorAddress = _artblocksOnChainGeneratorAddress;
+        emit PlatformUpdated(FIELD_ARTBLOCKS_ON_CHAIN_GENERATOR_ADDRESS);
+    }
+
     /**
      * @notice Updates artblocksPrimarySalesAddress to
      * `_artblocksPrimarySalesAddress`.
@@ -550,11 +580,8 @@ contract GenArt721CoreV3 is
         uint256 artblocksPrimarySalesPercentage_
     ) external {
         _onlyAdminACL(this.updateArtblocksPrimarySalesPercentage.selector);
-        require(
-            artblocksPrimarySalesPercentage_ <=
-                ART_BLOCKS_MAX_PRIMARY_SALES_PERCENTAGE,
-            "Max of ART_BLOCKS_MAX_PRIMARY_SALES_PERCENTAGE percent"
-        );
+        // anything above 100 percent is illogical
+        require(artblocksPrimarySalesPercentage_ <= 100, "Max of 100 percent");
         _artblocksPrimarySalesPercentage = uint8(
             artblocksPrimarySalesPercentage_
         );
@@ -896,6 +923,8 @@ contract GenArt721CoreV3 is
     /**
      * @notice Updates artist name for project `_projectId` to be
      * `_projectArtistName`.
+     * @dev allows admin to update after project is locked, due to our
+     * experiences of artist name changes being requested post-lock.
      * @param _projectId Project ID.
      * @param _projectArtistName New artist name.
      */
@@ -903,10 +932,17 @@ contract GenArt721CoreV3 is
         uint256 _projectId,
         string memory _projectArtistName
     ) external {
-        _onlyUnlocked(_projectId);
-        _onlyArtistOrAdminACL(
-            _projectId,
-            this.updateProjectArtistName.selector
+        // checks
+        // if unlocked, only artist may update, if locked, only admin may update
+        require(
+            _projectUnlocked(_projectId)
+                ? msg.sender == projectIdToFinancials[_projectId].artistAddress
+                : adminACLAllowed(
+                    msg.sender,
+                    address(this),
+                    this.updateProjectArtistName.selector
+                ),
+            "Only artist, owner when locked"
         );
         _onlyNonEmptyString(_projectArtistName);
         projects[_projectId].artist = _projectArtistName;
@@ -967,7 +1003,7 @@ contract GenArt721CoreV3 is
                     address(this),
                     this.updateProjectDescription.selector
                 ),
-            "Only artist when unlocked, owner when locked"
+            "Only artist, owner when locked"
         );
         // effects
         // store description in contract bytecode, replacing reference address from

package/contracts/{explorations → archive}/GenArt721CoreV3_Explorations.sol

@@ -43,7 +43,7 @@ import "../libs/v0.8.x/Bytes32Strings.sol";
  * - forbidNewProjects (forever forbidding new projects)
  * - updateDefaultBaseURI (used to initialize new project base URIs)
  * ----------------------------------------------------------------------------
- * The following functions are restricted to either the the Artist address or
+ * The following functions are restricted to either the Artist address or
  * the Admin ACL contract, only when the project is not locked:
  * - updateProjectName
  * - updateProjectArtistName
@@ -103,7 +103,7 @@ contract GenArt721CoreV3_Explorations is
     uint8 constant AT_CHARACTER_CODE = uint8(bytes1("@")); // 0x40
 
     // numeric constants
-    uint256 constant ART_BLOCKS_MAX_PRIMARY_SALES_PERCENTAGE = 100; // 100%
+    // max art blocks primary sales percentage is 100%
     uint256 constant ART_BLOCKS_MAX_SECONDARY_SALES_BPS = 10000; // 10_000 BPS = 100%
     uint256 constant ARTIST_MAX_SECONDARY_ROYALTY_PERCENTAGE = 95; // 95%
 
@@ -125,11 +125,14 @@ contract GenArt721CoreV3_Explorations is
     bytes32 constant FIELD_ARTBLOCKS_SECONDARY_SALES_ADDRESS =
         "artblocksSecondarySalesAddress";
     bytes32 constant FIELD_RANDOMIZER_ADDRESS = "randomizerAddress";
+    bytes32 constant FIELD_NEXT_CORE_CONTRACT = "nextCoreContract";
     // note: Curation registry address will never be updated on V3 Explorations
     bytes32 constant FIELD_ARTBLOCKS_CURATION_REGISTRY_ADDRESS =
         "curationRegistryAddress";
     bytes32 constant FIELD_ARTBLOCKS_DEPENDENCY_REGISTRY_ADDRESS =
         "dependencyRegistryAddress";
+    bytes32 constant FIELD_ARTBLOCKS_ON_CHAIN_GENERATOR_ADDRESS =
+        "onChainGeneratorAddress";
     bytes32 constant FIELD_ARTBLOCKS_PRIMARY_SALES_PERCENTAGE =
         "artblocksPrimaryPercentage";
     bytes32 constant FIELD_ARTBLOCKS_SECONDARY_SALES_BPS =
@@ -154,12 +157,17 @@ contract GenArt721CoreV3_Explorations is
     bytes32 constant FIELD_PROJECT_ASPECT_RATIO = "aspectRatio";
     bytes32 constant FIELD_PROJECT_BASE_URI = "baseURI";
 
+    /// pointer to next core contract associated with this contract
+    address public nextCoreContract;
+
     /// Curation registry is not relevant for Art Blocks Explorations, and will
     /// remain null for interface-conformance purposes only, specifically for
     /// indexing layers.
     address public artblocksCurationRegistryAddress;
     /// Dependency registry managed by Art Blocks
     address public artblocksDependencyRegistryAddress;
+    /// On chain generator managed by Art Blocks
+    address public artblocksOnChainGeneratorAddress;
 
     /// current randomizer contract
     IRandomizerV2 public randomizerContract;
@@ -408,7 +416,7 @@ contract GenArt721CoreV3_Explorations is
         unchecked {
             // invocationsBefore is uint24 << max uint256. In production use,
             // _projectId * ONE_MILLION must be << max uint256, otherwise
-            // tokenIdToProjectId function become invalid.
+            // tokenIdToProjectId function becomes invalid.
             // Therefore, no risk of overflow
             thisTokenId = (_projectId * ONE_MILLION) + invocationsBefore;
         }
@@ -489,6 +497,16 @@ contract GenArt721CoreV3_Explorations is
         Ownable.renounceOwnership();
     }
 
+    /**
+     * @notice Updates reference to next core contract, associated with this contract.
+     * @param _nextCoreContract Address of the next core contract
+     */
+    function updateNextCoreContract(address _nextCoreContract) external {
+        _onlyAdminACL(this.updateNextCoreContract.selector);
+        nextCoreContract = _nextCoreContract;
+        emit PlatformUpdated(FIELD_NEXT_CORE_CONTRACT);
+    }
+
     /**
      * @notice Warning: Configuring Curation Registry contract is not supported
      * on V3 Explorations version of this contract.
@@ -518,6 +536,19 @@ contract GenArt721CoreV3_Explorations is
         emit PlatformUpdated(FIELD_ARTBLOCKS_DEPENDENCY_REGISTRY_ADDRESS);
     }
 
+    /**
+     * @notice Updates reference to Art Blocks On Chain Generator contract.
+     * @param _artblocksOnChainGeneratorAddress Address of new on chain generator.
+     */
+    function updateArtblocksOnChainGeneratorAddress(
+        address _artblocksOnChainGeneratorAddress
+    ) external {
+        _onlyAdminACL(this.updateArtblocksOnChainGeneratorAddress.selector);
+        _onlyNonZeroAddress(_artblocksOnChainGeneratorAddress);
+        artblocksOnChainGeneratorAddress = _artblocksOnChainGeneratorAddress;
+        emit PlatformUpdated(FIELD_ARTBLOCKS_ON_CHAIN_GENERATOR_ADDRESS);
+    }
+
     /**
      * @notice Updates artblocksPrimarySalesAddress to
      * `_artblocksPrimarySalesAddress`.
@@ -556,11 +587,8 @@ contract GenArt721CoreV3_Explorations is
         uint256 artblocksPrimarySalesPercentage_
     ) external {
         _onlyAdminACL(this.updateArtblocksPrimarySalesPercentage.selector);
-        require(
-            artblocksPrimarySalesPercentage_ <=
-                ART_BLOCKS_MAX_PRIMARY_SALES_PERCENTAGE,
-            "Max of ART_BLOCKS_MAX_PRIMARY_SALES_PERCENTAGE percent"
-        );
+        // anything above 100 percent is illogical
+        require(artblocksPrimarySalesPercentage_ <= 100, "Max of 100 percent");
         _artblocksPrimarySalesPercentage = uint8(
             artblocksPrimarySalesPercentage_
         );
@@ -902,6 +930,8 @@ contract GenArt721CoreV3_Explorations is
     /**
      * @notice Updates artist name for project `_projectId` to be
      * `_projectArtistName`.
+     * @dev allows admin to update after project is locked, due to our
+     * experiences of artist name changes being requested post-lock.
      * @param _projectId Project ID.
      * @param _projectArtistName New artist name.
      */
@@ -909,10 +939,16 @@ contract GenArt721CoreV3_Explorations is
         uint256 _projectId,
         string memory _projectArtistName
     ) external {
-        _onlyUnlocked(_projectId);
-        _onlyArtistOrAdminACL(
-            _projectId,
-            this.updateProjectArtistName.selector
+        // if unlocked, only artist may update, if locked, only admin may update
+        require(
+            _projectUnlocked(_projectId)
+                ? msg.sender == projectIdToFinancials[_projectId].artistAddress
+                : adminACLAllowed(
+                    msg.sender,
+                    address(this),
+                    this.updateProjectArtistName.selector
+                ),
+            "Only artist, owner when locked"
         );
         _onlyNonEmptyString(_projectArtistName);
         projects[_projectId].artist = _projectArtistName;
@@ -973,7 +1009,7 @@ contract GenArt721CoreV3_Explorations is
                     address(this),
                     this.updateProjectDescription.selector
                 ),
-            "Only artist when unlocked, owner when locked"
+            "Only artist, owner when locked"
         );
         // effects
         // store description in contract bytecode, replacing reference address from

package/contracts/{minter-suite → archive/minter-suite}/Minters/MinterBase_v0_1_1.sol

@@ -1,10 +1,10 @@
 // SPDX-License-Identifier: LGPL-3.0-only
 // Created By: Art Blocks Inc.
 
-import "../../interfaces/v0.8.x/IMinterBaseV0.sol";
-import "../../interfaces/v0.8.x/IGenArt721CoreContractV3_Base.sol";
-import "../../interfaces/v0.8.x/IGenArt721CoreContractV3.sol";
-import "../../interfaces/v0.8.x/IGenArt721CoreContractV3_Engine.sol";
+import "../../../interfaces/v0.8.x/IMinterBaseV0.sol";
+import "../../../interfaces/v0.8.x/IGenArt721CoreContractV3_Base.sol";
+import "../../../interfaces/v0.8.x/IGenArt721CoreContractV3.sol";
+import "../../../interfaces/v0.8.x/IGenArt721CoreContractV3_Engine.sol";
 
 import "@openzeppelin-4.7/contracts/token/ERC20/IERC20.sol";
 

package/contracts/{minter-suite/Minters → archive/minter-suite/Minters/MinterDAExp}/MinterDAExpV4.sol

@@ -1,10 +1,10 @@
 // SPDX-License-Identifier: LGPL-3.0-only
 // Created By: Art Blocks Inc.
 
-import "../../interfaces/v0.8.x/IGenArt721CoreContractV3_Base.sol";
-import "../../interfaces/v0.8.x/IMinterFilterV0.sol";
-import "../../interfaces/v0.8.x/IFilteredMinterDAExpV1.sol";
-import "./MinterBase_v0_1_1.sol";
+import "../../../../interfaces/v0.8.x/IGenArt721CoreContractV3_Base.sol";
+import "../../../../interfaces/v0.8.x/IMinterFilterV0.sol";
+import "../../../../interfaces/v0.8.x/IFilteredMinterDAExpV1.sol";
+import "../MinterBase_v0_1_1.sol";
 
 import "@openzeppelin-4.5/contracts/security/ReentrancyGuard.sol";
 import "@openzeppelin-4.5/contracts/utils/math/SafeCast.sol";