slender_data 0.1.0

checksums.yaml

@@ -0,0 +1,7 @@
+---
+SHA1:
+  metadata.gz: 1deea5d8aa969cdc2e213cb39e50b526a00615c0
+  data.tar.gz: 5b89a6bd314958eef91ddf872db9d10763f609d9
+SHA512:
+  metadata.gz: b3df0aa35a568a60aa088320e254183d632357f5ecee53b0f47a2ba900113a3fb546e6220f3b50890388f8e67e87c71c5e71db3a2f55563dd3c1c7e4ab14ccf1
+  data.tar.gz: 916850fc041b71ae70fc6c9d97308a7713f78d4ac41f6d4a7ac324f120db9f604f5c5fe6bb20f1c25da2b023822759b42bb745eacd6e5f4e2f665608324fe38c

data/MIT-LICENSE

@@ -0,0 +1,20 @@
+Copyright 2013 YOURNAME
+
+Permission is hereby granted, free of charge, to any person obtaining
+a copy of this software and associated documentation files (the
+"Software"), to deal in the Software without restriction, including
+without limitation the rights to use, copy, modify, merge, publish,
+distribute, sublicense, and/or sell copies of the Software, and to
+permit persons to whom the Software is furnished to do so, subject to
+the following conditions:
+
+The above copyright notice and this permission notice shall be
+included in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
+MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
+NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE
+LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION
+OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION
+WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.

data/Rakefile

@@ -0,0 +1,23 @@
+begin
+  require 'bundler/setup'
+rescue LoadError
+  puts 'You must `gem install bundler` and `bundle install` to run rake tasks'
+end
+
+require 'rdoc/task'
+
+RDoc::Task.new(:rdoc) do |rdoc|
+  rdoc.rdoc_dir = 'rdoc'
+  rdoc.title    = 'SlenderData'
+  rdoc.options << '--line-numbers'
+  rdoc.rdoc_files.include('README.rdoc')
+  rdoc.rdoc_files.include('lib/**/*.rb')
+end
+
+APP_RAKEFILE = File.expand_path("../spec/dummy/Rakefile", __FILE__)
+load 'rails/tasks/engine.rake'
+
+
+Bundler::GemHelper.install_tasks
+
+task :default => 'app:konacha:run'

data/app/assets/javascripts/slender_data/ajax_loader.coffee

@@ -0,0 +1,76 @@
+#= require slender_data/cache
+
+# A generic ajax loader for parallel GET requests.
+# Prevents duplicate requests, caches the responses
+# to answer subsequent requests immediately
+# without additional server requests.
+#
+# Warning: Caches the responses, so once a request is cached,
+#          any new content on the same URL will not be visible!
+class slender_data.AjaxLoader
+
+  constructor: (params = {}) ->
+
+    # Caches the callbacks.
+    @cb_cache = new slender_data.Cache()
+
+    # Whether to perform caching of data.
+    # Default: no.
+    @caching = !!params.caching
+
+    # Caches the data loaded.
+    @data_cache = new slender_data.Cache()
+
+    # The number of currently running loading operations.
+    @loader_count = 0
+
+
+  # The different events that this class can fire.
+  @events =
+    AJAX_LOADING: 'AJAX_LOADING'
+    AJAX_LOADED: 'AJAX_LOADED'
+
+
+  # Loads the data from the given URL asynchronously.
+  get: (url, callback) ->
+
+    # Return immediately if we have cached data.
+    if @caching
+      cached_data = @data_cache.get url
+      return callback(cached_data) if cached_data?
+
+    # Here, we have no cached data. Check
+
+    # If a GET call to this URL is already in progress -->
+    # add the given callback to the list of waiting callbacks.
+    request_in_progress = @cb_cache.get url
+    return request_in_progress.push(callback) if request_in_progress?
+
+    # Here, no request is currently in progress --> start a new one.
+
+    # Add callback to callback list.
+    @cb_cache.add url, [callback]
+
+    # Fire 'loading' event if this is the start of a loading operation.
+    @loader_count++
+    if @loader_count == 1
+      $('body').trigger slender_data.AjaxLoader.events.AJAX_LOADING
+
+    # Perform the request.
+    jQuery.get url, (data) =>
+
+      # Add result to cache.
+      if @caching
+        @data_cache.add url, data
+
+      # Call callbacks.
+      cb(data) for cb in @cb_cache.get url
+
+      # Remove request from callback list.
+      @cb_cache.remove url
+
+      # Fire 'loaded' event.
+      @loader_count--
+      if @loader_count == 0
+        $('body').trigger slender_data.AjaxLoader.events.AJAX_LOADED
+

data/app/assets/javascripts/slender_data/cache.coffee

