service_kiosk 0.5.0

data/provision/modules/apt/README.md

@@ -0,0 +1,119 @@
+# Apt module for Puppet
+
+## Description
+Provides helpful definitions for dealing with Apt.
+
+## Usage
+
+### apt
+The apt class provides a number of common resources and options which
+are shared by the various defined types in this module. This class
+should always be included in your manifests if you are using the `apt`
+module.
+
+    class { 'apt':
+      always_apt_update    => false,
+      disable_keys         => undef,
+      proxy_host           => false,
+      proxy_port           => '8080',
+      purge_sources_list   => false,
+      purge_sources_list_d => false,
+      purge_preferences_d  => false
+    }
+
+### apt::builddep
+Install the build depends of a specified package.
+
+    apt::builddep { "glusterfs-server": }
+
+### apt::force
+Force a package to be installed from a specific release.  Useful when
+using repositories like Debian unstable in Ubuntu.
+
+    apt::force { "glusterfs-server":
+	  release => "unstable",
+	  version => '3.0.3',
+	  require => Apt::Source["debian_unstable"],
+    }
+
+### apt::pin
+Add an apt pin for a certain release.
+
+    apt::pin { "karmic": priority => 700 }
+    apt::pin { "karmic-updates": priority => 700 }
+    apt::pin { "karmic-security": priority => 700 }
+
+### apt::ppa
+Add a ppa repository using `add-apt-repository`.  Somewhat experimental.
+
+    apt::ppa { "ppa:drizzle-developers/ppa": }
+
+### apt::release
+Set the default apt release.  Useful when using repositories like
+Debian unstable in Ubuntu.
+
+    apt::release { "karmic": }
+
+### apt::source
+Add an apt source to `/etc/apt/sources.list.d/`.
+
+    apt::source { "debian_unstable":
+      location          => "http://debian.mirror.iweb.ca/debian/",
+      release           => "unstable",
+      repos             => "main contrib non-free",
+      required_packages => "debian-keyring debian-archive-keyring",
+      key               => "55BE302B",
+      key_server        => "subkeys.pgp.net",
+      pin               => "-10",
+      include_src       => true
+    }
+
+This source will configure your system for the Puppet Labs APT
+repository.
+
+    apt::source { 'puppetlabs':
+      location   => 'http://apt.puppetlabs.com',
+      repos      => 'main',
+      key        => '4BD6EC30',
+      key_server => 'pgp.mit.edu',
+    }
+
+### apt::key
+Add a key to the list of keys used by apt to authenticate packages.
+
+    apt::key { "puppetlabs":
+      key        => "4BD6EC30",
+      key_server => "pgp.mit.edu",
+    }
+
+    apt::key { "jenkins":
+      key        => "D50582E6",
+      key_source => "http://pkg.jenkins-ci.org/debian/jenkins-ci.org.key",
+    }
+
+Note that use of the "key_source" parameter requires wget to be
+installed and working.
+
+
+## Contributors
+A lot of great people have contributed to this module. A somewhat
+current list follows.
+
+Ben Godfrey <ben.godfrey@wonga.com>
+Branan Purvine-Riley <branan@puppetlabs.com>
+Christian G. Warden <cwarden@xerus.org>  
+Dan Bode <bodepd@gmail.com> <dan@puppetlabs.com>  
+Garrett Honeycutt <github@garretthoneycutt.com>  
+Jeff Wallace <jeff@evolvingweb.ca> <jeff@tjwallace.ca>  
+Ken Barber <ken@bob.sh>  
+Matthaus Litteken <matthaus@puppetlabs.com> <mlitteken@gmail.com>  
+Matthias Pigulla <mp@webfactory.de>  
+Monty Taylor <mordred@inaugust.com>  
+Peter Drake <pdrake@allplayers.com>  
+Reid Vandewiele <marut@cat.pdx.edu>  
+Robert Navarro <rnavarro@phiivo.com>  
+Ryan Coleman <ryan@puppetlabs.com>  
+Scott McLeod <scott.mcleod@theice.com>  
+Spencer Krum <spencer@puppetlabs.com>  
+William Van Hevelingen <blkperl@cat.pdx.edu> <wvan13@gmail.com>  
+Zach Leslie <zach@puppetlabs.com>  

data/provision/modules/apt/Rakefile

@@ -0,0 +1 @@
+require 'puppetlabs_spec_helper/rake_tasks'

data/provision/modules/apt/manifests/backports.pp

