tent-status 0.0.1

data/assets/javascripts/view.js.coffee

@@ -0,0 +1,140 @@
+# Custom View Class extending Backbone.View
+#
+# Sample View Class:
+# class TentStatus.Views.DashboardArticles extends TentStatus.View
+#   templateName: 'foo/bar'
+#
+#   # e.g. dashboard/_header is available as @partials.header
+#   partialNames: ['baz/_header']
+#
+#   # wait for attributes to be set with @set before rendering
+#   dependentRenderAttributes: ['foos']
+# 
+#   initialize: (options) ->
+#     super
+#
+#     # Custom view initialization, e.g.:
+#     @on 'ready', @bindEvents
+# 
+#   # setup context object passed to template
+#   # context is the data object for the view
+#   # See (mustache syntax): http://mustache.github.com/mustache.5.html
+#   # See (hogan example): http://twitter.github.com/hogan.js/
+#   context: =>
+#     foos: foos.toJSON()
+#
+#   render: =>
+#     # do anything special here
+#
+#     super
+
+class TentStatus.View extends Backbone.View
+  # simpler version of @set and @get than given with Backbone.Model
+  # @set sets the key directly on the View instance
+  # it's used to pass data from the router to the view
+  set: (key, val) =>
+    @[key] = val
+    @trigger "change:#{key}"
+
+  # see render method in above sample
+  get: (key) =>
+    @[key]
+
+  # fetch template and partials
+  # once loaded @template will hold the compiled hogan template specified with @templateName
+  # and @partials will hold all compiled templates defined in @partialNames
+  initialize: (options) ->
+    @container ||= TentStatus.Views.container
+
+    unless @container
+      TentStatus.devWarning @, "You need to define @container View"
+
+    # fetch main template
+    if @templateName
+      TentStatus.fetchTemplate @templateName, (@template) =>
+        @trigger 'template:load'
+
+    # load all partials listed in partialNames
+    if @partialNames
+      @partials = {}
+      for p in @partialNames
+        do (p) =>
+          TentStatus.fetchTemplate p, (template) =>
+            name = @getPartialName(p)
+            @partials[name] = template
+            @trigger "partials:#{name}:load"
+
+    @on 'ready', @bindViews
+    @on 'ready', @bindEvents
+
+  loadMore: (key) =>
+    @get(key)?.nextPage()
+
+  bindEvents: =>
+    _.each $('.btn.load-more', @container?.el), (el) =>
+      viewKey = $(el).attr('data-key')
+
+      $(el).hide() if @get(viewKey)?.onLastPage
+      @get(viewKey)?.on 'fetch:start',   => $(el).hide()
+      @get(viewKey)?.on 'fetch:success', => $(el).show() unless @get(viewKey)?.onLastPage
+
+      $(el).off().on 'click', (=> @loadMore viewKey)
+
+  bindViews: =>
+    _.each $('[data-view]', @container?.el), (el) =>
+      viewClassName = $(el).attr 'data-view'
+      if viewClass = TentStatus.Views[viewClassName]
+        view = new viewClass el: el, parentView: @
+      else
+        TentStatus.devWarning @, "TentStatus.Views.#{viewClassName} is not defined!"
+        console.log el
+
+  getPartialName: (path) =>
+    path.replace(/.+\/_(.+)$/, "$1")
+
+  # called before fetching data in the router
+  empty: =>
+    @container?.render("")
+
+  context: =>
+    TentStatus.devWarning @, "You need to override context in your view class!"
+    {}
+
+  # wait for @template and @partials to load
+  # then render @template with @context and @partials
+  # and insert html into @container.el
+  render: =>
+    # wait for template to be loaded
+    if @templateName
+      unless @template
+        @once 'template:load', => @render(arguments...)
+        return false
+
+    # wait for partials to be loaded
+    if @partialNames
+      for p in @partialNames
+        name = @getPartialName(p)
+        unless @partials[name]
+          @once "partials:#{name}:load", => @render(arguments...)
+          return false
+
+    # wait for data to be loaded
+    if @dependentRenderAttributes
+      for key in @dependentRenderAttributes
+        if @get(key) == null
+          @once "change:#{key}", => @render(arguments...)
+          return false
+
+    context = _.extend {
+      authenticated: TentStatus.authenticated
+      guest_authenticated: TentStatus.guest_authenticated
+    }, @context()
+
+    html = @template.render(context, @partials)
+    if @container
+      @container.render(html)
+      @trigger 'ready'
+      true
+    else
+      html
+

data/assets/javascripts/views/container.js.coffee

@@ -0,0 +1,6 @@
+TentStatus.Views.container = new class ContainerView extends Backbone.View
+  initialize: ->
+    @setElement document.getElementById('main')
+
+  render: (html) =>
+    @$el.html(html)

