trackler 2.2.1.41 → 2.2.1.42

data/tracks/coldfusion/exercises/triangle/Triangle.cfc

@@ -1,18 +0,0 @@
-/**
-* Your implmentation of the Triangle exercise
-*/
-component {
-	
-	function equilateral( array sides ) {
-		// Implement me here
-	}
-	
-	function isosceles( array sides ) {
-		// Implement me here
-	}
-	
-	function scalene( array sides ) {
-		// Implement me here
-	}
-	
-}

data/tracks/coldfusion/exercises/triangle/TriangleTest.cfc

@@ -1,95 +0,0 @@
-component extends="testbox.system.BaseSpec" {
-
-	function beforeAll(){
-	  SUT = createObject( 'Triangle' );
-	}
-
-	function run(){
-	
-		describe( "My Triangle class", function(){			
-
-			describe( 'returns true if the triangle is equilateral', function(){
-
-				it( 'true if all sides are equal', function(){
-					expect( SUT.equilateral( sides=[2, 2, 2] ) ).toBeTrue();
-				});
-
-				it( 'false if any side is unequal', function(){
-					expect( SUT.equilateral( sides=[2, 3, 2] ) ).toBeFalse();
-				});
-
-				it( 'false if no sides are equal', function(){
-					expect( SUT.equilateral( sides=[5, 4, 6] ) ).toBeFalse();
-				});
-
-				it( 'All zero sides are illegal, so the triangle is not equilateral', function(){
-					expect( SUT.equilateral( sides=[0, 0, 0] ) ).toBeFalse();
-				});
-
-				it( 'sides may be floats', function(){
-					expect( SUT.equilateral( sides=[0.5, 0.5, 0.5] ) ).toBeTrue();
-				});
-
-			});
-
-			describe( 'returns true if the triangle is isosceles', function(){
-
-				it( 'true if last two sides are equal', function(){
-					expect( SUT.isosceles( sides=[3, 4, 4] ) ).toBeTrue();
-				});
-
-				it( 'true if first two sides are equal', function(){
-					expect( SUT.isosceles( sides=[4, 4, 3] ) ).toBeTrue();
-				});
-
-				it( 'true if first and last sides are equal', function(){
-					expect( SUT.isosceles( sides=[4, 3, 4] ) ).toBeTrue();
-				});
-
-				it( 'equilateral triangles are also isosceles', function(){
-					expect( SUT.isosceles( sides=[4, 4, 4] ) ).toBeTrue();
-				});
-
-				it( 'false if no sides are equal', function(){
-					expect( SUT.isosceles( sides=[2, 3, 4] ) ).toBeFalse();
-				});
-
-				it( 'Sides that violate triangle inequality are not isosceles, even if two are equal', function(){
-					expect( SUT.isosceles( sides=[1, 1, 3] ) ).toBeFalse();
-				});
-
-				it( 'sides may be floats', function(){
-					expect( SUT.isosceles( sides=[0.5, 0.4, 0.5] ) ).toBeTrue();
-				});
-
-			});
-
-			describe( 'returns true if the triangle is scalene', function(){
-
-				it( 'true if no sides are equal', function(){
-					expect( SUT.scalene( sides=[5, 4, 6] ) ).toBeTrue();
-				});
-
-				it( 'false if all sides are equal', function(){
-					expect( SUT.scalene( sides=[4, 4, 4] ) ).toBeFalse();
-				});
-
-				it( 'false if two sides are equal', function(){
-					expect( SUT.scalene( sides=[4, 4, 3] ) ).toBeFalse();
-				});
-
-				it( 'Sides that violate triangle inequality are not scalene, even if they are all different', function(){
-					expect( SUT.scalene( sides=[7, 3, 2] ) ).toBeFalse();
-				});
-
-				it( 'sides may be floats', function(){
-					expect( SUT.scalene( sides=[0.5, 0.4, 0.6] ) ).toBeTrue();
-				});
-
-			});
-
-		});
-		
-	}
- 
-}

data/tracks/coldfusion/exercises/triangle/box.json

@@ -1,8 +0,0 @@
-{
-    "dependencies":{
-        "testbox":"^2.5.0+107"
-    },
-    "installPaths":{
-        "testbox":"testbox"
-    }
-}

data/tracks/coldfusion/exercises/triangle/index.cfm

