@across-protocol/contracts 0.1.0

package/contracts/external/chainbridge/interfaces/IBridge.sol

@@ -0,0 +1,20 @@
+// SPDX-License-Identifier: AGPL-3.0-only
+pragma solidity ^0.8.0;
+
+/**
+    @title Interface for Bridge contract.
+    @author ChainSafe Systems.
+ */
+interface IBridge {
+    /**
+        @notice Exposing getter for {_chainID} instead of forcing the use of call.
+        @return uint8 The {_chainID} that is currently set for the Bridge contract.
+     */
+    function _chainID() external returns (uint8);
+
+    function deposit(
+        uint8 destinationChainID,
+        bytes32 resourceID,
+        bytes calldata data
+    ) external;
+}

package/contracts/external/chainbridge/interfaces/IDepositExecute.sol

@@ -0,0 +1,29 @@
+// SPDX-License-Identifier: AGPL-3.0-only
+pragma solidity ^0.8.0;
+
+/**
+    @title Interface for handler contracts that support deposits and deposit executions.
+    @author ChainSafe Systems.
+ */
+interface IDepositExecute {
+    /**
+        @notice It is intended that deposit are made using the Bridge contract.
+        @param destinationChainID Chain ID deposit is expected to be bridged to.
+        @param depositNonce This value is generated as an ID by the Bridge contract.
+        @param depositer Address of account making the deposit in the Bridge contract.
+        @param data Consists of additional data needed for a specific deposit.
+     */
+    function deposit(
+        bytes32 resourceID,
+        uint8 destinationChainID,
+        uint64 depositNonce,
+        address depositer,
+        bytes calldata data
+    ) external;
+
+    /**
+        @notice It is intended that proposals are executed by the Bridge contract.
+        @param data Consists of additional data needed for a specific deposit execution.
+     */
+    function executeProposal(bytes32 resourceID, bytes calldata data) external;
+}

package/contracts/external/chainbridge/interfaces/IERCHandler.sol

@@ -0,0 +1,33 @@
+// SPDX-License-Identifier: AGPL-3.0-only
+pragma solidity ^0.8.0;
+
+/**
+    @title Interface to be used with handlers that support ERC20s and ERC721s.
+    @author ChainSafe Systems.
+ */
+interface IERCHandler {
+    /**
+        @notice Correlates {resourceID} with {contractAddress}.
+        @param resourceID ResourceID to be used when making deposits.
+        @param contractAddress Address of contract to be called when a deposit is made and a deposited is executed.
+     */
+    function setResource(bytes32 resourceID, address contractAddress) external;
+
+    /**
+        @notice Marks {contractAddress} as mintable/burnable.
+        @param contractAddress Address of contract to be used when making or executing deposits.
+     */
+    function setBurnable(address contractAddress) external;
+
+    /**
+        @notice Used to manually release funds from ERC safes.
+        @param tokenAddress Address of token contract to release.
+        @param recipient Address to release tokens to.
+        @param amountOrTokenID Either the amount of ERC20 tokens or the ERC721 token ID to release.
+     */
+    function withdraw(
+        address tokenAddress,
+        address recipient,
+        uint256 amountOrTokenID
+    ) external;
+}

package/contracts/external/chainbridge/interfaces/IGenericHandler.sol

@@ -0,0 +1,23 @@
+// SPDX-License-Identifier: AGPL-3.0-only
+pragma solidity ^0.8.0;
+
+/**
+    @title Interface for handler that handles generic deposits and deposit executions.
+    @dev Copied directly from here: https://github.com/ChainSafe/chainbridge-solidity/releases/tag/v1.0.0.
+    @author ChainSafe Systems.
+ */
+interface IGenericHandler {
+    /**
+        @notice Correlates {resourceID} with {contractAddress}, {depositFunctionSig}, and {executeFunctionSig}.
+        @param resourceID ResourceID to be used when making deposits.
+        @param contractAddress Address of contract to be called when a deposit is made and a deposited is executed.
+        @param depositFunctionSig Function signature of method to be called in {contractAddress} when a deposit is made.
+        @param executeFunctionSig Function signature of method to be called in {contractAddress} when a deposit is executed.
+     */
+    function setResource(
+        bytes32 resourceID,
+        address contractAddress,
+        bytes4 depositFunctionSig,
+        bytes4 executeFunctionSig
+    ) external;
+}

