sensu-dashboard 0.9.8 → 0.9.9

data/lib/sensu-dashboard/assets/javascripts/views/auto_complete/auto_complete_results.coffee

@@ -0,0 +1,135 @@
+namespace "SensuDashboard.Views", (exports) ->
+
+  class exports.AutoCompleteResults extends exports.Base
+
+    tagName: "ul"
+    name: "autocomplete/results"
+    className: "auto-complete-results"
+    events:
+      "mousedown li": (e) ->
+        e.preventDefault()
+        e.stopPropagation()
+      "mouseup li": "selectItem"
+      "mouseover li": "_mouseoverItem"
+    visible: false
+
+    initialize: (options) ->
+      super
+
+      @selectedIndex = -1
+      @items = []
+
+    setDelegate: (delegate) ->
+      @delegate = delegate
+
+    renderItem: (item, index) ->
+      type = if item instanceof SensuDashboard.Models.Check
+        "check"
+      else if item instanceof SensuDashboard.Models.Client
+        "client"
+      else
+        "query"
+      context = if item.toJSON then item.toJSON() else { query: item }
+
+      HandlebarsTemplates["#{@name}_#{type}_item"](context)
+
+    renderCollection: ->
+      @render()
+
+      @$el.empty()
+      for model in @collection
+        @$el.append($(@renderItem(model)))
+
+      @items = @$el.find("> li").toArray()
+      @selectedIndex = -1
+      @selectAtIndex(0)
+
+      this
+
+    setCollection: (collection) ->
+      @collection = collection
+
+    selectNext: ->
+      item = @selectAtIndex(@selectedIndex + 1)
+      item.scrollIntoViewIfNeeded(false) if item
+
+    selectPrevious: ->
+      item = @selectAtIndex(@selectedIndex - 1)
+      item.scrollIntoViewIfNeeded(true) if item
+
+    selectedObject: ->
+      return @collection[@selectedIndex]
+
+    selectAtIndex: (index) ->
+      if 0 <= index < @items.length
+        @$el.find(".selected").removeClass("selected")
+        item = @items[index]
+        $(item).addClass("selected")
+        @selectedIndex = index
+        return item
+
+    selectItem: ->
+      return unless item = @selectedObject()
+      @trigger("item:selected", item)
+
+    deselectAll: ->
+      @$el.find(".selected").removeClass("selected")
+
+    #
+    # Private
+    #
+
+    _mouseoverItem: (e) ->
+      index = _.indexOf(@items, e.currentTarget)
+      return if @selectedIndex == index
+
+      @selectAtIndex index
+
+    keyDown: (e) ->
+      switch e.keyCode
+        when 40
+          e.preventDefault()
+          @selectNext()
+          return false
+
+        when 38
+          e.preventDefault()
+          @selectPrevious()
+          return false
+
+      true
+
+    _hide: ->
+      if @visible
+        @setElement($("<ul/>"))
+        $(@delegate.inputTester).popover("hide")
+        @visible = false
+
+    _show: ->
+      unless @visible
+        $(@delegate.inputTester).popover({
+          html: true
+          content: @$el
+          placement: "bottom"
+          trigger: "manual"
+        }).popover("show")
+        @setElement(@delegate.$el.find("div.popover-content ul.auto-complete-results")[0])
+        @visible = true
+      @renderCollection()
+
+    #
+    # Delegate
+    #
+
+    autoCompleteTokenFieldEmpty: ->
+      @_hide()
+
+    autoCompleteTokenFieldBlur: ->
+      @_hide()
+
+    autoCompleteTokenFieldResults: ->
+      @_show()
+
+    autoCompleteTokenFieldItemSelected: ->
+      @_hide()
+      @selectedObject()

data/lib/sensu-dashboard/assets/javascripts/views/auto_complete/auto_complete_token.coffee

@@ -0,0 +1,31 @@
+namespace "SensuDashboard.Views", (exports) ->
+
+  class exports.AutoCompleteToken extends exports.Base
+
+    tagName: "li"
+    className: "token"
+
+    initialize: ->
+      @delegate = @options.delegate
+      @setItem(@options.item)
+
+    setItem: (item) ->
+      @item = item
+      @type = if item instanceof SensuDashboard.Models.Check
+        "check"
+      else if item instanceof SensuDashboard.Models.Client
+        "client"
+      else
+        "query"
+
+    context: ->
+      if _.isString @item
+        { query: @item }
+      else
+        @item.toJSON()
+
+    render: ->
+      tmpl = HandlebarsTemplates["autocomplete/results_#{@type}_token"]
+      @$el.html(tmpl(@context()))
+
+      return this

data/lib/sensu-dashboard/assets/javascripts/views/base.coffee

