your_platform 0.0.1 → 0.0.2

data/vendor/assets/javascripts/gmaps4rails/base/objects/circle.coffee

@@ -0,0 +1,12 @@
+@Gmaps4Rails.Circle = { } 
+
+@Gmaps4Rails.Circle.Class =
+
+  DEFAULT_CONF:
+    fillColor: "#00AAFF"
+    fillOpacity: 0.35
+    strokeColor: "#FFAA00"
+    strokeOpacity: 0.8
+    strokeWeight: 2
+    clickable: false
+    zIndex: null

data/vendor/assets/javascripts/gmaps4rails/base/objects/kml.coffee

@@ -0,0 +1,8 @@
+@Gmaps4Rails.Kml = { } 
+
+@Gmaps4Rails.Kml.Instance =
+
+  DEFAULT_CONF:
+    clickable: true
+    preserveViewport: false
+    suppressInfoWindows: false

data/vendor/assets/javascripts/gmaps4rails/base/objects/map.coffee

@@ -0,0 +1,62 @@
+@Gmaps4Rails.Map =
+
+  DEFAULT_CONF:
+    id: 'map'
+    draggable: true
+    detect_location: false  # should the browser attempt to use geolocation detection features of HTML5?
+    center_on_user: false   # centers map on the location detected through the browser
+    center_latitude: 0
+    center_longitude: 0
+    zoom: 7
+    maxZoom: null
+    minZoom: null
+    auto_adjust : true      # adjust the map to the markers if set to true
+    auto_zoom: true         # zoom given by auto-adjust
+    bounds: []              # adjust map to these limits. Should be [{"lat": , "lng": }]
+    raw: {}                  # raw json to pass additional options
+
+  #to make the map fit the different LatLng points
+  adjustToBounds : ->
+    #reset previous bounds
+    @boundsObject = @createLatLngBounds()
+
+    #from markers
+    @extendBoundsWithMarkers()
+
+    #from polylines:
+    @extendBoundsWithPolylines()
+
+    #from polygons:
+    @extendBoundsWithPolygons()
+
+    #from circles
+    @extendBoundsWithCircles()
+
+    #in every case, I've to take into account the bounds set up by the user
+    @extendBoundsWithLatLng()
+
+    #SECOND_STEP: ajust the map to the bounds
+    @adaptToBounds()
+
+  extendBoundsWithMarkers : ->
+    for marker in @controller.markers
+      @extendBoundsWithMarker(marker) if marker.isVisible()
+        
+  extendBoundsWithPolylines: ()->
+    for polyline in @controller.polylines
+      @extendBoundsWithPolyline(polyline) #if polyline.isVisible()
+
+  extendBoundsWithPolygons: ()->
+    for polygon in @controller.polygons
+      @extendBoundsWithPolygon(polygon) #if polygon.isVisible()
+
+  extendBoundsWithCircles: ()->
+    for circle in @controller.circles
+      @extendBoundsWithCircle(circle) #if circle.isVisible()
+
+  extendBoundsWithLatLng: ()->
+    for bound in @options.bounds
+      @extendBound bound
+
+  autoAdjustRequested: ->
+    @options.auto_adjust or @options.bounds.length > 0

data/vendor/assets/javascripts/gmaps4rails/base/objects/marker.coffee

@@ -0,0 +1,24 @@
+@Gmaps4Rails.Marker = { } 
+
+@Gmaps4Rails.Marker.Class =
+
+  DEFAULT_CONF:
+    #Marker config
+    title: null
+    #MarkerImage config
+    picture : null
+    width: 22
+    length: 32
+    draggable: false
+    #clustering config
+    do_clustering: false     # do clustering if set to true
+    randomize: false         # Google maps can't display two markers which have the same coordinates. This randomizer enables to prevent this situation from happening.
+    max_random_distance: 100 # in meters. Each marker coordinate could be altered by this distance in a random direction
+    list_container: null     # id of the ul that will host links to all markers
+    offset: 0                # used when adding_markers to an existing map. Because new markers are concated with previous one, offset is here to prevent the existing from being re-created.
+    raw: {}                  # raw json to pass additional options
+
+@Gmaps4Rails.Marker.Instance =
+
+  getMap: ->
+    @controller.getMapObject()