@@ -0,0 +1,63 @@
+# A generic cache.
+# Stores key-value pairs.
+class slender_data.Cache
+
+  constructor: ->
+
+    # Container for the cached objects.
+    @cache = {}
+
+
+  # Adds the given entry to the cache.
+  # Overwrites existing entries.
+  add: (key, value) ->
+    @cache[key] = value
+
+
+  # Returns the entry with the given key from the cache, or NULL if no entry exists.
+  get: (key) ->
+    @cache[key]
+
+
+  # Looks up several entries at once.
+  # Returns a hash of found entries, and a list of missing entries.
+  get_many: (keys) ->
+    result = { found: {}, missing: [] }
+    for key in keys
+      do (key) =>
+        value = @cache[key]
+        if value
+          result.found[key] = value
+        else
+          result.missing.push key
+    result
+  getMany: Cache::get_many
+
+
+  # Returns the number of cached objects.
+  length: () ->
+    slender_data.object_length @cache
+
+
+  # Removes the entry with the given key.
+  remove: (key) =>
+    delete @cache[key]
+
+
+  # Removes all entries with the given keys.
+  remove_many: (keys) ->
+    @remove(key) for key in keys
+
+
+  # Replaces the cache with the given data.
+  # When 'key' is given, treats 'data' as an array of objects, and indexes each element by the given key.
+  # When 'key' is not given, treats 'data' as an already indexed hash object.
+  replace_all: (data, key) ->
+    if key
+      # Key given --> index the data array.
+      @add(entry[key], entry) for entry in data
+    else
+      # Key not given --> use data as the new cache.
+      @cache = data
+  replaceAll: Cache::replace_all
+

data/app/assets/javascripts/slender_data/indexed_cache.coffee

@@ -0,0 +1,32 @@
+#= require slender_data/cache
+
+# Provides fast and convenient retrieval of hash objects
+# by indexing them on a given key column.
+class slender_data.IndexedCache
+
+  constructor: (@key = 'id') ->
+    @cache = new slender_data.Cache
+
+
+  add: (entry) ->
+    @cache.add entry[@key], entry
+
+
+  add_all: (entries) ->
+    @add(entry) for entry in entries
+
+
+  remove: (entry_id) ->
+    @cache.remove entry_id
+
+
+  remove_many: (entry_ids) ->
+    @cache.remove_many entry_ids
+
+
+  get: (key) ->
+    @cache.get key
+
+
+  length: => @cache.length()
+

data/app/assets/javascripts/slender_data/persistence_manager.coffee

