@apple/tree-sitter-pkl 0.16.0

package/package.json

@@ -0,0 +1,51 @@
+{
+  "name": "@apple/tree-sitter-pkl",
+  "version": "0.16.0",
+  "description": "Pkl grammar for node-tree-sitter",
+  "repository": {
+    "type": "git",
+    "url": "https://github.com/apple/tree-sitter-pkl"
+  },
+  "main": "bindings/node",
+  "keywords": [
+    "parser",
+    "lexer"
+  ],
+  "author": "pkl-oss@group.apple.com",
+  "license": "Apache-2.0",
+  "bugs": {
+    "url": "https://github.com/apple/tree-sitter-pkl/issues"
+  },
+  "engines": {
+    "node": "18.17.0",
+    "npm": "9.6.0"
+  },
+  "dependencies": {
+    "nan": "^2.17.0"
+  },
+  "devDependencies": {
+    "@types/glob": "^8.1.0",
+    "@types/node": "^20.4.5",
+    "node-gyp": "^9.1.0",
+    "tree-sitter-cli": "^0.20.0",
+    "ts-node": "^10.0.0",
+    "typescript": "^4.9.0"
+  },
+  "scripts": {
+    "build": "tree-sitter generate && node-gyp configure && node-gyp build",
+    "test": "tree-sitter test",
+    "synctests": "ts-node src/synctests.ts",
+    "getVersion": "node -p \"require('./package.json').version\""
+  },
+  "tree-sitter": [
+    {
+      "scope": "source.pkl",
+      "file-types": [
+        "pkl",
+        "pcf"
+      ],
+      "first-line-regex": "#!.*\\bpkl$",
+      "injection-regex": "pkl"
+    }
+  ]
+}

package/queries/highlights.scm

@@ -0,0 +1,138 @@
+; Types
+
+(clazz (identifier) @type)
+(typeAlias (identifier) @type)
+((identifier) @type
+ (match? @type "^[A-Z]"))
+
+(typeArgumentList
+  "<" @punctuation.bracket
+  ">" @punctuation.bracket)
+
+; Method calls
+
+(methodCallExpr
+  (identifier) @function.method)
+
+; Method definitions
+
+(classMethod (methodHeader (identifier)) @function.method)
+(objectMethod (methodHeader (identifier)) @function.method)
+
+; Identifiers
+
+(classProperty (identifier) @property)
+(objectProperty (identifier) @property)
+
+(parameterList (typedIdentifier (identifier) @variable.parameter))
+(objectBodyParameters (typedIdentifier (identifier) @variable.parameter))
+
+(identifier) @variable
+
+; Literals
+
+(stringConstant) @string
+(slStringLiteral) @string
+(mlStringLiteral) @string
+
+(escapeSequence) @escape
+
+(intLiteral) @number
+(floatLiteral) @number
+
+(interpolationExpr
+  "\\(" @punctuation.special
+  ")" @punctuation.special) @embedded
+
+(interpolationExpr
+ "\\#(" @punctuation.special
+ ")" @punctuation.special) @embedded
+
+(interpolationExpr
+  "\\##(" @punctuation.special
+  ")" @punctuation.special) @embedded
+
+(lineComment) @comment
+(blockComment) @comment
+(docComment) @comment
+
+; Operators
+
+"??" @operator
+"@"  @operator
+"="  @operator
+"<"  @operator
+">"  @operator
+"!"  @operator
+"==" @operator
+"!=" @operator
+"<=" @operator
+">=" @operator
+"&&" @operator
+"||" @operator
+"+"  @operator
+"-"  @operator
+"**" @operator
+"*"  @operator
+"/"  @operator
+"~/" @operator
+"%"  @operator
+"|>" @operator
+
+"?"  @operator.type
+"|"  @operator.type
+"->" @operator.type
+
+"," @punctuation.delimiter
+":" @punctuation.delimiter
+"." @punctuation.delimiter
+"?." @punctuation.delimiter
+
+"(" @punctuation.bracket
+")" @punctuation.bracket
+; "[" @punctuation.bracket TODO: FIGURE OUT HOW TO REFER TO CUSTOM TOKENS
+"]" @punctuation.bracket
+"{" @punctuation.bracket
+"}" @punctuation.bracket
+
+; Keywords
+
+"abstract" @keyword
+"amends" @keyword
+"as" @keyword
+"class" @keyword
+"else" @keyword
+"extends" @keyword
+"external" @keyword
+(falseLiteral) @constant.builtin
+"for" @keyword
+"function" @keyword
+"hidden" @keyword
+"if" @keyword
+(importExpr "import" @function.method.builtin)
+(importGlobExpr "import*" @function.method.builtin)
+"import" @keyword
+"import*" @keyword
+"in" @keyword
+"is" @keyword
+"let" @keyword
+"local" @keyword
+(moduleExpr "module" @type.builtin)
+"module" @keyword
+"new" @keyword
+"nothing" @type.builtin
+(nullLiteral) @constant.builtin
+"open" @keyword
+"out" @keyword
+(outerExpr) @variable.builtin
+"read" @function.method.builtin
+"read?" @function.method.builtin
+"read*" @function.method.builtin
+"super" @variable.builtin
+(thisExpr) @variable.builtin
+"throw" @function.method.builtin
+"trace" @function.method.builtin
+(trueLiteral) @constant.builtin
+"typealias" @keyword
+"unknown" @type.builtin
+"when" @keyword

package/queries/injections.scm

@@ -0,0 +1,9 @@
+; this definition is imprecise in that 
+; * any qualified or unqualified call to a method named "Regex" is considered a regex
+; * string delimiters are considered part of the regex
+(
+  ((methodCallExpr (identifier) @methodName (argumentList (slStringLiteral) @injection.content))
+    (set! injection.language "regex"))
+  (eq? @methodName "Regex"))
+ 
+; TODO: inject markdown into doc comments

package/queries/locals.scm

@@ -0,0 +1,38 @@
+; Scopes
+
+(module) @local.scope
+(clazz) @local.scope
+(classMethod) @local.scope
+(objectMethod) @local.scope
+(functionLiteral) @local.scope
+(objectBody) @local.scope
+(letExpr) @local.scope
+(forGenerator) @local.scope
+
+; Definitions
+
+(clazz
+  (identifier) @local.definition)
+
+(typeAlias
+  (identifier) @local.definition)
+
+(classMethod
+  (methodHeader (identifier)) @local.definition)
+
+(objectMethod
+  (methodHeader (identifier)) @local.definition)
+  
+(classProperty
+  (identifier) @local.definition)
+
+(objectProperty
+  (identifier) @local.definition)
+
+(typedIdentifier 
+  (identifier) @local.definition)
+
+; References
+
+(variableExpr 
+  (identifier) @local.reference)