@@ -0,0 +1,48 @@
+# This adds the necessary components to get backports for ubuntu and debian
+#
+# == Parameters
+#
+# [*release*]
+#   The ubuntu/debian release name. Defaults to $lsbdistcodename. Setting this
+#   manually can cause undefined behavior. (Read: universe exploding)
+#
+# == Examples
+#
+#   include apt::backports
+#
+#   class { 'apt::backports':
+#     release => 'natty',
+#   }
+#
+# == Authors
+#
+# Ben Hughes, I think. At least blame him if this goes wrong.
+# I just added puppet doc.
+#
+# == Copyright
+#
+# Copyright 2011 Puppet Labs Inc, unless otherwise noted.
+class apt::backports(
+  $release  = $::lsbdistcodename,
+  $location = $apt::params::backports_location
+) inherits apt::params {
+
+  $release_real = downcase($release)
+  $key = $::lsbdistid ? {
+    'debian' => '55BE302B',
+    'ubuntu' => '437D05B5',
+  }
+  $repos = $::lsbdistid ? {
+    'debian' => 'main contrib non-free',
+    'ubuntu' => 'main universe multiverse restricted',
+  }
+
+  apt::source { 'backports':
+    location   => $location,
+    release    => "${release_real}-backports",
+    repos      => $repos,
+    key        => $key,
+    key_server => 'pgp.mit.edu',
+    pin        => '200',
+  }
+}

data/provision/modules/apt/manifests/builddep.pp

@@ -0,0 +1,16 @@
+# builddep.pp
+
+define apt::builddep() {
+  include apt::update
+
+  exec { "apt-builddep-${name}":
+    command   => "/usr/bin/apt-get -y --force-yes build-dep ${name}",
+    logoutput => 'on_failure',
+    notify    => Exec['apt_update'],
+  }
+
+  # Need anchor to provide containment for dependencies.
+  anchor { "apt::builddep::${name}":
+    require => Class['apt::update'],
+  }
+}

data/provision/modules/apt/manifests/conf.pp

@@ -0,0 +1,18 @@
+define apt::conf (
+  $content,
+  $ensure   = present,
+  $priority = '50'
+) {
+
+  include apt::params
+
+  $apt_conf_d = $apt::params::apt_conf_d
+
+  file { "${apt_conf_d}/${priority}${name}":
+    ensure  => $ensure,
+    content => $content,
+    owner   => root,
+    group   => root,
+    mode    => '0644',
+  }
+}

data/provision/modules/apt/manifests/debian/testing.pp

@@ -0,0 +1,21 @@
+# testing.pp
+
+class apt::debian::testing {
+  include apt
+
+  # deb http://debian.mirror.iweb.ca/debian/ testing main contrib non-free
+  # deb-src http://debian.mirror.iweb.ca/debian/ testing main contrib non-free
+  # Key: 55BE302B  Server: subkeys.pgp.net
+  # debian-keyring
+  # debian-archive-keyring
+
+  apt::source { 'debian_testing':
+    location          => 'http://debian.mirror.iweb.ca/debian/',
+    release           => 'testing',
+    repos             => 'main contrib non-free',
+    required_packages => 'debian-keyring debian-archive-keyring',
+    key               => '55BE302B',
+    key_server        => 'subkeys.pgp.net',
+    pin               => '-10',
+  }
+}

data/provision/modules/apt/manifests/debian/unstable.pp

@@ -0,0 +1,21 @@
+# unstable.pp
+
+class apt::debian::unstable {
+  include apt
+
+  # deb http://debian.mirror.iweb.ca/debian/ unstable main contrib non-free
+  # deb-src http://debian.mirror.iweb.ca/debian/ unstable main contrib non-free
+  # Key: 55BE302B  Server: subkeys.pgp.net
+  # debian-keyring
+  # debian-archive-keyring
+
+  apt::source { 'debian_unstable':
+    location          => 'http://debian.mirror.iweb.ca/debian/',
+    release           => 'unstable',
+    repos             => 'main contrib non-free',
+    required_packages => 'debian-keyring debian-archive-keyring',
+    key               => '55BE302B',
+    key_server        => 'subkeys.pgp.net',
+    pin               => '-10',
+  }
+}

data/provision/modules/apt/manifests/force.pp

@@ -0,0 +1,24 @@
+# force.pp
+# force a package from a specific release
+
+define apt::force(
+  $release = 'testing',
+  $version = false,
+  $timeout = 300
+) {
+
+  $version_string = $version ? {
+    false   => undef,
+    default => "=${version}",
+  }
+
+  $install_check = $version ? {
+    false   => "/usr/bin/dpkg -s ${name} | grep -q 'Status: install'",
+    default => "/usr/bin/dpkg -s ${name} | grep -q 'Version: ${version}'",
+  }
+  exec { "/usr/bin/aptitude -y -t ${release} install ${name}${version_string}":
+    unless    => $install_check,
+    logoutput => 'on_failure',
+    timeout   => $timeout,
+  }
+}

