tomkersten-vixploder 0.1.1 → 0.1.2

data/lib/dotfiles/vim/plugin/fuzzyfinder_textmate.vim

@@ -0,0 +1,150 @@
+if has("ruby")
+
+" ====================================================================================
+" COPIED FROM FUZZYFINDER.VIM {{{
+" since they can't be called from outside fuzzyfinder.vim
+" ====================================================================================
+function! s:GetCurrentTagFiles()
+  return sort(filter(map(tagfiles(), 'fnamemodify(v:val, '':p'')'), 'filereadable(v:val)'))
+endfunction
+
+function! s:HighlightPrompt(prompt, highlight)
+  syntax clear
+  execute printf('syntax match %s /^\V%s/', a:highlight, escape(a:prompt, '\'))
+endfunction
+
+function! s:HighlightError()
+  syntax clear
+  syntax match Error  /^.*$/
+endfunction
+" ------------------------------------------------------------------------------------
+" }}}
+" ====================================================================================
+
+command! -bang -narg=? -complete=file   FuzzyFinderTextMate   call FuzzyFinderTextMateLauncher(<q-args>, len(<q-bang>), bufnr('%'), s:GetCurrentTagFiles())
+
+function! InstantiateTextMateMode() "{{{
+ruby << RUBY
+  begin
+    require "#{ENV['HOME']}/.vim/ruby/fuzzy_file_finder"
+  rescue LoadError
+    begin
+      require 'rubygems'
+      begin
+        gem 'fuzzy_file_finder'
+      rescue Gem::LoadError
+        gem 'jamis-fuzzy_file_finder'
+      end
+    rescue LoadError
+    end
+
+    require 'fuzzy_file_finder'
+  end
+RUBY
+
+  " Configuration option: g:fuzzy_roots
+  " Specifies roots in which the FuzzyFinder will search.
+  if !exists('g:fuzzy_roots')
+    let g:fuzzy_roots = ['.']
+  endif
+
+  " Configuration option: g:fuzzy_ceiling
+  " Specifies the maximum number of files that FuzzyFinder allows to be searched
+  if !exists('g:fuzzy_ceiling')
+    let g:fuzzy_ceiling = 10000
+  endif
+
+  " Configuration option: g:fuzzy_ignore
+  " A semi-colon delimited list of file glob patterns to ignore
+  if !exists('g:fuzzy_ignore')
+    let g:fuzzy_ignore = ""
+  endif
+
+  " Configuration option: g:fuzzy_matching_limit
+  " The maximum number of matches to return at a time. Defaults to 200, via the
+  " g:FuzzyFinderMode.TextMate.matching_limit variable, but using a global variable
+  " makes it easier to set this value.
+
+ruby << RUBY
+  def finder
+    @finder ||= begin
+      roots = VIM.evaluate("g:fuzzy_roots").split("\n")
+      ceiling = VIM.evaluate("g:fuzzy_ceiling").to_i
+      ignore = VIM.evaluate("g:fuzzy_ignore").split(/;/)
+      FuzzyFileFinder.new(roots, ceiling, ignore)
+    end
+  end
+RUBY
+
+  let g:FuzzyFinderMode.TextMate = copy(g:FuzzyFinderMode.Base)
+
+  " ================================================================================
+  " This function is copied almost whole-sale from fuzzyfinder.vim. Ideally, I could
+  " used the on_complete callback to more cleanly add the new behavior, but the
+  " TextMate-style completion broke a few of fuzzyfinder.vim's assumptions, and the
+  " only way to patch that up was to override Base.complete...which required me to
+  " copy-and-paste much of the original implementation.
+  "
+  " Ugly. But effective.
+  " ================================================================================
+  function! g:FuzzyFinderMode.TextMate.complete(findstart, base)
+    if a:findstart
+      return 0
+    elseif  !self.exists_prompt(a:base) || len(self.remove_prompt(a:base)) < self.min_length
+      return []
+    endif
+    call s:HighlightPrompt(self.prompt, self.prompt_highlight)
+
+    let result = []
+
+    if exists('g:fuzzy_matching_limit')
+      let l:limit = g:fuzzy_matching_limit
+    else
+      let l:limit = self.matching_limit
+    endif
+
+    ruby << RUBY
+      text = VIM.evaluate('self.remove_prompt(a:base)')
+      limit = VIM.evaluate('l:limit').to_i
+
+      matches = finder.find(text, limit)
+      matches.sort_by { |a| [-a[:score], a[:path]] }.each_with_index do |match, index|
+        word = match[:path]
+        abbr = "%2d: %s" % [index+1, match[:abbr]]
+        menu = "[%5d]" % [match[:score] * 10000]
+        VIM.evaluate("add(result, { 'word' : #{word.inspect}, 'abbr' : #{abbr.inspect}, 'menu' : #{menu.inspect} })")
+      end
+RUBY
+
+    if empty(result) || len(result) >= self.matching_limit
+      call s:HighlightError()
+    endif
+
+    if !empty(result)
+      call feedkeys("\<C-p>\<Down>", 'n')
+    endif
+
+    return result
+  endfunction
+
+  function! FuzzyFinderTextMateLauncher(initial_text, partial_matching, prev_bufnr, tag_files)
+    call g:FuzzyFinderMode.TextMate.launch(a:initial_text, a:partial_matching, a:prev_bufnr, a:tag_files)
+  endfunction
+
+  let g:FuzzyFinderOptions.TextMate = copy(g:FuzzyFinderOptions.File)
+endfunction "}}}
+
+if !exists('loaded_fuzzyfinder') "{{{
+  function! FuzzyFinderTextMateLauncher(initial_text, partial_matching, prev_bufnr, tag_files)
+    call InstantiateTextMateMode()
+    function! FuzzyFinderTextMateLauncher(initial_text, partial_matching, prev_bufnr, tag_files)
+      call g:FuzzyFinderMode.TextMate.launch(a:initial_text, a:partial_matching, a:prev_bufnr, a:tag_files)
+    endfunction
+    call g:FuzzyFinderMode.TextMate.launch(a:initial_text, a:partial_matching, a:prev_bufnr, a:tag_files)
+  endfunction
+  finish
+end "}}}
+
+call InstantiateTextMateMode()
+
+endif

data/lib/dotfiles/vim/plugin/gist.vim

@@ -0,0 +1,241 @@
+"=============================================================================
+" File: gist.vim
+" Author: Yasuhiro Matsumoto <mattn.jp@gmail.com>
+" Last Change: 22-Dec-2008. Jan 2008
+" Version: 1.5
+" Usage:
+"
+"   :Gist
+"     post whole text to gist.
+"
+"   :'<,'>Gist
+"     post selected text to gist.
+"
+"   :Gist -p
+"     post whole text to gist with private.
+"
+"   :Gist XXXXX
+"     edit gist XXXXX.
+"
+"   :Gist -l
+"     list gists from mine.
+"
+"   :Gist -l mattn
+"     list gists from mattn.
+"
+"   :Gist -la
+"     list gists from all.
+"
+" Tips:
+"   * if set g:gist_clip_command, gist.vim will copy the gist code.
+"
+"     # mac
+"     let g:gist_clip_command = 'pbcopy'
+"
+"     # linux
+"     let g:gist_clip_command = 'xclip -selection clipboard'
+"
+"     # others(cygwin?)
+"     let g:gist_clip_command = 'putclip'
+"
+"   * if you want to detect filetype from gist's filename...
+"
+"     # detect filetype if vim failed auto-detection.
+"     let g:gist_detect_filetype = 1
+"
+"     # detect filetype always.
+"     let g:gist_detect_filetype = 2
+"
+" GetLatestVimScripts: 2423 1 :AutoInstall: gist.vim
+
+if &cp || (exists('g:loaded_gist_vim') && g:loaded_gist_vim)
+  finish
+endif
+let g:loaded_gist_vim = 1
+
+if (!exists('g:github_user') || !exists('g:github_token')) && !executable('git')
+  echoerr "Gist: require 'git' command"
+  finish
+endif
+
+if !executable('curl')
+  echoerr "Gist: require 'curl' command"
+  finish
+endif
+
+if !exists('g:gist_detect_filetype')
+  let g:gist_detect_filetype = 0
+endif
+
+function! s:nr2hex(nr)
+  let n = a:nr
+  let r = ""
+  while n
+    let r = '0123456789ABCDEF'[n % 16] . r
+    let n = n / 16
+  endwhile
+  return r
+endfunction
+
+function! s:encodeURIComponent(instr)
+  let instr = iconv(a:instr, &enc, "utf-8")
+  let len = strlen(instr)
+  let i = 0
+  let outstr = ''
+  while i < len
+    let ch = instr[i]
+    if ch =~# '[0-9A-Za-z-._~!''()*]'
+      let outstr = outstr . ch
+    elseif ch == ' '
+      let outstr = outstr . '+'
+    else
+      let outstr = outstr . '%' . substitute('0' . s:nr2hex(char2nr(ch)), '^.*\(..\)$', '\1', '')
+    endif
+    let i = i + 1
+  endwhile
+  return outstr
+endfunction
+
+function! s:GistList(user, token, gistls)
+  if a:gistls == '-all'
+    let url = 'http://gist.github.com/gists'
+  else
+    let url = 'http://gist.github.com/'.a:gistls
+  endif
+  exec 'silent split gist:'.a:gistls
+  exec 'silent 0r! curl -s '.url
+  silent! %s/>/>\r/g
+  silent! %s/</\r</g
+  silent! %g/<pre/,/<\/pre/join!
+  silent! %v/^\(gist:\|<pre>\)/d _
+  silent! %s/<div[^>]*>/\r  /g
+  silent! %s/<\/pre>/\r/g
+  silent! %s/<[^>]\+>//g
+  silent! %s/\r//g
+  silent! %s/&nbsp;/ /g
+  silent! %s/&quot;/"/g
+  silent! %s/&amp;/\&/g
+  silent! %s/&gt;/>/g
+  silent! %s/&lt;/</g
+  silent! %s/&#\(\d\d\);/\=nr2char(submatch(1))/g
+  setlocal nomodified
+  syntax match SpecialKey /^gist: /he=e-2
+  exec 'nnoremap <silent> <buffer> <cr> :call <SID>GistListAction()<cr>'
+  normal! gg
+endfunction
+
+function! s:GistDetectFiletype(gistid)
+  let url = 'http://gist.github.com/'.a:gistid
+  let res = system('curl -s '.url)
+  let res = substitute(res, '^.*<div class="meta">[\r\n ]*<div class="info">[\r\n ]*<span>\([^>]\+\)</span>.*$', '\1', '')
+  let res = substitute(res, '.*\(\.[^\.]\+\)$', '\1', '')
+  if res =~ '^\.'
+    silent! exec "doau BufRead *".res
+  else
+    silent! exec "setlocal ft=".tolower(res)
+  endif
+endfunction
+
+function! s:GistGet(user, token, gistid)
+  let url = 'http://gist.github.com/'.a:gistid.'.txt'
+  exec 'silent split gist:'.a:gistid
+  filetype detect
+  exec 'silent 0r! curl -s '.url
+  setlocal nomodified
+  doau StdinReadPost <buffer>
+  normal! gg
+  if (&ft == '' && g:gist_detect_filetype == 1) || g:gist_detect_filetype == 2
+    call s:GistDetectFiletype(a:gistid)
+  endif
+  if exists('g:gist_clip_command')
+    exec 'silent w !'.g:gist_clip_command
+  endif
+endfunction
+
+function! s:GistListAction()
+  let line = getline('.')
+  let mx = '^gist: \(\w\+\)$'
+  if line =~# mx
+    let gistid = substitute(line, mx, '\1', '')
+    call s:GistGet(g:github_user, g:github_token, gistid)
+  endif
+endfunction
+
+function! s:GistPut(user, token, content, private)
+  let ext = expand('%:e')
+  let ext = len(ext) ? '.'.ext : ''
+  let name = expand('%:t')
+  let query = [
+    \ 'file_ext[gistfile1]=%s',
+    \ 'file_name[gistfile1]=%s',
+    \ 'file_contents[gistfile1]=%s',
+    \ 'login=%s',
+    \ 'token=%s',
+    \ ]
+  if len(a:private)
+    call add(query, 'private=on')
+  endif
+  let squery = printf(join(query, '&'),
+    \ s:encodeURIComponent(ext),
+    \ s:encodeURIComponent(name),
+    \ s:encodeURIComponent(a:content),
+    \ s:encodeURIComponent(a:user),
+    \ s:encodeURIComponent(a:token))
+  unlet query
+
+  let file = tempname()
+  exec 'redir! > '.file 
+  silent echo squery
+  redir END
+  echon " Posting it to gist... "
+  let quote = &shellxquote == '"' ?  "'" : '"'
+  let url = 'http://gist.github.com/gists'
+  let res = system('curl -i -d @'.quote.file.quote.' '.url)
+  call delete(file)
+  let res = matchstr(split(res, "\n"), '^Location: ')
+  let res = substitute(res, '^.*: ', '', '')
+  let throwaway = system('echo '.quote.res.quote.'| pbcopy')
+  echo 'Done!'
+  echo 'Gist URL: '.res
+endfunction
+
+function! Gist(line1, line2, ...)
+  if !exists('g:github_user')
+    let g:github_user = substitute(system('git config --global github.user'), "\n", '', '')
+  endif
+  if !exists('g:github_token')
+    let g:github_token = substitute(system('git config --global github.token'), "\n", '', '')
+  endif
+
+  let opt = (a:0 > 0) ? substitute(a:1, ' ', '', 'g') : ''
+  let private = ''
+  let gistid = ''
+  let gistls = ''
+  let listmx = '^\(-l\|--list\)\s*\([^\s]\+\)\?$'
+  if opt =~ '^\(-la\|--listall\)'
+    let gistls = '-all'
+  elseif opt =~ listmx
+    let gistls = substitute(opt, listmx, '\2', '')
+    if len(gistls) == 0
+      let gistls = g:github_user
+    endif
+  elseif opt =~ '-p\|--private'
+    let private = 'on'
+  elseif opt =~ '^\w\+$'
+    let gistid = opt
+  elseif len(opt) > 0
+    echoerr 'Invalid arguments'
+    return
+  endif
+
+  if len(gistls) > 0
+    call s:GistList(g:github_user, g:github_token, gistls)
+  elseif len(gistid) > 0
+    call s:GistGet(g:github_user, g:github_token, gistid)
+  else
+    let content = join(getline(a:line1, a:line2), "\n")
+    call s:GistPut(g:github_user, g:github_token, content, private)
+  endif
+endfunction
+
+command! -nargs=? -range=% Gist :call Gist(<line1>, <line2>, <f-args>)

data/lib/dotfiles/vim/plugin/gitdiff.vim

@@ -0,0 +1,141 @@
+" gitdiff.vim : git helper functions
+" http://www.vim.org/scripts/script.php?script_id=1846
+"
+" Author:   Bart Trojanowski <bart@jukie.net>
+" Date:     2007/05/02
+" Version:  2
+" 
+" GetLatestVimScripts: 1846 1 :AutoInstall: gitdiff.vim
+
+"------------------------------------------------------------------------
+"
+" This script currently installs two new functions:
+"
+" :GITDiff [rev]
+"
+"    Vertical split with working buffer, showing vimdiff between current
+"    buffer and a commit.
+"
+" :GITChanges [rev]
+"
+"    Highlights modified lines in current buffer.
+"    Disable with :syntax on
+"
+"------------------------------------------------------------------------
+
+if exists("loaded_gitdiff") || &compatible
+    finish
+endif
+let loaded_gitdiff = 1
+
+"" ------------------------------------------------------------------------
+" based on svndiff from...
+" http://www.axisym3.net/jdany/vim-the-editor/
+"" ------------------------------------------------------------------------
+
+command! -nargs=? GITDiff :call s:GitDiff(<f-args>)
+
+function! s:GitDiff(...)
+    if a:0 == 1
+        let rev = a:1
+    else
+        let rev = 'HEAD'
+    endif
+
+    let ftype = &filetype
+
+    let prefix = system("git rev-parse --show-prefix")
+    let thisfile = substitute(expand("%"),getcwd(),'','')
+    let gitfile = substitute(prefix,'\n$','','') . thisfile
+
+    " Check out the revision to a temp file
+    let tmpfile = tempname()
+    let cmd = "git show  " . rev . ":" . gitfile . " > " . tmpfile
+    let cmd_output = system(cmd)
+    if v:shell_error && cmd_output != ""
+        echohl WarningMsg | echon cmd_output
+        return
+    endif
+
+    " Begin diff
+    exe "vert diffsplit" . tmpfile
+    exe "set filetype=" . ftype
+    set foldmethod=diff
+    wincmd l
+
+endfunction
+
+"" ------------------------------------------------------------------------
+"" this block is taken from svndiff.vim
+"" http://www.vim.org/scripts/script.php?script_id=1881#1.0
+"" by Zevv Ico
+"" ------------------------------------------------------------------------
+
+command! -nargs=? GITChanges :call s:GitChanges(<f-args>)
+
+function! s:GitChanges(...)
+  
+  if a:0 == 1
+    let rev = a:1
+  else
+    let rev = 'HEAD'
+  endif
+
+	" Check if this file is managed by git, exit otherwise
+
+  let prefix = system("git rev-parse --show-prefix")
+  let thisfile = substitute(expand("%"),getcwd(),'','')
+  let gitfile = substitute(prefix,'\n$','','') . thisfile
+	
+	" Reset syntax highlighting
+	
+	syntax off
+
+	" Pipe the current buffer contents to a shell command calculating the diff
+	" in a friendly parsable format
+
+	let contents = join(getbufline("%", 1, "$"), "\n")
+	let diff = system("diff -u0 <(git show " . rev . ":" . gitfile . ") <(cat;echo)", contents)
+
+	" Parse the output of the diff command and hightlight changed, added and
+	" removed lines
+
+	for line in split(diff, '\n')
+		
+    let part = matchlist(line, '@@ -\([0-9]*\),*\([0-9]*\) +\([0-9]*\),*\([0-9]*\) @@')
+
+		if ! empty(part)
+			let old_from  = part[1]
+			let old_count = part[2] == '' ? 1 : part[2]
+			let new_from  = part[3]
+			let new_count = part[4] == '' ? 1 : part[4]
+
+			" Figure out if text was added, removed or changed.
+			
+			if old_count == 0
+				let from  = new_from
+				let to    = new_from + new_count - 1
+				let group = 'DiffAdd'
+			elseif new_count == 0
+				let from  = new_from
+				let to    = new_from + 1
+				let group = 'DiffDelete'
+			else
+				let from  = new_from
+				let to    = new_from + new_count - 1
+				let group = 'DiffChange'
+			endif
+
+			" Set the actual syntax highlight
+			
+			exec 'syntax region ' . group . ' start=".*\%' . from . 'l" end=".*\%' . to . 'l"'
+
+		endif
+
+	endfor
+
+endfunction
+
+
+" vi: ts=2 sw=2
+