utils 0.0.0

data/lib/utils/config/vim/plugin/AlignMapsPlugin.vim

@@ -0,0 +1,242 @@
+" AlignMapsPlugin:   Alignment maps based upon <Align.vim> and <AlignMaps.vim>
+" Maintainer:        Dr. Charles E. Campbell, Jr. <NdrOchipS@PcampbellAfamily.Mbiz>
+" Date:              Mar 03, 2009
+"
+" NOTE: the code herein needs vim 6.0 or later
+"                       needs <Align.vim> v6 or later
+"                       needs <cecutil.vim> v5 or later
+" Copyright:    Copyright (C) 1999-2008 Charles E. Campbell, Jr. {{{1
+"               Permission is hereby granted to use and distribute this code,
+"               with or without modifications, provided that this copyright
+"               notice is copied with it. Like anything else that's free,
+"               AlignMaps.vim is provided *as is* and comes with no warranty
+"               of any kind, either expressed or implied. By using this
+"               plugin, you agree that in no event will the copyright
+"               holder be liable for any damages resulting from the use
+"               of this software.
+"
+" Usage: {{{1
+" Use 'a to mark beginning of to-be-aligned region,   Alternative:  use V
+" move cursor to end of region, and execute map.      (linewise visual mode) to
+" The maps also set up marks 'y and 'z, and retain    mark region, execute same
+" 'a at the beginning of region.                      map.  Uses 'a, 'y, and 'z.
+"
+" The start/end wrappers save and restore marks 'y and 'z.
+"
+" Although the comments indicate the maps use a leading backslash,
+" actually they use <Leader> (:he mapleader), so the user can
+" specify that the maps start how he or she prefers.
+"
+" Note: these maps all use <Align.vim>.
+"
+" Romans 1:20 For the invisible things of Him since the creation of the {{{1
+" world are clearly seen, being perceived through the things that are
+" made, even His everlasting power and divinity; that they may be
+" without excuse.
+
+" ---------------------------------------------------------------------
+" Load Once: {{{1
+if &cp || exists("g:loaded_AlignMapsPlugin")
+ finish
+endif
+let s:keepcpo                = &cpo
+let g:loaded_AlignMapsPlugin = "v41"
+set cpo&vim
+
+" =====================================================================
+"  Maps: {{{1
+
+" ---------------------------------------------------------------------
+" WS: wrapper start map (internal)  {{{2
+" Produces a blank line above and below, marks with 'y and 'z
+if !hasmapto('<Plug>WrapperStart')
+ map <unique> <SID>WS	<Plug>AlignMapsWrapperStart
+endif
+nmap <silent> <script> <Plug>AlignMapsWrapperStart	:set lz<CR>:call AlignMaps#WrapperStart(0)<CR>
+vmap <silent> <script> <Plug>AlignMapsWrapperStart	:<c-u>set lz<CR>:call AlignMaps#WrapperStart(1)<CR>
+
+" ---------------------------------------------------------------------
+" WE: wrapper end (internal)   {{{2
+" Removes guard lines, restores marks y and z, and restores search pattern
+if !hasmapto('<Plug>WrapperEnd')
+ nmap <unique> <SID>WE	<Plug>AlignMapsWrapperEnd
+endif
+nmap <silent> <script> <Plug>AlignMapsWrapperEnd	:call AlignMaps#WrapperEnd()<CR>:set nolz<CR>
+
+" ---------------------------------------------------------------------
+" Complex C-code alignment maps: {{{2
+if !hasmapto('<Plug>AM_a?')   |map <unique> <Leader>a?		<Plug>AM_a?|endif
+if !hasmapto('<Plug>AM_a,')   |map <unique> <Leader>a,		<Plug>AM_a,|endif
+if !hasmapto('<Plug>AM_a<')   |map <unique> <Leader>a<		<Plug>AM_a<|endif
+if !hasmapto('<Plug>AM_a=')   |map <unique> <Leader>a=		<Plug>AM_a=|endif
+if !hasmapto('<Plug>AM_a(')   |map <unique> <Leader>a(		<Plug>AM_a(|endif
+if !hasmapto('<Plug>AM_abox') |map <unique> <Leader>abox	<Plug>AM_abox|endif
+if !hasmapto('<Plug>AM_acom') |map <unique> <Leader>acom	<Plug>AM_acom|endif
+if !hasmapto('<Plug>AM_adcom')|map <unique> <Leader>adcom	<Plug>AM_adcom|endif
+if !hasmapto('<Plug>AM_aocom')|map <unique> <Leader>aocom	<Plug>AM_aocom|endif
+if !hasmapto('<Plug>AM_ascom')|map <unique> <Leader>ascom	<Plug>AM_ascom|endif
+if !hasmapto('<Plug>AM_adec') |map <unique> <Leader>adec	<Plug>AM_adec|endif
+if !hasmapto('<Plug>AM_adef') |map <unique> <Leader>adef	<Plug>AM_adef|endif
+if !hasmapto('<Plug>AM_afnc') |map <unique> <Leader>afnc	<Plug>AM_afnc|endif
+if !hasmapto('<Plug>AM_afnc') |map <unique> <Leader>afnc	<Plug>AM_afnc|endif
+if !hasmapto('<Plug>AM_aunum')|map <unique> <Leader>aunum	<Plug>AM_aenum|endif
+if !hasmapto('<Plug>AM_aenum')|map <unique> <Leader>aenum	<Plug>AM_aunum|endif
+if exists("g:alignmaps_euronumber") && !exists("g:alignmaps_usanumber")
+ if !hasmapto('<Plug>AM_anum')|map <unique> <Leader>anum	<Plug>AM_aenum|endif
+else
+ if !hasmapto('<Plug>AM_anum')|map <unique> <Leader>anum	<Plug>AM_aunum|endif
+endif
+
+map <silent> <script> <Plug>AM_a?		<SID>WS:AlignCtrl mIp1P1lC ? : : : : <CR>:'a,.Align<CR>:'a,'z-1s/\(\s\+\)? /?\1/e<CR><SID>WE
+map <silent> <script> <Plug>AM_a,		<SID>WS:'y,'zs/\(\S\)\s\+/\1 /ge<CR>'yjma'zk:call AlignMaps#CharJoiner(",")<cr>:silent 'y,'zg/,/call AlignMaps#FixMultiDec()<CR>'z:exe "norm \<Plug>AM_adec"<cr><SID>WE
+map <silent> <script> <Plug>AM_a<		<SID>WS:AlignCtrl mIp1P1=l << >><CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_a(       <SID>WS:AlignCtrl mIp0P1=l<CR>:'a,.Align [(,]<CR>:sil 'y+1,'z-1s/\(\s\+\),/,\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_a=		<SID>WS:AlignCtrl mIp1P1=l<CR>:AlignCtrl g :=<CR>:'a,'zAlign :\==<CR><SID>WE
+map <silent> <script> <Plug>AM_abox		<SID>WS:let g:alignmaps_iws=substitute(getline("'a"),'^\(\s*\).*$','\1','e')<CR>:'a,'z-1s/^\s\+//e<CR>:'a,'z-1s/^.*$/@&@/<CR>:AlignCtrl m=p01P0w @<CR>:'a,.Align<CR>:'a,'z-1s/@/ * /<CR>:'a,'z-1s/@$/*/<CR>'aYP:s/./*/g<CR>0r/'zkYp:s/./*/g<CR>0r A/<Esc>:exe "'a-1,'z-1s/^/".g:alignmaps_iws."/e"<CR><SID>WE
+map <silent> <script> <Plug>AM_acom		<SID>WS:'a,.s/\/[*/]\/\=/@&@/e<CR>:'a,.s/\*\//@&/e<CR>:'y,'zs/^\( *\) @/\1@/e<CR>'zk:call AlignMaps#StdAlign(2)<CR>:'y,'zs/^\(\s*\) @/\1/e<CR>:'y,'zs/ @//eg<CR><SID>WE
+map <silent> <script> <Plug>AM_adcom	<SID>WS:'a,.v/^\s*\/[/*]/s/\/[*/]\*\=/@&@/e<CR>:'a,.v/^\s*\/[/*]/s/\*\//@&/e<CR>:'y,'zv/^\s*\/[/*]/s/^\( *\) @/\1@/e<CR>'zk:call AlignMaps#StdAlign(3)<cr>:'y,'zv/^\s*\/[/*]/s/^\(\s*\) @/\1/e<CR>:'y,'zs/ @//eg<CR><SID>WE
+map <silent> <script> <Plug>AM_aocom	<SID>WS:AlignPush<CR>:AlignCtrl g /[*/]<CR>:exe "norm \<Plug>AM_acom"<cr>:AlignPop<CR><SID>WE
+map <silent> <script> <Plug>AM_ascom	<SID>WS:'a,.s/\/[*/]/@&@/e<CR>:'a,.s/\*\//@&/e<CR>:silent! 'a,.g/^\s*@\/[*/]/s/@//ge<CR>:AlignCtrl v ^\s*\/[*/]<CR>:AlignCtrl g \/[*/]<CR>'zk:call AlignMaps#StdAlign(2)<cr>:'y,'zs/^\(\s*\) @/\1/e<CR>:'y,'zs/ @//eg<CR><SID>WE
+map <silent> <script> <Plug>AM_adec		<SID>WS:'a,'zs/\([^ \t/(]\)\([*&]\)/\1 \2/e<CR>:'y,'zv/^\//s/\([^ \t]\)\s\+/\1 /ge<CR>:'y,'zv/^\s*[*/]/s/\([^/][*&]\)\s\+/\1/ge<CR>:'y,'zv/^\s*[*/]/s/^\(\s*\%(\K\k*\s\+\%([a-zA-Z_*(&]\)\@=\)\+\)\([*(&]*\)\s*\([a-zA-Z0-9_()]\+\)\s*\(\(\[.\{-}]\)*\)\s*\(=\)\=\s*\(.\{-}\)\=\s*;/\1@\2#@\3\4@\6@\7;@/e<CR>:'y,'zv/^\s*[*/]/s/\*\/\s*$/@*\//e<CR>:'y,'zv/^\s*[*/]/s/^\s\+\*/@@@@@* /e<CR>:'y,'zv/^\s*[*/]/s/^@@@@@\*\(.*[^*/]\)$/&@*/e<CR>'yjma'zk:AlignCtrl v ^\s*[*/#]<CR>:call AlignMaps#StdAlign(1)<cr>:'y,'zv/^\s*[*/]/s/@ //ge<CR>:'y,'zv/^\s*[*/]/s/\(\s*\);/;\1/e<CR>:'y,'zv/^#/s/# //e<CR>:'y,'zv/^\s\+[*/#]/s/\([^/*]\)\(\*\+\)\( \+\)/\1\3\2/e<CR>:'y,'zv/^\s\+[*/#]/s/\((\+\)\( \+\)\*/\2\1*/e<CR>:'y,'zv/^\s\+[*/#]/s/^\(\s\+\) \*/\1*/e<CR>:'y,'zv/^\s\+[*/#]/s/[ \t@]*$//e<CR>:'y,'zs/^[*]/ */e<CR><SID>WE
+map <silent> <script> <Plug>AM_adef		<SID>WS:AlignPush<CR>:AlignCtrl v ^\s*\(\/\*\<bar>\/\/\)<CR>:'a,.v/^\s*\(\/\*\<bar>\/\/\)/s/^\(\s*\)#\(\s\)*define\s*\(\I[a-zA-Z_0-9(),]*\)\s*\(.\{-}\)\($\<Bar>\/\*\)/#\1\2define @\3@\4@\5/e<CR>:'a,.v/^\s*\(\/\*\<bar>\/\/\)/s/\($\<Bar>\*\/\)/@&/e<CR>'zk:call AlignMaps#StdAlign(1)<cr>'yjma'zk:'a,.v/^\s*\(\/\*\<bar>\/\/\)/s/ @//g<CR><SID>WE
+map <silent> <script> <Plug>AM_afnc		:<c-u>set lz<CR>:silent call AlignMaps#Afnc()<CR>:set nolz<CR>
+map <silent> <script> <Plug>AM_aunum	<SID>WS:'a,'zs/\%([0-9.]\)\s\+\zs\([-+.]\=\d\)/@\1/ge<CR>:'a,'zs/\(\(^\|\s\)\d\+\)\(\s\+\)@/\1@\3@/ge<CR>:'a,'zs/\.@/\.0@/ge<CR>:AlignCtrl wmp0P0r<CR>:'a,'zAlign [.@]<CR>:'a,'zs/@/ /ge<CR>:'a,'zs/\(\.\)\(\s\+\)\([0-9.,eE+]\+\)/\1\3\2/ge<CR>:'a,'zs/\([eE]\)\(\s\+\)\([0-9+\-+]\+\)/\1\3\2/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_aenum	<SID>WS:'a,'zs/\%([0-9.]\)\s\+\([-+]\=\d\)/\1@\2/ge<CR>:'a,'zs/\.@/\.0@/ge<CR>:AlignCtrl wmp0P0r<CR>:'a,'zAlign [,@]<CR>:'a,'zs/@/ /ge<CR>:'a,'zs/\(,\)\(\s\+\)\([-0-9.,eE+]\+\)/\1\3\2/ge<CR>:'a,'zs/\([eE]\)\(\s\+\)\([0-9+\-+]\+\)/\1\3\2/ge<CR><SID>WE
+
+" ---------------------------------------------------------------------
+" html table alignment	{{{2
+if !hasmapto('<Plug>AM_Htd')|map <unique> <Leader>Htd	<Plug>AM_Htd|endif
+map <silent> <script> <Plug>AM_Htd <SID>WS:'y,'zs%<[tT][rR]><[tT][dD][^>]\{-}>\<Bar></[tT][dD]><[tT][dD][^>]\{-}>\<Bar></[tT][dD]></[tT][rR]>%@&@%g<CR>'yjma'zk:AlignCtrl m=Ilp1P0 @<CR>:'a,.Align<CR>:'y,'zs/ @/@/<CR>:'y,'zs/@ <[tT][rR]>/<[tT][rR]>/ge<CR>:'y,'zs/@//ge<CR><SID>WE
+
+" ---------------------------------------------------------------------
+" character-based right-justified alignment maps {{{2
+if !hasmapto('<Plug>AM_T|')|map <unique> <Leader>T|		<Plug>AM_T||endif
+if !hasmapto('<Plug>AM_T#')	 |map <unique> <Leader>T#		<Plug>AM_T#|endif
+if !hasmapto('<Plug>AM_T,')	 |map <unique> <Leader>T,		<Plug>AM_T,o|endif
+if !hasmapto('<Plug>AM_Ts,') |map <unique> <Leader>Ts,		<Plug>AM_Ts,|endif
+if !hasmapto('<Plug>AM_T:')	 |map <unique> <Leader>T:		<Plug>AM_T:|endif
+if !hasmapto('<Plug>AM_T;')	 |map <unique> <Leader>T;		<Plug>AM_T;|endif
+if !hasmapto('<Plug>AM_T<')	 |map <unique> <Leader>T<		<Plug>AM_T<|endif
+if !hasmapto('<Plug>AM_T=')	 |map <unique> <Leader>T=		<Plug>AM_T=|endif
+if !hasmapto('<Plug>AM_T?')	 |map <unique> <Leader>T?		<Plug>AM_T?|endif
+if !hasmapto('<Plug>AM_T@')	 |map <unique> <Leader>T@		<Plug>AM_T@|endif
+if !hasmapto('<Plug>AM_Tab') |map <unique> <Leader>Tab		<Plug>AM_Tab|endif
+if !hasmapto('<Plug>AM_Tsp') |map <unique> <Leader>Tsp		<Plug>AM_Tsp|endif
+if !hasmapto('<Plug>AM_T~')	 |map <unique> <Leader>T~		<Plug>AM_T~|endif
+
+map <silent> <script> <Plug>AM_T| <SID>WS:AlignCtrl mIp0P0=r <Bar><CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_T#   <SID>WS:AlignCtrl mIp0P0=r #<CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_T,   <SID>WS:AlignCtrl mIp0P1=r ,<CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_Ts,  <SID>WS:AlignCtrl mIp0P1=r ,<CR>:'a,.Align<CR>:'a,.s/\(\s*\),/,\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_T:   <SID>WS:AlignCtrl mIp1P1=r :<CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_T;   <SID>WS:AlignCtrl mIp0P0=r ;<CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_T<   <SID>WS:AlignCtrl mIp0P0=r <<CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_T=   <SID>WS:'a,'z-1s/\s\+\([*/+\-%<Bar>&\~^]\==\)/ \1/e<CR>:'a,'z-1s@ \+\([*/+\-%<Bar>&\~^]\)=@\1=@ge<CR>:'a,'z-1s/; */;@/e<CR>:'a,'z-1s/==/\="\<Char-0x0f>\<Char-0x0f>"/ge<CR>:'a,'z-1s/!=/\x="!\<Char-0x0f>"/ge<CR>:AlignCtrl mIp1P1=r = @<CR>:AlignCtrl g =<CR>:'a,'z-1Align<CR>:'a,'z-1s/; *@/;/e<CR>:'a,'z-1s/; *$/;/e<CR>:'a,'z-1s@\([*/+\-%<Bar>&\~^]\)\( \+\)=@\2\1=@ge<CR>:'a,'z-1s/\( \+\);/;\1/ge<CR>:'a,'z-1s/\xff/=/ge<CR><SID>WE:exe "norm <Plug>acom"
+map <silent> <script> <Plug>AM_T?   <SID>WS:AlignCtrl mIp0P0=r ?<CR>:'a,.Align<CR>:'y,'zs/ \( *\);/;\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_T@   <SID>WS:AlignCtrl mIp0P0=r @<CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_Tab  <SID>WS:'a,.s/^\(\t*\)\(.*\)/\=submatch(1).escape(substitute(submatch(2),'\t','@','g'),'\')/<CR>:AlignCtrl mI=r @<CR>:'a,.Align<CR>:'y+1,'z-1s/@/ /g<CR><SID>WE
+map <silent> <script> <Plug>AM_Tsp  <SID>WS:'a,.s/^\(\s*\)\(.*\)/\=submatch(1).escape(substitute(submatch(2),'\s\+','@','g'),'\')/<CR>:AlignCtrl mI=r @<CR>:'a,.Align<CR>:'y+1,'z-1s/@/ /g<CR><SID>WE
+map <silent> <script> <Plug>AM_T~   <SID>WS:AlignCtrl mIp0P0=r ~<CR>:'a,.Align<CR>:'y,'zs/ \( *\);/;\1/ge<CR><SID>WE
+
+" ---------------------------------------------------------------------
+" character-based left-justified alignment maps {{{2
+if !hasmapto('<Plug>AM_t|')	|map <unique> <Leader>t|	<Plug>AM_t||endif
+if !hasmapto('<Plug>AM_t#')		|map <unique> <Leader>t#	<Plug>AM_t#|endif
+if !hasmapto('<Plug>AM_t,')		|map <unique> <Leader>t,	<Plug>AM_t,|endif
+if !hasmapto('<Plug>AM_t:')		|map <unique> <Leader>t:	<Plug>AM_t:|endif
+if !hasmapto('<Plug>AM_t;')		|map <unique> <Leader>t;	<Plug>AM_t;|endif
+if !hasmapto('<Plug>AM_t<')		|map <unique> <Leader>t<	<Plug>AM_t<|endif
+if !hasmapto('<Plug>AM_t=')		|map <unique> <Leader>t=	<Plug>AM_t=|endif
+if !hasmapto('<Plug>AM_ts,')	|map <unique> <Leader>ts,	<Plug>AM_ts,|endif
+if !hasmapto('<Plug>AM_ts:')	|map <unique> <Leader>ts:	<Plug>AM_ts:|endif
+if !hasmapto('<Plug>AM_ts;')	|map <unique> <Leader>ts;	<Plug>AM_ts;|endif
+if !hasmapto('<Plug>AM_ts<')	|map <unique> <Leader>ts<	<Plug>AM_ts<|endif
+if !hasmapto('<Plug>AM_ts=')	|map <unique> <Leader>ts=	<Plug>AM_ts=|endif
+if !hasmapto('<Plug>AM_w=')		|map <unique> <Leader>w=	<Plug>AM_w=|endif
+if !hasmapto('<Plug>AM_t?')		|map <unique> <Leader>t?	<Plug>AM_t?|endif
+if !hasmapto('<Plug>AM_t~')		|map <unique> <Leader>t~	<Plug>AM_t~|endif
+if !hasmapto('<Plug>AM_t@')		|map <unique> <Leader>t@	<Plug>AM_t@|endif
+if !hasmapto('<Plug>AM_m=')		|map <unique> <Leader>m=	<Plug>AM_m=|endif
+if !hasmapto('<Plug>AM_tab')	|map <unique> <Leader>tab	<Plug>AM_tab|endif
+if !hasmapto('<Plug>AM_tml')	|map <unique> <Leader>tml	<Plug>AM_tml|endif
+if !hasmapto('<Plug>AM_tsp')	|map <unique> <Leader>tsp	<Plug>AM_tsp|endif
+if !hasmapto('<Plug>AM_tsq')	|map <unique> <Leader>tsq	<Plug>AM_tsq|endif
+if !hasmapto('<Plug>AM_tt')		|map <unique> <Leader>tt	<Plug>AM_tt|endif
+
+map <silent> <script> <Plug>AM_t|		<SID>WS:AlignCtrl mIp0P0=l <Bar><CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_t#		<SID>WS:AlignCtrl mIp0P0=l #<CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_t,		<SID>WS:AlignCtrl mIp0P1=l ,<CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_t:		<SID>WS:AlignCtrl mIp1P1=l :<CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_t;		<SID>WS:AlignCtrl mIp0P1=l ;<CR>:'a,.Align<CR>:sil 'y,'zs/\( *\);/;\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_t<		<SID>WS:AlignCtrl mIp0P0=l <<CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_t=		<SID>WS:call AlignMaps#Equals()<CR><SID>WE
+map <silent> <script> <Plug>AM_ts,		<SID>WS:AlignCtrl mIp0P1=l #<CR>:'a,.Align<CR>:sil 'y+1,'z-1s/\(\s*\)#/,\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_ts,		<SID>WS:AlignCtrl mIp0P1=l ,<CR>:'a,.Align<CR>:sil 'y+1,'z-1s/\(\s*\),/,\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_ts:		<SID>WS:AlignCtrl mIp1P1=l :<CR>:'a,.Align<CR>:sil 'y+1,'z-1s/\(\s*\):/:\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_ts;		<SID>WS:AlignCtrl mIp1P1=l ;<CR>:'a,.Align<CR>:sil 'y+1,'z-1s/\(\s*\);/;\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_ts<		<SID>WS:AlignCtrl mIp1P1=l <<CR>:'a,.Align<CR>:sil 'y+1,'z-1s/\(\s*\)</<\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_ts=		<SID>WS:AlignCtrl mIp1P1=l =<CR>:'a,.Align<CR>:sil 'y+1,'z-1s/\(\s*\)=/=\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_w=		<SID>WS:'a,'zg/=/s/\s\+\([*/+\-%<Bar>&\~^]\==\)/ \1/e<CR>:'a,'zg/=/s@ \+\([*/+\-%<Bar>&\~^]\)=@\1=@ge<CR>:'a,'zg/=/s/==/\="\<Char-0x0f>\<Char-0x0f>"/ge<CR>:'a,'zg/=/s/!=/\="!\<Char-0x0f>"/ge<CR>'zk:AlignCtrl mWp1P1=l =<CR>:AlignCtrl g =<CR>:'a,'z-1g/=/Align<CR>:'a,'z-1g/=/s@\([*/+\-%<Bar>&\~^!=]\)\( \+\)=@\2\1=@ge<CR>:'a,'z-1g/=/s/\( \+\);/;\1/ge<CR>:'a,'z-1v/^\s*\/[*/]/s/\/[*/]/@&@/e<CR>:'a,'z-1v/^\s*\/[*/]/s/\*\//@&/e<CR>'zk:call AlignMaps#StdAlign(1)<cr>:'y,'zs/^\(\s*\) @/\1/e<CR>:'a,'z-1g/=/s/\xff/=/ge<CR>:'y,'zg/=/s/ @//eg<CR><SID>WE
+map <silent> <script> <Plug>AM_t?		<SID>WS:AlignCtrl mIp0P0=l ?<CR>:'a,.Align<CR>:.,'zs/ \( *\);/;\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_t~		<SID>WS:AlignCtrl mIp0P0=l ~<CR>:'a,.Align<CR>:'y,'zs/ \( *\);/;\1/ge<CR><SID>WE
+map <silent> <script> <Plug>AM_t@		<SID>WS::call AlignMaps#StdAlign(1)<cr>:<SID>WE
+map <silent> <script> <Plug>AM_m=		<SID>WS:'a,'zs/\s\+\([*/+\-%<Bar>&\~^]\==\)/ \1/e<CR>:'a,'zs@ \+\([*/+\-%<Bar>&\~^]\)=@\1=@ge<CR>:'a,'zs/==/\="\<Char-0x0f>\<Char-0x0f>"/ge<CR>:'a,'zs/!=/\="!\<Char-0x0f>"/ge<CR>'zk:AlignCtrl mIp1P1=l =<CR>:AlignCtrl g =<CR>:'a,'z-1Align<CR>:'a,'z-1s@\([*/+\-%<Bar>&\~^!=]\)\( \+\)=@\2\1=@ge<CR>:'a,'z-1s/\( \+\);/;\1/ge<CR>:'a,'z-s/%\ze[^=]/ @%@ /e<CR>'zk:call AlignMaps#StdAlign(1)<cr>:'y,'zs/^\(\s*\) @/\1/e<CR>:'a,'z-1s/\xff/=/ge<CR>:'y,'zs/ @//eg<CR><SID>WE
+map <silent> <script> <Plug>AM_tab		<SID>WS:'a,.s/^\(\t*\)\(.*\)$/\=submatch(1).escape(substitute(submatch(2),'\t',"\<Char-0x0f>",'g'),'\')/<CR>:if &ts == 1<bar>exe "AlignCtrl mI=lp0P0 \<Char-0x0f>"<bar>else<bar>exe "AlignCtrl mI=l \<Char-0x0f>"<bar>endif<CR>:'a,.Align<CR>:exe "'y+1,'z-1s/\<Char-0x0f>/".((&ts == 1)? '\t' : ' ')."/g"<CR><SID>WE
+map <silent> <script> <Plug>AM_tml		<SID>WS:AlignCtrl mWp1P0=l \\\@<!\\\s*$<CR>:'a,.Align<CR><SID>WE
+map <silent> <script> <Plug>AM_tsp		<SID>WS:'a,.s/^\(\s*\)\(.*\)/\=submatch(1).escape(substitute(submatch(2),'\s\+','@','g'),'\')/<CR>:AlignCtrl mI=lp0P0 @<CR>:'a,.Align<CR>:'y+1,'z-1s/@/ /g<CR><SID>WE
+map <silent> <script> <Plug>AM_tsq		<SID>WS:'a,.AlignReplaceQuotedSpaces<CR>:'a,.s/^\(\s*\)\(.*\)/\=submatch(1).substitute(submatch(2),'\s\+','@','g')/<CR>:AlignCtrl mIp0P0=l @<CR>:'a,.Align<CR>:'y+1,'z-1s/[%@]/ /g<CR><SID>WE
+map <silent> <script> <Plug>AM_tt		<SID>WS:AlignCtrl mIp1P1=l \\\@<!& \\\\<CR>:'a,.Align<CR><SID>WE
+
+" =====================================================================
+" Menu Support: {{{1
+"   ma ..move.. use menu
+"   v V or ctrl-v ..move.. use menu
+if has("menu") && has("gui_running") && &go =~ 'm' && !exists("s:firstmenu")
+ let s:firstmenu= 1
+ if !exists("g:DrChipTopLvlMenu")
+  let g:DrChipTopLvlMenu= "DrChip."
+ endif
+ if g:DrChipTopLvlMenu != ""
+  let s:mapleader = exists("g:mapleader")? g:mapleader : '\'
+  let s:emapleader= escape(s:mapleader,'\ ')
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.<<\ and\ >><tab>'.s:emapleader.'a<	'.s:mapleader.'a<'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Assignment\ =<tab>'.s:emapleader.'t=	'.s:mapleader.'t='
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Assignment\ :=<tab>'.s:emapleader.'a=	'.s:mapleader.'a='
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Backslashes<tab>'.s:emapleader.'tml	'.s:mapleader.'tml'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Breakup\ Comma\ Declarations<tab>'.s:emapleader.'a,	'.s:mapleader.'a,'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.C\ Comment\ Box<tab>'.s:emapleader.'abox	'.s:mapleader.'abox'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Commas<tab>'.s:emapleader.'t,	'.s:mapleader.'t,'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Commas<tab>'.s:emapleader.'ts,	'.s:mapleader.'ts,'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Commas\ With\ Strings<tab>'.s:emapleader.'tsq	'.s:mapleader.'tsq'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Comments<tab>'.s:emapleader.'acom	'.s:mapleader.'acom'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Comments\ Only<tab>'.s:emapleader.'aocom	'.s:mapleader.'aocom'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Declaration\ Comments<tab>'.s:emapleader.'adcom	'.s:mapleader.'adcom'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Declarations<tab>'.s:emapleader.'adec	'.s:mapleader.'adec'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Definitions<tab>'.s:emapleader.'adef	'.s:mapleader.'adef'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Function\ Header<tab>'.s:emapleader.'afnc	'.s:mapleader.'afnc'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Html\ Tables<tab>'.s:emapleader.'Htd	'.s:mapleader.'Htd'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.(\.\.\.)?\.\.\.\ :\ \.\.\.<tab>'.s:emapleader.'a?	'.s:mapleader.'a?'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Numbers<tab>'.s:emapleader.'anum	'.s:mapleader.'anum'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Numbers\ (American-Style)<tab>'.s:emapleader.'aunum	<Leader>aunum	'.s:mapleader.'aunum	<Leader>aunum'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Numbers\ (Euro-Style)<tab>'.s:emapleader.'aenum	'.s:mapleader.'aenum'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Spaces\ (Left\ Justified)<tab>'.s:emapleader.'tsp	'.s:mapleader.'tsp'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Spaces\ (Right\ Justified)<tab>'.s:emapleader.'Tsp	'.s:mapleader.'Tsp'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Statements\ With\ Percent\ Style\ Comments<tab>'.s:emapleader.'m=	'.s:mapleader.'m='
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Symbol\ <<tab>'.s:emapleader.'t<	'.s:mapleader.'t<'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Symbol\ \|<tab>'.s:emapleader.'t\|	'.s:mapleader.'t|'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Symbol\ @<tab>'.s:emapleader.'t@	'.s:mapleader.'t@'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Symbol\ #<tab>'.s:emapleader.'t#	'.s:mapleader.'t#'
+  exe 'menu '.g:DrChipTopLvlMenu.'AlignMaps.Tabs<tab>'.s:emapleader.'tab	'.s:mapleader.'tab'
+  unlet s:mapleader
+  unlet s:emapleader
+ endif
+endif
+
+" =====================================================================
+"  Restore: {{{1
+let &cpo= s:keepcpo
+unlet s:keepcpo
+
+" ==============================================================================
+"  Modelines: {{{1
+" vim: ts=4 nowrap fdm=marker

data/lib/utils/config/vim/plugin/AlignPlugin.vim

@@ -0,0 +1,41 @@
+" AlignPlugin: tool to align multiple fields based on one or more separators
+"   Author:	 Charles E. Campbell, Jr.
+"   Date:    Nov 02, 2008
+" GetLatestVimScripts: 294 1 :AutoInstall: Align.vim
+" GetLatestVimScripts: 1066 1 :AutoInstall: cecutil.vim
+" Copyright:    Copyright (C) 1999-2007 Charles E. Campbell, Jr. {{{1
+"               Permission is hereby granted to use and distribute this code,
+"               with or without modifications, provided that this copyright
+"               notice is copied with it. Like anything else that's free,
+"               Align.vim is provided *as is* and comes with no warranty
+"               of any kind, either expressed or implied. By using this
+"               plugin, you agree that in no event will the copyright
+"               holder be liable for any damages resulting from the use
+"               of this software.
+"
+" Romans 1:16,17a : For I am not ashamed of the gospel of Christ, for it is {{{1
+" the power of God for salvation for everyone who believes; for the Jew first,
+" and also for the Greek.  For in it is revealed God's righteousness from
+" faith to faith.
+" ---------------------------------------------------------------------
+" Load Once: {{{1
+if &cp || exists("g:loaded_AlignPlugin")
+ finish
+endif
+let g:loaded_AlignPlugin = "v35"
+let s:keepcpo            = &cpo
+set cpo&vim
+
+" ---------------------------------------------------------------------
+" Public Interface: {{{1
+com! -bang -range -nargs=* Align <line1>,<line2>call Align#Align(<bang>0,<q-args>)
+com!       -range -nargs=0 AlignReplaceQuotedSpaces <line1>,<line2>call Align#AlignReplaceQuotedSpaces()
+com!              -nargs=* AlignCtrl call Align#AlignCtrl(<q-args>)
+com!              -nargs=0 AlignPush call Align#AlignPush()
+com!              -nargs=0 AlignPop  call Align#AlignPop()
+
+" ---------------------------------------------------------------------
+"  Restore: {{{1
+let &cpo= s:keepcpo
+unlet s:keepcpo
+" vim: ts=4 fdm=marker

data/lib/utils/config/vim/plugin/Decho.vim

@@ -0,0 +1,592 @@
+" Decho.vim:   Debugging support for VimL
+" Maintainer:  Charles E. Campbell, Jr. PhD <cec@NgrOyphSon.gPsfAc.nMasa.gov>
+" Date:        Oct 23, 2008
+" Version:     20
+"
+" Usage: {{{1
+"   Decho "a string"
+"   call Decho("another string")
+"   let g:decho_bufname = "ANewDBGBufName"
+"   let g:decho_bufenter= 1    " tells Decho to ignore BufEnter, WinEnter,
+"                              " WinLeave events while Decho is working
+"   call Decho("one","thing","after","another")
+"   DechoOn     : removes any first-column '"' from lines containing Decho
+"   DechoOff    : inserts a '"' into the first-column in lines containing Decho
+"   DechoMsgOn  : use echomsg instead of DBG buffer
+"   DechoMsgOff : turn debugging off
+"   DechoRemOn  : turn remote Decho messaging on
+"   DechoRemOff : turn remote Decho messaging off
+"   DechoVarOn [varname] : use variable to write debugging messages to
+"   DechoVarOff : turn debugging off
+"   DechoTabOn  : turn debugging on (uses a separate tab)
+"   DechoTabOff : turn debugging off
+"
+" GetLatestVimScripts: 120 1 :AutoInstall: Decho.vim
+" GetLatestVimScripts: 1066 1 :AutoInstall: cecutil.vim
+
+" ---------------------------------------------------------------------
+" Load Once: {{{1
+if exists("g:loaded_Decho") || &cp
+ finish
+endif
+let g:loaded_Decho = "v20"
+let s:keepcpo      = &cpo
+set cpo&vim
+
+" ---------------------------------------------------------------------
+"  Default Values For Variables: {{{1
+if !exists("g:decho_bufname")
+ let g:decho_bufname= "DBG"
+endif
+if !exists("s:decho_depth")
+ let s:decho_depth  = 0
+endif
+if !exists("g:decho_winheight")
+ let g:decho_winheight= 5
+endif
+if !exists("g:decho_bufenter")
+ let g:decho_bufenter= 0
+endif
+if !exists("g:dechomode") || !exists("s:DECHOWIN")
+ let s:DECHOWIN = 1
+ let s:DECHOMSG = 2
+ let s:DECHOVAR = 3
+ let s:DECHOREM = 4
+ let s:DECHOTAB = 5
+ let g:dechomode= s:DECHOWIN
+endif
+if !exists("g:dechovarname")
+ let g:dechovarname = "g:dechovar"
+endif
+
+" ---------------------------------------------------------------------
+"  User Interface: {{{1
+com! -nargs=+ -complete=expression Decho	call Decho(<args>)
+com! -nargs=+ -complete=expression Dredir	call Dredir(<args>)
+com! -nargs=0 -range=% DechoOn				call DechoOn(<line1>,<line2>)
+com! -nargs=0 -range=% DechoOff				call DechoOff(<line1>,<line2>)
+com! -nargs=0 Dhide    						call s:Dhide(1)
+com! -nargs=0 Dshow    						call s:Dhide(0)
+com! -nargs=0 DechoMsgOn					call s:DechoMsg(1,expand("<sfile>"))
+com! -nargs=0 DechoMsgOff					call s:DechoMsg(0)
+if has("clientserver") && executable("gvim")
+ com! -nargs=0 DechoRemOn					call s:DechoRemote(1,expand("<sfile>"))
+ com! -nargs=0 DechoRemOff					call s:DechoRemote(0)
+endif
+com! -nargs=? DechoSep						call DechoSep(<args>)
+com! -nargs=? Dsep						    call DechoSep(<args>)
+com! -nargs=? DechoVarOn					call s:DechoVarOn(expand("<sfile>"),<args>)
+com! -nargs=0 DechoVarOff					call s:DechoVarOff()
+if v:version >= 700
+ com! -nargs=? DechoTabOn                   set lz|call s:DechoTab(1,expand("<sfile>"))|set nolz
+ com! -nargs=? DechoTabOff                  set lz|call s:DechoTab(0)|set nolz
+endif
+com! -nargs=0 DechoPause					call DechoPause()
+au Filetype Decho nmap <silent> <buffer> <F1> :setlocal noro ma<cr>
+
+" ---------------------------------------------------------------------
+" Decho: the primary debugging function: splits the screen as necessary and {{{1
+"        writes messages to a small window (g:decho_winheight lines)
+"        on the bottom of the screen
+fun! Decho(...)
+ 
+  " make sure that SaveWinPosn() and RestoreWinPosn() are available
+  if !exists("g:loaded_cecutil")
+   runtime plugin/cecutil.vim
+   if !exists("g:loaded_cecutil") && exists("g:loaded_AsNeeded")
+   	AN SWP
+   endif
+   if !exists("g:loaded_cecutil")
+   	echoerr "***Decho*** need to load <cecutil.vim>"
+	return
+   endif
+  endif
+
+  " open DBG window (if dechomode is dechowin)
+  if g:dechomode == s:DECHOWIN
+   let swp   = SaveWinPosn(0)
+   let curbuf= bufnr("%")
+   if g:decho_bufenter
+    let eikeep= &ei
+	let eakeep= &ea
+	set ei=BufEnter,WinEnter,WinLeave,ShellCmdPost,FocusGained noea
+   endif
+ 
+   " As needed, create/switch-to the DBG buffer
+   if !bufexists(g:decho_bufname) && bufnr("*/".g:decho_bufname."$") == -1
+    " if requested DBG-buffer doesn't exist, create a new one
+    " at the bottom of the screen.
+	exe "keepjumps silent! bot ".g:decho_winheight."new ".fnameescape(g:decho_bufname)
+    setlocal noswf
+	keepjumps silent! %d
+ 
+   elseif bufwinnr(g:decho_bufname) > 0
+    " if requested DBG-buffer exists in a window,
+    " go to that window (by window number)
+    exe "keepjumps ".bufwinnr(g:decho_bufname)."wincmd W"
+    exe "res ".g:decho_winheight
+ 
+   else
+    " user must have closed the DBG-buffer window.
+    " create a new one at the bottom of the screen.
+    exe "keepjumps silent bot ".g:decho_winheight."new"
+    setlocal noswf
+    exe "keepjumps b ".bufnr(g:decho_bufname)
+   endif
+ 
+   set ft=Decho
+   setlocal noswapfile noro nobl fo=n2croql
+ 
+   "  make sure DBG window is on the bottom
+   wincmd J
+  endif
+
+  " Build Message
+  let i  = 1
+  let msg= ""
+  while i <= a:0
+   try
+    exe "let msg=msg.a:".i
+   catch /^Vim\%((\a\+)\)\=:E730/
+       " looks like a:i is a list
+    exe "let msg=msg.string(a:".i.")"
+   endtry
+   if i < a:0
+    let msg=msg." "
+   endif
+   let i=i+1
+  endwhile
+
+  " Initialize message
+  let smsg   = ""
+  let idepth = 0
+  while idepth < s:decho_depth
+   let smsg   = "|".smsg
+   let idepth = idepth + 1
+  endwhile
+
+  " Handle special characters (\t \r \n)
+  " and append msg to smsg
+  let i    = 1
+  while msg != ""
+   let chr  = strpart(msg,0,1)
+   let msg  = strpart(msg,1)
+   if char2nr(chr) < 32
+   	let smsg = smsg.'^'.nr2char(64+char2nr(chr))
+   else
+    let smsg = smsg.chr
+   endif
+  endwhile
+
+"  echomsg "g:dechomode=".g:dechomode
+  if g:dechomode == s:DECHOMSG
+   " display message with echomsg
+   exe "echomsg '".substitute(smsg,"'","'.\"'\".'","ge")."'"
+
+  elseif g:dechomode == s:DECHOVAR
+   " "display" message by appending to variable named by g:dechovarname
+   let smsg= substitute(smsg,"'","''","ge")
+   if exists(g:dechovarname)
+    exe "let ".g:dechovarname."= ".g:dechovarname.".'\n".smsg."'"
+   else
+    exe "let ".g:dechovarname."= '".smsg."'"
+   endif
+
+  elseif g:dechomode == s:DECHOREM
+   " display message by appending it to remote DECHOREMOTE vim server
+   let smsg= substitute(smsg,"\<esc>","\<c-v>\<esc>","ge")
+   try
+    call remote_send("DECHOREMOTE",':set ma fo-=at'."\<cr>".'Go'.smsg."\<esc>".':set noma nomod'."\<cr>")
+   catch /^Vim\%((\a\+)\)\=:E241/
+       let g:dechomode= s:DECHOWIN
+   endtry
+
+  elseif g:dechomode == s:DECHOTAB
+   " display message by appending it to the debugging tab window
+   let eikeep= &ei
+   set ei=all
+   let g:dechotabcur = tabpagenr()
+   exe "silent! tabn ".g:dechotabnr
+   if expand("%") != "Decho Tab"
+	" looks like a new tab has been inserted -- look for the "Decho Tab" tab
+	let g:dechotabnr= 1
+	silent! tabn 1
+	while expand("%") != "Decho Tab"
+	 let g:dechotabnr= g:dechotabnr + 1
+	 if g:dechotabnr > tabpagenr("$")
+	  " re-enable the "Decho Tab" tab -- looks like it was closed!
+	  call s:DechoTab(1)
+	  break
+	 endif
+     exe "tabn".g:dechotabnr
+    endwhile
+   endif
+   " append message to "Decho Tab" tab
+   setlocal ma noro
+   call setline(line("$")+1,smsg)
+   setlocal noma nomod
+   " restore tab# to original user tab
+   exe "tabn ".g:dechotabcur
+   let &ei= eikeep
+
+  else
+   " Write Message to DBG buffer
+   setlocal ma
+   keepjumps $
+   keepjumps let res= append("$",smsg)
+   setlocal nomod
+ 
+   " Put cursor at bottom of DBG window, then return to original window
+   exe "res ".g:decho_winheight
+   keepjumps norm! G
+   if exists("g:decho_hide") && g:decho_hide > 0
+    setlocal hidden
+    q
+   endif
+   keepjumps wincmd p
+   if exists("swp")
+    call RestoreWinPosn(swp)
+   endif
+ 
+   if g:decho_bufenter
+    let &ei= eikeep
+	let &ea= eakeep
+   endif
+  endif
+endfun
+
+" ---------------------------------------------------------------------
+"  Dfunc: just like Decho, except that it also bumps up the depth {{{1
+"         It also appends a "{" to facilitate use of %
+"         Usage:  call Dfunc("functionname([opt arglist])")
+fun! Dfunc(...)
+  " Build Message
+  let i  = 1
+  let msg= ""
+  while i <= a:0
+   exe "let msg=msg.a:".i
+   if i < a:0
+    let msg=msg." "
+   endif
+   let i=i+1
+  endwhile
+  let msg= msg." {"
+  call Decho(msg)
+  let s:decho_depth= s:decho_depth + 1
+  let s:Dfunclist_{s:decho_depth}= substitute(msg,'[( \t].*$','','')
+endfun
+
+" ---------------------------------------------------------------------
+"  Dret: just like Decho, except that it also bumps down the depth {{{1
+"        It also appends a "}" to facilitate use of %
+"         Usage:  call Dret("functionname [optional return] [: optional extra info]")
+fun! Dret(...)
+  " Build Message
+  let i  = 1
+  let msg= ""
+  while i <= a:0
+   exe "let msg=msg.a:".i
+   if i < a:0
+    let msg=msg." "
+   endif
+   let i=i+1
+  endwhile
+  let msg= msg." }"
+  call Decho("return ".msg)
+  if s:decho_depth > 0
+   let retfunc= substitute(msg,'\s.*$','','e')
+   if  retfunc != s:Dfunclist_{s:decho_depth}
+   	echoerr "Dret: appears to be called by<".s:Dfunclist_{s:decho_depth}."> but returning from<".retfunc.">"
+   endif
+   unlet s:Dfunclist_{s:decho_depth}
+   let s:decho_depth= s:decho_depth - 1
+  endif
+endfun
+
+" ---------------------------------------------------------------------
+" DechoOn: {{{1
+fun! DechoOn(line1,line2)
+  let ickeep= &ic
+  set noic
+  let swp    = SaveWinPosn(0)
+  let dbgpat = '\<D\%(echo\|func\|redir\|ret\|echo\%(Msg\|Rem\|Tab\|Var\)O\%(n\|ff\)\)\>'
+  if search(dbgpat,'cnw') == 0
+   echoerr "this file<".expand("%")."> does not contain any Decho/Dfunc/Dret commands or function calls!"
+  else
+   exe "keepjumps ".a:line1.",".a:line2.'g/'.dbgpat.'/s/^"\+//'
+  endif
+  call RestoreWinPosn(swp)
+  let &ic= ickeep
+endfun
+
+" ---------------------------------------------------------------------
+" DechoOff: {{{1
+fun! DechoOff(line1,line2)
+  let ickeep= &ic
+  set noic
+  let swp=SaveWinPosn(0)
+  let swp= SaveWinPosn(0)
+  exe "keepjumps ".a:line1.",".a:line2.'g/\<D\%(echo\|func\|redir\|ret\|echo\%(Msg\|Rem\|Tab\|Var\)O\%(n\|ff\)\)\>/s/^[^"]/"&/'
+  call RestoreWinPosn(swp)
+  let &ic= ickeep
+endfun
+
+" ---------------------------------------------------------------------
+" DechoDepth: allow user to force depth value {{{1
+fun! DechoDepth(depth)
+  let s:decho_depth= a:depth
+endfun
+
+" ---------------------------------------------------------------------
+" s:DechoMsg: {{{2
+fun! s:DechoMsg(onoff,...)
+"  call Dfunc("s:DechoMsg(onoff=".a:onoff.") a:0=".a:0)
+  if a:onoff
+   let g:dechomode = s:DECHOMSG
+   let g:dechofile = (a:0 > 0)? a:1 : ""
+  else
+   let g:dechomode= s:DECHOWIN
+  endif
+"  call Dret("s:DechoMsg")
+endfun
+
+" ---------------------------------------------------------------------
+" Dhide: (un)hide DBG buffer {{{1
+fun! <SID>Dhide(hide)
+
+  if !bufexists(g:decho_bufname) && bufnr("*/".g:decho_bufname."$") == -1
+   " DBG-buffer doesn't exist, simply set g:decho_hide
+   let g:decho_hide= a:hide
+
+  elseif bufwinnr(g:decho_bufname) > 0
+   " DBG-buffer exists in a window, so its not currently hidden
+   if a:hide == 0
+   	" already visible!
+    let g:decho_hide= a:hide
+   else
+   	" need to hide window.  Goto window and make hidden
+	let curwin = winnr()
+	let dbgwin = bufwinnr(g:decho_bufname)
+    exe bufwinnr(g:decho_bufname)."wincmd W"
+	setlocal hidden
+	q
+	if dbgwin != curwin
+	 " return to previous window
+     exe curwin."wincmd W"
+	endif
+   endif
+
+  else
+   " The DBG-buffer window is currently hidden.
+   if a:hide == 0
+	let curwin= winnr()
+    exe "silent bot ".g:decho_winheight."new"
+    setlocal bh=wipe
+    exe "b ".bufnr(g:decho_bufname)
+    exe curwin."wincmd W"
+   else
+   	let g:decho_hide= a:hide
+   endif
+  endif
+  let g:decho_hide= a:hide
+endfun
+
+" ---------------------------------------------------------------------
+" Dredir: this function performs a debugging redir by temporarily using {{{1
+"         register a in a redir @a of the given command.  Register a's
+"         original contents are restored.
+"   Usage:  Dredir(["string","string",...,]"cmd")
+fun! Dredir(...)
+  if a:0 <= 0
+   return
+  endif
+  let icmd = 1
+  while icmd < a:0
+   call Decho(a:{icmd})
+   let icmd= icmd + 1
+  endwhile
+  let cmd= a:{icmd}
+
+  " save register a, initialize
+  let keep_rega = @a
+  let v:errmsg  = ''
+
+  " do the redir of the command to the register a
+  try
+   redir @a
+    exe "keepjumps silent ".cmd
+  catch /.*/
+   let v:errmsg= substitute(v:exception,'^[^:]\+:','','e')
+  finally
+   redir END
+   if v:errmsg == ''
+   	let output= @a
+   else
+   	let output= v:errmsg
+   endif
+   let @a= keep_rega
+  endtry
+
+  " process output via Decho()
+  while output != ""
+   if output =~ "\n"
+   	let redirline = substitute(output,'\n.*$','','e')
+   	let output    = substitute(output,'^.\{-}\n\(.*$\)$','\1','e')
+   else
+   	let redirline = output
+   	let output    = ""
+   endif
+   call Decho("redir<".cmd.">: ".redirline)
+  endwhile
+endfun
+
+" ---------------------------------------------------------------------
+" DechoSep: puts a separator with counter into debugging output {{{2
+fun! DechoSep(...)
+"  call Dfunc("DechoSep() a:0=".a:0)
+  if !exists("s:dechosepcnt")
+   let s:dechosepcnt= 1
+  else
+   let s:dechosepcnt= s:dechosepcnt + 1
+  endif
+  let eikeep= &ei
+  set ei=all
+  call Decho("--sep".s:dechosepcnt."--".((a:0 > 0)? " ".a:1 : ""))
+  let &ei= eikeep
+"  call Dret("DechoSep")
+endfun
+
+" ---------------------------------------------------------------------
+" DechoPause: puts a pause-until-<cr> into operation; will place a {{{2
+"             separator into the debug output for reporting
+fun! DechoPause()
+"  call Dfunc("DechoPause()")
+  redraw!
+  call DechoSep("(pause)")
+  call inputsave()
+  call input("Press <cr> to continue")
+  call inputrestore()
+"  call Dret("DechoPause")
+endfun
+
+ " ---------------------------------------------------------------------
+ " DechoRemote: supports sending debugging to a remote vim {{{1
+if has("clientserver") && executable("gvim")
+ fun! s:DechoRemote(mode,...)
+   if a:mode == 0
+    " turn remote debugging off
+    if g:dechomode == s:DECHOREM
+    	let g:dechomode= s:DECHOWIN
+    endif
+ 
+   elseif a:mode == 1
+    " turn remote debugging on
+    if g:dechomode != s:DECHOREM
+ 	 let g:dechomode= s:DECHOREM
+    endif
+	let g:dechofile= (a:0 > 0)? a:1 : ""
+    if serverlist() !~ '\<DECHOREMOTE\>'
+ "   " start up remote Decho server
+ "   call Decho("start up DECHOREMOTE server")
+     if has("win32") && executable("start")
+      call system("start gvim --servername DECHOREMOTE")
+	 else
+      call system("gvim --servername DECHOREMOTE")
+	 endif
+     while 1
+      try
+ 	   call remote_send("DECHOREMOTE",':silent set ft=Decho fo-=at'."\<cr>")
+       call remote_send("DECHOREMOTE",':file [Decho\ Remote\ Server]'."\<cr>")
+ 	   call remote_send("DECHOREMOTE",":put ='-----------------------------'\<cr>")
+ 	   call remote_send("DECHOREMOTE",":put ='Remote Decho Debugging Window'\<cr>")
+ 	   call remote_send("DECHOREMOTE",":put ='-----------------------------'\<cr>")
+ 	   call remote_send("DECHOREMOTE","1GddG")
+	   call remote_send("DECHOREMOTE",':silent set noswf noma nomod nobl nonu ch=1 fo=n2croql nosi noai'."\<cr>")
+ 	   call remote_send("DECHOREMOTE",':'."\<cr>")
+ 	   call remote_send("DECHOREMOTE",':silent set ft=Decho'."\<cr>")
+ 	   call remote_send("DECHOREMOTE",':silent syn on'."\<cr>")
+ 	   break
+      catch /^Vim\%((\a\+)\)\=:E241/
+ 	   sleep 200m
+      endtry
+     endwhile
+    endif
+ 
+   else
+    echohl Warning | echomsg "DechoRemote(".a:mode.") not supported" | echohl None
+   endif
+ 
+ endfun
+endif
+
+" ---------------------------------------------------------------------
+"  DechoVarOn: turu debugging-to-a-variable on.  The variable is given {{{1
+"  by the user;   DechoVarOn [varname]
+fun! s:DechoVarOn(...)
+  let g:dechomode= s:DECHOVAR
+  
+  if a:0 > 0
+   let g:dechofile= a:1
+   if a:2 =~ '^g:'
+    exe "let ".a:2.'= ""'
+   else
+    exe "let g:".a:2.'= ""'
+   endif
+  else
+   let g:dechovarname= "g:dechovar"
+  endif
+endfun
+
+" ---------------------------------------------------------------------
+" DechoVarOff: {{{1
+fun! s:DechoVarOff()
+  if exists("g:dechovarname")
+   if exists(g:dechovarname)
+    exe "unlet ".g:dechovarname
+   endif
+  endif
+  let g:dechomode= s:DECHOWIN
+endfun
+
+ " --------------------------------------------------------------------
+ " DechoTab: {{{1
+if v:version >= 700
+ fun! s:DechoTab(mode,...)
+ "  call Dfunc("DechoTab(mode=".a:mode.") a:0=".a:0)
+ 
+   if a:mode
+    let g:dechomode = s:DECHOTAB
+	let g:dechofile = (a:0 > 0)? a:1 : ""
+    let dechotabcur = tabpagenr()
+    if !exists("g:dechotabnr")
+	 let eikeep= &ei
+	 set ei=all
+	 tabnew
+	 file Decho\ Tab
+	 setlocal ma
+	 put ='---------'
+	 put ='Decho Tab '.g:dechofile
+	 put ='---------'
+	 norm! 1GddG
+	 let g:dechotabnr = tabpagenr()
+	 let &ei          = ""
+	 set ft=Decho
+	 set ei=all
+	 setlocal noma nomod nobl noswf ch=1 fo=n2croql
+	 exe "tabn ".dechotabcur
+	 let &ei= eikeep
+	endif
+   else
+    let g:dechomode= s:DECHOWIN
+   endif
+ 
+ "  call Dret("DechoTab")
+ endfun
+endif
+
+" ---------------------------------------------------------------------
+"  End Plugin: {{{1
+let &cpo= s:keepcpo
+unlet s:keepcpo
+" ---------------------------------------------------------------------
+"  vim: ts=4 fdm=marker