@@ -1,37 +0,0 @@
-<!--- 
-
-This file will only be used if you want to start up a web server in this directory.  You can do so by running:
-
-$> box
-CommandBox> install
-CommandBox> server start
-
-However, this is not necessary unless you really just want to use the HTML reporters on TestBox.  
-Ideally, you'll skip the need for this file entirely and just run the tests directly frm the CLI like this:
-
-CommandBox> task run TestRunner
-
- --->
-<cfsetting showDebugOutput="false">
-<cfparam name="url.reporter" 		default="simple">
-<cfscript>
-	// get a list of all CFCs in this folder whose name looks like "XXXTest.cfc"
-	// And turn it into compnent path relative to the web root
-	url.bundles = directoryList(
-			path=expandPath( '/' ),
-			filter='*Test.cfc' )
-		.map( function( path ) {
-			return path
-					.replaceNoCase( expandPath( '/' ), '' )
-					.left( -4 )
-		} )
-		.toList();
-</cfscript>
-
-<!--- Ensure TestBox --->
-<cfif fileExists( "/testbox/system/runners/HTMLRunner.cfm" )>
-	<!--- Include the TestBox HTML Runner --->
-	<cfinclude template="/testbox/system/runners/HTMLRunner.cfm">
-<cfelse>
-	Oops, you don't have TestBox installed yet! Please run <b>box install</b> from the root of your excercise folder and refresh this page.	
-</cfif>

data/tracks/coldfusion/exercises/word-count/Solution.cfc

@@ -1,22 +0,0 @@
-/**
-* Here is an example solution for the WordCount exercise
-*/
-component {
-		
-	function countwords( input ) {
-		return input
-			// Strip out chars we don't care about
-			.reReplaceNoCase( '[^a-z0-9'' ]', '', 'all' )
-			// Break string into array
-			.listToArray( ' ' )
-			// Reduce arary into struct of word counts
-			.reduce( function( wordStats, word ){
-				// Clean quoted words
-				word = word.reReplaceNocase( "^'(.*)'$", "\1" );
-				// Aggregate word counts
-				wordStats[ word ] = ( wordStats[ word ] ?: 0 ) + 1;
-				return wordStats;
-			}, {} );
-	}
-	
-}

data/tracks/coldfusion/exercises/word-count/SolutionTest.cfc

@@ -1,7 +0,0 @@
-component extends="WordCountTest" {
-
-	function beforeAll(){
-	  SUT = createObject( 'Solution' );
-	}
-
-}

data/tracks/coldfusion/exercises/word-count/TestRunner.cfc

@@ -1,103 +0,0 @@
-/**
-* I am a CommandBox task runner which you can use to test your implementation of this exercise against the 
-* provided test suite.  To use me, open the CommandBox CLI and run this:
-* 
-* CommandBox> task run TestRunner
-*
-* To start up a test watcher that will automatically rerun the test suite every time you save a file change, run this:
-*
-* CommandBox> task run TestRunner --watcher
-*
-*/
-component {
-	
-	/**
-	* @solution Runs the tests against the solution
-	* @watcher Start up a file watch that re-runs the tests on file changes. Use Ctrl-C to stop
-	*/
-	function run( boolean solution=false, boolean watcher=false ) {
-		
-		ensureTestBox();
-
-		if( watcher ) {
-		
-			// Tabula rasa
-			command( 'cls' ).run();
-				
-			// Start watcher
-			watch()
-				.paths( '*.cfc' )
-				.inDirectory( getCWD() )
-				.withDelay( 500 )
-				.onChange( function() {
-	
-					// Clear the screen
-					command( 'cls' )
-						.run();
-
-					// This is neccessary so changes to tests get picked up right away.
-					pagePoolClear();	
-					
-					runTests( solution );
-	
-				} )
-				.start();
-					
-		} else {
-			runTests( solution );
-		}			
-
-	}
-
-	/**
-	* Make sure the TestBox framework is installed
-	*/
-	private function ensureTestBox() {
-		var excerciseRoot = getCWD();
-		var testBoxRoot = excerciseRoot & '/testbox';
-		
-		if( !directoryExists( testBoxRoot ) ) {
-			
-			print.boldYellowLine( 'Installing some missing dependencies for you!' ).toConsole();
-			command( 'install' )
-				.inWorkingDirectory( excerciseRoot )
-				.run();
-		}
-		
-		// Bootstrap TestBox framework
-		filesystemUtil.createMapping( '/testbox', testBoxRoot );
-	}
-
-	/**
-	* Invoke TestBox to run the test suite
-	*/
-	private function runTests( boolean solution=false ) {
-		
-		// Create TestBox and run the tests
-		testData = new testbox.system.TestBox()
-			.runRaw( directory = {
-				// Find all CFCs...
-				mapping = filesystemUtil.makePathRelative( getCWD() ),
-				// ... in this directory ...
-				recurse = false,
-				// ... whose name ends in "test"
-				filter = function( path ) {
-					return path.reFind( ( solution ? 'Solution' : '' ) & 'Test.cfc$' );
-				 }
-			} )
-			.getMemento();
-		
-		// Print out the results with ANSI formatting for the CLI
-		getInstance( 'CLIRenderer@testbox-commands' )
-			.render( print, testData, true );
-			
-		print.toConsole();
-		
-		// Set proper exit code
-		if( testData.totalFail || testData.totalError ) {
-			setExitCode( 1 );
-		}
-	}
-
-}
-