@@ -0,0 +1,239 @@
+#= require slender_data/ajax_loader
+#= require slender_data/indexed_cache
+#= require slender_data/tools
+
+# Provides persistence services for data models.
+#
+# This class operates against a standard RESTful data API, whole path is given in params.url.
+# In addition to the standard RESTful routes, the data API is expected to support these methods for performance reasons:
+# * DELETE /entries: Delete a whole batch of entries at once. The ids of the entries to delete are given as a JSON hash in the body of the request.
+# *
+class slender_data.PersistenceManager
+
+  constructor: (params) ->
+
+    # Copy of the data as it is on the server.
+    @server_data = new slender_data.IndexedCache
+
+    # Copy of the data as it is on the client.
+    @client_data = new slender_data.IndexedCache
+
+    # The base url on the server. Expected to be a fully RESTful API.
+    @base_url = params.url
+
+    # Name of the 'id' column for models.
+    @key = params.key or 'id'
+
+    # Name of the model class (e.g. "user").
+    @model_name = params.model_name
+
+    # For handling parallel requests to the server.
+    @loader = new slender_data.AjaxLoader { cache: no }
+
+
+  # Adds the given data objects to the server cache.
+  add_all: (data) ->
+    @server_data.add_all data
+
+
+  # Returns an array containing only the changed objects.
+  # Each object contains only the changed columns + key column.
+  changed_objects_columns: (objects) ->
+    slender_data.tap [], (result) =>
+      for object in objects
+        diff = slender_data.object_diff @server_data.get(object[@key]), object
+        continue if slender_data.object_length(diff) == 0
+        diff[@key] = object[@key]
+        result.push(diff)
+
+
+  # Returns the URL to access the collection of objects.
+  collection_url: ->
+    "#{@base_url}.json"
+
+
+  # Creates the given object on the server.
+  create: (obj, success_callback, error_callback) ->
+    data = {}
+    data[@model_name] = obj
+
+    jQuery.ajax
+      url: @collection_url()
+      type: 'POST'
+      data: data
+      success: (server_response) =>
+        server_obj = server_response[@model_name]
+        @server_data.add server_obj
+        success_callback server_obj
+      error: (xhr) =>
+        error_callback(xhr.responseText) if error_callback
+
+
+  # Deletes the given object from the server.
+  delete: (obj, success_callback, error_callback) ->
+    @client_data.remove obj
+    @server_data.remove obj
+    jQuery.ajax
+      url: @entry_url(obj)
+      type: 'DELETE'
+      success: ->
+        success_callback() if success_callback?
+      error: (xhr) ->
+        error_callback(xhr.responseText) if error_callback
+
+
+  # Deletes the given objects from the server.
+  delete_many: (object_ids, success_callback, error_callback) ->
+    @client_data.remove_many object_ids
+    @server_data.remove_many object_ids
+    jQuery.ajax
+      url: @base_url
+      type: 'DELETE'
+      data: {ids: object_ids}
+      success: ->
+        success_callback() if success_callback?
+      error: (xhr) ->
+        error_callback(xhr.responseText) if error_callback
+
+
+  # Returns the url to access a single entry.
+  entry_url: (entry) ->
+    "#{@base_url}/#{entry[@key]}.json"
+
+
+  # Returns the url to access the collection of entries.
+  entries_url: ->
+    "#{@base_url}.json"
+
+
+  # Returns the cached data object, or undefined.
+  get_cached: (key) ->
+
+    # Try to use client_data cache.
+    client_obj = @client_data.get key
+    return client_obj if client_obj
+
+    # No data in client cache --> try to use server cache.
+    server_obj = @server_data.get key
+    if server_obj
+      client_obj = slender_data.clone_hash server_obj
+      @client_data.add client_obj
+      return client_obj
+
+    # Object not found in client or server cache.
+    return undefined
+
+
+  # Returns the entry with the given key.
+  load: (key, success_callback) ->
+
+    # Try to load from cache.
+    return success_callback(entry) if entry = @get_cached key
+
+    # No data on client at all --> load data from server.
+    @loader.get "#{@base_url}/#{key}", (server_entry) =>
+      @server_data.add server_entry
+      client_entry = slender_data.clone_hash server_entry
+      @client_data.add client_entry
+      success_callback client_entry
+
+
+  # Loads all objects from the server.
+  # Provides the given params as parameters to the GET request.
+  load_all: (params, success_callback, error_callback) ->
+    jQuery.ajax
+      url: @collection_url()
+      cache: no
+      data: params
+      success: (data) =>
+        @server_data.add_all data
+        success_callback() if success_callback
+      error: (xhr) ->
+        error_callback(xhr.responseText) if error_callback
+
+
+  # Loads all entries with the given ids.
+  load_many: (ids, success_callback) ->
+    missing_ids = []
+    entries = []
+    $.each ids, (pos, id) =>
+      entry = @get_cached id
+      if entry
+        entries.push entry
+      else
+        missing_ids.push id
+
+    if missing_ids.length == 0
+      return success_callback(entries)
+
+    alert "uncached entries found: #{missing_ids}"
+
+
+  # Saves the given object.
+  # Does the right thing (create or update) dependent on
+  # whether the object already has a key parameter.
+  save: (obj, success_callback, error_callback) ->
+    if obj[@key]?
+      @update obj, success_callback, error_callback
+    else
+      @create obj, success_callback, error_callback
+
+
+  # Updates the given object.
+  #
+  # The given object must exist on the server already,
+  # and have a proper value in the key attribute.
+  update: (obj, success_callback, error_callback) ->
+
+    # Handle updating several objects.
+    return @update_many(obj, success_callback, error_callback) if $.type(obj) == 'array'
+
+    # Create a new hash, containing only the changed attributes between obj and it's replica in @server_data.
+    diff_obj = slender_data.object_diff @server_data.get(obj[@key]), obj
+    if slender_data.object_length(diff_obj) == 0
+      success_callback obj if success_callback
+      return
+
+    # Send to server
+    data = {}
+    data[@model_name] = diff_obj
+    jQuery.ajax
+      url: @entry_url(obj)
+      type: 'PUT'
+      data: data
+      success: (server_response) =>
+        server_obj = server_response[@model_name]
+        @server_data.add server_obj
+        client_obj = slender_data.clone_hash server_obj
+        @client_data.add client_obj
+        success_callback client_obj if success_callback
+      error: (xhr) ->
+        error_callback(xhr.responseText) if error_callback
+
+
+  # Bulk-updates the given objects.
+  # All the existing objects must exist on the server already,
+  # and have a value in the key attribute.
+  update_many: (objects, success_callback, error_callback) ->
+
+    # Find all objects that have been changed on the client.
+    diff_objects = @changed_objects_columns objects
+
+    # Send to server
+    data = {}
+    data["#{@model_name}s"] = diff_objects
+    jQuery.ajax
+      url: @entries_url()
+      type: 'PUT'
+      data: data
+      success: (server_response) =>
+        server_objects = server_response["#{@model_name}s"]
+        client_objects = (for server_object in server_objects
+          @server_data.add server_object
+          client_object = slender_data.clone_hash server_object
+          @client_data.add client_object
+          client_object)
+        success_callback(client_objects) if success_callback
+      error: (xhr) ->
+        error_callback(xhr.responseText) if error_callback
+

