webpack_rails 0.3.0 → 1.0.0

data/lib/webpack_rails/node_modules/express/node_modules/proxy-addr/node_modules/ipaddr.js/src/ipaddr.coffee

@@ -0,0 +1,374 @@
+# Define the main object
+ipaddr = {}
+
+root = this
+
+# Export for both the CommonJS and browser-like environment
+if module? && module.exports
+  module.exports = ipaddr
+else
+  root['ipaddr'] = ipaddr
+
+# A generic CIDR (Classless Inter-Domain Routing) RFC1518 range matcher.
+matchCIDR = (first, second, partSize, cidrBits) ->
+  if first.length != second.length
+    throw new Error "ipaddr: cannot match CIDR for objects with different lengths"
+
+  part = 0
+  while cidrBits > 0
+    shift = partSize - cidrBits
+    shift = 0 if shift < 0
+
+    if first[part] >> shift != second[part] >> shift
+      return false
+
+    cidrBits -= partSize
+    part     += 1
+
+  return true
+
+# An utility function to ease named range matching. See examples below.
+ipaddr.subnetMatch = (address, rangeList, defaultName='unicast') ->
+  for rangeName, rangeSubnets of rangeList
+    # ECMA5 Array.isArray isn't available everywhere
+    if toString.call(rangeSubnets[0]) != '[object Array]'
+      rangeSubnets = [ rangeSubnets ]
+
+    for subnet in rangeSubnets
+      return rangeName if address.match.apply(address, subnet)
+
+  return defaultName
+
+# An IPv4 address (RFC791).
+class ipaddr.IPv4
+  # Constructs a new IPv4 address from an array of four octets.
+  # Verifies the input.
+  constructor: (octets) ->
+    if octets.length != 4
+      throw new Error "ipaddr: ipv4 octet count should be 4"
+
+    for octet in octets
+      if !(0 <= octet <= 255)
+        throw new Error "ipaddr: ipv4 octet is a byte"
+
+    @octets = octets
+
+  # The 'kind' method exists on both IPv4 and IPv6 classes.
+  kind: ->
+    return 'ipv4'
+
+  # Returns the address in convenient, decimal-dotted format.
+  toString: ->
+    return @octets.join "."
+
+  # Returns an array of byte-sized values in network order
+  toByteArray: ->
+    return @octets.slice(0) # octets.clone
+
+  # Checks if this address matches other one within given CIDR range.
+  match: (other, cidrRange) ->
+    if cidrRange == undefined
+      [other, cidrRange] = other
+
+    if other.kind() != 'ipv4'
+      throw new Error "ipaddr: cannot match ipv4 address with non-ipv4 one"
+
+    return matchCIDR(this.octets, other.octets, 8, cidrRange)
+
+  # Special IPv4 address ranges.
+  SpecialRanges:
+    unspecified: [
+      [ new IPv4([0,     0,    0,   0]),  8 ]
+    ]
+    broadcast: [
+      [ new IPv4([255, 255,  255, 255]), 32 ]
+    ]
+    multicast: [ # RFC3171
+      [ new IPv4([224,   0,    0,   0]), 4  ]
+    ]
+    linkLocal: [ # RFC3927
+      [ new IPv4([169,   254,  0,   0]), 16 ]
+    ]
+    loopback: [ # RFC5735
+      [ new IPv4([127,   0,    0,   0]), 8  ]
+    ]
+    private: [ # RFC1918
+      [ new IPv4([10,    0,    0,   0]), 8  ]
+      [ new IPv4([172,   16,   0,   0]), 12 ]
+      [ new IPv4([192,   168,  0,   0]), 16 ]
+    ]
+    reserved: [ # Reserved and testing-only ranges; RFCs 5735, 5737, 2544, 1700
+      [ new IPv4([192,   0,    0,   0]), 24 ]
+      [ new IPv4([192,   0,    2,   0]), 24 ]
+      [ new IPv4([192,  88,   99,   0]), 24 ]
+      [ new IPv4([198,  51,  100,   0]), 24 ]
+      [ new IPv4([203,   0,  113,   0]), 24 ]
+      [ new IPv4([240,   0,    0,   0]), 4  ]
+    ]
+
+  # Checks if the address corresponds to one of the special ranges.
+  range: ->
+    return ipaddr.subnetMatch(this, @SpecialRanges)
+
+  # Convrets this IPv4 address to an IPv4-mapped IPv6 address.
+  toIPv4MappedAddress: ->
+    return ipaddr.IPv6.parse "::ffff:#{@toString()}"
+
+# A list of regular expressions that match arbitrary IPv4 addresses,
+# for which a number of weird notations exist.
+# Note that an address like 0010.0xa5.1.1 is considered legal.
+ipv4Part = "(0?\\d+|0x[a-f0-9]+)"
+ipv4Regexes =
+  fourOctet: new RegExp "^#{ipv4Part}\\.#{ipv4Part}\\.#{ipv4Part}\\.#{ipv4Part}$", 'i'
+  longValue: new RegExp "^#{ipv4Part}$", 'i'
+
+# Classful variants (like a.b, where a is an octet, and b is a 24-bit
+# value representing last three octets; this corresponds to a class C
+# address) are omitted due to classless nature of modern Internet.
+ipaddr.IPv4.parser = (string) ->
+  parseIntAuto = (string) ->
+    if string[0] == "0" && string[1] != "x"
+      parseInt(string, 8)
+    else
+      parseInt(string)
+
+  # parseInt recognizes all that octal & hexadecimal weirdness for us
+  if match = string.match(ipv4Regexes.fourOctet)
+    return (parseIntAuto(part) for part in match[1..5])
+  else if match = string.match(ipv4Regexes.longValue)
+    value = parseIntAuto(match[1])
+    if value > 0xffffffff || value < 0
+      throw new Error "ipaddr: address outside defined range"
+    return ((value >> shift) & 0xff for shift in [0..24] by 8).reverse()
+  else
+    return null
+
+# An IPv6 address (RFC2460)
+class ipaddr.IPv6
+  # Constructs an IPv6 address from an array of eight 16-bit parts.
+  # Throws an error if the input is invalid.
+  constructor: (parts) ->
+    if parts.length != 8
+      throw new Error "ipaddr: ipv6 part count should be 8"
+
+    for part in parts
+      if !(0 <= part <= 0xffff)
+        throw new Error "ipaddr: ipv6 part should fit to two octets"
+
+    @parts = parts
+
+  # The 'kind' method exists on both IPv4 and IPv6 classes.
+  kind: ->
+    return 'ipv6'
+
+  # Returns the address in compact, human-readable format like
+  # 2001:db8:8:66::1
+  toString: ->
+    stringParts = (part.toString(16) for part in @parts)
+
+    compactStringParts = []
+    pushPart = (part) -> compactStringParts.push part
+
+    state = 0
+    for part in stringParts
+      switch state
+        when 0
+          if part == '0'
+            pushPart('')
+          else
+            pushPart(part)
+
+          state = 1
+        when 1
+          if part == '0'
+            state = 2
+          else
+            pushPart(part)
+        when 2
+          unless part == '0'
+            pushPart('')
+            pushPart(part)
+            state = 3
+        when 3
+          pushPart(part)
+
+    if state == 2
+      pushPart('')
+      pushPart('')
+
+    return compactStringParts.join ":"
+
+  # Returns an array of byte-sized values in network order
+  toByteArray: ->
+    bytes = []
+    for part in @parts
+      bytes.push(part >> 8)
+      bytes.push(part & 0xff)
+
+    return bytes
+
+  # Returns the address in expanded format with all zeroes included, like
+  # 2001:db8:8:66:0:0:0:1
+  toNormalizedString: ->
+    return (part.toString(16) for part in @parts).join ":"
+
+  # Checks if this address matches other one within given CIDR range.
+  match: (other, cidrRange) ->
+    if cidrRange == undefined
+      [other, cidrRange] = other
+
+    if other.kind() != 'ipv6'
+      throw new Error "ipaddr: cannot match ipv6 address with non-ipv6 one"
+
+    return matchCIDR(this.parts, other.parts, 16, cidrRange)
+
+  # Special IPv6 ranges
+  SpecialRanges:
+    unspecified: [ new IPv6([0,      0,      0, 0, 0,      0,      0, 0]), 128 ] # RFC4291, here and after
+    linkLocal:   [ new IPv6([0xfe80, 0,      0, 0, 0,      0,      0, 0]), 10  ]
+    multicast:   [ new IPv6([0xff00, 0,      0, 0, 0,      0,      0, 0]), 8   ]
+    loopback:    [ new IPv6([0,      0,      0, 0, 0,      0,      0, 1]), 128 ]
+    uniqueLocal: [ new IPv6([0xfc00, 0,      0, 0, 0,      0,      0, 0]), 7   ]
+    ipv4Mapped:  [ new IPv6([0,      0,      0, 0, 0,      0xffff, 0, 0]), 96  ]
+    rfc6145:     [ new IPv6([0,      0,      0, 0, 0xffff, 0,      0, 0]), 96  ] # RFC6145
+    rfc6052:     [ new IPv6([0x64,   0xff9b, 0, 0, 0,      0,      0, 0]), 96  ] # RFC6052
+    '6to4':      [ new IPv6([0x2002, 0,      0, 0, 0,      0,      0, 0]), 16  ] # RFC3056
+    teredo:      [ new IPv6([0x2001, 0,      0, 0, 0,      0,      0, 0]), 32  ] # RFC6052, RFC6146
+    reserved: [
+      [ new IPv6([ 0x2001, 0xdb8, 0, 0, 0, 0, 0, 0]), 32 ] # RFC4291
+    ]
+
+  # Checks if the address corresponds to one of the special ranges.
+  range: ->
+    return ipaddr.subnetMatch(this, @SpecialRanges)
+
+  # Checks if this address is an IPv4-mapped IPv6 address.
+  isIPv4MappedAddress: ->
+    return @range() == 'ipv4Mapped'
+
+  # Converts this address to IPv4 address if it is an IPv4-mapped IPv6 address.
+  # Throws an error otherwise.
+  toIPv4Address: ->
+    unless @isIPv4MappedAddress()
+      throw new Error "ipaddr: trying to convert a generic ipv6 address to ipv4"
+
+    [high, low] = @parts[-2..-1]
+
+    return new ipaddr.IPv4([high >> 8, high & 0xff, low >> 8, low & 0xff])
+
+# IPv6-matching regular expressions.
+# For IPv6, the task is simpler: it is enough to match the colon-delimited
+# hexadecimal IPv6 and a transitional variant with dotted-decimal IPv4 at
+# the end.
+ipv6Part = "(?:[0-9a-f]+::?)+"
+ipv6Regexes =
+  native:       new RegExp "^(::)?(#{ipv6Part})?([0-9a-f]+)?(::)?$", 'i'
+  transitional: new RegExp "^((?:#{ipv6Part})|(?:::)(?:#{ipv6Part})?)" +
+                           "#{ipv4Part}\\.#{ipv4Part}\\.#{ipv4Part}\\.#{ipv4Part}$", 'i'
+
+# Expand :: in an IPv6 address or address part consisting of `parts` groups.
+expandIPv6 = (string, parts) ->
+  # More than one '::' means invalid adddress
+  if string.indexOf('::') != string.lastIndexOf('::')
+    return null
+
+  # How many parts do we already have?
+  colonCount = 0
+  lastColon = -1
+  while (lastColon = string.indexOf(':', lastColon + 1)) >= 0
+    colonCount++
+
+  # 0::0 is two parts more than ::
+  colonCount-- if string[0] == ':'
+  colonCount-- if string[string.length-1] == ':'
+
+  # The following loop would hang if colonCount > parts
+  if colonCount > parts
+    return null
+
+  # replacement = ':' + '0:' * (parts - colonCount)
+  replacementCount = parts - colonCount
+  replacement = ':'
+  while replacementCount--
+    replacement += '0:'
+
+  # Insert the missing zeroes
+  string = string.replace('::', replacement)
+
+  # Trim any garbage which may be hanging around if :: was at the edge in
+  # the source string
+  string = string[1..-1] if string[0] == ':'
+  string = string[0..-2] if string[string.length-1] == ':'
+
+  return (parseInt(part, 16) for part in string.split(":"))
+
+# Parse an IPv6 address.
+ipaddr.IPv6.parser = (string) ->
+  if string.match(ipv6Regexes['native'])
+    return expandIPv6(string, 8)
+
+  else if match = string.match(ipv6Regexes['transitional'])
+    parts = expandIPv6(match[1][0..-2], 6)
+    if parts
+      parts.push(parseInt(match[2]) << 8 | parseInt(match[3]))
+      parts.push(parseInt(match[4]) << 8 | parseInt(match[5]))
+      return parts
+
+  return null
+
+# Checks if a given string is formatted like IPv4/IPv6 address.
+ipaddr.IPv4.isIPv4 = ipaddr.IPv6.isIPv6 = (string) ->
+  return @parser(string) != null
+
+# Checks if a given string is a valid IPv4/IPv6 address.
+ipaddr.IPv4.isValid = ipaddr.IPv6.isValid = (string) ->
+  try
+    new this(@parser(string))
+    return true
+  catch e
+    return false
+
+# Tries to parse and validate a string with IPv4/IPv6 address.
+# Throws an error if it fails.
+ipaddr.IPv4.parse = ipaddr.IPv6.parse = (string) ->
+  parts = @parser(string)
+  if parts == null
+    throw new Error "ipaddr: string is not formatted like ip address"
+
+  return new this(parts)
+
+ipaddr.IPv4.parseCIDR = ipaddr.IPv6.parseCIDR = (string) ->
+  if match = string.match(/^(.+)\/(\d+)$/)
+    return [@parse(match[1]), parseInt(match[2])]
+
+  throw new Error "ipaddr: string is not formatted like a CIDR range"
+
+# Checks if the address is valid IP address
+ipaddr.isValid = (string) ->
+  return ipaddr.IPv6.isValid(string) || ipaddr.IPv4.isValid(string)
+
+# Try to parse an address and throw an error if it is impossible
+ipaddr.parse = (string) ->
+  if ipaddr.IPv6.isValid(string)
+    return ipaddr.IPv6.parse(string)
+  else if ipaddr.IPv4.isValid(string)
+    return ipaddr.IPv4.parse(string)
+  else
+    throw new Error "ipaddr: the address has neither IPv6 nor IPv4 format"
+
+ipaddr.parseCIDR = (string) ->
+  try
+    return ipaddr.IPv6.parseCIDR(string)
+  catch e
+    try
+      return ipaddr.IPv4.parseCIDR(string)
+    catch e
+      throw new Error "ipaddr: the address has neither IPv6 nor IPv4 CIDR format"
+
+# Parse an address and return plain IPv4 address if it is an IPv4-mapped address
+ipaddr.process = (string) ->
+  addr = @parse(string)
+  if addr.kind() == 'ipv6' && addr.isIPv4MappedAddress()
+    return addr.toIPv4Address()
+  else
+    return addr