data/assets/javascripts/views/expanding_textarea.js.coffee

@@ -0,0 +1,14 @@
+class TentStatus.Views.ExpandingTextArea extends Backbone.View
+  initialize: ->
+    @$el.on 'keyup', @adjustSize
+
+    @initialHeight = @$el.height()
+
+  adjustSize: (shouldExecute = false) =>
+    @_padding ||= (parseInt(@$el.css 'padding-top') || 0) + (parseInt(@$el.css 'padding-bottom') || 0)
+    scrollY = window.scrollY
+    scrollX = window.scrollX
+    @$el.height(0)
+    @$el.css('height', "#{ Math.max(@el.scrollHeight - @_padding, @initialHeight) }px")
+    window.scrollTo scrollX, scrollY
+

data/assets/javascripts/views/fetch_posts_pool.js.coffee

@@ -0,0 +1,61 @@
+class TentStatus.Views.FetchPostsPool extends Backbone.View
+  initialize: (options = {}) ->
+    @parentView = options.parentView
+
+    @$numNewPosts = ($ '.num_new_posts', @$el)
+    @numNewPosts = 0
+
+    @$postsList = ($ 'ul.posts', @parentView.container.$el)
+
+    @sinceId = @parentView.posts.first()?.get('id')
+    @pool = new TentStatus.FetchPool( new TentStatus.Collections.Posts, { sinceId: @sinceId })
+    @pool.on 'fetch:success', @update
+
+    @fetchDelay = 3000
+    @fetchDelayOffset = 0
+
+    @setFetchInterval()
+
+    @$el.on 'click', (e)=>
+      e.preventDefault()
+      @emptyPool()
+      false
+    
+  setFetchInterval: (interval=@fetchDelay+@fetchDelayOffset) =>
+    clearInterval TentStatus._fetchPostsPoolInterval
+    TentStatus._fetchPostsPoolInterval = setInterval @pool.fetch, interval
+
+  update: =>
+    lastSinceId = @sinceId
+    @sinceId = @pool.sinceId
+    if lastSinceId == @sinceId
+      @fetchDelayOffset = Math.min(@fetchDelayOffset + @fetchDelay, 57000) # max delay: 1 min
+      @setFetchInterval()
+    else
+      @fetchDelayOffset = 0
+      @setFetchInterval()
+
+    @numNewPosts = @pool.collection.length
+    @$numNewPosts.text @numNewPosts
+    @show() if @numNewPosts > 0
+
+  show: => @$el.show()
+  hide: => @$el.hide()
+
+  emptyPool: =>
+    for i in [0...@numNewPosts]
+      post = @pool.collection.shift()
+      TentStatus.Collections.posts.unshift(post)
+      # @createPostView(post)
+    @parentView.render()
+    @pool.sinceId = @parentView.posts.first()?.get('id') || @pool.sinceId
+    @numNewPosts = 0
+    @$numNewPosts.text @numNewPosts
+    @hide()
+
+  createPostView: (post) =>
+    el = ($ '<li>').prependTo(@$postsList)
+    view = new TentStatus.Views.Post el: el, parentView: @parentView
+    view.post = post
+    context = view.context(post)
+    view.render(context)

data/assets/javascripts/views/follower_groups_form.js.coffee

@@ -0,0 +1,26 @@
+class TentStatus.Views.FollowerGroupsForm extends Backbone.View
+  initialize: (options = {}) ->
+    @parentView = options.parentView
+
+    followerId = @$el.attr 'data-follower-id'
+    @follower = TentStatus.Collections.followers.find (follower) -> follower.get('id') == followerId
+
+    @$groupsSelect = ($ 'select[name=groups]', @$el)
+    @$groupsSelect.chosen
+      persistent_create_option: true
+      no_results_text: 'No groups match'
+      create_option_text: 'Create new group'
+      create_option: (name) =>
+        group = new TentStatus.Models.Group({ name: name })
+        group.once 'sync', =>
+          TentStatus.Collections.groups.push(group)
+          @follower.set 'groups', (@follower.get('groups') || []).concat([group.get('id')])
+          @follower.save()
+          @parentView.render()
+        group.save()
+
+    @$groupsSelect.change =>
+      @follower.set 'groups', @$groupsSelect.val()
+      @follower.once 'sync', => @parentView.render()
+      @follower.save()
+

data/assets/javascripts/views/followers.js.coffee

