snappy 0.0.17-java → 0.3.0-java

data/vendor/snappy/Makefile.am

@@ -1,26 +0,0 @@
-ACLOCAL_AMFLAGS = -I m4
-
-# Library.
-lib_LTLIBRARIES = libsnappy.la
-libsnappy_la_SOURCES = snappy.cc snappy-sinksource.cc snappy-stubs-internal.cc snappy-c.cc
-libsnappy_la_LDFLAGS = -version-info $(SNAPPY_LTVERSION)
-
-include_HEADERS = snappy.h snappy-sinksource.h snappy-stubs-public.h snappy-c.h
-noinst_HEADERS = snappy-internal.h snappy-stubs-internal.h snappy-test.h
-
-# Unit tests and benchmarks.
-snappy_unittest_CPPFLAGS = $(gflags_CFLAGS) $(GTEST_CPPFLAGS)
-snappy_unittest_SOURCES = snappy_unittest.cc snappy-test.cc
-snappy_unittest_LDFLAGS = $(GTEST_LDFLAGS)
-snappy_unittest_LDADD = libsnappy.la $(UNITTEST_LIBS) $(gflags_LIBS) $(GTEST_LIBS)
-TESTS = snappy_unittest
-noinst_PROGRAMS = $(TESTS)
-
-EXTRA_DIST = autogen.sh testdata/alice29.txt testdata/asyoulik.txt testdata/baddata1.snappy testdata/baddata2.snappy testdata/baddata3.snappy testdata/geo.protodata testdata/fireworks.jpeg testdata/html testdata/html_x_4 testdata/kppkn.gtb testdata/lcet10.txt testdata/paper-100k.pdf testdata/plrabn12.txt testdata/urls.10K
-dist_doc_DATA = ChangeLog COPYING INSTALL NEWS README format_description.txt framing_format.txt
-
-pkgconfigdir = $(libdir)/pkgconfig
-nodist_pkgconfig_DATA = snappy.pc
-
-libtool: $(LIBTOOL_DEPS)
-	$(SHELL) ./config.status --recheck

data/vendor/snappy/autogen.sh

@@ -1,12 +0,0 @@
-#! /bin/sh -e
-rm -rf autom4te.cache
-aclocal -I m4
-autoheader
-if glibtoolize --version >/dev/null 2>/dev/null; then
-  LIBTOOLIZE=${LIBTOOLIZE:-glibtoolize}
-else
-  LIBTOOLIZE=${LIBTOOLIZE:-libtoolize}
-fi
-$LIBTOOLIZE --copy
-automake --add-missing --copy
-autoconf

data/vendor/snappy/configure.ac