data/provision/modules/apt/manifests/init.pp

@@ -0,0 +1,114 @@
+# Class: apt
+#
+# This module manages the initial configuration of apt.
+#
+# Parameters:
+#   The parameters listed here are not required in general and were
+#     added for use cases related to development environments.
+#   disable_keys - disables the requirement for all packages to be signed
+#   always_apt_update - rather apt should be updated on every run (intended
+#     for development environments where package updates are frequent)
+#   purge_sources_list - Accepts true or false. Defaults to false If set to
+#     true, Puppet will purge all unmanaged entries from sources.list
+#   purge_sources_list_d - Accepts true or false. Defaults to false. If set
+#     to true, Puppet will purge all unmanaged entries from sources.list.d
+#
+# Actions:
+#
+# Requires:
+#   puppetlabs/stdlib
+# Sample Usage:
+#  class { 'apt': }
+
+class apt(
+  $always_apt_update    = false,
+  $disable_keys         = undef,
+  $proxy_host           = false,
+  $proxy_port           = '8080',
+  $purge_sources_list   = false,
+  $purge_sources_list_d = false,
+  $purge_preferences_d  = false
+) {
+
+  include apt::params
+  include apt::update
+
+  validate_bool($purge_sources_list, $purge_sources_list_d, $purge_preferences_d)
+
+  $sources_list_content = $purge_sources_list ? {
+    false => undef,
+    true  => "# Repos managed by puppet.\n",
+  }
+
+  if $always_apt_update == true {
+    Exec <| title=='apt_update' |> {
+      refreshonly => false,
+    }
+  }
+
+  $root           = $apt::params::root
+  $apt_conf_d     = $apt::params::apt_conf_d
+  $sources_list_d = $apt::params::sources_list_d
+  $preferences_d  = $apt::params::preferences_d
+  $provider       = $apt::params::provider
+
+  file { 'sources.list':
+    ensure  => present,
+    path    => "${root}/sources.list",
+    owner   => root,
+    group   => root,
+    mode    => '0644',
+    content => $sources_list_content,
+    notify  => Exec['apt_update'],
+  }
+
+  file { 'sources.list.d':
+    ensure  => directory,
+    path    => $sources_list_d,
+    owner   => root,
+    group   => root,
+    purge   => $purge_sources_list_d,
+    recurse => $purge_sources_list_d,
+    notify  => Exec['apt_update'],
+  }
+
+  file { 'preferences.d':
+    ensure  => directory,
+    path    => $preferences_d,
+    owner   => root,
+    group   => root,
+    purge   => $purge_preferences_d,
+    recurse => $purge_preferences_d,
+  }
+
+  case $disable_keys {
+    true: {
+      file { '99unauth':
+        ensure  => present,
+        content => "APT::Get::AllowUnauthenticated 1;\n",
+        path    => "${apt_conf_d}/99unauth",
+      }
+    }
+    false: {
+      file { '99unauth':
+        ensure => absent,
+        path   => "${apt_conf_d}/99unauth",
+      }
+    }
+    undef:   { } # do nothing
+    default: { fail('Valid values for disable_keys are true or false') }
+  }
+
+  if ($proxy_host) {
+    file { 'configure-apt-proxy':
+      path    => "${apt_conf_d}/proxy",
+      content => "Acquire::http::Proxy \"http://${proxy_host}:${proxy_port}\";",
+      notify  => Exec['apt_update'],
+    }
+  }
+
+  # Need anchor to provide containment for dependencies.
+  anchor { 'apt::update':
+    require => Class['apt::update'],
+  }
+}

data/provision/modules/apt/manifests/key.pp

