RubyGems - upjs-rails - Versions diffs - 0.1.0 - Mend

upjs-rails 0.1.0

This diff represents the content of publicly available package versions that have been released to one of the supported registries. The information contained in this diff is provided for informational purposes only and reflects changes between package versions as they appear in their respective public registries.

Files changed (121) hide show

checksums.yaml +7 -0
data/.gitignore +17 -0
data/.ruby-version +2 -0
data/LICENSE.txt +22 -0
data/README.md +47 -0
data/Rakefile +1 -0
data/bin/doc-server +3 -0
data/bin/install-ydoc +4 -0
data/design/animation-ghosting.txt +72 -0
data/design/design.txt +34 -0
data/design/draft.html.erb +48 -0
data/design/draft.rb +9 -0
data/lib/assets/javascripts/up/browser.js.coffee +20 -0
data/lib/assets/javascripts/up/bus.js.coffee +54 -0
data/lib/assets/javascripts/up/flow.js.coffee +160 -0
data/lib/assets/javascripts/up/form.js.coffee +162 -0
data/lib/assets/javascripts/up/history.js.coffee +33 -0
data/lib/assets/javascripts/up/index.js +13 -0
data/lib/assets/javascripts/up/link.js.coffee +95 -0
data/lib/assets/javascripts/up/magic.js.coffee +79 -0
data/lib/assets/javascripts/up/modal.js.coffee +51 -0
data/lib/assets/javascripts/up/module.js.coffee +4 -0
data/lib/assets/javascripts/up/motion.js.coffee +276 -0
data/lib/assets/javascripts/up/navigation.js.coffee +63 -0
data/lib/assets/javascripts/up/popup.js.coffee +143 -0
data/lib/assets/javascripts/up/util.js.coffee +287 -0
data/lib/assets/stylesheets/up/follow.css.sass +2 -0
data/lib/assets/stylesheets/up/index.css +3 -0
data/lib/assets/stylesheets/up/modal.css.sass +54 -0
data/lib/assets/stylesheets/up/popup.css.sass +9 -0
data/lib/upjs/rails/engine.rb +6 -0
data/lib/upjs/rails/redirection.rb +26 -0
data/lib/upjs/rails/request.rb +13 -0
data/lib/upjs/rails/version.rb +5 -0
data/lib/upjs-rails.rb +7 -0
data/spec_app/.firefox-version +1 -0
data/spec_app/.gitignore +17 -0
data/spec_app/Gemfile +24 -0
data/spec_app/Gemfile.lock +239 -0
data/spec_app/README.rdoc +28 -0
data/spec_app/Rakefile +6 -0
data/spec_app/app/assets/images/.keep +0 -0
data/spec_app/app/assets/javascripts/application.js +16 -0
data/spec_app/app/assets/stylesheets/application.css +15 -0
data/spec_app/app/assets/stylesheets/blocks/card.css.sass +11 -0
data/spec_app/app/assets/stylesheets/blocks/controls.css.sass +7 -0
data/spec_app/app/assets/stylesheets/blocks/field_with_errors.css.sass +5 -0
data/spec_app/app/assets/stylesheets/blocks/menu.css.sass +13 -0
data/spec_app/app/assets/stylesheets/blocks/panel.css.sass +8 -0
data/spec_app/app/controllers/application_controller.rb +14 -0
data/spec_app/app/controllers/cards_controller.rb +51 -0
data/spec_app/app/controllers/concerns/.keep +0 -0
data/spec_app/app/controllers/pages_controller.rb +6 -0
data/spec_app/app/helpers/application_helper.rb +2 -0
data/spec_app/app/mailers/.keep +0 -0
data/spec_app/app/models/card.rb +6 -0
data/spec_app/app/models/concerns/.keep +0 -0
data/spec_app/app/models/tests.rb +27 -0
data/spec_app/app/views/cards/_side.html.haml +4 -0
data/spec_app/app/views/cards/index.html.haml +10 -0
data/spec_app/app/views/cards/new.html.haml +15 -0
data/spec_app/app/views/cards/show.html.haml +11 -0
data/spec_app/app/views/layouts/application.html.erb +12 -0
data/spec_app/app/views/pages/home.html.haml +5 -0
data/spec_app/bin/bundle +3 -0
data/spec_app/bin/rails +8 -0
data/spec_app/bin/rake +8 -0
data/spec_app/bin/setup +29 -0
data/spec_app/bin/spring +18 -0
data/spec_app/config/application.rb +26 -0
data/spec_app/config/boot.rb +3 -0
data/spec_app/config/cucumber.yml +8 -0
data/spec_app/config/database.yml +25 -0
data/spec_app/config/environment.rb +5 -0
data/spec_app/config/environments/development.rb +41 -0
data/spec_app/config/environments/production.rb +79 -0
data/spec_app/config/environments/test.rb +42 -0
data/spec_app/config/initializers/assets.rb +11 -0
data/spec_app/config/initializers/backtrace_silencers.rb +7 -0
data/spec_app/config/initializers/cookies_serializer.rb +3 -0
data/spec_app/config/initializers/filter_parameter_logging.rb +4 -0
data/spec_app/config/initializers/inflections.rb +16 -0
data/spec_app/config/initializers/mime_types.rb +4 -0
data/spec_app/config/initializers/session_store.rb +3 -0
data/spec_app/config/initializers/wrap_parameters.rb +14 -0
data/spec_app/config/locales/en.yml +23 -0
data/spec_app/config/routes.rb +6 -0
data/spec_app/config/secrets.yml +22 -0
data/spec_app/config.ru +4 -0
data/spec_app/db/migrate/20141225125143_create_card.rb +9 -0
data/spec_app/db/schema.rb +23 -0
data/spec_app/db/seeds.rb +7 -0
data/spec_app/features/history.feature +30 -0
data/spec_app/features/navigation.feature +9 -0
data/spec_app/features/step_definitions/factory_steps.rb +5 -0
data/spec_app/features/step_definitions/navigation_steps.rb +29 -0
data/spec_app/features/step_definitions/utility_steps.rb +15 -0
data/spec_app/features/support/env.rb +73 -0
data/spec_app/features/support/find_by_anything.rb +19 -0
data/spec_app/features/support/paths.rb +51 -0
data/spec_app/lib/assets/.keep +0 -0
data/spec_app/lib/tasks/.keep +0 -0
data/spec_app/lib/tasks/cucumber.rake +65 -0
data/spec_app/log/.keep +0 -0
data/spec_app/public/404.html +67 -0
data/spec_app/public/422.html +67 -0
data/spec_app/public/500.html +66 -0
data/spec_app/public/favicon.ico +0 -0
data/spec_app/public/robots.txt +5 -0
data/spec_app/script/cucumber +10 -0
data/spec_app/test/controllers/.keep +0 -0
data/spec_app/test/fixtures/.keep +0 -0
data/spec_app/test/helpers/.keep +0 -0
data/spec_app/test/integration/.keep +0 -0
data/spec_app/test/mailers/.keep +0 -0
data/spec_app/test/models/.keep +0 -0
data/spec_app/test/test_helper.rb +10 -0
data/spec_app/vendor/assets/javascripts/.keep +0 -0
data/spec_app/vendor/assets/stylesheets/.keep +0 -0
data/upjs-rails.gemspec +24 -0
metadata +207 -0

