unpoly-rails 0.61.1 → 2.0.0.pre.rc4

data/lib/assets/javascripts/unpoly/classes/reveal_motion.coffee

@@ -1,102 +0,0 @@
-e = up.element
-
-class up.RevealMotion
-
-  constructor: (@element, options = {}) ->
-    layoutConfig = up.viewport.config
-    @viewport = options.viewport ? up.viewport.closest(@element)
-    up.legacy.fixKey(layoutConfig, 'snap', 'revealSnap')
-    snapDefault = layoutConfig.revealSnap
-    @snap = options.snap ? options.revealSnap ? snapDefault
-    if @snap == false
-      @snap = 0
-    else if @snap == true
-      @snap = snapDefault
-    @padding = options.padding ? options.revealPadding ? layoutConfig.revealPadding
-    @top = options.top
-    @fixedTop = options.fixedTop ? layoutConfig.fixedTop
-    @fixedBottom = options.fixedBottom ? layoutConfig.fixedBottom
-
-    # Options for up.ScrollMotion
-    @speed = options.speed ? options.scrollSpeed ? layoutConfig.scrollSpeed
-    @behavior = options.behavior ? options.scrollBehavior
-
-  start: ->
-    elementRect = up.Rect.fromElement(@element)
-    viewportRect = @getViewportRect(@viewport)
-
-    @addPadding(elementRect)
-    @substractObstructions(viewportRect)
-
-    if viewportRect.height <= 0
-      return Promise.reject(new Error('Viewport has no visible area'))
-
-    originalScrollTop = @viewport.scrollTop
-    newScrollTop = originalScrollTop
-
-    if @top || elementRect.height > viewportRect.height
-      # Element is either larger than the viewport,
-      # or the user has explicitely requested for the element to align at top
-      # => Scroll the viewport so the first element row is the first viewport row
-      diff = elementRect.top - viewportRect.top
-      newScrollTop += diff
-    else if elementRect.top < viewportRect.top
-      # Element fits within viewport, but sits too high
-      # => Scroll up (reduce scrollY), so the element comes down
-      newScrollTop -= (viewportRect.top - elementRect.top)
-    else if elementRect.bottom > viewportRect.bottom
-      # Element fits within viewport, but sits too low
-      # => Scroll down (increase scrollY), so the element comes up
-      newScrollTop += (elementRect.bottom - viewportRect.bottom)
-    else
-      # Element is fully visible within viewport
-      # => Do nothing
-
-    if newScrollTop < @snap && elementRect.top < (0.5 * viewportRect.height)
-      newScrollTop = 0
-
-    if newScrollTop != originalScrollTop
-      @scrollTo(newScrollTop)
-    else
-      Promise.resolve()
-
-  scrollTo: (newScrollTop) ->
-    scrollOptions =
-      speed: @speed
-      behavior: @behavior
-    @scrollMotion = new up.ScrollMotion(@viewport, newScrollTop, scrollOptions)
-    @scrollMotion.start()
-
-  getViewportRect: ->
-    if up.viewport.isRoot(@viewport)
-      # Other than an element with overflow-y, the document viewport
-      # stretches to the full height of its contents. So we create a viewport
-      # sized to the usuable screen area.
-      new up.Rect
-        left: 0
-        top: 0
-        width: up.viewport.rootWidth()
-        height: up.viewport.rootHeight()
-    else
-      up.Rect.fromElement(@viewport)
-
-  addPadding: (elementRect) ->
-    elementRect.top -= @padding
-    elementRect.height += 2 * @padding
-
-  substractObstructions: (viewportRect) ->
-    for obstruction in e.list(@fixedTop...)
-      obstructionRect = up.Rect.fromElement(obstruction)
-      diff = obstructionRect.bottom - viewportRect.top
-      if diff > 0
-        viewportRect.top += diff
-        viewportRect.height -= diff
-
-    for obstruction in e.list(@fixedBottom...)
-      obstructionRect = up.Rect.fromElement(obstruction)
-      diff = viewportRect.bottom - obstructionRect.top
-      if diff > 0
-        viewportRect.height -= diff
-
-  finish: ->
-    @scrollMotion?.finish()