data/lib/webpack_rails/node_modules/express/node_modules/proxy-addr/node_modules/ipaddr.js/test/ipaddr.test.coffee

@@ -0,0 +1,262 @@
+ipaddr = require '../lib/ipaddr'
+
+module.exports =
+  'should define main classes': (test) ->
+    test.ok(ipaddr.IPv4?, 'defines IPv4 class')
+    test.ok(ipaddr.IPv6?, 'defines IPv6 class')
+    test.done()
+
+  'can construct IPv4 from octets': (test) ->
+    test.doesNotThrow ->
+      new ipaddr.IPv4([192, 168, 1, 2])
+    test.done()
+
+  'refuses to construct invalid IPv4': (test) ->
+    test.throws ->
+      new ipaddr.IPv4([300, 1, 2, 3])
+    test.throws ->
+      new ipaddr.IPv4([8, 8, 8])
+    test.done()
+
+  'converts IPv4 to string correctly': (test) ->
+    addr = new ipaddr.IPv4([192, 168, 1, 1])
+    test.equal(addr.toString(), '192.168.1.1')
+    test.done()
+
+  'returns correct kind for IPv4': (test) ->
+    addr = new ipaddr.IPv4([1, 2, 3, 4])
+    test.equal(addr.kind(), 'ipv4')
+    test.done()
+
+  'allows to access IPv4 octets': (test) ->
+    addr = new ipaddr.IPv4([42, 0, 0, 0])
+    test.equal(addr.octets[0], 42)
+    test.done()
+
+  'checks IPv4 address format': (test) ->
+    test.equal(ipaddr.IPv4.isIPv4('192.168.007.0xa'), true)
+    test.equal(ipaddr.IPv4.isIPv4('1024.0.0.1'),      true)
+    test.equal(ipaddr.IPv4.isIPv4('8.0xa.wtf.6'),     false)
+    test.done()
+
+  'validates IPv4 addresses': (test) ->
+    test.equal(ipaddr.IPv4.isValid('192.168.007.0xa'), true)
+    test.equal(ipaddr.IPv4.isValid('1024.0.0.1'),      false)
+    test.equal(ipaddr.IPv4.isValid('8.0xa.wtf.6'),     false)
+    test.done()
+
+  'parses IPv4 in several weird formats': (test) ->
+    test.deepEqual(ipaddr.IPv4.parse('192.168.1.1').octets,  [192, 168, 1, 1])
+    test.deepEqual(ipaddr.IPv4.parse('0xc0.168.1.1').octets, [192, 168, 1, 1])
+    test.deepEqual(ipaddr.IPv4.parse('192.0250.1.1').octets, [192, 168, 1, 1])
+    test.deepEqual(ipaddr.IPv4.parse('0xc0a80101').octets,   [192, 168, 1, 1])
+    test.deepEqual(ipaddr.IPv4.parse('030052000401').octets, [192, 168, 1, 1])
+    test.deepEqual(ipaddr.IPv4.parse('3232235777').octets,   [192, 168, 1, 1])
+    test.done()
+
+  'barfs at invalid IPv4': (test) ->
+    test.throws ->
+      ipaddr.IPv4.parse('10.0.0.wtf')
+    test.done()
+
+  'matches IPv4 CIDR correctly': (test) ->
+    addr = new ipaddr.IPv4([10, 5, 0, 1])
+    test.equal(addr.match(ipaddr.IPv4.parse('0.0.0.0'), 0),   true)
+    test.equal(addr.match(ipaddr.IPv4.parse('11.0.0.0'), 8),  false)
+    test.equal(addr.match(ipaddr.IPv4.parse('10.0.0.0'), 8),  true)
+    test.equal(addr.match(ipaddr.IPv4.parse('10.0.0.1'), 8),  true)
+    test.equal(addr.match(ipaddr.IPv4.parse('10.0.0.10'), 8), true)
+    test.equal(addr.match(ipaddr.IPv4.parse('10.5.5.0'), 16), true)
+    test.equal(addr.match(ipaddr.IPv4.parse('10.4.5.0'), 16), false)
+    test.equal(addr.match(ipaddr.IPv4.parse('10.4.5.0'), 15), true)
+    test.equal(addr.match(ipaddr.IPv4.parse('10.5.0.2'), 32), false)
+    test.equal(addr.match(addr, 32), true)
+    test.done()
+
+  'parses IPv4 CIDR correctly': (test) ->
+    addr = new ipaddr.IPv4([10, 5, 0, 1])
+    test.equal(addr.match(ipaddr.IPv4.parseCIDR('0.0.0.0/0')),   true)
+    test.equal(addr.match(ipaddr.IPv4.parseCIDR('11.0.0.0/8')),  false)
+    test.equal(addr.match(ipaddr.IPv4.parseCIDR('10.0.0.0/8')),  true)
+    test.equal(addr.match(ipaddr.IPv4.parseCIDR('10.0.0.1/8')),  true)
+    test.equal(addr.match(ipaddr.IPv4.parseCIDR('10.0.0.10/8')), true)
+    test.equal(addr.match(ipaddr.IPv4.parseCIDR('10.5.5.0/16')), true)
+    test.equal(addr.match(ipaddr.IPv4.parseCIDR('10.4.5.0/16')), false)
+    test.equal(addr.match(ipaddr.IPv4.parseCIDR('10.4.5.0/15')), true)
+    test.equal(addr.match(ipaddr.IPv4.parseCIDR('10.5.0.2/32')), false)
+    test.equal(addr.match(ipaddr.IPv4.parseCIDR('10.5.0.1/32')), true)
+    test.throws ->
+      ipaddr.IPv4.parseCIDR('10.5.0.1')
+    test.done()
+
+  'detects reserved IPv4 networks': (test) ->
+    test.equal(ipaddr.IPv4.parse('0.0.0.0').range(),         'unspecified')
+    test.equal(ipaddr.IPv4.parse('0.1.0.0').range(),         'unspecified')
+    test.equal(ipaddr.IPv4.parse('10.1.0.1').range(),        'private')
+    test.equal(ipaddr.IPv4.parse('192.168.2.1').range(),     'private')
+    test.equal(ipaddr.IPv4.parse('224.100.0.1').range(),     'multicast')
+    test.equal(ipaddr.IPv4.parse('169.254.15.0').range(),    'linkLocal')
+    test.equal(ipaddr.IPv4.parse('127.1.1.1').range(),       'loopback')
+    test.equal(ipaddr.IPv4.parse('255.255.255.255').range(), 'broadcast')
+    test.equal(ipaddr.IPv4.parse('240.1.2.3').range(),       'reserved')
+    test.equal(ipaddr.IPv4.parse('8.8.8.8').range(),         'unicast')
+    test.done()
+
+  'can construct IPv6 from parts': (test) ->
+    test.doesNotThrow ->
+      new ipaddr.IPv6([0x2001, 0xdb8, 0xf53a, 0, 0, 0, 0, 1])
+    test.done()
+
+  'refuses to construct invalid IPv6': (test) ->
+    test.throws ->
+      new ipaddr.IPv6([0xfffff, 0, 0, 0, 0, 0, 0, 1])
+    test.throws ->
+      new ipaddr.IPv6([0xfffff, 0, 0, 0, 0, 0, 1])
+    test.done()
+
+  'converts IPv6 to string correctly': (test) ->
+    addr = new ipaddr.IPv6([0x2001, 0xdb8, 0xf53a, 0, 0, 0, 0, 1])
+    test.equal(addr.toNormalizedString(), '2001:db8:f53a:0:0:0:0:1')
+    test.equal(addr.toString(), '2001:db8:f53a::1')
+    test.equal(new ipaddr.IPv6([0, 0, 0, 0, 0, 0, 0, 1]).toString(), '::1')
+    test.equal(new ipaddr.IPv6([0x2001, 0xdb8, 0, 0, 0, 0, 0, 0]).toString(), '2001:db8::')
+    test.done()
+
+  'returns correct kind for IPv6': (test) ->
+    addr = new ipaddr.IPv6([0x2001, 0xdb8, 0xf53a, 0, 0, 0, 0, 1])
+    test.equal(addr.kind(), 'ipv6')
+    test.done()
+
+  'allows to access IPv6 address parts': (test) ->
+    addr = new ipaddr.IPv6([0x2001, 0xdb8, 0xf53a, 0, 0, 42, 0, 1])
+    test.equal(addr.parts[5], 42)
+    test.done()
+
+  'checks IPv6 address format': (test) ->
+    test.equal(ipaddr.IPv6.isIPv6('2001:db8:F53A::1'),     true)
+    test.equal(ipaddr.IPv6.isIPv6('200001::1'),            true)
+    test.equal(ipaddr.IPv6.isIPv6('::ffff:192.168.1.1'),   true)
+    test.equal(ipaddr.IPv6.isIPv6('::ffff:300.168.1.1'),   true)
+    test.equal(ipaddr.IPv6.isIPv6('::ffff:300.168.1.1:0'), false)
+    test.equal(ipaddr.IPv6.isIPv6('fe80::wtf'),            false)
+    test.done()
+
+  'validates IPv6 addresses': (test) ->
+    test.equal(ipaddr.IPv6.isValid('2001:db8:F53A::1'),    true)
+    test.equal(ipaddr.IPv6.isValid('200001::1'),           false)
+    test.equal(ipaddr.IPv6.isValid('::ffff:192.168.1.1'),   true)
+    test.equal(ipaddr.IPv6.isValid('::ffff:300.168.1.1'),   false)
+    test.equal(ipaddr.IPv6.isValid('::ffff:300.168.1.1:0'), false)
+    test.equal(ipaddr.IPv6.isValid('2001:db8::F53A::1'),   false)
+    test.equal(ipaddr.IPv6.isValid('fe80::wtf'),           false)
+    test.done()
+
+  'parses IPv6 in different formats': (test) ->
+    test.deepEqual(ipaddr.IPv6.parse('2001:db8:F53A:0:0:0:0:1').parts, [0x2001, 0xdb8, 0xf53a, 0, 0, 0, 0, 1])
+    test.deepEqual(ipaddr.IPv6.parse('fe80::10').parts, [0xfe80, 0, 0, 0, 0, 0, 0, 0x10])
+    test.deepEqual(ipaddr.IPv6.parse('2001:db8:F53A::').parts, [0x2001, 0xdb8, 0xf53a, 0, 0, 0, 0, 0])
+    test.deepEqual(ipaddr.IPv6.parse('::1').parts, [0, 0, 0, 0, 0, 0, 0, 1])
+    test.deepEqual(ipaddr.IPv6.parse('::').parts, [0, 0, 0, 0, 0, 0, 0, 0])
+    test.done()
+
+  'barfs at invalid IPv6': (test) ->
+    test.throws ->
+      ipaddr.IPv6.parse('fe80::0::1')
+    test.done()
+
+  'matches IPv6 CIDR correctly': (test) ->
+    addr = ipaddr.IPv6.parse('2001:db8:f53a::1')
+    test.equal(addr.match(ipaddr.IPv6.parse('::'), 0),                  true)
+    test.equal(addr.match(ipaddr.IPv6.parse('2001:db8:f53a::1:1'), 64), true)
+    test.equal(addr.match(ipaddr.IPv6.parse('2001:db8:f53b::1:1'), 48), false)
+    test.equal(addr.match(ipaddr.IPv6.parse('2001:db8:f531::1:1'), 44), true)
+    test.equal(addr.match(ipaddr.IPv6.parse('2001:db8:f500::1'), 40),   true)
+    test.equal(addr.match(ipaddr.IPv6.parse('2001:db9:f500::1'), 40),   false)
+    test.equal(addr.match(addr, 128), true)
+    test.done()
+
+  'parses IPv6 CIDR correctly': (test) ->
+    addr = ipaddr.IPv6.parse('2001:db8:f53a::1')
+    test.equal(addr.match(ipaddr.IPv6.parseCIDR('::/0')),                  true)
+    test.equal(addr.match(ipaddr.IPv6.parseCIDR('2001:db8:f53a::1:1/64')), true)
+    test.equal(addr.match(ipaddr.IPv6.parseCIDR('2001:db8:f53b::1:1/48')), false)
+    test.equal(addr.match(ipaddr.IPv6.parseCIDR('2001:db8:f531::1:1/44')), true)
+    test.equal(addr.match(ipaddr.IPv6.parseCIDR('2001:db8:f500::1/40')),   true)
+    test.equal(addr.match(ipaddr.IPv6.parseCIDR('2001:db9:f500::1/40')),   false)
+    test.equal(addr.match(ipaddr.IPv6.parseCIDR('2001:db8:f53a::1/128')),  true)
+    test.throws ->
+      ipaddr.IPv6.parseCIDR('2001:db8:f53a::1')
+    test.done()
+
+  'converts between IPv4-mapped IPv6 addresses and IPv4 addresses': (test) ->
+    addr = ipaddr.IPv4.parse('77.88.21.11')
+    mapped = addr.toIPv4MappedAddress()
+    test.deepEqual(mapped.parts, [0, 0, 0, 0, 0, 0xffff, 0x4d58, 0x150b])
+    test.deepEqual(mapped.toIPv4Address().octets, addr.octets)
+    test.done()
+
+  'refuses to convert non-IPv4-mapped IPv6 address to IPv4 address': (test) ->
+    test.throws ->
+      ipaddr.IPv6.parse('2001:db8::1').toIPv4Address()
+    test.done()
+
+  'detects reserved IPv6 networks': (test) ->
+    test.equal(ipaddr.IPv6.parse('::').range(),                        'unspecified')
+    test.equal(ipaddr.IPv6.parse('fe80::1234:5678:abcd:0123').range(), 'linkLocal')
+    test.equal(ipaddr.IPv6.parse('ff00::1234').range(),                'multicast')
+    test.equal(ipaddr.IPv6.parse('::1').range(),                       'loopback')
+    test.equal(ipaddr.IPv6.parse('fc00::').range(),                    'uniqueLocal')
+    test.equal(ipaddr.IPv6.parse('::ffff:192.168.1.10').range(),       'ipv4Mapped')
+    test.equal(ipaddr.IPv6.parse('::ffff:0:192.168.1.10').range(),     'rfc6145')
+    test.equal(ipaddr.IPv6.parse('64:ff9b::1234').range(),             'rfc6052')
+    test.equal(ipaddr.IPv6.parse('2002:1f63:45e8::1').range(),         '6to4')
+    test.equal(ipaddr.IPv6.parse('2001::4242').range(),                'teredo')
+    test.equal(ipaddr.IPv6.parse('2001:db8::3210').range(),            'reserved')
+    test.equal(ipaddr.IPv6.parse('2001:470:8:66::1').range(),          'unicast')
+    test.done()
+
+  'is able to determine IP address type': (test) ->
+    test.equal(ipaddr.parse('8.8.8.8').kind(), 'ipv4')
+    test.equal(ipaddr.parse('2001:db8:3312::1').kind(), 'ipv6')
+    test.done()
+
+  'throws an error if tried to parse an invalid address': (test) ->
+    test.throws ->
+      ipaddr.parse('::some.nonsense')
+    test.done()
+
+  'correctly processes IPv4-mapped addresses': (test) ->
+    test.equal(ipaddr.process('8.8.8.8').kind(), 'ipv4')
+    test.equal(ipaddr.process('2001:db8:3312::1').kind(), 'ipv6')
+    test.equal(ipaddr.process('::ffff:192.168.1.1').kind(), 'ipv4')
+    test.done()
+
+  'correctly converts IPv6 and IPv4 addresses to byte arrays': (test) ->
+    test.deepEqual(ipaddr.parse('1.2.3.4').toByteArray(),
+          [0x1, 0x2, 0x3, 0x4]);
+    # Fuck yeah. The first byte of Google's IPv6 address is 42. 42!
+    test.deepEqual(ipaddr.parse('2a00:1450:8007::68').toByteArray(),
+          [42, 0x00, 0x14, 0x50, 0x80, 0x07, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x68 ])
+    test.done()
+
+  'correctly parses 1 as an IPv4 address': (test) ->
+    test.equal(ipaddr.IPv6.isValid('1'), false)
+    test.equal(ipaddr.IPv4.isValid('1'), true)
+    test.deepEqual(new ipaddr.IPv4([0, 0, 0, 1]), ipaddr.parse('1'))
+    test.done()
+
+  'correctly detects IPv4 and IPv6 CIDR addresses': (test) ->
+    test.deepEqual([ipaddr.IPv6.parse('fc00::'), 64],
+                   ipaddr.parseCIDR('fc00::/64'))
+    test.deepEqual([ipaddr.IPv4.parse('1.2.3.4'), 5],
+                   ipaddr.parseCIDR('1.2.3.4/5'))
+    test.done()
+
+  'does not consider a very large or very small number a valid IP address': (test) ->
+    test.equal(ipaddr.isValid('4999999999'), false)
+    test.equal(ipaddr.isValid('-1'), false)
+    test.done()
+
+  'does not hang on ::8:8:8:8:8:8:8:8:8': (test) ->
+    test.equal(ipaddr.IPv6.isValid('::8:8:8:8:8:8:8:8:8'), false)
+    test.done()