data/vendor/assets/javascripts/gmaps4rails/base/objects/polygon.coffee

@@ -0,0 +1,11 @@
+@Gmaps4Rails.Polygon = { } 
+
+@Gmaps4Rails.Polygon.Class =
+
+  DEFAULT_CONF:
+    strokeColor: "#FFAA00"
+    strokeOpacity: 0.8
+    strokeWeight: 2
+    fillColor: "#000000"
+    fillOpacity: 0.35
+    clickable: false

data/vendor/assets/javascripts/gmaps4rails/base/objects/polyline.coffee

@@ -0,0 +1,11 @@
+@Gmaps4Rails.Polyline = { } 
+
+@Gmaps4Rails.Polyline.Class =
+
+  DEFAULT_CONF:
+    strokeColor: "#FF0000"
+    strokeOpacity: 1
+    strokeWeight: 2
+    clickable: false
+    zIndex: null
+    icons: null

data/vendor/assets/javascripts/gmaps4rails/bing.coffee

@@ -0,0 +1 @@
+#= require './bing/main'

data/vendor/assets/javascripts/gmaps4rails/bing/main.coffee

@@ -0,0 +1,29 @@
+#= require './shared'
+
+#= require_tree './objects'
+
+class @Gmaps4RailsBing extends Gmaps4Rails.BaseController
+
+  @include Gmaps4Rails.Bing.Shared
+  
+  constructor: ->
+    super
+
+
+  getModule: ->
+    Gmaps4Rails.Bing
+
+  #////////////////////////////////////////////////////
+  #/////////////////// Clusterer //////////////////////
+  #////////////////////////////////////////////////////
+  
+  createClusterer: (marker_serviceObject_array)->
+
+  clearClusterer: ->
+
+  #overwriting method from base controller since it doesn't fit here
+  clearMarkers: ->
+
+  #////////////////////////////////////////////////////
+  #/////////////// Private methods ////////////////////
+  #////////////////////////////////////////////////////

data/vendor/assets/javascripts/gmaps4rails/bing/objects/map.coffee

@@ -0,0 +1,63 @@
+class @Gmaps4Rails.Bing.Map extends Gmaps4Rails.Common
+
+  @include Gmaps4Rails.Interfaces.Map
+
+  @include  Gmaps4Rails.Map
+  @include  Gmaps4Rails.Bing.Shared
+  @include  Gmaps4Rails.Configuration
+
+  CONF:
+    type:  "road" # aerial, auto, birdseye, collinsBart, mercator, ordnanceSurvey, road
+
+  constructor:(map_options, controller) ->
+    @controller    = controller
+
+    defaultOptions = @setConf()
+    @options  = @mergeObjects map_options, defaultOptions
+
+    bingOptions = 
+      credentials:  @options.provider_key,
+      mapTypeId:    @_getMapType(@options),
+      center:       @createLatLng(@options.center_latitude, @options.center_longitude),
+      zoom:         @options.zoom
+
+    mergedBingOptions = @mergeObjects map_options.raw, bingOptions
+
+    @serviceObject = new Microsoft.Maps.Map(document.getElementById(@options.id), mergedBingOptions)
+
+  extendBoundsWithMarkers : ->
+    locationsArray = []
+    for marker in @controller.markers
+      locationsArray.push(marker.serviceObject.getLocation())
+    @boundsObject = Microsoft.Maps.LocationRect.fromLocations(locationsArray)
+
+  extendBoundsWithPolyline: (polyline)->
+
+  extendBoundsWithPolygon: (polygon)->
+
+  extendBoundsWithCircle: (circle)->
+
+  extendBound: (bound)->
+
+  adaptToBounds: ->
+    @_fitBounds()
+
+  centerMapOnUser : (position)->
+    @serviceObject.setView({ center: position})
+  
+  _fitBounds: ->
+    @serviceObject.setView({bounds: @boundsObject})
+
+  _getMapType: (map_options)-> 
+    switch map_options.type
+      when "road"           then return Microsoft.Maps.MapTypeId.road
+      when "aerial"         then return Microsoft.Maps.MapTypeId.aerial
+      when "auto"           then return Microsoft.Maps.MapTypeId.auto
+      when "birdseye"       then return Microsoft.Maps.MapTypeId.birdseye
+      when "collinsBart"    then return Microsoft.Maps.MapTypeId.collinsBart
+      when "mercator"       then return Microsoft.Maps.MapTypeId.mercator
+      when "ordnanceSurvey" then return Microsoft.Maps.MapTypeId.ordnanceSurvey
+      else return Microsoft.Maps.MapTypeId.auto
+
+
+    