data/lib/assets/javascripts/up/history.js.coffee ADDED Viewed

@@ -0,0 +1,33 @@
+up.history = (->
+  replace = (url) ->
+    manipulate "replace", url
+  push = (url) ->
+    manipulate "push", url
+  manipulate = (method, url) ->
+    method += "State" # resulting in either pushState or replaceState
+    window.history[method]({ fromUp: true }, '', url)
+  pop = (event) ->
+    state = event.originalEvent.state
+    console.log "popping state", state
+    console.log "current href", currentUrl()
+    if state?.fromUp
+      up.visit currentUrl(), history: { method: 'replace' }
+    else
+      console.log "null state"
+  currentUrl = ->
+    location.href
+  setTimeout (->
+    $(window).on "popstate", pop
+    replace(currentUrl())
+  ), 200
+  push: push
+  replace: replace
+)()

data/lib/assets/javascripts/up/index.js ADDED Viewed

@@ -0,0 +1,13 @@
+//= require up/module
+//= require up/util
+//= require up/browser
+//= require up/bus
+//= require up/flow
+//= require up/magic
+//= require up/history
+//= require up/motion
+//= require up/link
+//= require up/form
+//= require up/popup
+//= require up/modal
+//= require up/navigation

data/lib/assets/javascripts/up/link.js.coffee ADDED Viewed