package/contracts/external/ovm/OVM_CrossDomainEnabled.sol

@@ -0,0 +1,114 @@
+// Copied from: https://github.com/ethereum-optimism/optimism/blob/5fc728da7381eda6b6f858c091636c947186a3ce/packages/contracts/contracts/optimistic-ethereum/libraries/bridge/OVM_CrossDomainEnabled.sol
+
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+/**
+ * @title iOVM_CrossDomainMessenger
+ */
+interface iOVM_CrossDomainMessenger {
+    /**********
+     * Events *
+     **********/
+
+    event SentMessage(bytes message);
+    event RelayedMessage(bytes32 msgHash);
+    event FailedRelayedMessage(bytes32 msgHash);
+
+    /*************
+     * Variables *
+     *************/
+
+    function xDomainMessageSender() external view returns (address);
+
+    /********************
+     * Public Functions *
+     ********************/
+
+    /**
+     * Sends a cross domain message to the target messenger.
+     * @param _target Target contract address.
+     * @param _message Message to send to the target.
+     * @param _gasLimit Gas limit for the provided message.
+     */
+    function sendMessage(
+        address _target,
+        bytes calldata _message,
+        uint32 _gasLimit
+    ) external;
+}
+
+/**
+ * @title OVM_CrossDomainEnabled
+ * @dev Helper contract for contracts performing cross-domain communications
+ *
+ * Compiler used: defined by inheriting contract
+ * Runtime target: defined by inheriting contract
+ */
+contract OVM_CrossDomainEnabled {
+    /*************
+     * Variables *
+     *************/
+
+    // Messenger contract used to send and recieve messages from the other domain.
+    address public messenger;
+
+    /***************
+     * Constructor *
+     ***************/
+
+    /**
+     * @param _messenger Address of the CrossDomainMessenger on the current layer.
+     */
+    constructor(address _messenger) {
+        messenger = _messenger;
+    }
+
+    /**********************
+     * Function Modifiers *
+     **********************/
+
+    /**
+     * Enforces that the modified function is only callable by a specific cross-domain account.
+     * @param _sourceDomainAccount The only account on the originating domain which is
+     *  authenticated to call this function.
+     */
+    modifier onlyFromCrossDomainAccount(address _sourceDomainAccount) {
+        require(msg.sender == address(getCrossDomainMessenger()), "OVM_XCHAIN: messenger contract unauthenticated");
+
+        require(
+            getCrossDomainMessenger().xDomainMessageSender() == _sourceDomainAccount,
+            "OVM_XCHAIN: wrong sender of cross-domain message"
+        );
+
+        _;
+    }
+
+    /**********************
+     * Internal Functions *
+     **********************/
+
+    /**
+     * Gets the messenger, usually from storage. This function is exposed in case a child contract
+     * needs to override.
+     * @return The address of the cross-domain messenger contract which should be used.
+     */
+    function getCrossDomainMessenger() internal virtual returns (iOVM_CrossDomainMessenger) {
+        return iOVM_CrossDomainMessenger(messenger);
+    }
+
+    /**
+     * Sends a message to an account on another domain
+     * @param _crossDomainTarget The intended recipient on the destination domain
+     * @param _message The data to send to the target (usually calldata to a function with
+     *  `onlyFromCrossDomainAccount()`)
+     * @param _gasLimit The gasLimit for the receipt of the message on the target domain.
+     */
+    function sendCrossDomainMessage(
+        address _crossDomainTarget,
+        uint32 _gasLimit,
+        bytes memory _message
+    ) internal {
+        getCrossDomainMessenger().sendMessage(_crossDomainTarget, _message, _gasLimit);
+    }
+}

package/contracts/external/polygon/lib/Merkle.sol