@@ -0,0 +1,16 @@
+namespace "SensuDashboard.Views", (exports) ->
+
+  class exports.Base extends Backbone.View
+
+    template: (args) ->
+      tmpl = HandlebarsTemplates[@name]
+      tmpl(args) if tmpl
+
+    assign: (view, selector) ->
+      view.setElement(@$(selector)).render()
+
+    dispose: ->
+      @remove()
+      @off()
+      @model.off(null, null , @) if @model
+      @collection.off(null, null, @) if @collection

data/lib/sensu-dashboard/assets/javascripts/views/checks/index.coffee

@@ -0,0 +1,18 @@
+namespace "SensuDashboard.Views.Checks", (exports) ->
+
+  class exports.Index extends SensuDashboard.Views.Base
+
+    name: "checks/index"
+
+    initialize: ->
+      @autocomplete_view = new SensuDashboard.Views.AutoCompleteField()
+      @subview = new exports.List({
+        collection: @collection
+        autocomplete_view: @autocomplete_view
+      })
+
+    render: ->
+      @$el.html(@template(checks: @collection))
+      @assign(@subview, "#checks_container")
+      @$el.find("#filter").html(@autocomplete_view.render().el)
+      this

data/lib/sensu-dashboard/assets/javascripts/views/checks/list.coffee

@@ -0,0 +1,48 @@
+namespace "SensuDashboard.Views.Checks", (exports) ->
+
+  class exports.List extends SensuDashboard.Views.List
+
+    name: "checks/list"
+
+    initialize: ->
+      @autocomplete_view = @options.autocomplete_view
+      @autocomplete_view.delegate = this
+      super
+
+    itemClass: ->
+      exports.ListItem
+
+    resolvedCollection: ->
+      resolved = @collection.chain()
+      for token in @autocomplete_view.tokens
+        resolved = if _.isString(token.object)
+          resolved.filter (record) =>
+            result = @matchForKeys(token.object, record,
+              { key: "interval", threshold: 1 },
+              { key: "name", threshold: 0.92 }
+            )
+            result || _.detect(record.get("subscribers"), (sub) =>
+              liquidMetal.score(sub, token.object) > 0.96) != undefined
+
+      resolved
+
+    matchForKeys: (q, record, args...) ->
+      result = _.detect args, (options) =>
+        value = record.get(options.key).toString()
+        score = liquidMetal.score(value, q)
+        score >= (options.threshold || 0.7)
+
+      !(result is undefined)
+
+    renderCollection: ->
+      super(_(@resolvedCollection().map().value()))
+
+    renderEmpty: ->
+      super(_(@resolvedCollection().map().value()))
+
+    #
+    # Autocomplete delegate
+    #
+
+    filtersUpdated: ->
+      @render()

data/lib/sensu-dashboard/assets/javascripts/views/checks/list_item.coffee

@@ -0,0 +1,17 @@
+namespace "SensuDashboard.Views.Checks", (exports) ->
+
+  class exports.ListItem extends SensuDashboard.Views.ListItem
+
+    name: "checks/list_item"
+
+    className: ->
+      @model.get("name")
+
+    render: ->
+      @$el.html(@template(@presenter()))
+      this
+
+    presenter: ->
+      _.extend(@model.toJSON(), {
+        standalone: @model.get("standalone") || "false"
+      })

data/lib/sensu-dashboard/assets/javascripts/views/clients/counts.coffee

@@ -0,0 +1,13 @@
+namespace "SensuDashboard.Views.Clients", (exports) ->
+
+  class exports.Counts extends SensuDashboard.Views.Base
+
+    name: "clients/counts"
+
+    initialize: (collection) ->
+      @listenTo(@collection, "all", @render)
+
+    render: ->
+      template_data = { count: @collection.models.length }
+      @$el.html(@template(template_data))
+      this

data/lib/sensu-dashboard/assets/javascripts/views/clients/index.coffee

