ultimate-base 0.2.0

data/app/assets/javascripts/ultimate/improves/form-errors.js.coffee

@@ -0,0 +1,146 @@
+# TODO this is part of custom forms
+# TODO registrable
+# TODO may be, replace "clear immune" technique with something more effective, ex. additional class
+
+( ( $ ) ->
+
+  $.errorableFields = {}
+  $.errorableFieldsSelector = ''
+  
+  $.registerErrorableField = (selector, events, errorCleaner) ->
+    $.errorableFields[selector.split(/\s+/)[0]] = arguments
+    $.errorableFieldsSelector = _.keys($.errorableFields).join(', ')
+    true
+
+  $.fieldWithErrorsWrapperClass = 'field_with_errors'
+  $.fieldWithClearImmuneWrapperClass = 'immune'
+  $.labelForFieldWithErrorClass = 'with-error'
+
+  #  [ selector: String = '.g-select, .g-text-field, .g-text-area' ]
+  #  [ [, ]errors: Array = [] ]
+  #  [ [, ]clearImmune: Boolean = false ]
+  $.fn.setFormErrors = ->
+    # dafault parameters
+    selector = $.errorableFieldsSelector # '.g-select, .g-text-field, .g-text-area'
+    errors = []
+    clearImmune = false
+    # parsing arguments
+    # TODO liquid arguments parser ( by arguments info, ex: {selector: String, errors: Array, clearImmune: Boolean} )
+    a = args arguments
+    if a.length
+      first = a.shift()
+      if _.isString first
+        selector = first
+        if a.length
+          first = a.shift()
+          if _.isString first
+            first = [first]
+      if _.isArray first
+        errors = _.uniq first
+      if a.length
+        first = a.shift()
+        if _.isBoolean first
+          clearImmune = first
+    # ui process
+    @clearFormErrors selector, clearImmune
+    wrapperSelector = ".#{$.fieldWithErrorsWrapperClass}"
+    if clearImmune
+      wrapperSelector += ".#{$.fieldWithClearImmuneWrapperClass}"
+    jErrorWrappers = @find(selector).wrap(selectorToHtml wrapperSelector).parent()
+    jErrorWrappers.append (for err in errors  then  content_tag('div', err, class: 'error')).join("\n")
+    jErrorWrappers.closestLabel().addClass($.labelForFieldWithErrorClass)
+
+  $.fn.setErrors = ->
+    deprecate('jQ.setErrors(...)', 'jQ.setFormErrors(...)')
+    @setFormErrors.apply(@, arguments)
+
+  # [selector]
+  # [clearImmune]
+  $.fn.clearFormErrors = ->
+    selector = $.errorableFieldsSelector # '.g-select, .g-text-field, .g-text-area'
+    clearImmune = false
+    # parsing arguments
+    # TODO liquid arguments parser ( by arguments info, ex: {selector: String, clearImmune: Boolean} )
+    a = args arguments
+    if a.length
+      first = a.shift()
+      if _.isString first
+        selector = first
+        if a.length
+          first = a.shift()
+      if _.isBoolean(first)
+        clearImmune = first
+    wrapperSelector = ".#{$.fieldWithErrorsWrapperClass}"
+    if clearImmune
+      wrapperSelector += ".#{$.fieldWithClearImmuneWrapperClass}"
+    else
+      wrapperSelector += ":not(.#{$.fieldWithClearImmuneWrapperClass})"
+    fullSelector = "#{wrapperSelector}:has(#{selector})"
+    jErrorWrappers = @find fullSelector
+    jErrorWrappers = @closest fullSelector  unless jErrorWrappers.length
+    if jErrorWrappers.length
+      jErrorWrappers.closestLabel().removeClass($.labelForFieldWithErrorClass)
+      jErrorWrappers.children('.error').remove()
+      jErrorWrappers.children(selector).unwrap()
+    @
+
+  $.fn.clearFromErrors = ->
+    deprecate('jQ.clearFromErrors(...)', 'jQ.clearFormErrors(...)')
+    @clearFormErrors.apply(@, arguments)
+
+  $.ujsAjaxError = (event, jqXHR) ->
+    jForm = $(@).clearFormErrors()
+    try
+      responseJSON = $.parseJSON jqXHR.responseText
+      errors = responseJSON['errors'] or responseJSON
+      if errors
+        jFields = jForm.find '[name*="["]:input:visible' # TODO research without :visible, because has custom elements
+        if jFields.length
+          for fieldErrors, fieldName of errors
+            jField = jFields.filter "[name$=\"[#{fieldName}]\"]"
+            if jField.length
+              jField.closestEdge().setErrors fieldErrors
+    catch e
+      # nop
+    true
+
+
+  $.fn.customErrorsHandler = (suspend = true, eventName = 'ajax:error', selector = 'form[data-remote="true"]') ->
+    if @length
+      if @is 'form'
+        jForms = @filter selector
+        jForms.off eventName, $.ujsAjaxError
+        jForms.on eventName, $.ujsAjaxError  if suspend
+      else  
+        @off eventName, selector, $.ujsAjaxError
+        @on eventName, selector, $.ujsAjaxError  if suspend
+    @
+
+
+
+    
+  $.fn.errorCleaners = (suspend = true) ->
+    if @length
+      jDocks = if @is ':input' then @closestEdge() else @
+      for fieldWrapperSelector, [selector, events, errorCleaner] of $.errorableFields
+        fullSelector = ".#{$.fieldWithErrorsWrapperClass} > #{selector}"
+        jDocks.off events, fullSelector
+        jDocks.on events, fullSelector, errorCleaner  if suspend
+    @
+
+
+
+  $.registerErrorableField '.g-text-field input:visible', 'change keyup', ->
+    # text-fields error cleaner
+    jTextField = $ @
+    unless jTextField.val() is '' # TODO may be use isEmptyString()
+      jTextField.clearFormErrors('.g-text-field').clearFormErrors('.g-text-field', true)
+      jTextField.change().focus() # unwraping break change, and there changing continue
+
+  $.registerErrorableField '.g-select select', 'change', ->
+    # selects error cleaner
+    jSelect = $ @
+    unless jSelect.val() is '' # TODO may be use isEmptyString() 
+      jSelect.clearFormErrors('.g-select').clearFormErrors('.g-select', true)
+
+)( jQuery )

