@artblocks/contracts 1.0.3 → 1.1.0

package/contracts/libs/v0.8.x/minter-libs/DAExpLib.sol

@@ -0,0 +1,250 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {DALib} from "./DALib.sol";
+
+/**
+ * @title Art Blocks Dutch Auction (exponential price curve) Library
+ * @notice This library is designed to implement logic and checks for Art
+ * Blocks projects using an exponential Dutch auctionprice curve for minting
+ * tokens.
+ * @author Art Blocks Inc.
+ */
+
+library DAExpLib {
+    /**
+     * @notice Auction details set for project `projectId` on core contract
+     * `coreContract`.
+     * @param projectId Project Id for which auction details were set
+     * @param coreContract Core contract address for which auction details were
+     * set
+     * @param auctionTimestampStart Timestamp when auction will start
+     * @param priceDecayHalfLifeSeconds Half life of price decay, in seconds
+     * @param startPrice Start price of auction
+     * @param basePrice Base price of auction (end price)
+     */
+    event SetAuctionDetailsExp(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        uint40 auctionTimestampStart,
+        uint40 priceDecayHalfLifeSeconds,
+        uint256 startPrice,
+        uint256 basePrice
+    );
+    /// Minimum allowed price decay half life seconds updated.
+
+    /**
+     * @notice Minimum allowed price decay half life on the minter updated to
+     * `minimumPriceDecayHalfLifeSeconds`.
+     * @param minimumPriceDecayHalfLifeSeconds minimum price decay half life
+     * for new auctions, in seconds
+     */
+    event AuctionMinHalfLifeSecondsUpdated(
+        uint256 minimumPriceDecayHalfLifeSeconds
+    );
+
+    // position of DA Exp Lib storage, using a diamond storage pattern
+    // for this library
+    bytes32 constant DAE_EXP_LIB_STORAGE_POSITION =
+        keccak256("daexplib.storage");
+
+    struct DAProjectConfig {
+        // @dev max uint40 ~= 1.1e12 sec ~= 34 thousand years
+        uint40 timestampStart;
+        uint40 priceDecayHalfLifeSeconds;
+        // @dev max uint88 ~= 3e26 Wei = ~300 million ETH, which is well above
+        // the expected prices of any NFT mint in the foreseeable future.
+        uint88 startPrice;
+        uint88 basePrice;
+    }
+
+    // Diamond storage pattern is used in this library
+    struct DAExpLibStorage {
+        mapping(address coreContract => mapping(uint256 projectId => DAProjectConfig)) DAProjectConfigs_;
+    }
+
+    /**
+     * @notice Sets auction details for an exponential-price auction type.
+     * @dev The function sets the auction start timestamp, price decay
+     * half-life, starting, and base prices for an exponential-price auction.
+     * @dev Minter implementations should ensure that any additional guard-
+     * rails are properly checked outside of this function. For example, the
+     * minter should check that _priceDecayHalfLifeSeconds is greater than the
+     * minter's minimum allowable value for price decay half-life (if the
+     * minter chooses to include that guard-rail).
+     * @param projectId The project Id to set auction details for.
+     * @param coreContract The core contract address to set auction details.
+     * @param auctionTimestampStart The timestamp when the auction will start.
+     * @param priceDecayHalfLifeSeconds The half-life time for price decay in
+     * seconds.
+     * @param startPrice The starting price of the auction.
+     * @param basePrice The base price of the auction.
+     * @param allowReconfigureAfterStart Bool indicating whether the auction
+     * can be reconfigured after it has started. This is sometimes useful for
+     * minter implementations that want to allow an artist to reconfigure the
+     * auction after it has reached minter-local max invocations, for example.
+     */
+    function setAuctionDetailsExp(
+        uint256 projectId,
+        address coreContract,
+        uint40 auctionTimestampStart,
+        uint40 priceDecayHalfLifeSeconds,
+        uint88 startPrice,
+        uint88 basePrice,
+        bool allowReconfigureAfterStart
+    ) internal {
+        DAProjectConfig storage DAProjectConfig_ = getDAProjectConfig({
+            projectId: projectId,
+            coreContract: coreContract
+        });
+        require(
+            DAProjectConfig_.timestampStart == 0 || // uninitialized
+                block.timestamp < DAProjectConfig_.timestampStart || // auction not yet started
+                allowReconfigureAfterStart, // specifically allowing reconfiguration after start
+            "No modifications mid-auction"
+        );
+        require(
+            block.timestamp < auctionTimestampStart,
+            "Only future auctions"
+        );
+        require(
+            startPrice > basePrice,
+            "Auction start price must be greater than auction end price"
+        );
+
+        // EFFECTS
+        DAProjectConfig_.timestampStart = auctionTimestampStart;
+        DAProjectConfig_.priceDecayHalfLifeSeconds = priceDecayHalfLifeSeconds;
+        DAProjectConfig_.startPrice = startPrice;
+        DAProjectConfig_.basePrice = basePrice;
+
+        emit SetAuctionDetailsExp({
+            projectId: projectId,
+            coreContract: coreContract,
+            auctionTimestampStart: auctionTimestampStart,
+            priceDecayHalfLifeSeconds: priceDecayHalfLifeSeconds,
+            startPrice: startPrice,
+            basePrice: basePrice
+        });
+    }
+
+    function resetAuctionDetails(
+        uint256 projectId,
+        address coreContract
+    ) internal {
+        DAProjectConfig storage DAProjectConfig_ = getDAProjectConfig({
+            projectId: projectId,
+            coreContract: coreContract
+        });
+
+        DAProjectConfig_.timestampStart = 0;
+        DAProjectConfig_.priceDecayHalfLifeSeconds = 0;
+        DAProjectConfig_.startPrice = 0;
+        DAProjectConfig_.basePrice = 0;
+
+        emit DALib.ResetAuctionDetails({
+            projectId: projectId,
+            coreContract: coreContract
+        });
+    }
+
+    /**
+     * @notice Gets price of minting a token given the project's
+     * DAProjectConfig.
+     * This function reverts if auction has not yet started, or if auction is
+     * unconfigured, which is relied upon by certain minter implications for
+     * security.
+     * @param projectId Project Id to get price for
+     * @param coreContract Core contract address to get price for
+     * @return uint256 current price of token in Wei
+     */
+    function getPriceExp(
+        uint256 projectId,
+        address coreContract
+    ) internal view returns (uint256) {
+        DAProjectConfig storage DAProjectConfig_ = getDAProjectConfig({
+            projectId: projectId,
+            coreContract: coreContract
+        });
+        // move parameters to memory if used more than once
+        uint256 timestampStart = DAProjectConfig_.timestampStart;
+        uint256 priceDecayHalfLifeSeconds = DAProjectConfig_
+            .priceDecayHalfLifeSeconds;
+
+        require(block.timestamp >= timestampStart, "Auction not yet started");
+        require(priceDecayHalfLifeSeconds > 0, "Only configured auctions");
+        uint256 decayedPrice = DAProjectConfig_.startPrice;
+        uint256 elapsedTimeSeconds;
+        unchecked {
+            // already checked that block.timestamp > _timestampStart above
+            elapsedTimeSeconds = block.timestamp - timestampStart;
+        }
+        // Divide by two (via bit-shifting) for the number of entirely completed
+        // half-lives that have elapsed since auction start time.
+        unchecked {
+            // already required priceDecayHalfLifeSeconds > 0
+            decayedPrice >>= elapsedTimeSeconds / priceDecayHalfLifeSeconds;
+        }
+        // Perform a linear interpolation between partial half-life points, to
+        // approximate the current place on a perfect exponential decay curve.
+        unchecked {
+            // value of expression is provably always less than decayedPrice,
+            // so no underflow is possible when the subtraction assignment
+            // operator is used on decayedPrice.
+            decayedPrice -=
+                ((decayedPrice *
+                    (elapsedTimeSeconds % priceDecayHalfLifeSeconds)) /
+                    priceDecayHalfLifeSeconds) >>
+                1; // divide by 2 via bitshift 1
+        }
+        uint256 basePrice = DAProjectConfig_.basePrice;
+        if (decayedPrice < basePrice) {
+            // Price may not decay below stay `basePrice`.
+            return basePrice;
+        }
+        return decayedPrice;
+    }
+
+    /**
+     * Gets auction base price for project `projectId` on core contract
+     * `coreContract`.
+     * @param projectId Project Id to get price for
+     * @param coreContract Core contract address to get price for
+     */
+    function getAuctionBasePrice(
+        uint256 projectId,
+        address coreContract
+    ) internal view returns (uint256) {
+        return
+            getDAProjectConfig({
+                projectId: projectId,
+                coreContract: coreContract
+            }).basePrice;
+    }
+
+    /**
+     * Loads the DAProjectConfig for a given project and core contract.
+     * @param projectId Project Id to get config for
+     * @param coreContract Core contract address to get config for
+     */
+    function getDAProjectConfig(
+        uint256 projectId,
+        address coreContract
+    ) internal view returns (DAProjectConfig storage) {
+        return s().DAProjectConfigs_[coreContract][projectId];
+    }
+
+    /**
+     * @notice Return the storage struct for reading and writing. This library
+     * uses a diamond storage pattern when managing storage.
+     * @return storageStruct The DAExpLibStorage struct.
+     */
+    function s() internal pure returns (DAExpLibStorage storage storageStruct) {
+        bytes32 position = DAE_EXP_LIB_STORAGE_POSITION;
+        assembly ("memory-safe") {
+            storageStruct.slot := position
+        }
+    }
+}

