teaspoon-jasmine 2.2.0

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine1.coffee

@@ -0,0 +1,10 @@
+#= require teaspoon/teaspoon
+#= require_self
+#= require_tree ./jasmine1
+
+unless jasmine?
+  throw new Teaspoon.Error('Jasmine 1 not found -- use `suite.use_framework :jasmine` and adjust or remove the `suite.javascripts` directive.')
+
+@Teaspoon ?= {}
+@Teaspoon.Jasmine1 ?= {}
+@Teaspoon.Jasmine1.Reporters ?= {}

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine1/fixture.coffee

@@ -0,0 +1,29 @@
+#= require teaspoon/fixture
+
+class Teaspoon.Jasmine1.Fixture extends Teaspoon.Fixture
+
+  @load: ->
+    args = arguments
+    throw "Teaspoon can't load fixtures outside of describe." unless @env().currentSuite || @env().currentSpec
+    if @env().currentSuite
+      @env().beforeEach => fixture.__super__.constructor.load.apply(@, args)
+      @env().afterEach => @cleanup()
+      super
+    else
+      @env().currentSpec.after => @cleanup()
+      super
+
+
+  @set: ->
+    args = arguments
+    throw "Teaspoon can't load fixtures outside of describe." unless @env().currentSuite || @env().currentSpec
+    if @env().currentSuite
+      @env().beforeEach => fixture.__super__.constructor.set.apply(@, args)
+      @env().afterEach => @cleanup()
+      super
+    else
+      @env().currentSpec.after => @cleanup()
+      super
+
+
+  @env: -> window.jasmine.getEnv()

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine1/initialize.coffee

@@ -0,0 +1 @@
+Teaspoon.setFramework(Teaspoon.Jasmine1)

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine1/reporters/html.coffee

@@ -0,0 +1,13 @@
+#= require teaspoon/reporters/html
+
+class Teaspoon.Jasmine1.Reporters.HTML extends Teaspoon.Reporters.HTML
+
+  readConfig: ->
+    super
+    jasmine.CATCH_EXCEPTIONS = @config["use-catch"]
+
+
+  envInfo: ->
+    ver = jasmine.getEnv().version()
+    verString = [ver.major, ver.minor, ver.build].join(".")
+    "jasmine #{verString} revision #{ver.revision}"

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine1/responder.coffee

@@ -0,0 +1,23 @@
+class Teaspoon.Jasmine1.Responder
+
+  constructor: (@reporter) ->
+
+  
+  reportRunnerStarting: (runner) ->
+    @reporter.reportRunnerStarting(total: runner.specs().length)
+
+  
+  reportRunnerResults: ->
+    @reporter.reportRunnerResults()
+
+
+  reportSuiteResults: (suite) ->
+    @reporter.reportSuiteResults(new Teaspoon.Jasmine1.Suite(suite))
+
+
+  reportSpecStarting: (spec) ->
+    @reporter.reportSpecStarting(new Teaspoon.Jasmine1.Spec(spec))
+
+
+  reportSpecResults: (spec) ->
+    @reporter.reportSpecResults(new Teaspoon.Jasmine1.Spec(spec))

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine1/runner.coffee

@@ -0,0 +1,32 @@
+#= require teaspoon/runner
+
+class Teaspoon.Jasmine1.Runner extends Teaspoon.Runner
+
+  constructor: ->
+    @env = window.jasmine.getEnv()
+    super
+    @env.execute()
+
+
+  setup: ->
+    @env.updateInterval = 1000
+
+    # add the spec filter
+    if grep = @params["grep"]
+      @env.specFilter = (spec) -> spec.getFullName().indexOf(grep) == 0
+
+    # add the reporter
+    reporter = new (@getReporter())()
+    responder = new Teaspoon.Jasmine1.Responder(reporter)
+    @env.addReporter(responder)
+
+    # add fixture support
+    @addFixtureSupport()
+
+
+  addFixtureSupport: ->
+    return unless jasmine.getFixtures && @fixturePath
+    jasmine.getFixtures().containerId = "teaspoon-fixtures"
+    jasmine.getFixtures().fixturesPath = @fixturePath
+    jasmine.getStyleFixtures().fixturesPath = @fixturePath
+    jasmine.getJSONFixtures().fixturesPath = @fixturePath

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine1/spec.coffee