data/app/assets/javascripts/ultimate/improves/form.js.coffee

@@ -0,0 +1,155 @@
+( ( $ ) ->
+
+  # TODO try optimize, excepting Edge and search in siblings for next cycle
+  $.fn.nearestFind = (selector, extremeEdgeSelector = 'form, body') ->
+    jEdge = @
+    jResult = jEdge.find selector
+    until jResult.length or jEdge.is extremeEdgeSelector
+      jEdge = jEdge.parent()
+      jResult = jEdge.find selector
+    jResult
+  
+
+
+  $.fn.closestEdge = (edgeSelector = '.input-line, .field, .field-line, tr, li, fieldset, .g-box, form') ->
+    # TODO remove and extract edgeSelector, else undeprecate
+    deprecate 'closestEdge', '$().closest(\'your selector\')'
+    @closest edgeSelector
+
+
+
+  # @param strongById: Boolean = false
+  $.fn.closestLabel = ( strongById = false, passCache = false ) ->
+    (if @is(':input') then @ else @find(':input')).filter(':not(input[type="hidden"])').map ->
+      jInput = $ @
+      jLabel = jInput.data 'closestLabel'  unless passCache
+      unless jLabel
+        if jLabel is false
+          return null
+        else
+          jLabel = {length: 0}
+          jEdge = jInput.closestEdge()   # TODO may be need params
+          inputId = jInput.attr 'id'
+          if inputId
+            # try search label by id linkage
+            labelSelectorByFor = "label[for=\"#{inputId}\"]"
+            # at first search in the edge area
+            jLabel = jEdge.find labelSelectorByFor
+            unless jLabel.length
+              # try search in the closest form
+              jLabel = jInput.closest('form').find labelSelectorByFor
+              # trust only unique label on the form
+              jLabel = {length: 0}  if jLabel.length > 1
+          # try get first labet in the edge area
+          jLabel = jEdge.find('label:first')  unless jLabel.length
+          # taken!
+          if jLabel.length
+            # oh, this label already linked
+            if jLabel.data 'closestInput'
+              jLabel = {length: 0}
+            else
+              jLabel.data 'closestInput', jInput
+          jInput.data 'closestLabel', jLabel
+      if jLabel.length
+        if strongById and jLabel.attr('for') isnt jInput.attr('id')
+          null
+        else
+          jLabel[0]
+      else
+        null
+
+
+
+  $.linkedLabelsClick = ->
+    jLabel = $ @
+    jInput = jLabel.data 'closestInput'
+
+    unless jInput
+      attrFor = jLabel.attr 'for'
+      jInput = jLabel.nearestFind ":input##{attrFor}"
+      jInput = jLabel.nearestFind ':input'  unless jInput.length is 1
+      jLabel.data 'closestInput', jInput  if jInput.length
+
+    if jInput and jInput.length is 1
+      if jInput.is 'input:checkbox, input:radio'
+        jInput.click()
+      else if jInput.is 'select'
+          # TODO try: jInput.click() в любом случае свести к универсальносит
+        jInput.closest('.g-select').click()
+      else
+        jInput.focus()
+      false
+
+  # Cacheble bulletproof labels
+  # example: $('body').linkedLabels();
+  $.fn.linkedLabels = (suspend = true, eventName = 'click.linked-labels') ->
+    if @is 'label'
+      jLabels = @filter 'label'
+      jLabels.off eventName
+      jLabels.on eventName, $.linkedLabelsClick  if suspend
+    else
+      @off eventName, 'label'
+      @on eventName, 'label', $.linkedLabelsClick  if suspend
+    @
+
+
+
+  # [ additionAttr: String = 'data-nested-addition' ]
+  $.fn.setNestedAdditions = (additionAttr = 'data-nested-addition') ->
+    @find(":input[#{additionAttr}]").each ->
+      jInput = $ @
+      inputId = jInput.attr 'id'
+      if inputId
+        newId = "#{inputId}_#{jInput.attr additionAttr}"
+        jInput.attr 'id', newId
+        jLabel = jInput.closestLabel(true)
+        jLabel.attr 'for', newId  if jLabel.length
+        jInput.removeAttr additionAttr
+    @
+
+
+
+  # setNestedIndex(params = {nestedField: index || [index, old_index]})
+  # setNestedIndex(nestedField, index, [old_index])
+  $.fn.setNestedIndex = ->
+    params = {}
+    if arguments.length is 1
+      params = arguments[0]
+    else
+      params[arguments[0]] = (if arguments.length > 2 then [arguments[1], arguments[2]] else arguments[1])
+    replacers =
+      name: []
+      id: []
+    for nestedField, index of params
+      if $.isArray index
+        [index, oldIndex] = index
+      else
+        oldIndex = '\\d*'
+      replacers['id'].push   [ (new RegExp "_#{nestedField}_#{oldIndex}"),           "_#{nestedField}_#{index}"  ]
+      replacers['name'].push [ (new RegExp "\\[#{nestedField}\\]\\[#{oldIndex}\\]"), "[#{nestedField}][#{index}]" ]
+    ( if @is(':input') then @filter('[name]') else @find(':input[name]') ).map ->
+      jInput = $ @
+      for replacerAttr, replacerPairs of replacers
+        # if extract attribute
+        if attr = jInput.attr replacerAttr
+          # dup attr
+          newAttr = attr
+          for pair in replacerPairs
+            newAttr = newAttr.replace pair[0], pair[1]
+          if newAttr isnt attr
+            jInput.closestLabel(true).attr('for', newAttr)  if replacerAttr is 'id'
+            jInput.attr replacerAttr, newAttr
+    @
+
+
+
+  $.fillTabIndexesCounter = 0
+
+  # TODO this may be .is 'input'
+  $.fn.fillTabIndexes = (onlyVisible = false) ->
+    if @length
+      @find("input:not([readonly])#{if onlyVisible then ':visible' else ''}").each ->
+        $(@).attr 'tabindex', ++$.fillTabIndexesCounter
+    @
+
+)( jQuery )