data/lib/assets/javascripts/unpoly/classes/scroll_motion.coffee

@@ -1,67 +0,0 @@
-u = up.util
-
-class up.ScrollMotion
-
-  # We want to make the default speed mimic Chrome's smooth scrolling behavior.
-  # We also want to keep the default value in up.viewport.config.scrollSpeed to be 1.
-  # For our calculation in #animationFrame() we need to multiply it with this factor.
-  SPEED_CALIBRATION = 0.065
-
-  constructor: (@scrollable, @targetTop, options = {}) ->
-    # The option for up.scroll() is { behavior }, but coming
-    # from up.replace() it's { scrollBehavior }.
-    @behavior = options.behavior ? options.scrollBehavior ? 'auto'
-
-    # The option for up.scroll() is { behavior }, but coming
-    # from up.replace() it's { scrollSpeed }.
-    @speed = (options.speed ? options.scrollSpeed ? up.viewport.config.scrollSpeed) * SPEED_CALIBRATION
-
-  start: =>
-    return new Promise (@resolve, @reject) =>
-      if @behavior == 'smooth' && up.motion.isEnabled()
-        @startAnimation()
-      else
-        @finish()
-
-  startAnimation: ->
-    @startTime = Date.now()
-    @startTop = @scrollable.scrollTop
-    @topDiff = @targetTop - @startTop
-    # We're applying a square root to become slower for small distances
-    # and faster for large distances.
-    @duration = Math.sqrt(Math.abs(@topDiff)) / @speed
-    requestAnimationFrame(@animationFrame)
-
-  animationFrame: =>
-    return if @settled
-
-    # When the scroll position is not the one we previously set, we assume
-    # that the user has tried scrolling on her own. We then cancel the scrolling animation.
-    if @frameTop && Math.abs(@frameTop - @scrollable.scrollTop) > 1.5
-      @cancel('Animation aborted due to user intervention')
-
-    currentTime = Date.now()
-    timeElapsed = currentTime - @startTime
-    timeFraction = Math.min(timeElapsed / @duration, 1)
-
-    @frameTop = @startTop + (u.simpleEase(timeFraction) * @topDiff)
-
-    # When we're very close to the target top, finish the animation
-    # directly to deal with rounding errors.
-    if Math.abs(@targetTop - @frameTop) < 0.3
-      @finish()
-    else
-      @scrollable.scrollTop = @frameTop
-      requestAnimationFrame(@animationFrame)
-
-  cancel: (reason) =>
-    @settled = true
-    @reject(new Error(reason))
-
-  finish: =>
-    # In case we're animating with emulation, cancel the next scheduled frame
-    @settled = true
-    # Setting the { scrollTop } prop will also finish a native scrolling
-    # animation in Firefox and Chrome.
-    @scrollable.scrollTop = @targetTop
-    @resolve()

data/lib/assets/javascripts/unpoly/classes/selector.coffee

@@ -1,60 +0,0 @@
-u = up.util
-
-class up.Selector
-
-  CSS_HAS_SUFFIX_PATTERN = new RegExp("\\:has\\(([^\\)]+)\\)$")
-  MATCH_FN_NAME = if up.browser.isIE11() then 'msMatchesSelector' else 'matches'
-
-  constructor: (@selector, @filterFn) ->
-
-  matches: (element) ->
-    doesMatch = element[MATCH_FN_NAME](@selector)
-    doesMatch &&= @filterFn(element) if @filterFn
-    doesMatch
-
-  descendants: (root) ->
-    matches = root.querySelectorAll(@selector)
-    if @filterFn
-      matches = u.filter(matches, @filterFn)
-    matches
-
-  descendant: (root) ->
-    if !@filterFn
-     root.querySelector(@selector)
-    else
-      candidates = root.querySelectorAll(@selector)
-      u.find(candidates, @filterFn)
-
-  subtree: (root) ->
-    matches = []
-    if @matches(root)
-      matches.push(root)
-    matches.push(@descendants(root)...)
-    matches
-
-  closest: (root) ->
-    if root.closest && !@filterFn
-      return root.closest(@selector)
-    else
-      return @closestPolyfill(root)
-
-  closestPolyfill: (root) ->
-    if @matches(root, @selector)
-      root
-    else
-      @ancestor(root)
-
-  ancestor: (element) ->
-    if parentElement = element.parentElement
-      if @matches(parentElement)
-        parentElement
-      else
-        @ancestor(parentElement)
-
-  @parse: (selector) ->
-    filter = null
-    selector = selector.replace CSS_HAS_SUFFIX_PATTERN, (match, descendantSelector) ->
-      filter = (element) ->
-        element.querySelector(descendantSelector)
-      return ''
-    new @(selector, filter)