@@ -0,0 +1,95 @@
+###*
+Links.
+@class up.link
+###
+up.link = (->
+  ###*
+  Visits the given URL without a full page load.
+  This is done by fetching `url` through an AJAX request
+  and replaceing the current `<body>` tag with the response's `<body>` tag..
+  @method up.visit
+  @param {String} url
+    The URL to visit.
+  @param {Object} options
+    See options for {{#crossLink "up.flow/up.replace"}}{{/crossLink}}.
+  @example
+      <a href="/users" up-follow>User list</a>
+  ###
+  visit = (url, options) ->
+    console.log("up.visit", url)
+    # options = up.util.options(options, )
+    up.replace('body', url, options)
+  ###*
+  Follows the given link and replaces a selector in the current page
+  with corresponding elements from a new page fetched from the server.
+  @method up.follow
+  @param {Element|jQuery|String} link
+    An element or selector which resolves to an `<a>` tag
+    or any element that is marked up with an `up-follow` attribute.
+  @param {String} [options.target]
+    The selector to replace.
+    Defaults to the `up-target` attribute on `link`,
+    or to `body` if such an attribute does not exist.
+  @param {Function|String} [options.transition]
+    A transition function or name.
+  @example
+      <a href="/users" up-target=".main">User list</a>
+  ###
+  follow = (link, options) ->
+    $link = $(link)
+    options = up.util.options(options)
+    url = up.util.presentAttr($link, 'href', 'up-follow')
+    selector = options.target || $link.attr("up-target") || 'body'
+    options.transition ||= $link.attr('up-transition')
+    up.replace(selector, url, options)
+  resolve = (element) ->
+    $element = $(element)
+    if $element.is('a') || up.util.presentAttr($element, 'up-follow')
+      $element
+    else
+      $element.find('a:first')
+  resolveUrl = (element) ->
+    if link = resolve(element)
+      up.util.presentAttr(link, 'href', 'up-follow')
+  markActive = (element) ->
+    markUnactive()
+    $element = $(element)
+    $clickArea = $element.ancestors('up-follow')
+    $clickArea = $element unless $clickArea.length
+    $clickArea.addClass('up-active')
+  markUnactive = ->
+    $('[up-active]').removeClass('up-active')
+  up.on 'click', 'a[up-target]', (event, $link) ->
+    event.preventDefault()
+    follow($link)
+  up.on 'click', '[up-follow]', (event, $element) ->
+    childLinkClicked = ->
+      $target = $(event.target)
+      $target.closest('a').length && $element.has($target).length
+    unless childLinkClicked()
+      event.preventDefault()
+      follow(resolve($element))
+  visit: visit
+  follow: follow
+  resolve: resolve
+  resolveUrl: resolveUrl
+)()
+up.visit = up.link.visit
+up.follow = up.link.follow

data/lib/assets/javascripts/up/magic.js.coffee ADDED Viewed

@@ -0,0 +1,79 @@
+###*
+Event handling.
+@class up.magic
+###
+up.magic = (->
+  AWAKENED_CLASS = 'up-awakened'
+  DESTROYER_KEY = 'up-destroyer'
+  ###*
+  Binds an event handler to the document,
+  which will be executed whenever the given event
+  is triggered on the given selector.
+  @method up.on
+  @param {String} events
+    A space-separated list of event names to bind.
+  @param {String} selector
+    The selector an on which the event must be triggered.
+  @param {Function} behavior
+    The handler that should be called.
+  ###
+  live = (events, selector, behavior) ->
+    $(document).on events, selector, (event) ->
+      behavior.apply(this, [event, $(this)])
+  awakeners = []
+  ###*
+  Registers a function to be called whenever an element with
+  the given selector is inserted into the DOM through Up.js.
+  @method up.awaken
+  @param {String} selector
+    The selector to match.
+  @param {Function} awakener
+    The function to call when a matching element is inserted.
+    The function takes the new element as the first argument (as a jQuery object).
+    It may return another function that destroys the awakened
+    object when it is removed from the DOM, by clearing global state such as
+    time-outs and event handlers bound to the document.
+  ###
+  awaken = (selector, awakener) ->
+    awakeners.push
+      selector: selector
+      behavior: awakener
+  $deepFilter = ($element, selector) ->
+    $element.find(selector).addBack(selector)
+  compile = ($fragment) ->
+    for awakener in awakeners
+      $deepFilter($fragment, awakener.selector).each ->
+        $element = $(this)
+        destroyer = awakener.behavior.apply(this, [$element])
+        if up.util.isFunction(destroyer)
+          $element.prop(AWAKENED_CLASS, true)
+          $element.data(DESTROYER_KEY, destroyer)
+  destroy = ($fragment) ->
+    $deepFilter($fragment, "[#{AWAKENED_CLASS}]").each ->
+      $element = $(this)
+      destroyer = $element.data(DESTROYER_KEY)
+      destroyer()
+  up.bus.on 'app:ready', (-> up.bus.emit 'fragment:ready', $(document.body))
+  up.bus.on 'fragment:ready', compile
+  up.bus.on 'fragment:destroy', destroy
+  $(document).on 'ready', -> up.bus.emit('app:ready')
+  awaken: awaken
+  on: live
+)()
+up.awaken = up.magic.awaken
+up.on = up.magic.on

data/lib/assets/javascripts/up/modal.js.coffee ADDED Viewed

@@ -0,0 +1,51 @@
+###*
+Modal dialogs (WIP).
+@class up.modal
+###
+up.modal = (->
+#  configuration =
+#    width: 600
+#    height: 400
+#    template:
+#      """
+#      <div class="up-modal">
+#        <div class="up-modal-overlay"></div>
+#        <div class="up-modal-dialog">
+#          <a href="#" class="up-modal-close">
+#            <span class="up-modal-close-label">Close</span>
+#            <span class="up-modal-close-key">ESC</span>
+#          </a>
+#          <div class="up-modal-content"></div>
+#        </div>
+#      </div>
+#      """
+#
+#  defaults = (defaults) ->
+#    up.util.extend(configuration, defaults)
+#
+#  open = (link, options) ->
+#    $link = $(link)
+#    url = $link.attr("href")
+#    selector = $link.attr("up-modal") || $link.attr("up-target") || 'body'
+#    options.source = true
+#    replace(selector, url, options)
+#    options = up.util.options(options, configuration)
+#    createElements()
+#    update(options)
+#
+#  close = ->
+#    if $container
+#      $container.remove()
+#      $container = null
+  source = ->
+    $('.up-modal').find('[up-source]').attr('up-source')
+#  defaults: defaults
+#  open: open
+#  close: close
+  source: source
+)()

data/lib/assets/javascripts/up/module.js.coffee ADDED Viewed

@@ -0,0 +1,4 @@
+###*
+@module up
+###
+window.up = {}

data/lib/assets/javascripts/up/motion.js.coffee ADDED Viewed

@@ -0,0 +1,276 @@
+###*
+Animation and transition effects.
+@class up.motion
+###
+up.motion = (->
+  defaultOptions =
+    duration: 300
+    easing: 'ease'
+  animations = {}
+  transitions = {}
+  cssAnimate = up.util.cssAnimate
+  ###*
+  Animates an element.
+  The following animations are pre-registered:
+  - `fade-in`
+  - `fade-out`
+  - `move-to-top`
+  - `move-from-top`
+  - `move-to-bottom`
+  - `move-from-bottom`
+  - `move-to-left`
+  - `move-from-left`
+  - `move-to-right`
+  - `move-from-right`
+  - `none`
+  @method up.animate
+  @param {Element|jQuery|String} elementOrSelector
+  @param {String|Function} animationOrName
+  @param {Number} [options.duration]
+  @param {String} [options.easing]
+  @return {Promise}
+    A promise for the animation's end.
+  ###
+  animate = (elementOrSelector, animationOrName, options) ->
+    $element = $(elementOrSelector)
+    console.log("animating with", animationOrName)
+    options = up.util.options(options, defaultOptions)
+    anim = if up.util.isFunction(animationOrName)
+      animationOrName
+    else
+      animations[animationOrName] or up.util.error("Unknown animation", animationName)
+    assertIsPromise(
+      anim($element, options),
+      ["Animation did not return a Promise", animationOrName]
+    )
+  withGhosts = ($old, $new, block) ->
+    $oldGhost = null
+    $newGhost = null
+    up.util.temporaryCss $new, display: 'none', ->
+      $oldGhost = up.util.prependGhost($old)
+    up.util.temporaryCss $old, display: 'none', ->
+      $newGhost = up.util.prependGhost($new)
+    # $old should take up space in the page flow until the transition ends
+    $old.css(visibility: 'hidden')
+    newCssMemo = up.util.temporaryCss($new, display: 'none')
+    promise = block($oldGhost, $newGhost)
+    promise.then ->
+      $oldGhost.remove()
+      $newGhost.remove()
+      # Now that the transition is over we show $new again.
+      # Since we expect $old to be removed in a heartblink,
+      # $new should take up space
+      $old.css(display: 'none')
+      newCssMemo()
+  assertIsPromise = (object, messageParts) ->
+    up.util.isPromise(object) or up.util.error(messageParts...)
+    object
+  ###*
+  Performs a transition between two elements.
+  The following transitions  are pre-registered:
+  - `cross-fade`
+  - `move-top`
+  - `move-bottom`
+  - `move-left`
+  - `move-right`
+  - `none`
+  You can also compose a transition from two animation names
+  separated by a slash character (`/`):
+  - `move-to-bottom/fade-in`
+  - `move-to-left/move-from-top`
+  @method up.morph
+  @param {Element|jQuery|String} source
+  @param {Element|jQuery|String} target
+  @param {Function|String} transitionOrName
+  @param {Number} [options.duration]
+  @param {String} [options.easing]
+  @return {Promise}
+    A promise for the transition's end.
+  ###
+  morph = (source, target, transitionOrName, options) ->
+    options = up.util.options(defaultOptions)
+    $old = $(source)
+    $new = $(target)
+    transition = up.util.presence(transitionOrName, up.util.isFunction) || transitions[transitionOrName]
+    if transition
+      withGhosts $old, $new, ($oldGhost, $newGhost) ->
+        assertIsPromise(
+          transition($oldGhost, $newGhost, options),
+          ["Transition did not return a promise", transitionOrName]
+        )
+    else if animation = animations[transitionOrName]
+      $old.hide()
+      animate($new, animation, options)
+    else if up.util.isString(transitionOrName) && transitionOrName.indexOf('/') >= 0
+      parts = transitionOrName.split('/')
+      transition = ($old, $new, options) ->
+        $.when(
+          animate($old, parts[0], options),
+          animate($new, parts[1], options)
+        )
+      morph($old, $new, transition, options)
+    else
+      up.util.error("Unknown transition: #{transitionOrName}")
+  ###*
+  Defines a named transition.
+  @method up.transition
+  @param {String} name
+  @param {Function} transition
+  ###
+  transition = (name, transition) ->
+    transitions[name] = transition
+  ###*
+  Defines a named animation.
+  @method up.animation
+  @param {String} name
+  @param {Function} animation
+  ###
+  animation = (name, animation) ->
+    animations[name] = animation
+  ###*
+  Returns a no-op animation or transition which has no visual effects
+  and completes instantly.
+  @method up.motion.none
+  @return {Promise}
+    A resolved promise
+  ###
+  none = ->
+    deferred = $.Deferred()
+    deferred.resolve()
+    deferred.promise()
+  animation('none', none)
+  animation('fade-in', ($ghost, options) ->
+    $ghost.css(opacity: 0)
+    cssAnimate($ghost, { opacity: 1 }, options)
+  )
+  animation('fade-out', ($ghost, options) ->
+    $ghost.css(opacity: 1)
+    cssAnimate($ghost, { opacity: 0 }, options)
+  )
+  animation('move-to-top', ($ghost, options) ->
+    $ghost.css('margin-top': '0%')
+    cssAnimate($ghost, { 'margin-top': '-100%' }, options)
+  )
+  animation('move-from-top', ($ghost, options) ->
+    $ghost.css('margin-top': '-100%')
+    cssAnimate($ghost, { 'margin-top': '0%' }, options)
+  )
+  animation('move-to-bottom', ($ghost, options) ->
+    $ghost.css('margin-top': '0%')
+    cssAnimate($ghost, { 'margin-top': '100%' }, options)
+  )
+  animation('move-from-bottom', ($ghost, options) ->
+    $ghost.css('margin-top': '100%')
+    cssAnimate($ghost, { 'margin-top': '0%' }, options)
+  )
+  animation('move-to-left', ($ghost, options) ->
+    $ghost.css('margin-left': '0%')
+    cssAnimate($ghost, { 'margin-left': '-100%' }, options)
+  )
+  animation('move-from-left', ($ghost, options) ->
+    $ghost.css('margin-left': '-100%')
+    cssAnimate($ghost, { 'margin-left': '0%' }, options)
+  )
+  animation('move-to-right', ($ghost, options) ->
+    $ghost.css('margin-left': '0%')
+    cssAnimate($ghost, { 'margin-left': '100%' }, options)
+  )
+  animation('move-from-right', ($ghost, options) ->
+    $ghost.css('margin-left': '100%')
+    cssAnimate($ghost, { 'margin-left': '0%' }, options)
+  )
+  animation('roll-down', ($ghost, options) ->
+    fullHeight = $ghost.height()
+    styleMemo = up.util.temporaryCss($ghost,
+      height: '0px'
+      overflow: 'hidden'
+    )
+    cssAnimate($ghost, { height: "#{fullHeight}px" }, options).then(styleMemo)
+  )
+  transition('none', none)
+  transition('move-left', ($old, $new, options) ->
+    $.when(
+      animate($old, 'move-to-left', options),
+      animate($new, 'move-from-right', options)
+    )
+  )
+  transition('move-right', ($old, $new, options) ->
+    $.when(
+      animate($old, 'move-to-right', options),
+      animate($new, 'move-from-left', options)
+    )
+  )
+  transition('move-top', ($old, $new, options) ->
+    $.when(
+      animate($old, 'move-to-top', options),
+      animate($new, 'move-from-bottom', options)
+    )
+  )
+  transition('move-bottom', ($old, $new, options) ->
+    $.when(
+      animate($old, 'move-to-bottom', options),
+      animate($new, 'move-from-top', options)
+    )
+  )
+  transition('cross-fade', ($old, $new, options) ->
+    $.when(
+      animate($old, 'fade-out', options),
+      animate($new, 'fade-in', options)
+    )
+  )
+  morph: morph
+  animate: animate
+  transition: transition
+  animation: animation
+  none: none
+)()
+up.transition = up.motion.transition
+up.animation = up.motion.animation
+up.morph = up.motion.morph
+up.animate = up.motion.animate

data/lib/assets/javascripts/up/navigation.js.coffee ADDED Viewed

@@ -0,0 +1,63 @@
+###*
+This module marks up link elements with classes indicating that
+they are currently loading (class `up-active`) or linking
+to the current location (class `up-current`).
+The current location is either:
+- the URL displayed in the browser window's location bar
+- the source URL of a currently opened {{#crossLink "up.modal"}}modal dialog{{/crossLink}}
+- the source URL of a currently opened {{#crossLink "up.popup"}}popup overlay{{/crossLink}}
+@class up.navigation
+###
+up.navigation = (->
+  CLASS_ACTIVE = 'up-active'
+  CLASS_CURRENT = 'up-current'
+  SELECTOR_SECTION = 'a[href], a[up-target], [up-follow], [up-modal], [up-popup]'
+  SELECTOR_ACTIVE = ".#{CLASS_ACTIVE}"
+  locationChanged = ->
+    windowLocation = up.util.normalizeUrl(location.href, search: false)
+    modalLocation = up.modal.source()
+    popupLocation = up.popup.source()
+    up.util.each $(SELECTOR_SECTION), (section) ->
+      $section = $(section)
+      # if $section is marked up with up-follow,
+      # the actual link might be a child element.
+      url = up.link.resolveUrl($section)
+      url = up.util.normalizeUrl(url, search: false)
+      if url == windowLocation || url == modalLocation || url == popupLocation
+        $section.addClass(CLASS_CURRENT)
+      else
+        $section.removeClass(CLASS_CURRENT)
+  sectionClicked = ($section) ->
+    unmarkActive()
+    $section = enlargeClickArea($section)
+    $section.addClass(CLASS_ACTIVE)
+  enlargeClickArea = ($section) ->
+    up.util.presence($section.parents(SELECTOR_SECTION)) || $section
+  unmarkActive = ->
+    $(SELECTOR_ACTIVE).removeClass(CLASS_ACTIVE)
+  up.on 'click', SELECTOR_SECTION, (event, $section) ->
+    sectionClicked($section)
+  # If a new fragment is inserted, it's likely to be the result
+  # to the active action. So we can remove the active marker.
+  up.bus.on 'fragment:ready', ->
+    unmarkActive()
+    locationChanged()
+  # If the destroyed fragment is a modal or popup container
+  # this changes which URLs we consider currents.
+  up.bus.on 'fragment:destroy', ($fragment) ->
+    if $fragment.is('.up-modal, .up-popup')
+      locationChanged()
+)()