data/app/assets/javascripts/slender_data/tools.coffee

@@ -0,0 +1,31 @@
+# Returns a replica of the given hash.
+# Don't use this method for real objects with superclasses, prototypes, and stuff.
+slender_data.clone_hash = (obj) ->
+  result = {}
+  result[key] = value for own key, value of obj
+  result
+
+
+# Returns an object that contains only the attributes
+# that are different between obj_1 and obj_2.
+# Only looks for changed attributes, not missing attributes.
+slender_data.object_diff = (obj_1, obj_2) ->
+  result = {}
+  for own key, value_2 of obj_2
+    do (key, value_2) ->
+      value_1 = obj_1[key]
+      result[key] = value_2 if value_1 != value_2
+  result
+
+
+# Returns the number of attributes of the given object.
+# NOTE(KG): This doesn't work in IE8.
+slender_data.object_length = (obj) ->
+  Object.keys(obj).length
+
+
+# Allows to populate the given object through a callback.
+slender_data.tap = (obj, callback) ->
+  callback obj
+  obj
+

data/app/assets/javascripts/slender_data.js

@@ -0,0 +1,8 @@
+//= require_self
+//= require ./slender_data/tools
+//= require ./slender_data/cache
+//= require ./slender_data/indexed_cache
+//= require ./slender_data/ajax_loader
+//= require ./slender_data/persistence_manager
+
+window.slender_data = window.slender_data || {}

data/lib/slender_data/engine.rb

@@ -0,0 +1,5 @@
+module SlenderData
+  class Engine < ::Rails::Engine
+    isolate_namespace SlenderData
+  end
+end

data/lib/slender_data/version.rb

@@ -0,0 +1,3 @@
+module SlenderData
+  VERSION = "0.1.0"
+end

data/lib/slender_data.rb

@@ -0,0 +1,4 @@
+require "slender_data/engine"
+
+module SlenderData
+end

data/lib/tasks/slender_data_tasks.rake

@@ -0,0 +1,4 @@
+# desc "Explaining what the task does"
+# task :slender_data do
+#   # Task goes here
+# end

metadata

@@ -0,0 +1,155 @@
+--- !ruby/object:Gem::Specification
+name: slender_data
+version: !ruby/object:Gem::Version
+  version: 0.1.0
+platform: ruby
+authors:
+- Kevin Goslar
+autorequire: 
+bindir: bin
+cert_chain: []
+date: 2013-08-15 00:00:00.000000000 Z
+dependencies:
+- !ruby/object:Gem::Dependency
+  name: rails
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: 3.1.0
+  type: :runtime
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: 3.1.0
+- !ruby/object:Gem::Dependency
+  name: coffee-rails
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :runtime
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+- !ruby/object:Gem::Dependency
+  name: guard-livereload
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+- !ruby/object:Gem::Dependency
+  name: rspec
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+- !ruby/object:Gem::Dependency
+  name: selenium-webdriver
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+- !ruby/object:Gem::Dependency
+  name: sqlite3
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+- !ruby/object:Gem::Dependency
+  name: uglifier
+  requirement: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+  type: :development
+  prerelease: false
+  version_requirements: !ruby/object:Gem::Requirement
+    requirements:
+    - - '>='
+      - !ruby/object:Gem::Version
+        version: '0'
+description: Provides simple and extensible data management services to JavaScript
+  applications.
+email:
+- kevin.goslar@gmail.com
+executables: []
+extensions: []
+extra_rdoc_files: []
+files:
+- app/assets/javascripts/slender_data/ajax_loader.coffee
+- app/assets/javascripts/slender_data/cache.coffee
+- app/assets/javascripts/slender_data/indexed_cache.coffee
+- app/assets/javascripts/slender_data/persistence_manager.coffee
+- app/assets/javascripts/slender_data/tools.coffee
+- app/assets/javascripts/slender_data.js
+- lib/slender_data/engine.rb
+- lib/slender_data/version.rb
+- lib/slender_data.rb
+- lib/tasks/slender_data_tasks.rake
+- MIT-LICENSE
+- Rakefile
+homepage: http://github.com/kevgo/slender_data
+licenses: []
+metadata: {}
+post_install_message: 
+rdoc_options: []
+require_paths:
+- lib
+required_ruby_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+required_rubygems_version: !ruby/object:Gem::Requirement
+  requirements:
+  - - '>='
+    - !ruby/object:Gem::Version
+      version: '0'
+requirements: []
+rubyforge_project: 
+rubygems_version: 2.0.3
+signing_key: 
+specification_version: 4
+summary: A JS micro-framework for lightweight AJAX data management against RESTful
+  APIs.
+test_files: []