data/vendor/assets/javascripts/gmaps4rails/bing/objects/marker.coffee

@@ -0,0 +1,78 @@
+class @Gmaps4Rails.Bing.Marker extends Gmaps4Rails.Common
+
+  @include Gmaps4Rails.Interfaces.Marker
+
+  @include Gmaps4Rails.Bing.Shared
+  @include Gmaps4Rails.Marker.Instance
+  @extend  Gmaps4Rails.Marker.Class
+  @extend  Gmaps4Rails.Configuration
+  
+  @CONF:
+    infobox:  "description" #description or htmlContent
+
+  constructor: (args, controller)->
+    @controller = controller
+
+    markerLatLng = @createLatLng(args.lat, args.lng)
+    anchorLatLng = @_createImageAnchorPosition([args.lat, args.lng])
+
+    #// Marker sizes are expressed as a Size of X,Y
+    if args.marker_picture?
+      @serviceObject = new Microsoft.Maps.Pushpin(markerLatLng, {
+        draggable: args.marker_draggable,
+        anchor:    anchorLatLng,
+        icon:      args.marker_picture,
+        height:    args.marker_height,
+        text:      args.marker_title,
+        width:     args.marker_width
+        }
+      );
+    else
+      @serviceObject = new Microsoft.Maps.Pushpin(markerLatLng, {
+        draggable: args.marker_draggable,
+        anchor:    anchorLatLng,
+        text:      args.marker_title
+        }
+      );
+
+    @_addToMap(@serviceObject)
+
+
+  #// creates infowindows
+  createInfoWindow: () ->
+    if @description?
+      #//create the infowindow
+      if @controller.markers_conf.infobox == "description"
+        @info_window = new Microsoft.Maps.Infobox(@serviceObject.getLocation(), { description: @description, visible: false, showCloseButton: true})
+      else
+        @info_window = new Microsoft.Maps.Infobox(@serviceObject.getLocation(), { htmlContent: @description, visible: false})
+
+      #//add the listener associated
+      Microsoft.Maps.Events.addHandler(@serviceObject, 'click', @_openInfoWindow(@controller, @info_window))
+      @_addToMap(@info_window)
+
+  #cheap integration, I admit
+  isVisible: ->
+    true
+
+  clear: ->
+    @_removeFromMap(@serviceObject)
+
+  show: ->
+    @serviceObject.setOptions({ visible: true })
+
+  hide: ->
+    @serviceObject.setOptions({ visible: false })
+
+  _openInfoWindow: (controller, infoWindow) ->
+    return ->
+      # Close the latest selected marker before opening the current one.
+      if controller.visibleInfoWindow
+        controller.visibleInfoWindow.setOptions({ visible: false })
+      infoWindow.setOptions({ visible:true })
+      controller.visibleInfoWindow = infoWindow
+
+  #creates Image Anchor Position or return null if nothing passed
+  _createImageAnchorPosition : (anchorLocation) ->
+    return null unless anchorLocation?
+    @createPoint(anchorLocation[0], anchorLocation[1])

data/vendor/assets/javascripts/gmaps4rails/bing/shared.coffee

@@ -0,0 +1,20 @@
+Gmaps4Rails.Bing = {}
+
+Gmaps4Rails.Bing.Shared = 
+
+  createPoint: (lat, lng) ->
+    new Microsoft.Maps.Point(lat, lng)
+
+  createLatLng:(lat, lng) ->
+    new Microsoft.Maps.Location(lat, lng)
+  
+  createLatLngBounds: ->
+
+  createSize: (width, height) ->
+    new google.maps.Size(width, height)
+
+  _addToMap: (object)->
+    @controller.getMapObject().entities.push(object)
+
+  _removeFromMap: (object)->
+    @controller.getMapObject().entities.remove(object)

