tebako 0.5.0 → 0.5.2

data/tools/cmake-scripts/macos-environment.cmake

@@ -0,0 +1,116 @@
+# Copyright (c) 2021-2023, [Ribose Inc](https://www.ribose.com).
+# All rights reserved.
+# This file is a part of tamatebako
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+# 1. Redistributions of source code must retain the above copyright
+#    notice, this list of conditions and the following disclaimer.
+# 2. Redistributions in binary form must reproduce the above copyright
+#    notice, this list of conditions and the following disclaimer in the
+#    documentation and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+# ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
+# TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR CONTRIBUTORS
+# BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
+# CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
+# SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
+# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
+# CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+# ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+# POSSIBILITY OF SUCH DAMAGE.
+#
+
+set(GNU_BASH "bash")
+
+if (CMAKE_HOST_SYSTEM_NAME MATCHES "Darwin")
+# If we are cross compiling TARGET_HOMEBREW will point to homebrew environment for target
+# If we are not cross-compiling it will be empty
+# Note that below for Bison, Flex and bash we are using host homebrew environment (just 'brew')
+# while other packages refer target environment potentially specified by BREW_BIN
+  execute_process(
+    COMMAND brew --prefix
+    RESULT_VARIABLE BREW_PREFIX_RES
+    OUTPUT_VARIABLE BUILD_BREW_PREFIX
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+  )
+  if(NOT (BREW_PREFIX_RES EQUAL 0 AND EXISTS ${BUILD_BREW_PREFIX}))
+    message(FATAL "Could not find build brew setup")
+  endif()
+
+  message("Using build brew environment at ${BUILD_BREW_PREFIX}")
+# https://github.com/actions/virtual-environments/blob/main/images/macos/macos-10.15-Readme.me
+  set(BUILD_OPENSSL_ROOT_DIR "${BUILD_BREW_PREFIX}/opt/openssl@1.1")
+  set(BUILD_CMAKE_PREFIX_PATH "${BUILD_BREW_PREFIX}")
+
+  #  https://stackoverflow.com/questions/53877344/cannot-configure-cmake-to-look-for-homebrew-installed-version-of-bison
+  execute_process(
+    COMMAND brew --prefix bison
+    RESULT_VARIABLE BREW_BISON
+    OUTPUT_VARIABLE BREW_BISON_PREFIX
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+  )
+  if (BREW_BISON EQUAL 0 AND EXISTS "${BREW_BISON_PREFIX}")
+    message(STATUS "Found Bison keg installed by Homebrew at ${BREW_BISON_PREFIX}")
+    set(BISON_EXECUTABLE "${BREW_BISON_PREFIX}/bin/bison")
+  endif()
+
+  execute_process(
+    COMMAND brew --prefix flex
+    RESULT_VARIABLE BREW_FLEX
+    OUTPUT_VARIABLE BREW_FLEX_PREFIX
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+  )
+  if (BREW_FLEX EQUAL 0 AND EXISTS "${BREW_FLEX_PREFIX}")
+    message(STATUS "Found Flex keg installed by Homebrew at ${BREW_FLEX_PREFIX}")
+    set(FLEX_EXECUTABLE "${BREW_FLEX_PREFIX}/bin/flex")
+  endif()
+
+  execute_process(
+    COMMAND brew --prefix bash
+    RESULT_VARIABLE BREW_BASH
+    OUTPUT_VARIABLE BREW_BASH_PREFIX
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+  )
+  if (BREW_BASH EQUAL 0 AND EXISTS "${BREW_BASH_PREFIX}")
+    message(STATUS "Found GNU bash keg installed by Homebrew at ${BREW_BASH_PREFIX}")
+    set(GNU_BASH "${BREW_BASH_PREFIX}/bin/bash")
+  endif()
+
+  if(NOT TARGET_HOMEBREW)
+    set(TARGET_BREW_PREFIX ${BUILD_BREW_PREFIX} )
+  else()
+    execute_process(
+        COMMAND "${TARGET_HOMEBREW}/bin/brew" --prefix
+        RESULT_VARIABLE BREW_PREFIX_RES
+        OUTPUT_VARIABLE TARGET_BREW_PREFIX
+        OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+    if(NOT (BREW_PREFIX_RES EQUAL 0 AND EXISTS ${TARGET_BREW_PREFIX}))
+        message(FATAL "Could not find target brew setup")
+    endif()
+  endif()
+
+  message("Using target brew environment at ${TARGET_BREW_PREFIX}")
+  set(OPENSSL_ROOT_DIR "${TARGET_BREW_PREFIX}/opt/openssl@1.1")
+  set(CMAKE_PREFIX_PATH "${TARGET_BREW_PREFIX}")
+  include_directories("${TARGET_BREW_PREFIX}/include")
+
+# Suppress superfluous randlib warnings about "*.a" having no symbols on MacOSX.
+  set(CMAKE_C_ARCHIVE_CREATE   "<CMAKE_AR> Scr <TARGET> <LINK_FLAGS> <OBJECTS>")
+  set(CMAKE_CXX_ARCHIVE_CREATE "<CMAKE_AR> Scr <TARGET> <LINK_FLAGS> <OBJECTS>")
+  set(CMAKE_C_ARCHIVE_FINISH   "<CMAKE_RANLIB> -no_warning_for_no_symbols -c <TARGET>")
+  set(CMAKE_CXX_ARCHIVE_FINISH "<CMAKE_RANLIB> -no_warning_for_no_symbols -c <TARGET>")
+
+  set(CMAKE_CXX_FLAGS "-DTARGET_OS_SIMULATOR=0 -DTARGET_OS_IPHONE=0")
+
+  set(BUILD_CMAKE_ARGUMENTS -DCMAKE_PREFIX_PATH=${BUILD_CMAKE_PREFIX_PATH}
+                            -DOPENSSL_ROOT_DIR=${BUILD_OPENSSL_ROOT_DIR}
+                            -DBISON_EXECUTABLE=${BISON_EXECUTABLE}
+                            -DFLEX_EXECUTABLE=${FLEX_EXECUTABLE}
+  )
+
+endif()

data/tools/cmake-scripts/msys-environment.cmake

@@ -0,0 +1,78 @@
+# Copyright (c) 2022, [Ribose Inc](https://www.ribose.com).
+# All rights reserved.
+# This file is a part of tamatebako
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+# 1. Redistributions of source code must retain the above copyright
+#    notice, this list of conditions and the following disclaimer.
+# 2. Redistributions in binary form must reproduce the above copyright
+#    notice, this list of conditions and the following disclaimer in the
+#    documentation and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+# ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
+# TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR CONTRIBUTORS
+# BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
+# CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
+# SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
+# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
+# CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+# ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+# POSSIBILITY OF SUCH DAMAGE.
+#
+
+if(MINGW)
+# These days Windows has its own bash.exe that points to WSL installation even if nothing is installed
+# So we (1) go look for 'sh' (presumably we will find MSys version)
+#       (2) assume that MSys bash is add_subdirectory
+#       (3) convert path to Windows
+  execute_process(
+    COMMAND "which" "sh"
+    RESULT_VARIABLE SH_RES
+    OUTPUT_VARIABLE SH
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+  )
+
+  if(NOT (SH_RES EQUAL 0))
+    message(FATAL_ERROR "Could not find MSystem /usr/bin")
+  endif()
+
+  get_filename_component(BASH_DIR "${SH}" DIRECTORY)
+
+  execute_process(
+    COMMAND "cygpath" "-w" "${BASH_DIR}"
+    RESULT_VARIABLE BASH_RES
+    OUTPUT_VARIABLE MSYS_BIN_RAW
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+  )
+
+  if(NOT (BASH_RES EQUAL 0))
+    message(FATAL_ERROR "Could not find MSys root")
+  endif()
+
+# Some black magic below
+  cmake_path(SET MSYS_USR_RAW NORMALIZE "${MSYS_BIN_RAW}\\..\\..\\usr")
+  cmake_path(SET MSYS_TMP_RAW NORMALIZE "${MSYS_USR_RAW}\\..\\tmp")
+
+  string(REPLACE "\\" "\\\\" MSYS_BIN ${MSYS_BIN_RAW} )
+  string(REPLACE "/" "\\\\" MSYS_USR ${MSYS_USR_RAW} )
+  string(REPLACE "/" "\\\\" MSYS_TMP ${MSYS_TMP_RAW} )
+
+  set(BASH "${BASH_DIR}/bash.exe")
+
+  execute_process(
+    COMMAND "cygpath" "-w" "${BASH}"
+    RESULT_VARIABLE BASH_RES
+    OUTPUT_VARIABLE GNU_BASH
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+  )
+
+  if(NOT (BASH_RES EQUAL 0 AND EXISTS ${GNU_BASH}))
+    message(FATAL_ERROR "Could not find gnu bash")
+  endif()
+
+  message(STATUS "Using gnu bash at ${GNU_BASH}")
+endif(MINGW)

data/tools/cmake-scripts/setup-openssl.cmake

@@ -0,0 +1,69 @@
+# Copyright (c) 2023 [Ribose Inc](https://www.ribose.com).
+# All rights reserved.
+# This file is a part of tebako
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+# 1. Redistributions of source code must retain the above copyright
+#    notice, this list of conditions and the following disclaimer.
+# 2. Redistributions in binary form must reproduce the above copyright
+#    notice, this list of conditions and the following disclaimer in the
+#    documentation and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+# ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
+# TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR CONTRIBUTORS
+# BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
+# CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
+# SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
+# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
+# CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+# ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+# POSSIBILITY OF SUCH DAMAGE.
+
+set(WITH_OPENSSL_BUILD ON)
+
+execute_process(
+  COMMAND "${DEPS}/bin/openssl" "version"
+  RESULT_VARIABLE OPENSSL_RES
+  OUTPUT_VARIABLE OPENSSL_VER_STR
+  OUTPUT_STRIP_TRAILING_WHITESPACE
+)
+
+if(OPENSSL_RES EQUAL 0)
+  string(REGEX MATCH "^OpenSSL ([1-9][.][0-9][.][0-9])" OPENSSL_VER_TMP ${OPENSSL_VER_STR})
+  set(OPENSSL_VER ${CMAKE_MATCH_1})
+  message(STATUS "Found OpenSSL version ${OPENSSL_VER} at ${DEPS}/bin/openssl")
+  if((${OPENSSL_VER} VERSION_GREATER_EQUAL "1.1.0") AND (${OPENSSL_VER} VERSION_LESS "3.0.0"))
+    set(WITH_OPENSSL_BUILD OFF)
+  endif((${OPENSSL_VER} VERSION_GREATER_EQUAL "1.1.0") AND (${OPENSSL_VER} VERSION_LESS "3.0.0"))
+endif(OPENSSL_RES EQUAL 0)
+
+if(WITH_OPENSSL_BUILD)
+  execute_process(
+    COMMAND "openssl" "version"
+    RESULT_VARIABLE OPENSSL_RES
+    OUTPUT_VARIABLE OPENSSL_VER_STR
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+  )
+  if(OPENSSL_RES EQUAL 0)
+    execute_process(
+      COMMAND "which" "openssl"
+      RESULT_VARIABLE OPENSSL_RES
+      OUTPUT_VARIABLE OPENSSL_LOC
+      OUTPUT_STRIP_TRAILING_WHITESPACE
+    )
+    if(NOT OPENSSL_RES EQUAL 0)
+      set(OPENSSL_LOC "<unknown>")
+    endif(NOT OPENSSL_RES EQUAL 0)
+
+    string(REGEX MATCH "^OpenSSL ([1-9][.][0-9][.][0-9])" OPENSSL_VER_TMP ${OPENSSL_VER_STR})
+    set(OPENSSL_VER ${CMAKE_MATCH_1})
+    message(STATUS "Found OpenSSL version ${OPENSSL_VER} at ${OPENSSL_LOC}")
+    if((${OPENSSL_VER} VERSION_GREATER_EQUAL "1.1.0") AND (${OPENSSL_VER} VERSION_LESS "3.0.0"))
+      set(WITH_OPENSSL_BUILD OFF)
+    endif((${OPENSSL_VER} VERSION_GREATER_EQUAL "1.1.0") AND (${OPENSSL_VER} VERSION_LESS "3.0.0"))
+  endif(OPENSSL_RES EQUAL 0)
+endif(WITH_OPENSSL_BUILD)

data/tools/cmake-scripts/version.cmake

@@ -0,0 +1,162 @@
+# Copyright (c) 2018-2021 Ribose Inc.
+# All rights reserved.
+#
+# Redistribution and use in source and binary forms, with or without
+# modification, are permitted provided that the following conditions
+# are met:
+# 1. Redistributions of source code must retain the above copyright
+#    notice, this list of conditions and the following disclaimer.
+# 2. Redistributions in binary form must reproduce the above copyright
+#    notice, this list of conditions and the following disclaimer in the
+#    documentation and/or other materials provided with the distribution.
+#
+# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+# ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
+# TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+# PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR CONTRIBUTORS
+# BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
+# CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
+# SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
+# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
+# CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+# ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+# POSSIBILITY OF SUCH DAMAGE.
+
+# desired length of commit hash
+set(GIT_REV_LEN 7)
+
+# call git, store output in var (can fail)
+macro(_git var)
+  execute_process(
+    COMMAND "${GIT_EXECUTABLE}" ${ARGN}
+    WORKING_DIRECTORY "${source_dir}"
+    RESULT_VARIABLE _git_ec
+    OUTPUT_VARIABLE ${var}
+    OUTPUT_STRIP_TRAILING_WHITESPACE
+    ERROR_QUIET
+  )
+endmacro()
+
+function(extract_version_info version var_prefix)
+  # extract the main components
+  #   v1.9.0-3-g5b92266+1546836556
+  #   v1.9.0-3-g5b92266-dirty+1546836556
+  string(REGEX MATCH "^v?([0-9]+\\.[0-9]+\\.[0-9]+)(-([0-9]+)-g([0-9a-f]+)(-dirty)?)?(\\+([0-9]+))?$" matches "${version}")
+  if (NOT matches)
+    message(FATAL_ERROR "Failed to extract version components from ${version}.")
+  endif()
+  set(${var_prefix}_VERSION "${CMAKE_MATCH_1}" PARENT_SCOPE) # 1.9.0
+  if (NOT CMAKE_MATCH_3)
+    set(CMAKE_MATCH_3 "0")
+  endif()
+  set(${var_prefix}_VERSION_NCOMMITS "${CMAKE_MATCH_3}" PARENT_SCOPE) # 3
+  if (NOT CMAKE_MATCH_4)
+    set(CMAKE_MATCH_4 "0")
+  endif()
+  set(${var_prefix}_VERSION_GIT_REV "${CMAKE_MATCH_4}" PARENT_SCOPE) # 5b92266
+  if (CMAKE_MATCH_5 STREQUAL "-dirty")
+    set(${var_prefix}_VERSION_IS_DIRTY TRUE PARENT_SCOPE)
+  else()
+    set(${var_prefix}_VERSION_IS_DIRTY FALSE PARENT_SCOPE)
+  endif()
+  # timestamp is optional, default to 0
+  if (NOT CMAKE_MATCH_7)
+    set(CMAKE_MATCH_7 "0")
+  endif()
+  set(${var_prefix}_VERSION_COMMIT_TIMESTAMP "${CMAKE_MATCH_7}" PARENT_SCOPE) # 1546836556
+endfunction()
+
+function(determine_version source_dir var_prefix)
+  set(has_release_tag NO)
+  set(has_version_txt NO)
+  set(local_prefix "_determine_ver")
+  # find out base version via version.txt
+  set(base_version "0.0.0")
+  if (EXISTS "${source_dir}/version.txt")
+    set(has_version_txt YES)
+    file(STRINGS "${source_dir}/version.txt" version_file)
+    extract_version_info("${version_file}" "${local_prefix}")
+    set(base_version "${${local_prefix}_VERSION}")
+    message(STATUS "Found version.txt with ${version_file}")
+  else()
+    message(STATUS "Found no version.txt.")
+  endif()
+  # for GIT_EXECUTABLE
+  find_package(Git)
+  # get a description of the version, something like:
+  #   v1.9.1-0-g38ffe82        (a tagged release)
+  #   v1.9.1-0-g38ffe82-dirty  (a tagged release with local modifications)
+  #   v1.9.0-3-g5b92266        (post-release snapshot)
+  #   v1.9.0-3-g5b92266-dirty  (post-release snapshot with local modifications)
+  _git(version describe --abbrev=${GIT_REV_LEN} --match "v[0-9]*" --long --dirty)
+  if (NOT _git_ec EQUAL 0)
+    # no annotated tags, fake one
+    message(STATUS "Found no annotated tags.")
+    _git(revision rev-parse --short=${GIT_REV_LEN} --verify HEAD)
+    if (_git_ec EQUAL 0)
+      set(version "v${base_version}-0-g${revision}")
+      # check if dirty (this won't detect untracked files, but should be ok)
+      _git(changes diff-index --quiet HEAD --)
+      if (NOT _git_ec EQUAL 0)
+        string(APPEND version "-dirty")
+      endif()
+      # append the commit timestamp of the most recent commit (only
+      # in non-release branches -- typically master)
+      _git(commit_timestamp show -s --format=%ct)
+      if (_git_ec EQUAL 0)
+        string(APPEND version "+${commit_timestamp}")
+      endif()
+    elseif(has_version_txt)
+      # Nothing to get from git - so use version.txt completely
+      set(version "${version_file}")
+    else()
+      # Sad case - no git, no version.txt
+      set(version "v${base_version}")
+    endif()
+  else()
+    set(has_release_tag YES)
+    message(STATUS "Found annotated tag ${version}")
+  endif()
+  extract_version_info("${version}" "${local_prefix}")
+  if ("${has_version_txt}" AND NOT ${base_version} STREQUAL ${local_prefix}_VERSION)
+    message(WARNING "Tagged version ${${local_prefix}_VERSION} doesn't match one from the version.txt: ${base_version}")
+    if (${base_version} VERSION_GREATER ${local_prefix}_VERSION)
+      set(${local_prefix}_VERSION ${base_version})
+    endif()
+  endif()
+  foreach(suffix VERSION VERSION_NCOMMITS VERSION_GIT_REV VERSION_IS_DIRTY VERSION_COMMIT_TIMESTAMP)
+    if (NOT DEFINED ${local_prefix}_${suffix})
+      message(FATAL_ERROR "Unable to determine version.")
+    endif()
+    set(${var_prefix}_${suffix} "${${local_prefix}_${suffix}}" PARENT_SCOPE)
+    message(STATUS "${var_prefix}_${suffix}: ${${local_prefix}_${suffix}}")
+  endforeach()
+  # Set VERSION_SUFFIX and VERSION_FULL. When making changes, be aware that
+  # this is used in packaging as well and will affect ordering.
+  # | state                 | version_full                |
+  # |-----------------------------------------------------|
+  # | exact tag             | 0.9.0                       |
+  # | exact tag, dirty      | 0.9.0+git20180604           |
+  # | after tag             | 0.9.0+git20180604.1.085039f |
+  # | no tag, version.txt   | 0.9.0+git20180604.2ee02af   |
+  # | no tag, no version.txt| 0.0.0+git20180604.2ee02af   |
+  string(TIMESTAMP date "%Y%m%d" UTC)
+  set(version_suffix "")
+  if (NOT ${local_prefix}_VERSION_NCOMMITS EQUAL 0)
+    # 0.9.0+git20150604.4.289818b
+    string(APPEND version_suffix "+git${date}.${${local_prefix}_VERSION_NCOMMITS}.${${local_prefix}_VERSION_GIT_REV}")
+  elseif ((NOT has_release_tag) AND ((NOT has_version_txt) OR ("${base_version}" STREQUAL "0.0.0") OR (NOT "${revision}" STREQUAL "")))
+    # 0.9.0+git20150604.289818b
+    string(APPEND version_suffix "+git${date}.${${local_prefix}_VERSION_GIT_REV}")
+  elseif(${local_prefix}_VERSION_IS_DIRTY)
+    # 0.9.0+git20150604
+    string(APPEND version_suffix "+git${date}")
+  endif()
+  set(version_full "${${local_prefix}_VERSION}${version_suffix}")
+  # set the results
+  set(${var_prefix}_VERSION_SUFFIX "${version_suffix}" PARENT_SCOPE)
+  set(${var_prefix}_VERSION_FULL "${version_full}" PARENT_SCOPE)
+  # for informational purposes
+  message(STATUS "${var_prefix}_VERSION_SUFFIX: ${version_suffix}")
+  message(STATUS "${var_prefix}_VERSION_FULL: ${version_full}")
+endfunction()

data/tools/include/pro-statvfs.h

@@ -0,0 +1,57 @@
+/**
+ *
+ * Copyright (c) 2022, [Ribose Inc](https://www.ribose.com).
+ * All rights reserved.
+ * This file is a part of tebako (libdwarfs-wr)
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in the
+ *    documentation and/or other materials provided with the distribution.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+ * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
+ * TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR
+ * PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDERS OR CONTRIBUTORS
+ * BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
+ * CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
+ * SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
+ * INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
+ * CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
+ * ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ *
+ */
+
+#pragma once
+
+#ifdef _WIN32
+  using fsblkcnt_t = unsigned long;
+  using fsfilcnt_t = unsigned long;
+  struct statvfs {
+    unsigned long  f_bsize;    /* Filesystem block size */
+    unsigned long  f_frsize;   /* Fragment size */
+    fsblkcnt_t     f_blocks;   /* Size of fs in f_frsize units */
+    fsblkcnt_t     f_bfree;    /* Number of free blocks */
+    fsblkcnt_t     f_bavail;   /* Number of free blocks for
+                                             unprivileged users */
+    fsfilcnt_t     f_files;    /* Number of inodes */
+    fsfilcnt_t     f_ffree;    /* Number of free inodes */
+    fsfilcnt_t     f_favail;   /* Number of free inodes for
+                                             unprivileged users */
+    unsigned long  f_fsid;     /* Filesystem ID */
+    unsigned long  f_flag;     /* Mount flags */
+    unsigned long  f_namemax;  /* Maximum filename length */
+  };
+
+  enum {
+    ST_RDONLY = 1,		/* Mount read-only.  */
+#define ST_RDONLY	ST_RDONLY
+    ST_NOSUID = 2			/* Ignore suid and sgid bits.  */
+#define ST_NOSUID	ST_NOSUID
+  };
+#endif

data/version.txt

@@ -0,0 +1 @@
+0.5.2

metadata

@@ -1,14 +1,14 @@
 --- !ruby/object:Gem::Specification
 name: tebako
 version: !ruby/object:Gem::Version
-  version: 0.5.0
+  version: 0.5.2
 platform: ruby
 authors:
 - Ribose Inc.
 autorequire:
 bindir: exe
 cert_chain: []
-date: 2023-06-16 00:00:00.000000000 Z
+date: 2023-07-08 00:00:00.000000000 Z
 dependencies:
 - !ruby/object:Gem::Dependency
   name: thor
@@ -46,6 +46,7 @@ email:
 - open.source@ribose.com
 executables:
 - tebako
+- tebako-packager
 extensions: []
 extra_rdoc_files: []
 files:
@@ -59,9 +60,10 @@ files:
 - cmake/def_tty_colours.cmake
 - common.env
 - exe/tebako
+- exe/tebako-packager
 - include/tebako/tebako-fs.h
 - include/tebako/tebako-main.h
-- lib/cli.rb
+- lib/tebako.rb
 - lib/tebako/cli.rb
 - lib/tebako/cli_helpers.rb
 - lib/tebako/error.rb
@@ -133,6 +135,24 @@ files:
 - tests/test-18/tebako-test-run.rb
 - tests/test-19/Gemfile
 - tests/test-19/tebako-test-run.rb
+- tools/.gitattributes
+- tools/.github/workflows/lint.yml
+- tools/README.md
+- tools/ci-scripts/arm-brew-install.sh
+- tools/ci-scripts/arm-brew-setup.sh
+- tools/ci-scripts/level-up.sh
+- tools/ci-scripts/patch-fbthrift.sh
+- tools/ci-scripts/patch-folly.sh
+- tools/ci-scripts/patch-system-includes.sh
+- tools/ci-scripts/x86-brew-install.sh
+- tools/ci-scripts/x86-brew-setup.sh
+- tools/cmake-scripts/def-external-project.cmake
+- tools/cmake-scripts/macos-environment.cmake
+- tools/cmake-scripts/msys-environment.cmake
+- tools/cmake-scripts/setup-openssl.cmake
+- tools/cmake-scripts/version.cmake
+- tools/include/pro-statvfs.h
+- version.txt
 homepage: https://github.com/tamatebako/tebako
 licenses:
 - BSD-2-Clause