data/tracks/coldfusion/exercises/word-count/WordCount.cfc

@@ -1,13 +0,0 @@
-/**
-* Your implmentation of the WordCount exercise
-*/
-component {
-	
-	/**
-	* @returns 
-	*/
-	function countwords( input ) {
-		// Implement me here
-	}
-	
-}

data/tracks/coldfusion/exercises/word-count/WordCountTest.cfc

@@ -1,55 +0,0 @@
-component extends="testbox.system.BaseSpec" {
-
-	function beforeAll(){
-	  SUT = createObject( 'WordCount' );
-	}
-
-	function run(){
-	
-		describe( "My WordCount class", function(){			
-
-			it( 'count one word', function(){
-				expect( SUT.countwords( input='word' ) ).toBe( {"word":1} );
-			});
-
-			it( 'count one of each word', function(){
-				expect( SUT.countwords( input='one of each' ) ).toBe( {"one":1,"of":1,"each":1} );
-			});
-
-			it( 'multiple occurrences of a word', function(){
-				expect( SUT.countwords( input='one fish two fish red fish blue fish' ) ).toBe( {"one":1,"fish":4,"two":1,"red":1,"blue":1} );
-			});
-
-			it( 'handles cramped lists', function(){
-				expect( SUT.countwords( input='one, two, three' ) ).toBe( {"one":1,"two":1,"three":1} );
-			});
-
-			it( 'handles expanded lists', function(){
-				expect( SUT.countwords( input='one, #chr( 10 )#two, #chr( 10 )#three' ) ).toBe( {"one":1,"two":1,"three":1} );
-			});
-
-			it( 'ignore punctuation', function(){
-				expect( SUT.countwords( input='car: carpet as java: javascript!!&@$%^&' ) ).toBe( {"car":1,"carpet":1,"as":1,"java":1,"javascript":1} );
-			});
-
-			it( 'include numbers', function(){
-				expect( SUT.countwords( input='testing,  1,  2 testing' ) ).toBe( {"testing":2,"1":1,"2":1} );
-			});
-
-			it( 'normalize case', function(){
-				expect( SUT.countwords( input='go Go GO Stop stop' ) ).toBe( {"go":3,"stop":2} );
-			});
-
-			it( 'with apostrophes', function(){
-				expect( SUT.countwords( input='First: don''t laugh. Then: don''t cry.' ) ).toBe( {"first":1,"don't":2,"laugh":1,"then":1,"cry":1} );
-			});
-
-			it( 'with quotations', function(){
-				expect( SUT.countwords( input='Joe can''t tell between ''large'' and large.' ) ).toBe( {"joe":1,"can't":1,"tell":1,"between":1,"large":2,"and":1} );
-			});
-
-		});
-		
-	}
- 
-}

data/tracks/coldfusion/exercises/word-count/box.json

@@ -1,8 +0,0 @@
-{
-    "dependencies":{
-        "testbox":"^2.5.0+107"
-    },
-    "installPaths":{
-        "testbox":"testbox"
-    }
-}

data/tracks/coldfusion/exercises/word-count/index.cfm