@@ -0,0 +1,36 @@
+// SPDX-License-Identifier: MIT
+// Copied with no modifications from Polygon demo FxTunnel repo: https://github.com/jdkanani/fx-portal
+// except bumping version from 0.7.3 --> 0.8
+pragma solidity ^0.8.0;
+
+library Merkle {
+    function checkMembership(
+        bytes32 leaf,
+        uint256 index,
+        bytes32 rootHash,
+        bytes memory proof
+    ) internal pure returns (bool) {
+        require(proof.length % 32 == 0, "Invalid proof length");
+        uint256 proofHeight = proof.length / 32;
+        // Proof of size n means, height of the tree is n+1.
+        // In a tree of height n+1, max #leafs possible is 2 ^ n
+        require(index < 2**proofHeight, "Leaf index is too big");
+
+        bytes32 proofElement;
+        bytes32 computedHash = leaf;
+        for (uint256 i = 32; i <= proof.length; i += 32) {
+            assembly {
+                proofElement := mload(add(proof, i))
+            }
+
+            if (index % 2 == 0) {
+                computedHash = keccak256(abi.encodePacked(computedHash, proofElement));
+            } else {
+                computedHash = keccak256(abi.encodePacked(proofElement, computedHash));
+            }
+
+            index = index / 2;
+        }
+        return computedHash == rootHash;
+    }
+}

package/contracts/external/polygon/lib/MerklePatriciaProof.sol

@@ -0,0 +1,139 @@
+// SPDX-License-Identifier: MIT
+// Copied with no modifications from Polygon demo FxTunnel repo: https://github.com/jdkanani/fx-portal
+// except bumping version from 0.7.3 --> 0.8
+pragma solidity ^0.8.0;
+
+import { RLPReader } from "./RLPReader.sol";
+
+library MerklePatriciaProof {
+    /*
+     * @dev Verifies a merkle patricia proof.
+     * @param value The terminating value in the trie.
+     * @param encodedPath The path in the trie leading to value.
+     * @param rlpParentNodes The rlp encoded stack of nodes.
+     * @param root The root hash of the trie.
+     * @return The boolean validity of the proof.
+     */
+    function verify(
+        bytes memory value,
+        bytes memory encodedPath,
+        bytes memory rlpParentNodes,
+        bytes32 root
+    ) internal pure returns (bool proofValidity) {
+        RLPReader.RLPItem memory item = RLPReader.toRlpItem(rlpParentNodes);
+        RLPReader.RLPItem[] memory parentNodes = RLPReader.toList(item);
+
+        bytes memory currentNode;
+        RLPReader.RLPItem[] memory currentNodeList;
+
+        bytes32 nodeKey = root;
+        uint256 pathPtr = 0;
+
+        bytes memory path = _getNibbleArray(encodedPath);
+        if (path.length == 0) {
+            return false;
+        }
+
+        for (uint256 i = 0; i < parentNodes.length; i++) {
+            if (pathPtr > path.length) {
+                return false;
+            }
+
+            currentNode = RLPReader.toRlpBytes(parentNodes[i]);
+            if (nodeKey != keccak256(currentNode)) {
+                return false;
+            }
+            currentNodeList = RLPReader.toList(parentNodes[i]);
+
+            if (currentNodeList.length == 17) {
+                if (pathPtr == path.length) {
+                    if (keccak256(RLPReader.toBytes(currentNodeList[16])) == keccak256(value)) {
+                        return true;
+                    } else {
+                        return false;
+                    }
+                }
+
+                uint8 nextPathNibble = uint8(path[pathPtr]);
+                if (nextPathNibble > 16) {
+                    return false;
+                }
+                nodeKey = bytes32(RLPReader.toUintStrict(currentNodeList[nextPathNibble]));
+                pathPtr += 1;
+            } else if (currentNodeList.length == 2) {
+                uint256 traversed = _nibblesToTraverse(RLPReader.toBytes(currentNodeList[0]), path, pathPtr);
+                if (pathPtr + traversed == path.length) {
+                    //leaf node
+                    if (keccak256(RLPReader.toBytes(currentNodeList[1])) == keccak256(value)) {
+                        return true;
+                    } else {
+                        return false;
+                    }
+                }
+
+                //extension node
+                if (traversed == 0) {
+                    return false;
+                }
+
+                pathPtr += traversed;
+                nodeKey = bytes32(RLPReader.toUintStrict(currentNodeList[1]));
+            } else {
+                return false;
+            }
+        }
+    }
+
+    function _nibblesToTraverse(
+        bytes memory encodedPartialPath,
+        bytes memory path,
+        uint256 pathPtr
+    ) private pure returns (uint256) {
+        uint256 len = 0;
+        // encodedPartialPath has elements that are each two hex characters (1 byte), but partialPath
+        // and slicedPath have elements that are each one hex character (1 nibble)
+        bytes memory partialPath = _getNibbleArray(encodedPartialPath);
+        bytes memory slicedPath = new bytes(partialPath.length);
+
+        // pathPtr counts nibbles in path
+        // partialPath.length is a number of nibbles
+        for (uint256 i = pathPtr; i < pathPtr + partialPath.length; i++) {
+            bytes1 pathNibble = path[i];
+            slicedPath[i - pathPtr] = pathNibble;
+        }
+
+        if (keccak256(partialPath) == keccak256(slicedPath)) {
+            len = partialPath.length;
+        } else {
+            len = 0;
+        }
+        return len;
+    }
+
+    // bytes b must be hp encoded
+    function _getNibbleArray(bytes memory b) internal pure returns (bytes memory) {
+        bytes memory nibbles = "";
+        if (b.length > 0) {
+            uint8 offset;
+            uint8 hpNibble = uint8(_getNthNibbleOfBytes(0, b));
+            if (hpNibble == 1 || hpNibble == 3) {
+                nibbles = new bytes(b.length * 2 - 1);
+                bytes1 oddNibble = _getNthNibbleOfBytes(1, b);
+                nibbles[0] = oddNibble;
+                offset = 1;
+            } else {
+                nibbles = new bytes(b.length * 2 - 2);
+                offset = 0;
+            }
+
+            for (uint256 i = offset; i < nibbles.length; i++) {
+                nibbles[i] = _getNthNibbleOfBytes(i - offset + 2, b);
+            }
+        }
+        return nibbles;
+    }
+
+    function _getNthNibbleOfBytes(uint256 n, bytes memory str) private pure returns (bytes1) {
+        return bytes1(n % 2 == 0 ? uint8(str[n / 2]) / 0x10 : uint8(str[n / 2]) % 0x10);
+    }
+}