@@ -0,0 +1,37 @@
+class Teaspoon.Jasmine1.Spec
+
+  constructor: (@spec) ->
+    @fullDescription = @spec.getFullName()
+    @description = @spec.description
+    @link = "?grep=#{encodeURIComponent(@fullDescription)}"
+    @parent = @spec.suite
+    @suiteName = @parent.getFullName()
+    @viewId = @spec.viewId
+    @pending = @spec.pending
+
+
+  errors: ->
+    return [] unless @spec.results
+    for item in @spec.results().getItems()
+      continue if item.passed()
+      {message: item.message, stack: item.trace.stack}
+
+
+  getParents: ->
+    return @parents if @parents
+    @parents ||= []
+    parent = @parent
+    while parent
+      parent = new Teaspoon.Jasmine1.Suite(parent)
+      @parents.unshift(parent)
+      parent = parent.parent
+    @parents
+
+
+  result: ->
+    results = @spec.results()
+    status = "failed"
+    status = "passed" if results.passed()
+    status = "pending" if @spec.pending
+    status: status
+    skipped: results.skipped

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine1/suite.coffee

@@ -0,0 +1,8 @@
+class Teaspoon.Jasmine1.Suite
+
+  constructor: (@suite) ->
+    @fullDescription = @suite.getFullName()
+    @description = @suite.description
+    @link = "?grep=#{encodeURIComponent(@fullDescription)}"
+    @parent = @suite.parentSuite
+    @viewId = @suite.viewId

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine2.coffee

@@ -0,0 +1,10 @@
+#= require teaspoon/teaspoon
+#= require_self
+#= require_tree ./jasmine2
+
+unless jasmineRequire?
+  throw new Teaspoon.Error('Jasmine 2 not found -- use `suite.use_framework :jasmine` and adjust or remove the `suite.javascripts` directive.')
+
+@Teaspoon ?= {}
+@Teaspoon.Jasmine2 ?= {}
+@Teaspoon.Jasmine2.Reporters ?= {}

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine2/fixture.coffee

@@ -0,0 +1,19 @@
+#= require teaspoon/fixture
+
+class Teaspoon.Jasmine2.Fixture extends Teaspoon.Fixture
+
+  @load: ->
+    args = arguments
+    @env().beforeEach => fixture.__super__.constructor.load.apply(@, args)
+    @env().afterEach => @cleanup()
+    super
+
+
+  @set: ->
+    args = arguments
+    @env().beforeEach => fixture.__super__.constructor.set.apply(@, args)
+    @env().afterEach => @cleanup()
+    super
+
+
+  @env: -> window.jasmine.getEnv()

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine2/initialize.coffee

@@ -0,0 +1,23 @@
+Teaspoon.setFramework(Teaspoon.Jasmine2)
+
+# Jasmine 2 runs the spec filter when the #it block are evaluated. This
+# means we need to set the filter upon page load, instead of when the
+# runner is initialized. Since Jasmine is loaded into the page first, then
+# the tests, then Teaspoon is initialized, this is set up to run early in
+# the boot process.
+setupSpecFilter = (env) ->
+  if grep = Teaspoon.Runner::getParams()["grep"]
+    env.specFilter = (spec) ->
+      spec.getFullName().indexOf(grep) == 0
+
+extend = (destination, source) ->
+  for property of source
+    destination[property] = source[property]
+  destination
+
+
+# Set up Jasmine 2
+window.jasmine = jasmineRequire.core(jasmineRequire)
+env = window.jasmine.getEnv()
+setupSpecFilter(env)
+extend(window, jasmineRequire.interface(jasmine, env))

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine2/reporters/console.coffee

@@ -0,0 +1,18 @@
+#= require teaspoon/reporters/console
+
+class Teaspoon.Jasmine2.Reporters.Console extends Teaspoon.Reporters.Console
+
+  reportRunnerStarting: ->
+    @currentAssertions = []
+    @log
+      type:  "runner"
+      total: null
+      start: JSON.parse(JSON.stringify(@start))
+
+
+  reportRunnerResults: =>
+    @log
+      type:    "result"
+      elapsed: ((new Teaspoon.Date().getTime() - @start.getTime()) / 1000).toFixed(5)
+      coverage: window.__coverage__
+    Teaspoon.finished = true

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine2/reporters/html.coffee