data/app/assets/javascripts/ultimate/improves/magic-radios.js.coffee

@@ -0,0 +1,41 @@
+#
+# Magic Radios
+#
+#  @example
+#    = f.radio_button :main_addr_same_as_jur, true, data: {disable: ".main-addr"}
+#    = f.radio_button :main_addr_same_as_jur, false, data: {enable: ".main-addr"}
+#    = f.text_field :main_addr, :disabled => @profile.main_addr_same_as_jur, :class => "main-addr"
+#    javascript:
+#      $('.some form').magicRadios();
+
+( ( $ ) ->
+
+  $.fn.magicRadios = (suspend = true, closestDock = 'fieldset, form, body', eventName = 'change.magic-radios') ->
+    if @length
+      jDocks = if @is 'input:radio' then @closest closestDock else @
+      jDocks.off eventName
+      if suspend
+        jDocks.on eventName, 'input:radio', (event) ->
+          jDock = $ event.delegateTarget
+          rules = [
+            ['enable',   'disabled', false, true]
+            ['check',    'checked',  true]
+            ['uncheck',  'checked',  false]
+            ['disable',  'disabled', true]
+            ['writable', 'readonly', false, true]
+            ['readonly', 'readonly', true]
+          ]
+          for rule in rules
+            [dataParam, propName, propValue, focusFirst] = rule
+            linkedFields = $(@).data dataParam
+            if linkedFields
+              jFounded = jDock.find linkedFields
+              jFields = jFounded.filter ':input'
+              jFields = jFounded.find ':input'  unless jFields.length
+              if jFields.length
+                jFields.prop propName, propValue
+                jFields.first().focus()  if focusFirst
+          true
+    @
+
+)( jQuery )