data/lib/assets/javascripts/unpoly/classes/store/memory.coffee

@@ -1,26 +0,0 @@
-up.store ||= {}
-
-u = up.util
-
-class up.store.Memory
-
-  constructor: ->
-    @clear()
-
-  clear: =>
-    @data = {}
-
-  get: (key) =>
-    @data[key]
-
-  set: (key, value) =>
-    @data[key] = value
-
-  remove: (key) =>
-    delete @data[key]
-
-  keys: =>
-    Object.keys(@data)
-
-  values: =>
-    u.values(@data)

data/lib/assets/javascripts/unpoly/classes/store/session.coffee

@@ -1,59 +0,0 @@
-u = up.util
-
-##
-# Store implementation backed by window.sessionStorage
-# ====================================================
-#
-# This improves plain sessionStorage access in several ways:
-#
-# - Falls back to in-memory storage if window.sessionStorage is not available (see below).
-# - Allows to store other types of values than just strings.
-# - Allows to store structured values.
-# - Allows to invalidate existing data by incrementing a version number on the server.
-#
-# On sessionStorage availability
-# ------------------------------
-#
-# All supported browsers have sessionStorage, but the property is `null`
-# in private browsing mode in Safari and the default Android webkit browser.
-# See https://makandracards.com/makandra/32865-sessionstorage-per-window-browser-storage
-#
-# Also Chrome explodes upon access of window.sessionStorage when
-# user blocks third-party cookies and site data and this page is embedded
-# as an <iframe>. See https://bugs.chromium.org/p/chromium/issues/detail?id=357625
-#
-class up.store.Session extends up.store.Memory
-
-  constructor: (rootKey) ->
-    @rootKey = rootKey
-    @loadFromSessionStorage()
-
-  clear: =>
-    super()
-    @saveToSessionStorage()
-
-  set: (key, value) =>
-    super(key, value)
-    @saveToSessionStorage()
-
-  remove: (key) =>
-    super(key)
-    @saveToSessionStorage()
-
-  loadFromSessionStorage: =>
-    try
-      if raw = sessionStorage?.getItem(@rootKey)
-        @data = JSON.parse(raw)
-    catch
-      # window.sessionStorage not supported (see class comment)
-      # or JSON syntax error. We start with a blank object instead.
-
-    @data ||= {}
-
-  saveToSessionStorage: =>
-    json = JSON.stringify(@data)
-    try
-      sessionStorage?.setItem(@rootKey, json)
-    catch
-      # window.sessionStorage not supported (see class comment).
-      # We do nothing and only keep data in-memory.

data/lib/assets/javascripts/unpoly/classes/tether.coffee