@@ -0,0 +1,11 @@
+#= require teaspoon/reporters/html
+
+class Teaspoon.Jasmine2.Reporters.HTML extends Teaspoon.Reporters.HTML
+
+  readConfig: ->
+    super
+    jasmine.CATCH_EXCEPTIONS = @config["use-catch"]
+
+
+  envInfo: ->
+    "jasmine #{jasmine.version}"

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine2/responder.coffee

@@ -0,0 +1,39 @@
+class Teaspoon.Jasmine2.Responder
+
+  constructor: (@reporter) ->
+
+  
+  jasmineStarted: (runner) ->
+    @reporter.reportRunnerStarting(total: runner.totalSpecsDefined)
+
+  
+  jasmineDone: ->
+    @reporter.reportRunnerResults()
+
+
+  suiteStarted: (suite) ->
+    if @currentSuite # suite already running, we're nested
+      suite.parent = @currentSuite
+    @currentSuite = suite
+
+    @reporter.reportSuiteStarting(new Teaspoon.Jasmine2.Suite(suite))
+
+
+  suiteDone: (suite) ->
+    @currentSuite = @currentSuite.parent
+
+    @reporter.reportSuiteResults(new Teaspoon.Jasmine2.Suite(suite))
+
+
+  specStarted: (spec) ->
+    # Jasmine 2 reports the spec starting even though it may
+    # be filtered out, but there's no way to tell.
+    # TODO: Is there a way to clean this up?
+    if jasmine.getEnv().specFilter(getFullName: -> spec.fullName)
+      spec.parent = @currentSuite
+      @reporter.reportSpecStarting(new Teaspoon.Jasmine2.Spec(spec))
+
+
+  specDone: (spec) ->
+    spec.parent = @currentSuite
+    @reporter.reportSpecResults(new Teaspoon.Jasmine2.Spec(spec))

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine2/runner.coffee

@@ -0,0 +1,26 @@
+#= require teaspoon/runner
+
+class Teaspoon.Jasmine2.Runner extends Teaspoon.Runner
+
+  constructor: ->
+    @env = window.jasmine.getEnv()
+    super
+    @env.execute()
+
+
+  setup: ->
+    # add the responder
+    reporter = new (@getReporter())()
+    responder = new Teaspoon.Jasmine2.Responder(reporter)
+    @env.addReporter(responder)
+
+    # add fixture support
+    @addFixtureSupport()
+
+
+  addFixtureSupport: ->
+    return unless jasmine.getFixtures && @fixturePath
+    jasmine.getFixtures().containerId = "teaspoon-fixtures"
+    jasmine.getFixtures().fixturesPath = @fixturePath
+    jasmine.getStyleFixtures().fixturesPath = @fixturePath
+    jasmine.getJSONFixtures().fixturesPath = @fixturePath

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine2/spec.coffee

@@ -0,0 +1,36 @@
+class Teaspoon.Jasmine2.Spec
+
+  constructor: (@spec) ->
+    @fullDescription = @spec.fullName
+    @description = @spec.description
+    @link = "?grep=#{encodeURIComponent(@fullDescription)}"
+    @parent = @spec.parent
+    @suiteName = @parent.fullName
+    @viewId = @spec.id
+    @pending = @spec.status == "pending"
+
+
+  errors: ->
+    return [] unless @spec.failedExpectations.length
+    for item in @spec.failedExpectations
+      {message: item.message, stack: item.stack}
+
+
+  getParents: ->
+    return @parents if @parents
+    @parents ||= []
+    parent = @parent
+    while parent
+      parent = new Teaspoon.Jasmine2.Suite(parent)
+      @parents.unshift(parent)
+      parent = parent.parent
+    @parents
+
+
+  result: ->
+    status: @status()
+    skipped: @spec.status == "disabled"
+
+
+  status: ->
+    if @spec.status == "disabled" then "passed" else @spec.status

data/lib/teaspoon/jasmine/assets/teaspoon/jasmine2/suite.coffee

@@ -0,0 +1,8 @@
+class Teaspoon.Jasmine2.Suite
+
+  constructor: (@suite) ->
+    @fullDescription = @suite.fullName
+    @description = @suite.description
+    @link = "?grep=#{encodeURIComponent(@fullDescription)}"
+    @parent = @suite.parent
+    @viewId = @suite.id

data/lib/teaspoon/jasmine/framework.rb