data/vendor/assets/javascripts/gmaps4rails/google.coffee

@@ -0,0 +1 @@
+#= require './google/main'

data/vendor/assets/javascripts/gmaps4rails/google/main.coffee

@@ -0,0 +1,47 @@
+#= require './shared'
+
+#= require_tree './objects'
+
+#######################################################################################################
+##############################################  Google maps  ##########################################
+#######################################################################################################
+
+class @Gmaps4RailsGoogle extends Gmaps4Rails.BaseController
+
+  @include Gmaps4Rails.Google.Shared
+  
+  getModule: ->
+    Gmaps4Rails.Google
+
+  constructor: ->
+    super
+    @markerImages = []
+
+  #////////////////////////////////////////////////////
+  #/////////////////// Clusterer //////////////////////
+  #////////////////////////////////////////////////////
+
+  createClusterer : (markers_array) ->
+    new MarkerClusterer( @getMapObject(), markers_array, {  maxZoom: @markers_conf.clusterer_maxZoom, gridSize: @markers_conf.clusterer_gridSize, styles: @customClusterer() })
+
+  clearClusterer : ->
+    @markerClusterer.clearMarkers()
+
+  #creates clusters
+  clusterize : ->
+    if @markers_conf.do_clustering
+      #first clear the existing clusterer if any
+      @clearClusterer() if @markerClusterer?
+
+      markers_array = []
+      for marker in @markers
+        markers_array.push(marker.serviceObject)
+
+      @markerClusterer = @createClusterer(markers_array)
+
+  _closeVisibleInfoWindow: ->
+    @visibleInfowindow.close() if @visibleInfowindow?
+
+  _setVisibleInfoWindow: (infowindow)->
+    @visibleInfowindow = infowindow
+ 

data/vendor/assets/javascripts/gmaps4rails/google/objects/circle.coffee

@@ -0,0 +1,38 @@
+class @Gmaps4Rails.Google.Circle extends Gmaps4Rails.Common
+
+  @include Gmaps4Rails.Interfaces.Basic
+
+  @include Gmaps4Rails.Google.Shared
+  @extend  Gmaps4Rails.Circle.Class
+  @extend  Gmaps4Rails.Configuration
+
+ #creates a single polyline, triggered by create_polylines
+  constructor : (circle, controller) ->
+    @controller = controller
+
+    #by convention, default style configuration could be integrated in the first element
+    if circle == @controller.circles[0]
+      @controller.circles_conf.strokeColor   = circle.strokeColor   if circle.strokeColor?
+      @controller.circles_conf.strokeOpacity = circle.strokeOpacity if circle.strokeOpacity?
+      @controller.circles_conf.strokeWeight  = circle.strokeWeight  if circle.strokeWeight?
+      @controller.circles_conf.fillColor     = circle.fillColor     if circle.fillColor?
+      @controller.circles_conf.fillOpacity   = circle.fillOpacity   if circle.fillOpacity?
+
+    if circle.lat? and circle.lng?
+      # always check if a config is given, if not, use defaults
+      # NOTE: is there a cleaner way to do this? Maybe a hash merge of some sort?
+      circleOptions = 
+        center:        @createLatLng(circle.lat, circle.lng)
+        strokeColor:   circle.strokeColor   || @controller.circles_conf.strokeColor
+        strokeOpacity: circle.strokeOpacity || @controller.circles_conf.strokeOpacity
+        strokeWeight:  circle.strokeWeight  || @controller.circles_conf.strokeWeight
+        fillOpacity:   circle.fillOpacity   || @controller.circles_conf.fillOpacity
+        fillColor:     circle.fillColor     || @controller.circles_conf.fillColor
+        clickable:     circle.clickable     || @controller.circles_conf.clickable
+        zIndex:        circle.zIndex        || @controller.circles_conf.zIndex
+        radius:        circle.radius
+
+      mergedOptions = @mergeObjects @controller.circles_conf.raw, circleOptions
+
+      @serviceObject = new google.maps.Circle mergedOptions
+      @serviceObject.setMap @controller.getMapObject()