package/contracts/external/polygon/lib/RLPReader.sol

@@ -0,0 +1,251 @@
+// SPDX-License-Identifier: MIT
+// Copied mostly from Polygon demo FxTunnel repo: https://github.com/jdkanani/fx-portal.
+// There are two modifications such that this contract compiles with Solidity v8:
+// - Line 86: cannot convert directly from uint256 --> address
+// - Line 226: cannot rely on wrapping arithmetic, must explicitly catch underflow/overflow with an unchecked{...}
+//   statement
+// More details on Solidity v0.8.0 breaking changes here:
+// https://docs.soliditylang.org/en/v0.8.4/080-breaking-changes.html#new-restrictions
+pragma solidity ^0.8.0;
+
+library RLPReader {
+    uint8 constant STRING_SHORT_START = 0x80;
+    uint8 constant STRING_LONG_START = 0xb8;
+    uint8 constant LIST_SHORT_START = 0xc0;
+    uint8 constant LIST_LONG_START = 0xf8;
+    uint8 constant WORD_SIZE = 32;
+
+    struct RLPItem {
+        uint256 len;
+        uint256 memPtr;
+    }
+
+    /*
+     * @param item RLP encoded bytes
+     */
+    function toRlpItem(bytes memory item) internal pure returns (RLPItem memory) {
+        require(item.length > 0, "RLPReader: INVALID_BYTES_LENGTH");
+        uint256 memPtr;
+        assembly {
+            memPtr := add(item, 0x20)
+        }
+
+        return RLPItem(item.length, memPtr);
+    }
+
+    /*
+     * @param item RLP encoded list in bytes
+     */
+    function toList(RLPItem memory item) internal pure returns (RLPItem[] memory) {
+        require(isList(item), "RLPReader: ITEM_NOT_LIST");
+
+        uint256 items = numItems(item);
+        RLPItem[] memory result = new RLPItem[](items);
+        uint256 listLength = _itemLength(item.memPtr);
+        require(listLength == item.len, "RLPReader: LIST_DECODED_LENGTH_MISMATCH");
+
+        uint256 memPtr = item.memPtr + _payloadOffset(item.memPtr);
+        uint256 dataLen;
+        for (uint256 i = 0; i < items; i++) {
+            dataLen = _itemLength(memPtr);
+            result[i] = RLPItem(dataLen, memPtr);
+            memPtr = memPtr + dataLen;
+        }
+
+        return result;
+    }
+
+    // @return indicator whether encoded payload is a list. negate this function call for isData.
+    function isList(RLPItem memory item) internal pure returns (bool) {
+        uint8 byte0;
+        uint256 memPtr = item.memPtr;
+        assembly {
+            byte0 := byte(0, mload(memPtr))
+        }
+
+        if (byte0 < LIST_SHORT_START) return false;
+        return true;
+    }
+
+    /** RLPItem conversions into data types **/
+
+    // @returns raw rlp encoding in bytes
+    function toRlpBytes(RLPItem memory item) internal pure returns (bytes memory) {
+        bytes memory result = new bytes(item.len);
+
+        uint256 ptr;
+        assembly {
+            ptr := add(0x20, result)
+        }
+
+        copy(item.memPtr, ptr, item.len);
+        return result;
+    }
+
+    function toAddress(RLPItem memory item) internal pure returns (address) {
+        require(!isList(item), "RLPReader: DECODING_LIST_AS_ADDRESS");
+        // 1 byte for the length prefix
+        require(item.len == 21, "RLPReader: INVALID_ADDRESS_LENGTH");
+
+        return address(uint160(toUint(item)));
+    }
+
+    function toUint(RLPItem memory item) internal pure returns (uint256) {
+        require(!isList(item), "RLPReader: DECODING_LIST_AS_UINT");
+        require(item.len <= 33, "RLPReader: INVALID_UINT_LENGTH");
+
+        uint256 itemLength = _itemLength(item.memPtr);
+        require(itemLength == item.len, "RLPReader: UINT_DECODED_LENGTH_MISMATCH");
+
+        uint256 offset = _payloadOffset(item.memPtr);
+        uint256 len = item.len - offset;
+        uint256 result;
+        uint256 memPtr = item.memPtr + offset;
+        assembly {
+            result := mload(memPtr)
+
+            // shfit to the correct location if neccesary
+            if lt(len, 32) {
+                result := div(result, exp(256, sub(32, len)))
+            }
+        }
+
+        return result;
+    }
+
+    // enforces 32 byte length
+    function toUintStrict(RLPItem memory item) internal pure returns (uint256) {
+        uint256 itemLength = _itemLength(item.memPtr);
+        require(itemLength == item.len, "RLPReader: UINT_STRICT_DECODED_LENGTH_MISMATCH");
+        // one byte prefix
+        require(item.len == 33, "RLPReader: INVALID_UINT_STRICT_LENGTH");
+
+        uint256 result;
+        uint256 memPtr = item.memPtr + 1;
+        assembly {
+            result := mload(memPtr)
+        }
+
+        return result;
+    }
+
+    function toBytes(RLPItem memory item) internal pure returns (bytes memory) {
+        uint256 listLength = _itemLength(item.memPtr);
+        require(listLength == item.len, "RLPReader: BYTES_DECODED_LENGTH_MISMATCH");
+        uint256 offset = _payloadOffset(item.memPtr);
+
+        uint256 len = item.len - offset; // data length
+        bytes memory result = new bytes(len);
+
+        uint256 destPtr;
+        assembly {
+            destPtr := add(0x20, result)
+        }
+
+        copy(item.memPtr + offset, destPtr, len);
+        return result;
+    }
+
+    /*
+     * Private Helpers
+     */
+
+    // @return number of payload items inside an encoded list.
+    function numItems(RLPItem memory item) private pure returns (uint256) {
+        // add `isList` check if `item` is expected to be passsed without a check from calling function
+        // require(isList(item), "RLPReader: NUM_ITEMS_NOT_LIST");
+
+        uint256 count = 0;
+        uint256 currPtr = item.memPtr + _payloadOffset(item.memPtr);
+        uint256 endPtr = item.memPtr + item.len;
+        while (currPtr < endPtr) {
+            currPtr = currPtr + _itemLength(currPtr); // skip over an item
+            require(currPtr <= endPtr, "RLPReader: NUM_ITEMS_DECODED_LENGTH_MISMATCH");
+            count++;
+        }
+
+        return count;
+    }
+
+    // @return entire rlp item byte length
+    function _itemLength(uint256 memPtr) private pure returns (uint256) {
+        uint256 itemLen;
+        uint256 byte0;
+        assembly {
+            byte0 := byte(0, mload(memPtr))
+        }
+
+        if (byte0 < STRING_SHORT_START) itemLen = 1;
+        else if (byte0 < STRING_LONG_START) itemLen = byte0 - STRING_SHORT_START + 1;
+        else if (byte0 < LIST_SHORT_START) {
+            assembly {
+                let byteLen := sub(byte0, 0xb7) // # of bytes the actual length is
+                memPtr := add(memPtr, 1) // skip over the first byte
+
+                /* 32 byte word size */
+                let dataLen := div(mload(memPtr), exp(256, sub(32, byteLen))) // right shifting to get the len
+                itemLen := add(dataLen, add(byteLen, 1))
+            }
+        } else if (byte0 < LIST_LONG_START) {
+            itemLen = byte0 - LIST_SHORT_START + 1;
+        } else {
+            assembly {
+                let byteLen := sub(byte0, 0xf7)
+                memPtr := add(memPtr, 1)
+
+                let dataLen := div(mload(memPtr), exp(256, sub(32, byteLen))) // right shifting to the correct length
+                itemLen := add(dataLen, add(byteLen, 1))
+            }
+        }
+
+        return itemLen;
+    }
+
+    // @return number of bytes until the data
+    function _payloadOffset(uint256 memPtr) private pure returns (uint256) {
+        uint256 byte0;
+        assembly {
+            byte0 := byte(0, mload(memPtr))
+        }
+
+        if (byte0 < STRING_SHORT_START) return 0;
+        else if (byte0 < STRING_LONG_START || (byte0 >= LIST_SHORT_START && byte0 < LIST_LONG_START)) return 1;
+        else if (byte0 < LIST_SHORT_START)
+            // being explicit
+            return byte0 - (STRING_LONG_START - 1) + 1;
+        else return byte0 - (LIST_LONG_START - 1) + 1;
+    }
+
+    /*
+     * @param src Pointer to source
+     * @param dest Pointer to destination
+     * @param len Amount of memory to copy from the source
+     */
+    function copy(
+        uint256 src,
+        uint256 dest,
+        uint256 len
+    ) private pure {
+        if (len == 0) return;
+
+        // copy as many word sizes as possible
+        for (; len >= WORD_SIZE; len -= WORD_SIZE) {
+            assembly {
+                mstore(dest, mload(src))
+            }
+
+            src += WORD_SIZE;
+            dest += WORD_SIZE;
+        }
+
+        unchecked {
+            // left over bytes. Mask is used to remove unwanted bytes from the word
+            uint256 mask = 256**(WORD_SIZE - len) - 1;
+            assembly {
+                let srcpart := and(mload(src), not(mask)) // zero out src
+                let destpart := and(mload(dest), mask) // retrieve the bytes
+                mstore(dest, or(destpart, srcpart))
+            }
+        }
+    }
+}