package/contracts/libs/v0.8.x/minter-libs/DALib.sol

@@ -0,0 +1,26 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+/**
+ * @title Art Blocks Dutch Auction (exponential price curve) Library
+ * @notice This library is designed to implement logic and checks for Art
+ * Blocks projects using an exponential Dutch auctionprice curve for minting
+ * tokens.
+ * @author Art Blocks Inc.
+ */
+
+library DALib {
+    /**
+     * @notice Auction details cleared for project `projectId` on core contract
+     * `coreContract`.
+     * @param projectId Project Id for which auction details were cleared
+     * @param coreContract Core contract address for which auction details were
+     * cleared
+     */
+    event ResetAuctionDetails(
+        uint256 indexed projectId,
+        address indexed coreContract
+    );
+}

package/contracts/libs/v0.8.x/minter-libs/DALinLib.sol

@@ -0,0 +1,216 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+import {DALib} from "./DALib.sol";
+
+/**
+ * @title Art Blocks Dutch Auction (linear price curve) Library
+ * @notice This library is designed to implement logic and checks for Art
+ * Blocks projects using an linear Dutch auctionprice curve for minting
+ * tokens.
+ * @author Art Blocks Inc.
+ */
+
+library DALinLib {
+    /**
+     * @notice Auction details set for project `projectId` on core contract
+     * `coreContract`.
+     * @param projectId Project Id for which auction details were set
+     * @param coreContract Core contract address for which auction details were
+     * set
+     * @param auctionTimestampStart Timestamp when auction will start
+     * @param auctionTimestampEnd Timestamp when auction will end
+     * @param startPrice Start price of auction
+     * @param basePrice Base price of auction (end price)
+     */
+    event SetAuctionDetailsLin(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        uint40 auctionTimestampStart,
+        uint40 auctionTimestampEnd,
+        uint256 startPrice,
+        uint256 basePrice
+    );
+
+    /**
+     * @notice Minimum allowed auction length updated to
+     * `minimumAuctionLengthSeconds` on the minter.
+     * @param minimumAuctionLengthSeconds minimum auction length for new
+     * auctions, in seconds
+     */
+    event AuctionMinimumLengthSecondsUpdated(
+        uint256 minimumAuctionLengthSeconds
+    );
+
+    // position of DA Lin Lib storage, using a diamond storage pattern
+    // for this library
+    bytes32 constant DAE_LIN_LIB_STORAGE_POSITION =
+        keccak256("dalinlib.storage");
+
+    struct DAProjectConfig {
+        // @dev max uint40 ~= 1.1e12 sec ~= 34 thousand years
+        uint40 timestampStart;
+        uint40 timestampEnd;
+        // @dev max uint88 ~= 3e26 Wei = ~300 million ETH, which is well above
+        // the expected prices of any NFT mint in the foreseeable future.
+        uint88 startPrice;
+        uint88 basePrice;
+    }
+
+    // Diamond storage pattern is used in this library
+    struct DALinLibStorage {
+        mapping(address coreContract => mapping(uint256 projectId => DAProjectConfig)) DAProjectConfigs_;
+    }
+
+    /**
+     * @notice Sets auction details for a linear-price auction type.
+     * @dev The function sets the auction start timestamp, auction end
+     * timestamp, starting, and base prices for a linear-price auction.
+     * @dev Minter implementations should ensure that any additional guard-
+     * rails are properly checked outside of this function. For example, the
+     * minter should check that auction length is greater than the minter's
+     * minimum allowable value (if the minter chooses to include that guard-
+     * rail).
+     * @param projectId The project Id to set auction details for.
+     * @param coreContract The core contract address to set auction details.
+     * @param auctionTimestampStart The timestamp when the auction will start.
+     * @param auctionTimestampEnd The timestamp when the auction will end.
+     * @param startPrice The starting price of the auction.
+     * @param basePrice The base price of the auction.
+     * @param allowReconfigureAfterStart Bool indicating whether the auction
+     * can be reconfigured after it has started. This is sometimes useful for
+     * minter implementations that want to allow an artist to reconfigure the
+     * auction after it has reached minter-local max invocations, for example.
+     */
+    function setAuctionDetailsLin(
+        uint256 projectId,
+        address coreContract,
+        uint40 auctionTimestampStart,
+        uint40 auctionTimestampEnd,
+        uint88 startPrice,
+        uint88 basePrice,
+        bool allowReconfigureAfterStart
+    ) internal {
+        DAProjectConfig storage DAProjectConfig_ = getDAProjectConfig({
+            projectId: projectId,
+            coreContract: coreContract
+        });
+        require(
+            DAProjectConfig_.timestampStart == 0 || // uninitialized
+                block.timestamp < DAProjectConfig_.timestampStart || // auction not yet started
+                allowReconfigureAfterStart, // specifically allowing reconfiguration after start
+            "No modifications mid-auction"
+        );
+        require(
+            block.timestamp < auctionTimestampStart,
+            "Only future auctions"
+        );
+        require(
+            startPrice > basePrice,
+            "Auction start price must be greater than auction end price"
+        );
+
+        // EFFECTS
+        DAProjectConfig_.timestampStart = auctionTimestampStart;
+        DAProjectConfig_.timestampEnd = auctionTimestampEnd;
+        DAProjectConfig_.startPrice = startPrice;
+        DAProjectConfig_.basePrice = basePrice;
+
+        emit SetAuctionDetailsLin({
+            projectId: projectId,
+            coreContract: coreContract,
+            auctionTimestampStart: auctionTimestampStart,
+            auctionTimestampEnd: auctionTimestampEnd,
+            startPrice: startPrice,
+            basePrice: basePrice
+        });
+    }
+
+    function resetAuctionDetails(
+        uint256 projectId,
+        address coreContract
+    ) internal {
+        DAProjectConfig storage DAProjectConfig_ = getDAProjectConfig({
+            projectId: projectId,
+            coreContract: coreContract
+        });
+
+        DAProjectConfig_.timestampStart = 0;
+        DAProjectConfig_.timestampEnd = 0;
+        DAProjectConfig_.startPrice = 0;
+        DAProjectConfig_.basePrice = 0;
+
+        emit DALib.ResetAuctionDetails({
+            projectId: projectId,
+            coreContract: coreContract
+        });
+    }
+
+    /**
+     * @notice Gets price of minting a token given the project's
+     * DAProjectConfig.
+     * This function reverts if auction has not yet started, or if auction is
+     * unconfigured.
+     * @param projectId Project Id to get price for
+     * @param coreContract Core contract address to get price for
+     * @return current price of token in Wei
+     */
+    function getPriceLin(
+        uint256 projectId,
+        address coreContract
+    ) internal view returns (uint256) {
+        DAProjectConfig storage _DAProjectConfig = getDAProjectConfig({
+            projectId: projectId,
+            coreContract: coreContract
+        });
+        // move parameters to memory if used more than once
+        uint256 timestampStart = _DAProjectConfig.timestampStart;
+        uint256 timestampEnd = _DAProjectConfig.timestampEnd;
+        uint256 startPrice = _DAProjectConfig.startPrice;
+        uint256 basePrice = _DAProjectConfig.basePrice;
+
+        require(block.timestamp > timestampStart, "Auction not yet started");
+        if (block.timestamp >= timestampEnd) {
+            require(timestampEnd > 0, "Only configured auctions");
+            return basePrice;
+        }
+        uint256 elapsedTime;
+        uint256 duration;
+        uint256 startToEndDiff;
+        unchecked {
+            // already checked that block.timestamp > _timestampStart
+            elapsedTime = block.timestamp - timestampStart;
+            // _timestampEnd > _timestampStart enforced during assignment
+            duration = timestampEnd - timestampStart;
+            // _startPrice > _basePrice enforced during assignment
+            startToEndDiff = startPrice - basePrice;
+        }
+        return startPrice - ((elapsedTime * startToEndDiff) / duration);
+    }
+
+    /**
+     * Loads the DAProjectConfig for a given project and core contract.
+     * @param projectId Project Id to get config for
+     * @param coreContract Core contract address to get config for
+     */
+    function getDAProjectConfig(
+        uint256 projectId,
+        address coreContract
+    ) internal view returns (DAProjectConfig storage) {
+        return s().DAProjectConfigs_[coreContract][projectId];
+    }
+
+    /**
+     * @notice Return the storage struct for reading and writing. This library
+     * uses a diamond storage pattern when managing storage.
+     * @return storageStruct The DALinLibStorage struct.
+     */
+    function s() internal pure returns (DALinLibStorage storage storageStruct) {
+        bytes32 position = DAE_LIN_LIB_STORAGE_POSITION;
+        assembly ("memory-safe") {
+            storageStruct.slot := position
+        }
+    }
+}