@@ -1,134 +0,0 @@
-m4_define([snappy_major], [1])
-m4_define([snappy_minor], [1])
-m4_define([snappy_patchlevel], [4])
-
-# Libtool shared library interface versions (current:revision:age)
-# Update this value for every release!  (A:B:C will map to foo.so.(A-C).C.B)
-# http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
-m4_define([snappy_ltversion], [4:1:3])
-
-AC_INIT([snappy], [snappy_major.snappy_minor.snappy_patchlevel])
-AC_CONFIG_MACRO_DIR([m4])
-AC_CONFIG_AUX_DIR([.])
-
-# These are flags passed to automake (though they look like gcc flags!)
-AM_INIT_AUTOMAKE([-Wall])
-
-LT_INIT
-AC_SUBST([LIBTOOL_DEPS])
-AC_PROG_CXX
-AC_LANG([C++])
-AC_C_BIGENDIAN
-AC_TYPE_SIZE_T
-AC_TYPE_SSIZE_T
-AC_CHECK_HEADERS([stdint.h stddef.h sys/mman.h sys/resource.h windows.h byteswap.h sys/byteswap.h sys/endian.h sys/time.h])
-
-# Don't use AC_FUNC_MMAP, as it checks for mappings of already-mapped memory,
-# which we don't need (and does not exist on Windows).
-AC_CHECK_FUNC([mmap])
-
-GTEST_LIB_CHECK([], [true], [true # Ignore; we can live without it.])
-
-AC_ARG_WITH([gflags],
-  [AS_HELP_STRING(
-    [--with-gflags],
-    [use Google Flags package to enhance the unit test @<:@default=check@:>@])],
-    [],
-    [with_gflags=check])
-
-if test "x$with_gflags" != "xno"; then
-  PKG_CHECK_MODULES(
-    [gflags],
-    [libgflags],
-    [AC_DEFINE([HAVE_GFLAGS], [1], [Use the gflags package for command-line parsing.])],
-    [if test "x$with_gflags" != "xcheck"; then
-      AC_MSG_FAILURE([--with-gflags was given, but test for gflags failed])
-    fi])
-fi
-
-# See if we have __builtin_expect.
-# TODO: Use AC_CACHE.
-AC_MSG_CHECKING([if the compiler supports __builtin_expect])
- 
-AC_TRY_COMPILE(, [
-    return __builtin_expect(1, 1) ? 1 : 0
-], [
-    snappy_have_builtin_expect=yes
-    AC_MSG_RESULT([yes])
-], [
-    snappy_have_builtin_expect=no
-    AC_MSG_RESULT([no])
-])
-if test x$snappy_have_builtin_expect = xyes ; then
-    AC_DEFINE([HAVE_BUILTIN_EXPECT], [1], [Define to 1 if the compiler supports __builtin_expect.])
-fi
-
-# See if we have working count-trailing-zeros intrinsics.
-# TODO: Use AC_CACHE.
-AC_MSG_CHECKING([if the compiler supports __builtin_ctzll])
-
-AC_TRY_COMPILE(, [
-    return (__builtin_ctzll(0x100000000LL) == 32) ? 1 : 0
-], [
-    snappy_have_builtin_ctz=yes
-    AC_MSG_RESULT([yes])
-], [
-    snappy_have_builtin_ctz=no
-    AC_MSG_RESULT([no])
-])
-if test x$snappy_have_builtin_ctz = xyes ; then
-    AC_DEFINE([HAVE_BUILTIN_CTZ], [1], [Define to 1 if the compiler supports __builtin_ctz and friends.])
-fi
-
-# Other compression libraries; the unit test can use these for comparison
-# if they are available. If they are not found, just ignore.
-UNITTEST_LIBS=""
-AC_DEFUN([CHECK_EXT_COMPRESSION_LIB], [
-  AH_CHECK_LIB([$1])
-  AC_CHECK_LIB(
-    [$1],
-    [$2],
-    [
-      AC_DEFINE_UNQUOTED(AS_TR_CPP(HAVE_LIB$1))
-      UNITTEST_LIBS="-l$1 $UNITTEST_LIBS"
-    ],
-    [true]
-  )
-])
-CHECK_EXT_COMPRESSION_LIB([z], [zlibVersion])
-CHECK_EXT_COMPRESSION_LIB([lzo2], [lzo1x_1_15_compress])
-CHECK_EXT_COMPRESSION_LIB([lzf], [lzf_compress])
-CHECK_EXT_COMPRESSION_LIB([fastlz], [fastlz_compress])
-CHECK_EXT_COMPRESSION_LIB([quicklz], [qlz_compress])
-AC_SUBST([UNITTEST_LIBS])
-
-# These are used by snappy-stubs-public.h.in.
-if test "$ac_cv_header_stdint_h" = "yes"; then
-    AC_SUBST([ac_cv_have_stdint_h], [1])
-else
-    AC_SUBST([ac_cv_have_stdint_h], [0])
-fi
-if test "$ac_cv_header_stddef_h" = "yes"; then
-    AC_SUBST([ac_cv_have_stddef_h], [1])
-else
-    AC_SUBST([ac_cv_have_stddef_h], [0])
-fi
-if test "$ac_cv_header_sys_uio_h" = "yes"; then
-    AC_SUBST([ac_cv_have_sys_uio_h], [1])
-else
-    AC_SUBST([ac_cv_have_sys_uio_h], [0])
-fi
-
-# Export the version to snappy-stubs-public.h.
-SNAPPY_MAJOR="snappy_major"
-SNAPPY_MINOR="snappy_minor"
-SNAPPY_PATCHLEVEL="snappy_patchlevel"
-
-AC_SUBST([SNAPPY_MAJOR])
-AC_SUBST([SNAPPY_MINOR])
-AC_SUBST([SNAPPY_PATCHLEVEL])
-AC_SUBST([SNAPPY_LTVERSION], snappy_ltversion)
-
-AC_CONFIG_HEADERS([config.h])
-AC_CONFIG_FILES([Makefile snappy-stubs-public.h snappy.pc])
-AC_OUTPUT

data/vendor/snappy/m4/gtest.m4

@@ -1,74 +0,0 @@
-dnl GTEST_LIB_CHECK([minimum version [,
-dnl                  action if found [,action if not found]]])
-dnl
-dnl Check for the presence of the Google Test library, optionally at a minimum
-dnl version, and indicate a viable version with the HAVE_GTEST flag. It defines
-dnl standard variables for substitution including GTEST_CPPFLAGS,
-dnl GTEST_CXXFLAGS, GTEST_LDFLAGS, and GTEST_LIBS. It also defines
-dnl GTEST_VERSION as the version of Google Test found. Finally, it provides
-dnl optional custom action slots in the event GTEST is found or not.
-AC_DEFUN([GTEST_LIB_CHECK],
-[
-dnl Provide a flag to enable or disable Google Test usage.
-AC_ARG_ENABLE([gtest],
-  [AS_HELP_STRING([--enable-gtest],
-                  [Enable tests using the Google C++ Testing Framework.
-                  (Default is enabled.)])],
-  [],
-  [enable_gtest=])
-AC_ARG_VAR([GTEST_CONFIG],
-           [The exact path of Google Test's 'gtest-config' script.])
-AC_ARG_VAR([GTEST_CPPFLAGS],
-           [C-like preprocessor flags for Google Test.])
-AC_ARG_VAR([GTEST_CXXFLAGS],
-           [C++ compile flags for Google Test.])
-AC_ARG_VAR([GTEST_LDFLAGS],
-           [Linker path and option flags for Google Test.])
-AC_ARG_VAR([GTEST_LIBS],
-           [Library linking flags for Google Test.])
-AC_ARG_VAR([GTEST_VERSION],
-           [The version of Google Test available.])
-HAVE_GTEST="no"
-AS_IF([test "x${enable_gtest}" != "xno"],
-  [AC_MSG_CHECKING([for 'gtest-config'])
-   AS_IF([test "x${enable_gtest}" = "xyes"],
-     [AS_IF([test -x "${enable_gtest}/scripts/gtest-config"],
-        [GTEST_CONFIG="${enable_gtest}/scripts/gtest-config"],
-        [GTEST_CONFIG="${enable_gtest}/bin/gtest-config"])
-      AS_IF([test -x "${GTEST_CONFIG}"], [],
-        [AC_MSG_RESULT([no])
-         AC_MSG_ERROR([dnl
-Unable to locate either a built or installed Google Test.
-The specific location '${enable_gtest}' was provided for a built or installed
-Google Test, but no 'gtest-config' script could be found at this location.])
-         ])],
-     [AC_PATH_PROG([GTEST_CONFIG], [gtest-config])])
-   AS_IF([test -x "${GTEST_CONFIG}"],
-     [AC_MSG_RESULT([${GTEST_CONFIG}])
-      m4_ifval([$1],
-        [_gtest_min_version="--min-version=$1"
-         AC_MSG_CHECKING([for Google Test at least version >= $1])],
-        [_gtest_min_version="--min-version=0"
-         AC_MSG_CHECKING([for Google Test])])
-      AS_IF([${GTEST_CONFIG} ${_gtest_min_version}],
-        [AC_MSG_RESULT([yes])
-         HAVE_GTEST='yes'],
-        [AC_MSG_RESULT([no])])],
-     [AC_MSG_RESULT([no])])
-   AS_IF([test "x${HAVE_GTEST}" = "xyes"],
-     [GTEST_CPPFLAGS=`${GTEST_CONFIG} --cppflags`
-      GTEST_CXXFLAGS=`${GTEST_CONFIG} --cxxflags`
-      GTEST_LDFLAGS=`${GTEST_CONFIG} --ldflags`
-      GTEST_LIBS=`${GTEST_CONFIG} --libs`
-      GTEST_VERSION=`${GTEST_CONFIG} --version`
-      AC_DEFINE([HAVE_GTEST],[1],[Defined when Google Test is available.])],
-     [AS_IF([test "x${enable_gtest}" = "xyes"],
-        [AC_MSG_ERROR([dnl
-Google Test was enabled, but no viable version could be found.])
-         ])])])
-AC_SUBST([HAVE_GTEST])
-AM_CONDITIONAL([HAVE_GTEST],[test "x$HAVE_GTEST" = "xyes"])
-AS_IF([test "x$HAVE_GTEST" = "xyes"],
-  [m4_ifval([$2], [$2])],
-  [m4_ifval([$3], [$3])])
-])

data/vendor/snappy/snappy.pc.in

@@ -1,10 +0,0 @@
-prefix=@prefix@
-exec_prefix=@exec_prefix@
-libdir=@libdir@
-includedir=@includedir@
-
-Name: @PACKAGE@
-Description: A fast compression/decompression library
-Version: @PACKAGE_VERSION@
-Libs: -L${libdir} -l@PACKAGE@
-Cflags: -I${includedir}