unpoly-rails 0.37.0 → 0.50.0

data/lib/assets/javascripts/unpoly/classes/follow_variant.coffee

@@ -0,0 +1,52 @@
+u = up.util
+
+class up.FollowVariant
+
+  constructor: (selector, options) ->
+    @followNow = options.follow
+    @preloadNow = options.preload
+    @selectors = selector.split(/\s*,\s*/)
+
+  onClick: (event, $link) =>
+    if @shouldProcessLinkEvent(event, $link)
+      if $link.is('[up-instant]')
+        # If the link was already processed on mousedown, we still need
+        # to prevent this later click event's chain.
+        up.bus.haltEvent(event)
+      else
+        up.bus.consumeAction(event)
+        @followLink($link)
+    else
+      # For tests
+      up.link.allowDefault(event)
+
+  onMousedown: (event, $link) =>
+    if @shouldProcessLinkEvent(event, $link)
+      up.bus.consumeAction(event)
+      @followLink($link)
+
+  fullSelector: (additionalClause = '') =>
+    parts = []
+    @selectors.forEach (variantSelector) ->
+      ['a', '[up-href]'].forEach (tagSelector) ->
+        parts.push "#{tagSelector}#{variantSelector}#{additionalClause}"
+    parts.join(', ')
+
+  registerEvents: ->
+    up.on 'click', @fullSelector(), (args...) =>
+      @onClick(args...)
+    up.on 'mousedown', @fullSelector('[up-instant]'), (args...) =>
+      @onMousedown(args...)
+
+  shouldProcessLinkEvent: (event, $link) =>
+    u.isUnmodifiedMouseEvent(event) && !up.link.childClicked(event, $link)
+
+  followLink: ($link, options = {}) =>
+    up.feedback.start $link, options, =>
+      @followNow($link, options)
+
+  preloadLink: ($link, options = {}) =>
+    @preloadNow($link, options)
+
+  matchesLink: ($link) =>
+    $link.is(@fullSelector())

data/lib/assets/javascripts/unpoly/classes/motion_tracker.coffee

@@ -0,0 +1,95 @@
+u = up.util
+
+class up.MotionTracker
+
+  constructor: (name) ->
+    @className = "up-#{name}"
+    @dataKey = "up-#{name}-finished"
+    @selector = ".#{@className}"
+    @finishEvent = "up:#{name}:finish"
+
+  ###*
+  Finishes all animations in the given element's ancestors and descendants,
+  then calls the animator.
+
+  @method claim
+  @param {jQuery} $element
+  @param {Function(jQuery): Promise} animator
+  @return {Promise} A promise that is fulfilled when the new animation ends.
+  ###
+  claim: ($element, animator) =>
+    @finish($element).then =>
+      @start($element, animator)
+
+  ###*
+  Calls the given animator to animate the given element.
+
+  The animation returned by the animator is tracked so it can be
+  [`finished`](/up.MotionTracker.finish) later.
+
+  No animations are finished before starting the new animation.
+  Use [`claim()`](/up.MotionTracker.claim) for that.
+
+  @method claim
+  @param {jQuery} $element
+  @param {Function(jQuery): Promise} animator
+  @return {Promise} A promise that is fulfilled when the new animation ends.
+  ###
+  start: ($element, animator) ->
+    promise = animator($element)
+    @markElement($element, promise)
+    promise.then => @unmarkElement($element)
+    promise
+
+  ###*
+  @method finish
+  @param {jQuery} [elements]
+    If no element is given, finishes all animations in the documnet.
+    If an element is given, only finishes animations in its subtree and ancestors.
+  @return {Promise} A promise that is fulfilled when animations have finished.
+  ###
+  finish: (elements) =>
+    $elements = @expandFinishRequest(elements)
+    allFinished = u.map($elements, @finishOneElement)
+    Promise.all(allFinished)
+
+  expandFinishRequest: (elements) ->
+    if elements
+      u.selectInDynasty($(elements), @selector)
+    else
+      $(@selector)
+
+  finishOneElement: (element) =>
+    $element = $(element)
+
+    # Animating code is expected to listen to this event, fast-forward
+    # the animation and resolve their promise. All built-ins like
+    # `up.animate`, `up.morph`, or `up.scroll` behave that way.
+    $element.trigger(@finishEvent)
+
+    # If animating code ignores the event, we cannot force the animation to
+    # finish from here. We will wait for the animation to end naturally before
+    # starting the next animation.
+    @whenElementFinished($element)
+
+  whenElementFinished: ($element) =>
+    # There are some cases related to element ghosting where an element
+    # has the class, but not the data value. In that case simply return
+    # a resolved promise.
+    $element.data(@dataKey) || Promise.resolve()
+
+  markElement: ($element, promise) =>
+    $element.addClass(@className)
+    $element.data(@dataKey, promise)
+
+  unmarkElement: ($element) =>
+    $element.removeClass(@className)
+    $element.removeData(@dataKey)
+
+  forwardFinishEvent: ($original, $ghost, duration) =>
+    @start $original, =>
+      doForward = => $ghost.trigger(@finishEvent)
+      # Forward the finish event to the $ghost that is actually animating
+      $original.on @finishEvent, doForward
+      # Our own pseudo-animation finishes when the actual animation on $ghost finishes
+      duration.then => $original.off @finishEvent, doForward