@@ -0,0 +1,28 @@
+class TentStatus.Views.Followers extends TentStatus.View
+  templateName: 'followers'
+  partialNames: ['_follower']
+
+  dependentRenderAttributes: ['followers', 'groups']
+
+  initialize: ->
+    @container = TentStatus.Views.container
+    super
+
+    @on 'ready', @initAutoPaginate
+
+  context: =>
+    followers: _.map(@followers.toArray(), (follower) => _.extend follower.toJSON(), {
+      name: follower.name()
+      avatar: follower.avatar()
+      groups: _.map(@groups.toArray(), (group) -> _.extend group.toJSON(), {
+        selected: follower.get('groups')?.indexOf(group.id) != -1
+      })
+    })
+
+  initAutoPaginate: =>
+    ($ window).off 'scroll.followers'
+    ($ window).on 'scroll.followers', (e)=>
+      height = $(document).height() - $(window).height()
+      delta = height - window.scrollY
+      if delta < 200
+        @followers?.nextPage() unless @followers.onLastPage

data/assets/javascripts/views/following_groups_form.js.coffee

@@ -0,0 +1,25 @@
+class TentStatus.Views.FollowingGroupsForm extends Backbone.View
+  initialize: (options = {}) ->
+    @parentView = options.parentView
+
+    followingId = @$el.attr 'data-following-id'
+    @following = TentStatus.Collections.followings.get(followingId)
+
+    @$groupsSelect = ($ 'select[name=groups]', @$el)
+    @$groupsSelect.chosen
+      persistent_create_option: true
+      no_results_text: 'No groups match'
+      create_option_text: 'Create new group'
+      create_option: (name) =>
+        group = new TentStatus.Models.Group({ name: name })
+        group.once 'sync', =>
+          TentStatus.Collections.groups.push(group)
+          @following.set 'groups', (@following.get('groups') || []).concat([group.get('id')])
+          @following.save()
+          @parentView.render()
+        group.save()
+
+    @$groupsSelect.change =>
+      @following.set 'groups', @$groupsSelect.val()
+      @following.once 'sync', => @parentView.render()
+      @following.save()

data/assets/javascripts/views/followings.js.coffee

@@ -0,0 +1,27 @@
+class TentStatus.Views.Followings extends TentStatus.View
+  templateName: 'followings'
+  partialNames: ['_following']
+
+  dependentRenderAttributes: ['followings', 'groups']
+
+  initialize: ->
+    @container = TentStatus.Views.container
+    super
+    @on 'ready', @initAutoPaginate
+
+  context: =>
+    followings: _.map(@followings.toArray(), (following) => _.extend following.toJSON(), {
+      name: following.name()
+      avatar: following.avatar()
+      groups: _.map(@groups.toArray(), (group) -> _.extend group.toJSON(), {
+        selected: following.get('groups')?.indexOf(group.id) != -1
+      })
+    })
+
+  initAutoPaginate: =>
+    ($ window).off 'scroll.followings'
+    ($ window).on 'scroll.followings', (e)=>
+      height = $(document).height() - $(window).height()
+      delta = height - window.scrollY
+      if delta < 200
+        @followings?.nextPage() unless @followings.onLastPage

data/assets/javascripts/views/new_following_form.js.coffee

@@ -0,0 +1,15 @@
+class TentStatus.Views.NewFollowingForm extends Backbone.View
+  initialize: (options = {}) ->
+    @parentView = options.parentView
+
+    @$el.on 'submit', @submit
+
+  submit: (e) =>
+    e.preventDefault()
+    entity = ($ '[name=entity]', @$el).val()
+    following = new TentStatus.Models.Following { entity: entity }
+    following.once 'sync', =>
+      TentStatus.Collections.followings.unshift(following)
+      @parentView.render()
+    following.save()
+    false

data/assets/javascripts/views/new_post_form.js.coffee

