@aiderdesk/tree-sitter-utils 0.1.0

package/resources/queries/ruby-tags.scm

@@ -0,0 +1,64 @@
+; Method definitions
+
+(
+  (comment)* @doc
+  .
+  [
+    (method
+      name: (_) @name.definition.method) @definition.method
+    (singleton_method
+      name: (_) @name.definition.method) @definition.method
+  ]
+  (#strip! @doc "^#\\s*")
+  (#select-adjacent! @doc @definition.method)
+)
+
+(alias
+  name: (_) @name.definition.method) @definition.method
+
+(setter
+  (identifier) @ignore)
+
+; Class definitions
+
+(
+  (comment)* @doc
+  .
+  [
+    (class
+      name: [
+        (constant) @name.definition.class
+        (scope_resolution
+          name: (_) @name.definition.class)
+      ]) @definition.class
+    (singleton_class
+      value: [
+        (constant) @name.definition.class
+        (scope_resolution
+          name: (_) @name.definition.class)
+      ]) @definition.class
+  ]
+  (#strip! @doc "^#\\s*")
+  (#select-adjacent! @doc @definition.class)
+)
+
+; Module definitions
+
+(
+  (module
+    name: [
+      (constant) @name.definition.module
+      (scope_resolution
+        name: (_) @name.definition.module)
+    ]) @definition.module
+)
+
+; Calls
+
+(call method: (identifier) @name.reference.call) @reference.call
+
+(
+  [(identifier) (constant)] @name.reference.call @reference.call
+  (#is-not? local)
+  (#not-match? @name.reference.call "^(lambda|load|require|require_relative|__FILE__|__LINE__)$")
+)

package/resources/queries/rust-tags.scm

@@ -0,0 +1,60 @@
+; ADT definitions
+
+(struct_item
+    name: (type_identifier) @name.definition.class) @definition.class
+
+(enum_item
+    name: (type_identifier) @name.definition.class) @definition.class
+
+(union_item
+    name: (type_identifier) @name.definition.class) @definition.class
+
+; type aliases
+
+(type_item
+    name: (type_identifier) @name.definition.class) @definition.class
+
+; method definitions
+
+(declaration_list
+    (function_item
+        name: (identifier) @name.definition.method)) @definition.method
+
+; function definitions
+
+(function_item
+    name: (identifier) @name.definition.function) @definition.function
+
+; trait definitions
+(trait_item
+    name: (type_identifier) @name.definition.interface) @definition.interface
+
+; module definitions
+(mod_item
+    name: (identifier) @name.definition.module) @definition.module
+
+; macro definitions
+
+(macro_definition
+    name: (identifier) @name.definition.macro) @definition.macro
+
+; references
+
+(call_expression
+    function: (identifier) @name.reference.call) @reference.call
+
+(call_expression
+    function: (field_expression
+        field: (field_identifier) @name.reference.call)) @reference.call
+
+(macro_invocation
+    macro: (identifier) @name.reference.call) @reference.call
+
+; implementations
+
+(impl_item
+    trait: (type_identifier) @name.reference.implementation) @reference.implementation
+
+(impl_item
+    type: (type_identifier) @name.reference.implementation
+    !trait) @reference.implementation

package/resources/queries/scala-tags.scm

@@ -0,0 +1,65 @@
+; Definitions
+
+(package_clause
+  name: (package_identifier) @name.definition.module) @definition.module
+
+(trait_definition
+  name: (identifier) @name.definition.interface) @definition.interface
+
+(enum_definition
+  name: (identifier) @name.definition.enum) @definition.enum
+
+(simple_enum_case
+  name: (identifier) @name.definition.class) @definition.class
+
+(full_enum_case
+  name: (identifier) @name.definition.class) @definition.class
+
+(class_definition
+  name: (identifier) @name.definition.class) @definition.class
+
+(object_definition
+  name: (identifier) @name.definition.object) @definition.object
+
+(function_definition
+  name: (identifier) @name.definition.function) @definition.function
+
+(val_definition
+  pattern: (identifier) @name.definition.variable) @definition.variable
+
+(given_definition
+  name: (identifier) @name.definition.variable) @definition.variable
+
+(var_definition
+  pattern: (identifier) @name.definition.variable) @definition.variable
+
+(val_declaration
+  name: (identifier) @name.definition.variable) @definition.variable
+
+(var_declaration
+  name: (identifier) @name.definition.variable) @definition.variable
+
+(type_definition
+  name: (type_identifier) @name.definition.type) @definition.type
+
+(class_parameter
+  name: (identifier) @name.definition.property) @definition.property
+
+; References
+
+(call_expression
+  (identifier) @name.reference.call) @reference.call
+
+(instance_expression
+  (type_identifier) @name.reference.interface) @reference.interface
+
+(instance_expression
+  (generic_type
+    (type_identifier) @name.reference.interface)) @reference.interface
+
+(extends_clause
+  (type_identifier) @name.reference.class) @reference.class
+
+(extends_clause
+  (generic_type
+    (type_identifier) @name.reference.class)) @reference.class

package/resources/queries/tsx-tags.scm

@@ -0,0 +1,51 @@
+(function_signature
+  name: (identifier) @name.definition.function) @definition.function
+
+(method_signature
+  name: (property_identifier) @name.definition.method) @definition.method
+
+(abstract_method_signature
+  name: (property_identifier) @name.definition.method) @definition.method
+
+(abstract_class_declaration
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(module
+  name: (identifier) @name.definition.module) @definition.module
+
+(interface_declaration
+  name: (type_identifier) @name.definition.interface) @definition.interface
+
+(type_annotation
+  (type_identifier) @name.reference.type) @reference.type
+
+(new_expression
+  constructor: (identifier) @name.reference.class) @reference.class
+
+(function_declaration
+  name: (identifier) @name.definition.function) @definition.function
+
+(method_definition
+  name: (property_identifier) @name.definition.method) @definition.method
+
+(class_declaration
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(interface_declaration
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(type_alias_declaration
+  name: (type_identifier) @name.definition.type) @definition.type
+
+(enum_declaration
+  name: (identifier) @name.definition.enum) @definition.enum
+
+; JSX Component references (only capture uppercase identifiers as component refs)
+(jsx_self_closing_element
+  name: (identifier) @name.reference.class
+  (#match? @name.reference.class "^[A-Z]")) @reference.class
+
+(jsx_element
+  open_tag: (jsx_opening_element
+    name: (identifier) @name.reference.class
+    (#match? @name.reference.class "^[A-Z]"))) @reference.class

package/resources/queries/typescript-tags.scm

@@ -0,0 +1,61 @@
+(function_signature
+  name: (identifier) @name.definition.function) @definition.function
+
+(method_signature
+  name: (property_identifier) @name.definition.method) @definition.method
+
+(abstract_method_signature
+  name: (property_identifier) @name.definition.method) @definition.method
+
+(abstract_class_declaration
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(module
+  name: (identifier) @name.definition.module) @definition.module
+
+(interface_declaration
+  name: (type_identifier) @name.definition.interface) @definition.interface
+
+(type_annotation
+  (type_identifier) @name.reference.type) @reference.type
+
+(new_expression
+  constructor: (identifier) @name.reference.class) @reference.class
+
+(function_declaration
+  name: (identifier) @name.definition.function) @definition.function
+
+(method_definition
+  name: (property_identifier) @name.definition.method) @definition.method
+
+(class_declaration
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(interface_declaration
+  name: (type_identifier) @name.definition.class) @definition.class
+
+(type_alias_declaration
+  name: (type_identifier) @name.definition.type) @definition.type
+
+(enum_declaration
+  name: (identifier) @name.definition.enum) @definition.enum
+
+; Interface and type properties
+(interface_declaration
+  body: (interface_body
+    (property_signature
+      name: (property_identifier) @name.definition.property))) @definition.property
+
+(type_alias_declaration
+  value: (object_type
+    (property_signature
+      name: (property_identifier) @name.definition.property))) @definition.property
+
+; Variables (const, let, var)
+(lexical_declaration
+  (variable_declarator
+    name: (identifier) @name.definition.variable)) @definition.variable
+
+(variable_declaration
+  (variable_declarator
+    name: (identifier) @name.definition.variable)) @definition.variable

package/resources/queries/zig-tags.scm

@@ -0,0 +1,3 @@
+(FnProto) @name.definition.function
+(VarDecl "const" @name.definition.constant)
+(VarDecl "var"   @name.definition.variable)