@@ -0,0 +1,35 @@
+require "teaspoon/framework/base"
+
+module Teaspoon
+  module Jasmine
+    class Framework < Teaspoon::Framework::Base
+      # specify the framework name
+      framework_name :jasmine
+
+      # register standard versions
+      register_version "1.3.1", "jasmine/1.3.1.js",
+                                dependencies: ["teaspoon-jasmine1.js"],
+                                dev_deps: ["teaspoon/jasmine1.js"]
+
+      versions = ["2.0.3", "2.1.3", "2.2.0"]
+
+      versions.each do |version|
+        register_version version, "jasmine/#{version}.js",
+                                  dependencies: ["teaspoon-jasmine2.js"],
+                                  dev_deps: ["teaspoon/jasmine2.js"]
+      end
+
+      # add asset paths
+      add_asset_path File.expand_path("../../../teaspoon/jasmine/assets", __FILE__)
+
+      # add custom install templates
+      add_template_path File.expand_path("../../../teaspoon/jasmine/templates", __FILE__)
+
+      # specify where to install, and add installation steps.
+      install_to "spec" do
+        ext = options[:coffee] ? ".coffee" : ".js"
+        copy_file "spec_helper#{ext}", "spec/javascripts/spec_helper#{ext}"
+      end
+    end
+  end
+end

data/lib/teaspoon/jasmine/templates/spec_helper.coffee

@@ -0,0 +1,32 @@
+# Teaspoon includes some support files, but you can use anything from your own support path too.
+# require support/jasmine-jquery-1.7.0
+# require support/jasmine-jquery-2.0.0
+# require support/jasmine-jquery-2.1.0
+# require support/sinon
+# require support/your-support-file
+#
+# PhantomJS (Teaspoons default driver) doesn't have support for Function.prototype.bind, which has caused confusion.
+# Use this polyfill to avoid the confusion.
+#= require support/bind-poly
+#
+# You can require your own javascript files here. By default this will include everything in application, however you
+# may get better load performance if you require the specific files that are being used in the spec that tests them.
+#= require application
+#
+# Deferring execution
+# If you're using CommonJS, RequireJS or some other asynchronous library you can defer execution. Call
+# Teaspoon.execute() after everything has been loaded. Simple example of a timeout:
+#
+# Teaspoon.defer = true
+# setTimeout(Teaspoon.execute, 1000)
+#
+# Matching files
+# By default Teaspoon will look for files that match _spec.{js,js.coffee,.coffee}. Add a filename_spec.js file in your
+# spec path and it'll be included in the default suite automatically. If you want to customize suites, check out the
+# configuration in teaspoon_env.rb
+#
+# Manifest
+# If you'd rather require your spec files manually (to control order for instance) you can disable the suite matcher in
+# the configuration and use this file as a manifest.
+#
+# For more information: http://github.com/modeset/teaspoon

data/lib/teaspoon/jasmine/templates/spec_helper.js

@@ -0,0 +1,32 @@
+// Teaspoon includes some support files, but you can use anything from your own support path too.
+// require support/jasmine-jquery-1.7.0
+// require support/jasmine-jquery-2.0.0
+// require support/jasmine-jquery-2.1.0
+// require support/sinon
+// require support/your-support-file
+//
+// PhantomJS (Teaspoons default driver) doesn't have support for Function.prototype.bind, which has caused confusion.
+// Use this polyfill to avoid the confusion.
+//= require support/bind-poly
+//
+// You can require your own javascript files here. By default this will include everything in application, however you
+// may get better load performance if you require the specific files that are being used in the spec that tests them.
+//= require application
+//
+// Deferring execution
+// If you're using CommonJS, RequireJS or some other asynchronous library you can defer execution. Call
+// Teaspoon.execute() after everything has been loaded. Simple example of a timeout:
+//
+// Teaspoon.defer = true
+// setTimeout(Teaspoon.execute, 1000)
+//
+// Matching files
+// By default Teaspoon will look for files that match _spec.{js,js.coffee,.coffee}. Add a filename_spec.js file in your
+// spec path and it'll be included in the default suite automatically. If you want to customize suites, check out the
+// configuration in teaspoon_env.rb
+//
+// Manifest
+// If you'd rather require your spec files manually (to control order for instance) you can disable the suite matcher in
+// the configuration and use this file as a manifest.
+//
+// For more information: http://github.com/modeset/teaspoon