data/app/assets/javascripts/ultimate/improves/tablesorter.js

@@ -0,0 +1,59 @@
+/**
+ * Декорирование таблиц с данными + добавление сортировки + доп. обработка таблиц с checkable строками
+ *
+ * @param {jQuery} jRoot корневые jQuery объекты, в которых будет осуществляться поиск table.tablesorter:not(.decorated)
+ * @returns {Number} count >= 0 количество продекорированных таблиц
+ */
+function decor_tables(jRoot) {
+  var jTables = jRoot.find('table.tablesorter:not(.decorated)'),
+      jTablesHeaders = jTables.find('thead th:not([colspan])'),
+      ts_initData = {};
+  if ( arguments.length > 1 ) ts_initData.sortList = arguments[1];
+  jTablesHeaders.prepend('<div class="bullet-wrapper"><div class="bullet"></div></div>');
+  jTables.find('thead')
+  .find('tr:first th:first').addClass('first-child')
+  .prepend('<div class="corner-wrapper"><div class="corner left"></div></div>')
+  .end().find('tr th:last-child').addClass('last-child').first()
+  .prepend('<div class="corner-wrapper"><div class="corner right"></div></div>');
+  jTables.find('td:last-child').addClass('last-child');
+  jTables.each( function () {
+    var jTable = $(this),
+        jTFoot = jTable.children('tfoot');
+    if ( !jTFoot.length ) jTFoot = $('<tfoot></tfoot>').appendTo(jTable);
+    var jRow = $('<tr></tr>').appendTo(jTFoot);
+    $('<td colspan="' + jTable.find('thead th').length + '" class="border-bottom"></td>').appendTo(jRow)
+    .append('<div class="corner-wrapper"><div class="corner left"></div><div class="corner right"></div></div>');
+  } )
+  .addClass('decorated')
+  .tablesorter(ts_initData);
+  jTables.filter('.checkable').tablesorter({headers: { 0: { sorter: false}}})
+  .find('thead th.first-child').removeClass('header')
+  .find('.bullet-wrapper').remove();
+  return jTables.length;
+}
+
+$('table.checkable thead th:first input:checkbox').live('change', function () {
+  var jThis = $(this),
+      jTable = jThis.closest('table.checkable'),
+      jCheckboxes = jTable.find('tbody input:checkbox');
+  jCheckboxes.prop('checked', jThis.prop('checked'));
+  refresh_states(jTable);
+} );
+
+$('table.checkable tbody td:first-child input:checkbox').live('change', function () {
+  var jTable = $(this).closest('table.checkable');
+  jTable.find('input:checkbox#select_all').prop('checked', jTable.find('tbody input:checkbox:not(:checked)').length === 0);
+  refresh_states(jTable);
+} );
+
+
+
+$( function () {
+
+  if ( $.tablesorter ) {
+    $.tablesorter.defaults.widgets = ['zebra'];
+  }
+
+  //decor_tables($('body'));
+
+} );