@@ -1,37 +0,0 @@
-<!--- 
-
-This file will only be used if you want to start up a web server in this directory.  You can do so by running:
-
-$> box
-CommandBox> install
-CommandBox> server start
-
-However, this is not necessary unless you really just want to use the HTML reporters on TestBox.  
-Ideally, you'll skip the need for this file entirely and just run the tests directly frm the CLI like this:
-
-CommandBox> task run TestRunner
-
- --->
-<cfsetting showDebugOutput="false">
-<cfparam name="url.reporter" 		default="simple">
-<cfscript>
-	// get a list of all CFCs in this folder whose name looks like "XXXTest.cfc"
-	// And turn it into compnent path relative to the web root
-	url.bundles = directoryList(
-			path=expandPath( '/' ),
-			filter='*Test.cfc' )
-		.map( function( path ) {
-			return path
-					.replaceNoCase( expandPath( '/' ), '' )
-					.left( -4 )
-		} )
-		.toList();
-</cfscript>
-
-<!--- Ensure TestBox --->
-<cfif fileExists( "/testbox/system/runners/HTMLRunner.cfm" )>
-	<!--- Include the TestBox HTML Runner --->
-	<cfinclude template="/testbox/system/runners/HTMLRunner.cfm">
-<cfelse>
-	Oops, you don't have TestBox installed yet! Please run <b>box install</b> from the root of your excercise folder and refresh this page.	
-</cfif>

data/tracks/coldfusion/tasks/GenerateTests.cfc