@@ -0,0 +1,80 @@
+define apt::key (
+  $key = $title,
+  $ensure = present,
+  $key_content = false,
+  $key_source = false,
+  $key_server = 'keyserver.ubuntu.com'
+) {
+
+  include apt::params
+
+  $upkey = upcase($key)
+
+  if $key_content {
+    $method = 'content'
+  } elsif $key_source {
+    $method = 'source'
+  } elsif $key_server {
+    $method = 'server'
+  }
+
+  # This is a hash of the parts of the key definition that we care about.
+  # It is used as a unique identifier for this instance of apt::key. It gets
+  # hashed to ensure that the resource name doesn't end up being pages and
+  # pages (e.g. in the situation where key_content is specified).
+  $digest = sha1("${upkey}/${key_content}/${key_source}/${key_server}/")
+
+  # Allow multiple ensure => present for the same key to account for many
+  # apt::source resources that all reference the same key.
+  case $ensure {
+    present: {
+
+      anchor { "apt::key/${title}": }
+
+      if defined(Exec["apt::key ${upkey} absent"]) {
+        fail("Cannot ensure Apt::Key[${upkey}] present; ${upkey} already ensured absent")
+      }
+
+      if !defined(Anchor["apt::key ${upkey} present"]) {
+        anchor { "apt::key ${upkey} present": }
+      }
+
+      if !defined(Exec[$digest]) {
+        $digest_command = $method ? {
+          'content' => "echo '${key_content}' | /usr/bin/apt-key add -",
+          'source'  => "wget -q '${key_source}' -O- | apt-key add -",
+          'server'  => "apt-key adv --keyserver '${key_server}' --recv-keys '${upkey}'",
+        }
+        exec { $digest:
+          command   => $digest_command,
+          path      => '/bin:/usr/bin',
+          unless    => "/usr/bin/apt-key list | /bin/grep '${upkey}'",
+          logoutput => 'on_failure',
+          before    => Anchor["apt::key ${upkey} present"],
+        }
+      }
+
+      Anchor["apt::key ${upkey} present"] -> Anchor["apt::key/${title}"]
+
+    }
+    absent: {
+
+      if defined(Anchor["apt::key ${upkey} present"]) {
+        fail("Cannot ensure Apt::Key[${upkey}] absent; ${upkey} already ensured present")
+      }
+
+      exec { "apt::key ${upkey} absent":
+        command   => "apt-key del '${upkey}'",
+        path      => '/bin:/usr/bin',
+        onlyif    => "apt-key list | grep '${upkey}'",
+        user      => 'root',
+        group     => 'root',
+        logoutput => 'on_failure',
+      }
+    }
+
+    default: {
+      fail "Invalid 'ensure' value '${ensure}' for aptkey"
+    }
+  }
+}

data/provision/modules/apt/manifests/params.pp

@@ -0,0 +1,23 @@
+class apt::params {
+  $root           = '/etc/apt'
+  $provider       = '/usr/bin/apt-get'
+  $sources_list_d = "${root}/sources.list.d"
+  $apt_conf_d     = "${root}/apt.conf.d"
+  $preferences_d  = "${root}/preferences.d"
+
+  case $::lsbdistid {
+    'debian': {
+      $backports_location = 'http://backports.debian.org/debian-backports'
+    }
+    'ubuntu': {
+      case $::lsbdistcodename {
+        'hardy','lucid','maverick','natty','oneiric','precise': {
+          $backports_location = 'http://us.archive.ubuntu.com/ubuntu'
+        }
+        default: {
+          $backports_location = 'http://old-releases.ubuntu.com/ubuntu'
+        }
+      }
+    }
+  }
+}

data/provision/modules/apt/manifests/pin.pp

@@ -0,0 +1,48 @@
+# pin.pp
+# pin a release in apt, useful for unstable repositories
+
+define apt::pin(
+  $ensure     = present,
+  $explanation = "${::caller_module_name}: ${name}",
+  $order      = '',
+  $packages   = '*',
+  $priority   = 0,
+  $release    = '',
+  $origin     = '',
+  $originator = '',
+  $version    = ''
+) {
+
+  include apt::params
+
+  $preferences_d = $apt::params::preferences_d
+
+  if $order != '' and !is_integer($order) {
+    fail('Only integers are allowed in the apt::pin order param')
+  }
+
+  if $release != '' {
+    $pin = "release a=${release}"
+  } elsif $origin != '' {
+    $pin = "origin \"${origin}\""
+  } elsif $originator != '' {
+    $pin = "release o=${originator}"
+  } elsif $version != '' {
+    $pin = "version ${version}"
+  } else {
+    $pin = "release a=${name}"
+  }
+
+  $path = $order ? {
+    ''      => "${preferences_d}/${name}.pref",
+    default => "${preferences_d}/${order}-${name}.pref",
+  }
+  file { "${name}.pref":
+    ensure  => $ensure,
+    path    => $path,
+    owner   => root,
+    group   => root,
+    mode    => '0644',
+    content => template('apt/pin.pref.erb'),
+  }
+}

data/provision/modules/apt/manifests/ppa.pp