package/contracts/libs/v0.8.x/minter-libs/GenericMinterEventsLib.sol

@@ -0,0 +1,171 @@
+// SPDX-License-Identifier: LGPL-3.0-only
+// Created By: Art Blocks Inc.
+
+pragma solidity ^0.8.0;
+
+/**
+ * @title Art Blocks Generic Events Library
+ * @notice This library is designed to define a set of generic events that all
+ * shared minter libraries may utilize to populate indexed extra minter details
+ * @dev Strings not supported. Recommend conversion of (short) strings to
+ * bytes32 to remain gas-efficient.
+ * @author Art Blocks Inc.
+ */
+library GenericMinterEventsLib {
+    /**
+     * @notice Generic project minter configuration event. Removes key `key`
+     * for project `projectId`.
+     * @param projectId Project ID to remove key for
+     * @param coreContract Core contract address that projectId is on
+     * @param key Key to remove
+     */
+    event ConfigKeyRemoved(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        bytes32 key
+    );
+    /// BOOL
+    /**
+     * @notice Generic project minter configuration event. Sets value of key
+     * `key` to `value` for project `projectId`.
+     * @param projectId Project ID to set key for
+     * @param coreContract Core contract address that projectId is on
+     * @param key Key to set
+     * @param value Value to set key to
+     */
+    event ConfigValueSet(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        bytes32 key,
+        bool value
+    );
+    /// UINT256
+    /**
+     * @notice Generic project minter configuration event. Sets value of key
+     * `key` to `value` for project `projectId`.
+     * @param projectId Project ID to set key for
+     * @param coreContract Core contract address that projectId is on
+     * @param key Key to set
+     * @param value Value to set key to
+     */
+    event ConfigValueSet(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        bytes32 key,
+        uint256 value
+    );
+    /**
+     * @notice Generic project minter configuration event. Adds value `value`
+     * to the set of uint256 at key `key` for project `projectId`.
+     * @param projectId Project ID to set key for
+     * @param coreContract Core contract address that projectId is on
+     * @param key Key to modify
+     * @param value Value to add to the key's set
+     */
+    event ConfigValueAddedToSet(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        bytes32 key,
+        uint256 value
+    );
+    /**
+     * @notice Generic project minter configuration event. Removes value
+     * `value` to the set of uint256 at key `key` for project `projectId`.
+     * @param projectId Project ID to set key for
+     * @param coreContract Core contract address that projectId is on
+     * @param key Key to modify
+     * @param value Value removed from the key's set
+     */
+    event ConfigValueRemovedFromSet(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        bytes32 key,
+        uint256 value
+    );
+    /// ADDRESS
+    /**
+     * @notice Generic project minter configuration event. Sets value of key
+     * `key` to `value` for project `projectId`.
+     * @param projectId Project ID to set key for
+     * @param coreContract Core contract address that projectId is on
+     * @param key Key to set
+     * @param value Value to set key to
+     */
+    event ConfigValueSet(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        bytes32 key,
+        address value
+    );
+    /**
+     * @notice Generic project minter configuration event. Adds value `value`
+     * to the set of addresses at key `key` for project `projectId`.
+     * @param projectId Project ID to set key for
+     * @param coreContract Core contract address that projectId is on
+     * @param key Key to modify
+     * @param value Value to add to the key's set
+     */
+    event ConfigValueAddedToSet(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        bytes32 key,
+        address value
+    );
+    /**
+     * @notice Generic project minter configuration event. Removes value
+     * `value` to the set of addresses at key `key` for project `projectId`.
+     * @param projectId Project ID to set key for
+     * @param coreContract Core contract address that projectId is on
+     * @param key Key to modify
+     * @param value Value removed from the key's set
+     */
+    event ConfigValueRemovedFromSet(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        bytes32 key,
+        address value
+    );
+    /// BYTES32
+    /**
+     * @notice Generic project minter configuration event. Sets value of key
+     * `key` to `value` for project `projectId`.
+     * @param projectId Project ID to set key for
+     * @param coreContract Core contract address that projectId is on
+     * @param key Key to set
+     * @param value Value to set key to
+     */
+    event ConfigValueSet(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        bytes32 key,
+        bytes32 value
+    );
+    /**
+     * @notice Generic project minter configuration event. Adds value `value`
+     * to the set of bytes32 at key `key` for project `projectId`.
+     * @param projectId Project ID to set key for
+     * @param coreContract Core contract address that projectId is on
+     * @param key Key to modify
+     * @param value Value to add to the key's set
+     */
+    event ConfigValueAddedToSet(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        bytes32 key,
+        bytes32 value
+    );
+    /**
+     * @notice Generic project minter configuration event. Removes value
+     * `value` to the set of bytes32 at key `key` for project `projectId`.
+     * @param projectId Project ID to set key for
+     * @param coreContract Core contract address that projectId is on
+     * @param key Key to modify
+     * @param value Value removed from the key's set
+     */
+    event ConfigValueRemovedFromSet(
+        uint256 indexed projectId,
+        address indexed coreContract,
+        bytes32 key,
+        bytes32 value
+    );
+}