@@ -0,0 +1,178 @@
+class TentStatus.Views.NewPostForm extends Backbone.View
+  initialize: (options = {}) ->
+    @parentView = options.parentView
+
+    @action = "#{TentStatus.api_root}/posts"
+
+    @$errors = ($ '.alert-error', @$el).first().hide()
+
+    @$post_btn = ($ 'input[type=submit]', @$el)
+
+    @$el.off().on 'submit', @submit
+
+    ## form validation and character limit counter
+    @$textarea = ($ 'textarea', @$el)
+    @$charLimit = ($ '.char-limit', @$el).first()
+    @charLimit = parseInt(@$charLimit.text())
+    @$textarea.on 'keyup', =>
+      clearTimeout @_validateTimeout
+      @_validateTimeout = setTimeout @validate, 300
+      @updateCharCounter()
+      null
+    @updateCharCounter()
+
+    ## cmd/ctr enter == submit
+    @$textarea.off('keydown.keysubmit').on 'keydown.keysubmit', (e) =>
+      if (e.metaKey || e.ctrlKey) && e.keyCode == 13
+        e.preventDefault()
+        @submit()
+        false
+      else
+        true
+
+    ## permissions
+    @$publicCheckbox = ($ '[name=public]', @$el)
+    @$permissions = ($ 'select[name=permissions]', @$el)
+    @$permissions.chosen
+      no_results_text: 'No matching entities or groups'
+
+    # disable public checkbox when permissions are added
+    @$permissions.change @checkPublicEnabled
+
+    ## mentions
+    @$mentionsSelect = ($ 'select[name=mentions]', @$el)
+    @$mentionsSelect.chosen
+      no_results_text: 'No matching entities'
+
+    ## licenses
+    @$licensesSelect = ($ 'select[name=licenses]', @$el)
+    @$licensesSelect.chosen
+      no_results_text: 'No matching licenses'
+
+    ## advanced options toggle
+    @$advancedOptions = ($ '.advanced-options', @$el).hide()
+    @$advancedOptionsToggle = ($ '.advanced-options-toggle', @$el)
+    @$advancedOptionsToggle.on 'click', (e) =>
+      e.preventDefault()
+      @$advancedOptions.toggle()
+      false
+
+  checkPublicEnabled: =>
+    if @$permissions.val() == null
+      @enablePublic()
+    else
+      @disablePublic()
+
+  enablePublic: =>
+    @$publicCheckbox.removeAttr('disabled')
+
+  disablePublic: =>
+    @$publicCheckbox.removeAttr('checked')
+    @$publicCheckbox.attr('disabled', 'disabled')
+
+  submit: (e) =>
+    e.preventDefault() if e
+    data = @getData()
+    return false unless @validate data
+
+    post = new TentStatus.Models.Post data
+    post.once 'sync', =>
+      window.location.reload() unless @parentView.emptyPool
+      @parentView.emptyPool()
+      TentStatus.Collections.posts.unshift(post)
+      @parentView.set('posts', TentStatus.Collections.posts)
+      @parentView.render()
+    post.save()
+    false
+
+  buildPermissions: (data) =>
+    _public = if data['public'] == 'on' then true else false
+    permissions = {
+      public: _public
+    }
+
+    _groups = _.each _.flatten(Array data.permissions), (entityOrGroupId) ->
+      return unless entityOrGroupId
+      [type, value] = [entityOrGroupId.slice(0,2), entityOrGroupId.slice(2, entityOrGroupId.length)]
+      switch type
+        when 'g:'
+          permissions.groups ||= []
+          permissions.groups.push { id: value }
+        when 'f:'
+          permissions.entities ||= {}
+          permissions.entities[value] = true
+
+    delete data['public']
+    delete data.permissible_groups
+    delete data.permissible_entities
+
+    data.permissions = permissions
+    data
+
+  buildMentions: (data) =>
+    mentions = _.compact (_.map _.flatten(Array data.mentions), (entity) ->
+      return unless entity
+      { entity: entity }
+    )
+    delete data.mentions
+
+    for entity in (data.text.match(/\^(\S+)/g) || [])
+      entity = entity.replace(/^\^/, '')
+      entity = entity.replace(/^/, 'https://') unless entity.match(/^https?/)
+      mentions.push { entity: entity }
+
+    data.mentions = mentions if mentions.length
+    data
+
+  buildLicenses: (data) =>
+    data.licenses = _.flatten(Array data.licenses) if data.licenses
+    data
+
+  buildDataObject: (serializedArray) =>
+    data = {}
+    for i in serializedArray
+      if data[i.name]
+        if data[i.name].push
+          data[i.name].push i.value
+        else
+          data[i.name] = [data[i.name], i.value]
+      else
+        data[i.name] = i.value
+
+    @buildLicenses(@buildMentions(@buildPermissions(data)))
+
+  getData: =>
+    @buildDataObject @$el.serializeArray()
+
+  validate: (data = @getData()) =>
+    post = new TentStatus.Models.Post data
+    errors = post.validate(data)
+    @$el.find(".error").removeClass('error')
+    @$errors.hide()
+    @showErrors(errors) if errors
+    return !errors
+
+  showErrors: (errors) =>
+    error_messages = []
+    for err in errors
+      for name, msg of err
+        $input = @$el.find("[name='#{name}']")
+        $input.addClass('error')
+        error_messages.push msg
+    @$errors.html error_messages.join('<br/>')
+    @$errors.show()
+
+  updateCharCounter: =>
+    charCount = @$textarea.val()?.length
+    delta = @charLimit - charCount
+    if delta < 0
+      @$post_btn.attr 'disabled', 'disabled'
+      @$charLimit.addClass 'alert-error'
+    else
+      if delta == @charLimit
+        @$post_btn.attr 'disabled', 'disabled'
+      else
+        @$post_btn.removeAttr 'disabled'
+      @$charLimit.removeClass 'alert-error'
+    @$charLimit.text delta
+