@@ -1,179 +0,0 @@
-/**
-* I scaffold a new exercise from the template.
-*/
-component {
-	
-	function run(
-		slug,
-		boolean all=false
-	) {
-		var repoRootPath = expandPath( getDirectoryFromPath( getCurrentTemplatePath() ) & '../' );
-		var problemSpecsPath = expandPath( getDirectoryFromPath( getCurrentTemplatePath() ) & '../../problem-specifications' );
-				
-		if( !directoryExists( problemSpecsPath ) ){
-			error( 'Cannot find [problem-specifications] repo.  It needs to be git cloned to [#problemSpecsPath#]' );
-		}
-		
-		if( all ) {
-			
-			// Get an array of all the excercise names
-			var exercises = directoryList( expandPath( getDirectoryFromPath( getCurrentTemplatePath() ) & '../exercises' ) )
-				.map( function( path ) {
-					return path.listLast( '/\' );
-				} );
-		
-		} else {
-		
-			// Acquire slug
-			if( isNull( arguments.slug ) ) {
-				arguments.slug = ask( 'Exercise slug as defined by Excercism. Ex: "hello-world": ' );
-			}
-			var exercises = [ slug ];
-			
-		}
-				
-		exercises.each( function( slug ) {
-			
-			try {
-				
-				// Slug of hello-world defaults to name of HelloWorld
-				var exerciseName = arguments.slug
-					.listToArray( '-' )
-					.map( function( i ){
-						return i.left( 1 ).uCase() & i.right( -1 ).lCase();
-					} )
-					.toList( '' );
-				
-				var exercisePath = problemSpecsPath & '/exercises/' & slug;
-				if( !directoryExists( exercisePath ) ){
-					error( 'Cannot find exercise [#slug#] in problem-specifications repo.  Tests not generated.' );
-				}
-				
-				var canonicalDataPath = exercisePath & '/canonical-data.json';
-				if( !fileExists( canonicalDataPath ) ){
-					error( 'Cannot find [canonical-data.json] for this slug.  No tests will be generated' );
-				}
-		
-				var canonicalData = deserializeJSON( fileRead( canonicalDataPath ) );
-				var testCases = generateCases( canonicalData.cases );
-				
-				var testStub = fileRead( repoRootPath & '/tasks/exercise_template/@@name@@Test.cfc' );
-				testStub = testStub.replace( '@@name@@', exerciseName, 'all' );
-				testStub = testStub.replace( '@@testCases@@', testCases, 'all' );
-				var targetExercisePath = repoRootPath & 'exercises/' & slug;
-				var newTestPath = targetExercisePath & '/' & exerciseName & 'Test.cfc';
-				
-				if( !directoryExists( targetExercisePath ) ) {
-					error( 'Target exercise does not exist! [#targetExercisePath#]' );
-				}
-				
-				fileWrite( newTestPath, testStub );
-				
-				print.greenLine( 'Test generated!' )
-					.indentedYellowLine( newTestPath )
-					.toConsole();
-			} catch( 'commandException' var e ) {
-				print.boldRedLine( e.message )
-					.line();
-			}
-			
-		} ); // End exercises.each()
-	}
-	
-	private function generateCases( cases, level=1 ) {
-		var CRLF = chr( 13 ) & chr( 10 );
-		var testCases = ''
-			
-		cases.each( function( case ) {
-				
-			// Nested spec
-			if( case.keyExists( 'cases' ) ) {
-				
-					testCases &=  "#CRLF##repeatString( chr( 9 ), level )#		describe( #generateDescription( case.description )#, function(){
-#generateCases( case.cases, level+1 )#
-#repeatString( chr( 9 ), level )#		});#CRLF#";
-					
-			} else {
-				case.expected = case.expected ?: '__NULL__';
-				// Don't adjust whitespace
-				testCases &=  "#CRLF##repeatString( chr( 9 ), level )#		it( #generateDescription( case.description )#, function(){#CRLF#";
-				// Special check for when error should be tested
-				if( isStruct( case.expected ) && case.expected.keyExists( 'error' ) ) {
-					testCases &=  "#repeatString( chr( 9 ), level )#			expect( function(){ SUT.#case.property#(#generateInput( case )#); } ).#generateExpectation( case.expected )#;#CRLF#";	
-				// "normal" expectation
-				} else {
-					testCases &=  "#repeatString( chr( 9 ), level )#			expect( SUT.#case.property#(#generateInput( case )#) ).#generateExpectation( case.expected )#;#CRLF#";
-				}
-				testCases &=  "#repeatString( chr( 9 ), level )#		});#CRLF#";
-			} 
-			
-		} );
-		
-		return testCases;
-	}
-	
-	private function generateDescription( description ) {
-		return escapeString( description );
-	}
-	
-	private function generateInput( case ) {
-		var thisInput = '';
-		for( var key in case ) {
-			if( !listFindNoCase( 'description,property,expected,cases,comments', key ) && !isNull( case[ key ] ) ) {
-				thisInput = thisInput.listAppend( "#key#=#escapeString( case[ key ] )#" );
-			}
-		}
-		if( thisInput.len() ) {
-			return ' ' & thisInput.listChangeDelims( ', ', ',' ) & ' ';				
-		} else {
-			return thisInput;				
-		}
-	}
-	
-	private function generateExpectation( expected ) {
-		if( isSimpleValue( expected ) && compareNoCase( expected, 'true' ) == 0 ) {
-			return 'toBeTrue()';
-		} else if( isSimpleValue( expected ) && compareNoCase( expected, 'false' ) == 0 ) {
-			return 'toBeFalse()';
-		} else if( isSimpleValue( expected) && expected == '__NULL__' ) {
-			return 'toBeNull()';
-		} else if( isStruct( expected ) && expected.keyExists( 'error' ) ) {
-			return 'toThrow( message=#escapeString( expected.error )# )';
-		} else {
-			return "toBe( #escapeString( expected )# )";
-		}
-		
-	}
-	
-	private function escapeString( myString ) {
-		if( isSimpleValue( myString ) ) {
-			myString = replace( myString, "'", "''", "all" );
-			myString = replace( myString, '##', '####', 'all' );
-			myString = replace( myString, chr( 13 ), '##chr( 13 )##', 'all' );
-			myString = replace( myString, chr( 10 ), '##chr( 10 )##', 'all' );
-			return "'" & myString & "'";
-		} else {
-			return convertJSONEscapesToCFML( serializeJSON( myString ) );			
-		}
-	}
-	
-	
-	// A complex value serialized as JSON differs from CFML struct literals in that
-	// double quotes are \" instead of "".  Any escaped double quotes must be converted
-	// to the CFML version to work as an object literal.
-	private function convertJSONEscapesToCFML( required string arg ) {
-		arguments.arg = replaceNoCase( arguments.arg, '\\', '__double_backslash_', 'all' );
-		arguments.arg = replaceNoCase( arguments.arg, '\/', '/', 'all' );
-		arguments.arg = replaceNoCase( arguments.arg, '\"', '""', 'all' );
-		arguments.arg = replaceNoCase( arguments.arg, '\t', '	', 'all' );
-		arguments.arg = replaceNoCase( arguments.arg, '\n', chr(13)&chr(10), 'all' );
-		arguments.arg = replaceNoCase( arguments.arg, '\r', chr(13), 'all' );
-		arguments.arg = replaceNoCase( arguments.arg, '\f', chr(12), 'all' );
-		arguments.arg = replaceNoCase( arguments.arg, '\b', chr(8), 'all' );
-		// This doesn't work-- I'd need to do it in a loop and replace each one individually.  Meh...
-		// arguments.arg = reReplaceNoCase( arguments.arg, '\\u([0-9a-f]{4})', chr( inputBaseN( '\1', 16 ) ), 'all' );
-		arguments.arg = replaceNoCase( arguments.arg, '__double_backslash_', '\', 'all' );
-		return arguments.arg;
-	}
-	
-}