data/lib/assets/javascripts/unpoly/classes/record.coffee

@@ -0,0 +1,16 @@
+u = up.util
+
+class up.Record
+
+  fields: ->
+    throw 'Return an array of property names'
+
+  constructor: (options) ->
+    u.assign(@, @attributes(options))
+
+  attributes: (source = @) =>
+    u.only(source, @fields()...)
+
+  copy: (changes = {}) =>
+    attributesWithChanges = u.merge(@attributes(), changes)
+    new @constructor(attributesWithChanges)

data/lib/assets/javascripts/unpoly/classes/request.coffee

@@ -0,0 +1,228 @@
+#= require ./record
+
+u = up.util
+
+###*
+Instances of `up.Request` normalizes properties of an [`AJAX request`](/up.request)
+such as the requested URL, form parameters and HTTP method.
+
+@class up.Request
+###
+class up.Request extends up.Record
+
+  ###*
+  The HTTP method for the request.
+
+  @property up.Request#method
+  @param {string} method
+  @stable
+  ###
+
+  ###*
+  The URL for the request.
+
+  @property up.Request#url
+  @param {string} url
+  @stable
+  ###
+
+  ###*
+  Parameters that should be sent as the request's payload.
+
+  Parameters may be passed as one of the following forms:
+
+  1. An object where keys are param names and the values are param values
+  2. An array of `{ name: 'param-name', value: 'param-value' }` objects
+  3. A [`FormData`](https://developer.mozilla.org/en-US/docs/Web/API/FormData) object
+
+  @property up.Request#data
+  @param {String} data
+  @stable
+  ###
+
+  ###*
+  The CSS selector that will be sent as an [`X-Up-Target` header](/up.protocol#optimizing-responses).
+
+  @property up.Request#target
+  @param {string} target
+  @stable
+  ###
+
+  ###*
+  The CSS selector that will be sent as an [`X-Up-Fail-Target` header](/up.protocol#optimizing-responses).
+
+  @property up.Request#failTarget
+  @param {string} failTarget
+  @stable
+  ###
+
+  ###*
+  An object of additional HTTP headers.
+
+  @property up.Request#headers
+  @param {object} headers
+  @stable
+  ###
+
+  ###*
+  A timeout in milliseconds.
+
+  If [`up.proxy.config.maxRequests`](/up.proxy.config#config.maxRequests) is set,
+  the timeout will not include the time spent waiting in the queue.
+
+  @property up.Request#timeout
+  @param {object|undefined} timeout
+  @stable
+  ###
+  fields: ->
+    [
+      'method',
+      'url',
+      'data',
+      'target',
+      'failTarget',
+      'headers',
+      'timeout'
+    ]
+
+  ###*
+  @constructor up.Request
+  @param {string} [attributes]
+  ###
+  constructor: (options) ->
+    super(options)
+    @normalize()
+
+  normalize: =>
+    @method = u.normalizeMethod(@method)
+    @headers ||= {}
+    @extractHashFromUrl()
+    if @data && !u.methodAllowsPayload(@method) && !u.isFormData(@data)
+      @transferDataToUrl()
+
+  extractHashFromUrl: =>
+    urlParts = u.parseUrl(@url)
+    # Remember the #hash for later revealing.
+    # It will be lost during normalization.
+    @hash = urlParts.hash
+    @url = u.normalizeUrl(urlParts, hash: false)
+
+  transferDataToUrl: =>
+    # GET methods are not allowed to have a payload, so we transfer { data } params to the URL.
+    query = u.requestDataAsQuery(@data)
+    separator = if u.contains(@url, '?') then '&' else '?'
+    @url += separator + query
+    # Now that we have transfered the params into the URL, we delete them from the { data } option.
+    @data = undefined
+
+  isSafe: =>
+    up.proxy.isSafeMethod(@method)
+
+  send: =>
+    # We will modify this request below.
+    # This would confuse API clients and cache key logic in up.proxy.
+    new Promise (resolve, reject) =>
+      xhr = new XMLHttpRequest()
+
+      xhrHeaders = u.copy(@headers)
+      xhrData = @data
+      xhrMethod = @method
+      xhrUrl = @url
+
+      [xhrMethod, xhrData] = up.proxy.wrapMethod(xhrMethod, xhrData)
+
+      if u.isFormData(xhrData)
+        delete xhrHeaders['Content-Type'] # let the browser set the content type
+      else if u.isPresent(xhrData)
+        xhrData = u.requestDataAsQuery(xhrData, purpose: 'form')
+        xhrHeaders['Content-Type'] = 'application/x-www-form-urlencoded'
+      else
+        # XMLHttpRequest expects null for an empty body
+        xhrData = null
+
+      xhrHeaders[up.protocol.config.targetHeader] = @target if @target
+      xhrHeaders[up.protocol.config.failTargetHeader] = @failTarget if @failTarget
+
+      if csrfToken = @csrfToken()
+        xhrHeaders[up.protocol.config.csrfHeader] = csrfToken
+
+      xhr.open(xhrMethod, xhrUrl)
+
+      for header, value of xhrHeaders
+        xhr.setRequestHeader(header, value)
+
+      resolveWithResponse = =>
+        response = @buildResponse(xhr)
+        if response.isSuccess()
+          resolve(response)
+        else
+          reject(response)
+
+      # Convert from XHR API to promise API
+      xhr.onload = resolveWithResponse
+      xhr.onerror = resolveWithResponse
+      xhr.ontimeout = resolveWithResponse
+
+      xhr.timeout = @timeout if @timeout
+
+      xhr.send(xhrData)
+
+  navigate: =>
+    $form = $('<form class="up-page-loader"></form>')
+
+    addField = (field) -> $('<input type="hidden">').attr(field).appendTo($form)
+
+    if @method == 'GET'
+      formMethod = 'GET'
+    else
+      # Browser forms can only have GET or POST methods.
+      # When we want to make a request with another method, most backend
+      # frameworks allow to pass the method as a param.
+      addField(name: up.protocol.config.methodParam, value: @method)
+      formMethod = 'POST'
+
+    $form.attr(method: formMethod, action: @url)
+
+    if (csrfParam = up.protocol.csrfParam()) && (csrfToken = @csrfToken())
+      addField(name: csrfParam, value: csrfToken)
+
+    u.each u.requestDataAsArray(@data), addField
+
+    $form.hide().appendTo('body')
+    up.browser.submitForm($form)
+
+  # Returns a csrfToken if this request requires it
+  csrfToken: =>
+    if !@isSafe() && !u.isCrossDomain(@url)
+      up.protocol.csrfToken()
+
+  buildResponse: (xhr) =>
+    responseAttrs =
+      method: @method
+      url: @url
+      text: xhr.responseText
+      status: xhr.status
+      request: @
+      xhr: xhr
+
+    if urlFromServer = up.protocol.locationFromXhr(xhr)
+      responseAttrs.url = urlFromServer
+      # If the server changes a URL, it is expected to signal a new method as well.
+      responseAttrs.method = up.protocol.methodFromXhr(xhr) ? 'GET'
+
+    responseAttrs.title = up.protocol.titleFromXhr(xhr)
+
+    new up.Response(responseAttrs)
+
+  isCachable: =>
+    @isSafe() && !u.isFormData(@data)
+
+  cacheKey: =>
+    [@url, @method, u.requestDataAsQuery(@data), @target].join('|')
+
+  @wrap: (object) ->
+    if object instanceof @
+      # This object has gone through instantiation and normalization before.
+      object
+    else
+      new @(object)

data/lib/assets/javascripts/unpoly/classes/response.coffee

@@ -0,0 +1,138 @@
+#= require ./record
+
+u = up.util
+
+###*
+Instances of `up.Response` describe the server response to an [`AJAX request`](/up.request).
+
+\#\#\# Example
+
+    up.request('/foo').then(function(response) {
+      console.log(response.status); // 200
+      console.log(response.text);   // "<html><body>..."
+    });
+
+@class up.Response
+###
+class up.Response extends up.Record
+
+  ###*
+  The HTTP method used for the response.
+
+  This is usually the HTTP method used by the request.
+  However, after a redirect the server should signal a `GET` method using
+  an [`X-Up-Method: GET` header](/up.protocol#redirect-detection).
+
+  @property up.Response#method
+  @param {string} method
+  @stable
+  ###
+
+  ###*
+  The URL used for the response.
+
+  This is usually the requested URL.
+  However, after a redirect the server should signal a the new URL
+  using an [`X-Up-Location: /new-url` header](/up.protocol#redirect-detection).
+
+  @property up.Response#url
+  @param {string} method
+  @stable
+  ###
+
+  ###*
+  The response body as a `string`.
+
+  @property up.Response#text
+  @param {string} text
+  @stable
+  ###
+
+  ###*
+  The response's
+  [HTTP status code](https://en.wikipedia.org/wiki/List_of_HTTP_status_codes)
+  as a `number`.
+
+  A successful response will usually have a `200` or `201' status code.
+
+  @property up.Response#status
+  @param {number} status
+  @stable
+  ###
+
+  ###*
+  The [request](/up.Request) that triggered this response.
+
+  @property up.Response#request
+  @param {up.Request} request
+  @experimental
+  ###
+
+  ###*
+  The [`XMLHttpRequest`](https://developer.mozilla.org/en-US/docs/Web/API/XMLHttpRequest)
+  object that was used to create this response.
+
+  @property up.Response#xhr
+  @param {XMLHttpRequest} xhr
+  @experimental
+  ###
+
+  ###*
+  A [document title pushed by the server](/up.protocol#pushing-a-document-title-to-the-client).
+
+  If the server pushed no title via HTTP header, this will be `undefined`.
+
+  @property up.Response#title
+  @param {string} [title]
+  @stable
+  ###
+  fields: ->
+    [
+      'method',
+      'url',
+      'text',
+      'status',
+      'request',
+      'xhr',
+      'title'
+    ]
+
+  constructor: (options) ->
+    super(options)
+
+  ###*
+  Returns whether the server responded with a 2xx HTTP status.
+
+  @function up.Response#isSuccess
+  @return {boolean}
+  @experimental
+  ###
+  isSuccess: =>
+    @status && (@status >= 200 && @status <= 299)
+
+  ###*
+  Returns whether the response was not [successful](/up.Request.prototype.isSuccess).
+
+  This also returns `true` when the request encountered a [fatal error](/up.Request.prototype.isFatalError)
+  like a timeout or loss of network connectivity.
+
+  @function up.Response#isError
+  @return {boolean}
+  @experimental
+  ###
+  isError: =>
+    !@isSuccess()
+
+  ###*
+  Returns whether the request encountered a [fatal error](/up.Request.prototype.isFatalError)
+  like a timeout or loss of network connectivity.
+
+  When the server produces an error message with an HTTP status like `500`,
+  this is not considered a fatal error and `false` is returned.
+
+  @function up.Response#isFatalError
+  @return {boolean}
+  @experimental
+  ###
+  isFatalError: =>
+    @isError() && u.isBlank(@text)