@@ -1,105 +0,0 @@
-u = up.util
-e = up.element
-
-class up.Tether
-
-  constructor: (options) ->
-    @anchor = options.anchor
-
-    [@position, @align] = options.position.split('-')
-    if @align
-      up.legacy.warn('The position value %o is deprecated. Use %o instead.', options.position, @describeConstraints())
-    else
-      @align = options.align
-
-    @alignAxis = if @position == 'top' || @position == 'bottom' then 'horizontal' else 'vertical'
-
-    @viewport = up.viewport.closest(@anchor)
-    # The document viewport is <html> on some browsers, and we cannot attach children to that.
-    @parent = if @viewport == e.root() then document.body else @viewport
-
-    # If the offsetParent is within the viewport (or is the viewport)
-    # we can simply absolutely position it and it will move as the viewport scrolls.
-    # If not however, we have no choice but to move it on every scroll event.
-    @syncOnScroll = !@viewport.contains(@anchor.offsetParent)
-
-    @root = e.affix(@parent, '.up-bounds')
-    @setBoundsOffset(0, 0)
-
-    @changeEventSubscription('on')
-
-  destroy: ->
-    e.remove(@root)
-    @changeEventSubscription('off')
-
-  changeEventSubscription: (fn) ->
-    up[fn](window, 'resize', @scheduleSync)
-    up[fn](@viewport, 'scroll', @scheduleSync) if @syncOnScroll
-
-  scheduleSync: =>
-    clearTimeout(@syncTimer)
-    @syncTimer = u.task(@sync)
-
-  sync: =>
-    rootBox = @root.getBoundingClientRect()
-    anchorBox = @anchor.getBoundingClientRect()
-
-    left = undefined
-    top = undefined
-
-    switch @alignAxis
-      when 'horizontal'
-        top = switch @position
-          when 'top'
-            anchorBox.top - rootBox.height
-          when 'bottom'
-            anchorBox.top + anchorBox.height
-
-        left = switch @align
-          when 'left'
-            # anchored to anchor's left, grows to the right
-            anchorBox.left
-          when 'center'
-            # anchored to anchor's horizontal center, grows equally to left/right
-            anchorBox.left + 0.5 * (anchorBox.width - rootBox.width)
-          when 'right'
-            # anchored to anchor's right, grows to the left
-            anchorBox.left + anchorBox.width - rootBox.width
-
-      when 'vertical'
-        top = switch @align
-          when 'top'
-            # anchored to the top, grows to the bottom
-            anchorBox.top
-          when 'center'
-            # anchored to anchor's vertical center, grows equally to left/right
-            anchorBox.top + 0.5 * (anchorBox.height - rootBox.height)
-          when 'bottom'
-            # anchored to the bottom, grows to the top
-            anchorBox.top + anchorBox.height - rootBox.height
-
-        left = switch @position
-          when 'left'
-            anchorBox.left - rootBox.width
-          when 'right'
-            anchorBox.left + anchorBox.width
-
-    if u.isDefined(left) || u.isDefined(top)
-      @moveTo(left, top)
-    else
-      up.fail('Invalid tether constraints: %o', @describeConstraints())
-
-  describeConstraints: ->
-    { @position, @align }
-
-  moveTo: (targetLeft, targetTop) ->
-    rootBox = @root.getBoundingClientRect()
-    @setBoundsOffset(
-      targetLeft - rootBox.left + @offsetLeft,
-      targetTop - rootBox.top + @offsetTop
-    )
-
-  setBoundsOffset: (left, top) ->
-    @offsetLeft = left
-    @offsetTop = top
-    e.setStyle(@root, { left, top })

data/lib/assets/javascripts/unpoly/classes/url_set.coffee

@@ -1,32 +0,0 @@
-u = up.util
-
-class up.UrlSet
-
-  constructor: (@urls, options = {}) ->
-    @normalizeUrl = options.normalizeUrl || u.normalizeUrl
-    @urls = u.map(@urls, @normalizeUrl)
-    @urls = u.compact(@urls)
-
-  matches: (testUrl) =>
-    if testUrl.indexOf('*') >= 0
-      @doesMatchPattern(testUrl)
-    else
-      @doesMatchFully(testUrl)
-
-  doesMatchFully: (testUrl) =>
-    u.contains(@urls, testUrl)
-
-  doesMatchPattern: (pattern) =>
-    placeholder = "__ASTERISK__"
-    pattern = pattern.replace(/\*/g, placeholder)
-    pattern = u.escapeRegexp(pattern)
-    pattern = pattern.replace(new RegExp(placeholder, 'g'), '.*?')
-    pattern = new RegExp('^' + pattern + '$')
-
-    u.find @urls, (url) -> pattern.test(url)
-
-  matchesAny: (testUrls) =>
-    u.find(testUrls, @matches)
-
-  "#{u.isEqual.key}": (otherSet) =>
-    u.isEqual(@urls, otherSet?.urls)