@@ -0,0 +1,49 @@
+# ppa.pp
+
+define apt::ppa(
+  $release = $::lsbdistcodename
+) {
+  include apt::params
+  include apt::update
+
+  $sources_list_d = $apt::params::sources_list_d
+
+  if ! $release {
+    fail('lsbdistcodename fact not available: release parameter required')
+  }
+
+  $filename_without_slashes = regsubst($name, '/', '-', G)
+  $filename_without_dots    = regsubst($filename_without_slashes, '\.', '_', G)
+  $filename_without_ppa     = regsubst($filename_without_dots, '^ppa:', '', G)
+  $sources_list_d_filename  = "${filename_without_ppa}-${release}.list"
+  
+  $package = $::lsbdistrelease ? {
+	  /^[1-9]\..*|1[01]\..*|12.04$/ => 'python-software-properties',
+	  default  => 'software-properties-common',
+  }
+  
+  if ! defined(Package[$package]) {
+    package { $package: }
+  }
+
+  exec { "add-apt-repository-${name}":
+    command   => "/usr/bin/add-apt-repository ${name}",
+    creates   => "${sources_list_d}/${sources_list_d_filename}",
+    logoutput => 'on_failure',
+    require   => [
+      File[$sources_list_d],
+      Package["${package}"],
+    ],
+    notify    => Exec['apt_update'],
+  }
+
+  file { "${sources_list_d}/${sources_list_d_filename}":
+    ensure  => file,
+    require => Exec["add-apt-repository-${name}"],
+  }
+
+  # Need anchor to provide containment for dependencies.
+  anchor { "apt::ppa::${name}":
+    require => Class['apt::update'],
+  }
+}

data/provision/modules/apt/manifests/release.pp

@@ -0,0 +1,17 @@
+# release.pp
+
+class apt::release (
+  $release_id
+) {
+
+  include apt::params
+
+  $root = $apt::params::root
+
+  file { "${root}/apt.conf.d/01release":
+    owner   => root,
+    group   => root,
+    mode    => '0644',
+    content => "APT::Default-Release \"${release_id}\";"
+  }
+}

data/provision/modules/apt/manifests/source.pp

@@ -0,0 +1,83 @@
+# source.pp
+# add an apt source
+
+define apt::source(
+  $ensure            = present,
+  $location          = '',
+  $release           = 'UNDEF',
+  $repos             = 'main',
+  $include_src       = true,
+  $required_packages = false,
+  $key               = false,
+  $key_server        = 'keyserver.ubuntu.com',
+  $key_content       = false,
+  $key_source        = false,
+  $pin               = false
+) {
+
+  include apt::params
+  include apt::update
+
+  $sources_list_d = $apt::params::sources_list_d
+  $provider       = $apt::params::provider
+
+  if $release == 'UNDEF' {
+    if $::lsbdistcodename == undef {
+      fail('lsbdistcodename fact not available: release parameter required')
+    } else {
+      $release_real = $::lsbdistcodename
+    }
+  } else {
+    $release_real = $release
+  }
+
+  file { "${name}.list":
+    ensure  => $ensure,
+    path    => "${sources_list_d}/${name}.list",
+    owner   => root,
+    group   => root,
+    mode    => '0644',
+    content => template("${module_name}/source.list.erb"),
+    notify  => Exec['apt_update'],
+  }
+
+
+  if ($pin != false) {
+    # Get the host portion out of the url so we can pin to origin
+    $url_split = split($location, '/')
+    $host      = $url_split[2]
+
+    apt::pin { $name:
+      ensure   => $ensure,
+      priority => $pin,
+      before   => File["${name}.list"],
+      origin   => $host,
+    }
+  }
+
+  if ($required_packages != false) and ($ensure == 'present') {
+    exec { "Required packages: '${required_packages}' for ${name}":
+      command     => "${provider} -y install ${required_packages}",
+      logoutput   => 'on_failure',
+      refreshonly => true,
+      subscribe   => File["${name}.list"],
+    }
+  }
+
+  # We do not want to remove keys when the source is absent.
+  if ($key != false) and ($ensure == 'present') {
+    apt::key { "Add key: ${key} from Apt::Source ${title}":
+      ensure      => present,
+      key         => $key,
+      key_server  => $key_server,
+      key_content => $key_content,
+      key_source  => $key_source,
+      before      => File["${name}.list"],
+    }
+  }
+
+  # Need anchor to provide containment for dependencies.
+  anchor { "apt::source::${name}":
+    require => Class['apt::update'],
+  }
+}