data/app/assets/javascripts/ultimate/improves/typed-field.js.coffee

@@ -0,0 +1,98 @@
+( ( $ ) ->
+
+  # ========= max & min  =========
+  $('input:text[data-gte], input:text[data-lte]').live 'change focusout blur', ->
+    jField = $ @
+    realValue = jField.val()
+    if realValue isnt ''
+      min = parseFloat jField.data('gte')
+      max = parseFloat jField.data('lte')
+      oldValue = parseFloat realValue
+      v = oldValue
+      v = 0  if isNaN v
+      v = min  if not isNaN(min) and v < min
+      v = max  if not isNaN(max) and v > max
+      jField.val(v).change()  unless v is oldValue
+
+  $.fn.setFieldBounds = (min, max) ->
+    @filter('input:text')
+      .attr
+        'data-gte': min
+        'data-lte': max
+      .data
+        'gte': min
+        'lte': max
+
+  # ========= regexpMask  =========
+
+  $.regexp = {}  unless $.regexp
+  $.regexp.typedField =
+    'integer'   : /^$|^\d+$/
+    'float'     : /^$|^\d+(\.\d*)?$/
+    'currency'  : /^$|^\d+(\.\d{0,2})?$/
+    'text'      : /^.*$/
+
+  $.fn.getRegExpMask = ->
+    mask = @data 'regexpMask'
+    if _.isString(mask)
+      try
+        mask = new RegExp mask
+        @data 'regexpMask', mask
+      catch e
+        # nop
+    else
+      dataType = @data 'dataType'
+      mask = $.regexp.typedField[dataType]  if dataType
+    unless mask
+      @val 'unknown dataType'
+      mask = $.regexp.typedField['text']
+    mask
+
+  $.fn.dropRegExpMask = ->
+    @
+      .removeAttr('data-regexp-mask')
+      .removeData('regexpMask')
+      .removeData('value')
+
+  $.fn.setRegExpMask = (mask) ->
+    stringMask = 'true'
+    if _.isString mask
+      stringMask = mask
+      try
+        mask = new RegExp mask
+      catch e
+        # nop
+    if _.isRegExp mask
+      @
+        .dropRegExpMask()
+        .attr('data-regexp-mask', stringMask)
+        .data('regexpMask', mask)
+        .change()
+    @
+
+  $.fn.observeTypedFields = (selector = 'input:text[data-data-type], input:text[data-regexp-mask]') ->
+    return @  unless @length
+
+    @on 'keypress', selector, (event) ->
+      if event.metaKey
+        $(@).trigger 'paste', arguments
+        return true
+      return true  unless event.charCode
+      jThis = $ @
+      oldValue = jThis.val()
+      newValue = oldValue.substring(0, @selectionStart) + String.fromCharCode(event.charCode) + oldValue.substring(@selectionEnd)
+      return false  unless jThis.getRegExpMask().test(newValue)
+      jThis.data 'value', newValue
+
+    @on 'change', selector, ->
+      jThis = $ @
+      if jThis.getRegExpMask().test(jThis.val())
+        jThis.data 'value', jThis.val()
+      else
+        jThis.val jThis.data('value')
+        
+    @on 'paste drop', selector, ->
+      jThis = $ @
+      setTimeout ( -> jThis.trigger 'change', arguments ), 100
+
+)( jQuery )