data/vendor/assets/javascripts/gmaps4rails/google/objects/kml.coffee

@@ -0,0 +1,16 @@
+class @Gmaps4Rails.Google.Kml extends Gmaps4Rails.Common
+
+  @include Gmaps4Rails.Interfaces.Basic
+
+  @include Gmaps4Rails.Google.Shared
+  @include Gmaps4Rails.Kml.Instance
+
+ #creates a single polyline, triggered by create_polylines
+  constructor : (kmlData, controller) ->
+    @controller = controller
+
+    @options = kmlData.options || {}
+    @options = @mergeObjects(@options, @DEFAULT_CONF)
+    kml =  new google.maps.KmlLayer( kmlData.url, @options)
+    kml.setMap @controller.getMapObject()
+    @serviceObject = kml

data/vendor/assets/javascripts/gmaps4rails/google/objects/map.coffee

@@ -0,0 +1,71 @@
+class Gmaps4Rails.Google.Map extends Gmaps4Rails.Common
+
+  @include Gmaps4Rails.Interfaces.Map
+
+  @include  Gmaps4Rails.Map
+  @include  Gmaps4Rails.Google.Shared
+  @include  Gmaps4Rails.Configuration
+
+  CONF:
+    disableDefaultUI:       false
+    disableDoubleClickZoom: false
+    type:                   "ROADMAP" # HYBRID, ROADMAP, SATELLITE, TERRAIN
+    mapTypeControl:         null
+
+  constructor:(map_options, controller) ->
+    @controller    = controller
+
+    defaultOptions = @setConf()
+    @options  = @mergeObjects map_options, defaultOptions
+
+    googleOptions =
+      maxZoom:                @options.maxZoom
+      minZoom:                @options.minZoom
+      zoom:                   @options.zoom
+      center:                 @createLatLng(@options.center_latitude, @options.center_longitude)
+      mapTypeId:              google.maps.MapTypeId[@options.type]
+      mapTypeControl:         @options.mapTypeControl
+      disableDefaultUI:       @options.disableDefaultUI
+      disableDoubleClickZoom: @options.disableDoubleClickZoom
+      draggable:              @options.draggable
+    
+    mergedGoogleOptions = @mergeObjects map_options.raw, googleOptions
+
+    @serviceObject = new google.maps.Map document.getElementById(@options.id), mergedGoogleOptions
+
+  extendBoundsWithMarker : (marker) ->
+    @boundsObject.extend(marker.serviceObject.position)
+
+  extendBoundsWithPolyline: (polyline)->
+    polyline_points = polyline.serviceObject.latLngs.getArray()[0].getArray()
+    for point in polyline_points
+      @boundsObject.extend point
+
+  extendBoundsWithPolygon: (polygon)->
+    polygon_points = polygon.serviceObject.latLngs.getArray()[0].getArray()
+    for point in polygon_points
+      @boundsObject.extend point
+
+  extendBoundsWithCircle: (circle)->
+    @boundsObject.extend(circle.serviceObject.getBounds().getNorthEast())
+    @boundsObject.extend(circle.serviceObject.getBounds().getSouthWest())
+
+  extendBound: (bound)->
+    #create points from bounds provided
+    @boundsObject.extend @createLatLng(bound.lat, bound.lng)
+
+  adaptToBounds:()->
+    #if autozoom is false, take user info into account
+    unless @options.auto_zoom
+      map_center = @boundsObject.getCenter()
+      @options.center_latitude  = map_center.lat()
+      @options.center_longitude = map_center.lng()
+      @serviceObject.setCenter(map_center)
+    else
+      @fitBounds()
+
+  fitBounds : ->
+    @serviceObject.fitBounds(@boundsObject) unless @boundsObject.isEmpty()
+
+  centerMapOnUser : (position)->
+    @serviceObject.setCenter(position)