@@ -0,0 +1,83 @@
+namespace "SensuDashboard.Views.Clients", (exports) ->
+
+  class exports.Index extends SensuDashboard.Views.Base
+
+    name: "clients/index"
+
+    events:
+      "click #toggle-checkboxes": "toggleSelected"
+      "click #select-all": "selectAll"
+      "click #select-none": "selectNone"
+      "click #select-silenced": "selectSilenced"
+      "click #select-unsilenced": "selectUnsilenced"
+      "click #silence-selected-clients": "silenceSelected"
+      "click #unsilence-selected-clients": "unsilenceSelected"
+
+    initialize: ->
+      @counts_subview = new SensuDashboard.Views.Clients.Counts(collection: @collection)
+      @autocomplete_view = new SensuDashboard.Views.AutoCompleteField()
+      @subview = new exports.List({
+        collection: @collection
+        autocomplete_view: @autocomplete_view
+      })
+
+    render: ->
+      @$el.html(@template(clients: @collection))
+      @assign(@counts_subview, "#counts")
+      @assign(@subview, "#clients_container")
+      @$el.find("#filter").html(@autocomplete_view.render().el)
+      this
+
+    toggleSelected: ->
+      @collection.toggleSelected()
+
+    selectAll: ->
+      @collection.selectAll()
+
+    selectNone: ->
+      @collection.selectNone()
+
+    selectSilenced: ->
+      @collection.selectSilenced()
+
+    selectUnsilenced: ->
+      @collection.selectUnsilenced()
+
+    silenceSelected: ->
+      @collection.silenceSelected
+        success: (model) ->
+          client_name = model.get("name")
+          toastr.success("Silenced client #{client_name}."
+            , "Success!"
+            , { positionClass: "toast-bottom-right" })
+        error: (model, xhr, opts) ->
+          client_name = model.get("name")
+          toastr.error("Error silencing client #{client_name}."
+            , "Silencing Error!"
+            , { positionClass: "toast-bottom-right" })
+
+    unsilenceSelected: ->
+      @collection.unsilenceSelected
+        success: (model) ->
+          client_name = model.get("name")
+          toastr.success("Un-silenced client #{client_name}."
+            , "Success!"
+            , { positionClass: "toast-bottom-right" })
+        error: (model) ->
+          client_name = model.get("name")
+          toastr.error("Error un-silencing client #{client_name}.
+            The client may already be un-sileneced or Sensu API is down."
+            , "Un-silencing Error!"
+            , { positionClass: "toast-bottom-right" })
+
+    removeSelected: ->
+      @collection.removeSelected
+        success: (model) ->
+          toastr.success("Removed client #{model.get("name")}."
+            , "Success!"
+            , { positionClass: "toast-bottom-right" })
+        error: (model) ->
+          toastr.error("Error removing client #{model.get("name")}.
+            The client may have already been removed or Sensu API is down."
+            , "Removal Error!"
+            , { positionClass: "toast-bottom-right" })

data/lib/sensu-dashboard/assets/javascripts/views/clients/list.coffee

@@ -0,0 +1,56 @@
+namespace "SensuDashboard.Views.Clients", (exports) ->
+
+  class exports.List extends SensuDashboard.Views.List
+
+    name: "clients/list"
+
+    initialize: ->
+      @autocomplete_view = @options.autocomplete_view
+      @autocomplete_view.delegate = this
+      super
+
+    itemClass: ->
+      exports.ListItem
+
+    resolvedCollection: ->
+      resolved = @collection.chain()
+      for token in @autocomplete_view.tokens
+        resolved = if _.isString(token.object)
+          resolved.filter (record) =>
+            result = @matchForKeys(token.object, record,
+              { key: "address", threshold: 0.85 },
+              { key: "name", threshold: 0.9 }
+            )
+            result || _.detect(record.get("subscriptions"), (sub) =>
+              liquidMetal.score(sub, token.object) > 0.96) != undefined
+
+      resolved
+
+    matchForKeys: (q, record, args...) ->
+      result = _.detect args, (options) =>
+        value = record.get(options.key)
+        score = liquidMetal.score(value, q)
+        score >= (options.threshold || 0.7)
+
+      !(result is undefined)
+
+    resolved: ->
+      _(@resolvedCollection().map().value())
+
+    renderCollection: (collection) ->
+      super(collection || @resolved())
+
+    renderEmpty: (collection) ->
+      super(collection || @resolved())
+
+    #
+    # Autocomplete delegate
+    #
+
+    filtersUpdated: ->
+      filtered = @resolved()
+      @collection.each (model) ->
+        model.set(selected: false) unless filtered.contains(model)
+
+      @$el.html(@template())
+      @renderCollection(filtered)

data/lib/sensu-dashboard/assets/javascripts/views/clients/list_item.coffee

@@ -0,0 +1,20 @@
+namespace "SensuDashboard.Views.Clients", (exports) ->
+
+  class exports.ListItem extends SensuDashboard.Views.ListItem
+
+    name: "clients/list_item"
+
+    className: ->
+      @model.get("name")
+
+    events:
+      "click td:not(.select)": "showDetails"
+      "click input[type=checkbox]": "toggleSelect"
+
+    toggleSelect: ->
+      @model.set(selected: !@model.get("selected"))
+
+    showDetails: ->
+      new SensuDashboard.Views.Clients.Modal
+        name: "clients/modal"
+        model: @model