package/contracts/external/polygon/test/FxChildMock.sol

@@ -0,0 +1,42 @@
+// SPDX-License-Identifier: MIT
+pragma solidity ^0.8.0;
+
+// IStateReceiver represents interface to receive state
+interface IStateReceiver {
+    function onStateReceive(uint256 stateId, bytes calldata data) external;
+}
+
+// IFxMessageProcessor represents interface to process message
+interface IFxMessageProcessor {
+    function processMessageFromRoot(
+        uint256 stateId,
+        address rootMessageSender,
+        bytes calldata data
+    ) external;
+}
+
+/**
+ * @title FxChild child contract for state receiver
+ */
+contract FxChildMock is IStateReceiver {
+    address public fxRoot;
+    address public systemCaller;
+
+    event NewFxMessage(address rootMessageSender, address receiver, bytes data);
+
+    constructor(address _systemCaller) {
+        systemCaller = _systemCaller;
+    }
+
+    function setFxRoot(address _fxRoot) public {
+        require(fxRoot == address(0x0));
+        fxRoot = _fxRoot;
+    }
+
+    function onStateReceive(uint256 stateId, bytes calldata _data) external override {
+        require(msg.sender == systemCaller, "Invalid sender: must be system super user");
+        (address rootMessageSender, address receiver, bytes memory data) = abi.decode(_data, (address, address, bytes));
+        emit NewFxMessage(rootMessageSender, receiver, data);
+        IFxMessageProcessor(receiver).processMessageFromRoot(stateId, rootMessageSender, data);
+    }
+}