scrivito_editors 0.71.2 → 0.90.0.rc1

data/app/assets/javascripts/scrivito_editors/permalink_editor.js.coffee

@@ -1,111 +0,0 @@
-scrivito.on 'content', (content) ->
-  return unless scrivito.in_editable_view()
-
-  $(content).find('''
-    [data-scrivito-field-name="_permalink"]:not([data-editor]),
-    [data-editor~=permalink]
-  ''').each -> create($(@))
-
-create = (field) ->
-  editor = field.html(render(field.scrivito('content') || ''))
-  input = editor.find('input')
-  button = editor.find('a')
-  error = editor.find('div.scrivito_error')
-  clear = editor.find('.scrivito_clear')
-
-  input.on 'input', ->
-    permalink = input.val()
-    if permalink == field.scrivito('content')
-      hideError()
-      disableSaveButton()
-    else if permalink.match(/^([\w._-]+[\/\w._-]*)?$/)
-      hideError()
-      enableSaveButton()
-    else
-      showError(
-        'The permalink may only contain letters from A to Z, periods, hyphens, and underscores.')
-      disableSaveButton()
-
-  clear.on 'click', ->
-    input.val('')
-    hideError()
-    if !field.scrivito('content')
-      disableSaveButton()
-    else
-      enableSaveButton()
-    off
-
-  button.on 'click', ->
-    trySave()
-    off
-
-  editor.on 'keyup', (event) ->
-    switch event.keyCode
-      when 13 # Enter
-        trySave()
-      when 27 # Esc
-        input.val(field.scrivito('content'))
-        hideError()
-        disableSaveButton()
-        input.blur()
-
-  trySave = ->
-    return off if button.hasClass('scrivito_disabled')
-
-    showSaving()
-
-    permalink = input.val()
-    if permalink
-      scrivito.obj_where('_permalink', 'equals', permalink).size().then (total) ->
-        if total > 0
-          hideSaving()
-          showError('Permalink already taken.')
-          disableSaveButton()
-          input.focus()
-        else
-          save(permalink)
-    else
-      save(null)
-
-  disableSaveButton = ->
-    button.addClass('scrivito_disabled')
-
-  enableSaveButton = ->
-    button.removeClass('scrivito_disabled scrivito_saving')
-
-  showError = (message) ->
-    disableSaveButton()
-    input.addClass('scrivito_error')
-    error.text(message)
-    error.show()
-
-  hideError = ->
-    input.removeClass('scrivito_error')
-    error.hide()
-
-  showSaving = ->
-    input.attr('disabled', 'disabled')
-    disableSaveButton()
-    button.addClass('scrivito_saving')
-    button.find('span').text('Saving...')
-
-  hideSaving = ->
-    input.removeAttr('disabled')
-    enableSaveButton()
-    button.find('span').text('Save')
-
-  save = (permalink) ->
-    field.scrivito('save', permalink).then ->
-      create(field)
-
-render = (content) ->
-  """
-    <div class="scrivito_permalink_editor">
-      <input type="text" value="#{content}" />
-      <span class="scrivito_clear"></span>
-      <a href="#" class="scrivito_editing_button scrivito_disabled">
-        <span>Save</span>
-      </a>
-      <div class="scrivito_error"></div>
-    </div>
-  """

data/app/assets/javascripts/scrivito_editors/placeholder.js.coffee

@@ -1,22 +0,0 @@
-$ ->
-  # Display a placeholder for empty CMS attributes. The placeholder can be overwritten by
-  # defining a +data-placeholder+ HTML attribute on the DOM element generated by +scrivito_tag+.
-  #
-  # For example:
-  #   scrivito_tag(:div, @obj, :my_attribute, data: { placeholder: 'My custom placeholder text.' })
-  addPlaceholder = ->
-    cmsFields = $('[data-scrivito-field-type]')
-      .not('[data-scrivito-field-type=widgetlist]')
-      .not('[data-scrivito-field-type$=enum]:not([data-values])')
-
-    cmsFields.each ->
-      cmsField = $(@)
-      fieldName = cmsField.attr('data-scrivito-field-name')
-      defaultPlaceholder = 'Click to edit the "' + fieldName + '" attribute ...'
-      placeholder = cmsField.attr('data-placeholder') || defaultPlaceholder
-
-      cmsField.attr('data-placeholder', placeholder)
-
-  scrivito.on 'content', ->
-    if scrivito.in_editable_view()
-      addPlaceholder()

data/app/assets/javascripts/scrivito_editors/redactor_plugins/scrivito_editors_image_manager.js.coffee

@@ -1,22 +0,0 @@
-@RedactorPlugins ?= {}
-
-$ ->
-  RedactorPlugins.scrivito_editors_image_manager = -> self =
-    init: ->
-      @modal.addCallback 'image', self.browse
-
-    browse: ->
-      filterContext = $.extend {_image: true}, @$element.data('filterContext')
-
-      scrivito.content_browser.open
-        filter: @$element.data('filter')
-        filter_context: filterContext
-        selection_mode: 'single'
-      .done (selection) =>
-        id = selection[0]
-        self.insert id if id?
-      .always =>
-        @modal.close()
-
-    insert: (id) ->
-      @image.insert "<img src='/#{id}'>"

data/app/assets/javascripts/scrivito_editors/redactor_plugins/scrivito_editors_link_manager.js.coffee

@@ -1,49 +0,0 @@
-@RedactorPlugins ?= {}
-
-$ ->
-  RedactorPlugins.scrivito_editors_link_manager = -> self =
-    init: ->
-      @modal.addTemplate 'scrivito_link_manager_browse', self.browseButtonHtml
-      @modal.addTemplate 'scrivito_link_manager_url', '/$id'
-      @modal.addCallback 'imageEdit', self.addBrowseToModal
-      @modal.addCallback 'link', self.addBrowseToModal
-
-    browseButtonHtml: """
-      <button class="editing-button editing-green">
-        <i class="editing-icon editing-icon-search"></i>
-        Browse
-      </button>
-    """
-
-    urlInput: ->
-      @modal.getModal().find '#redactor-link-url, #redactor-image-link'
-
-    addBrowseToModal: ->
-      self.urlInput()
-        .wrap '<div id="scrivito-link-manager-url"></div>'
-        .after @modal.getTemplate 'scrivito_link_manager_browse'
-        .siblings 'button'
-        .on 'click', self.browse
-
-    browse: ->
-      scrivito.content_browser.open
-        filter: @$element.data('filter')
-        filter_context: @$element.data('filterContext')
-        selection: self.getObjIds()
-        selection_mode: 'single'
-      .done (selection) =>
-        id = selection[0]
-        self.setObjId id if id?
-
-    getObjIds: ->
-      matches = self.urlInput()
-        .val()
-        .match(/[\/:]([a-f0-9]{16})\b/)
-      if matches? then [matches[1]] else []
-
-    setObjId: (id) ->
-      self.urlInput()
-        .val self.toUrl id
-
-    toUrl: (id) ->
-      @modal.getTemplate('scrivito_link_manager_url').replace("$id", id)

data/app/assets/javascripts/scrivito_editors/reference_editor.js.coffee

@@ -1,33 +0,0 @@
-$ ->
-  # Integrates a content browser based editor for reference CMS attributes.
-
-  scrivito.on 'load', ->
-    if scrivito.in_editable_view()
-      $('body').on 'click', '[data-scrivito-field-type="reference"]:not([data-editor]), [data-editor~="reference"]', (event) ->
-        event.preventDefault()
-
-        cmsField = $(event.currentTarget)
-        selected = [cmsField.scrivito('content')].filter (element) -> element
-        filters = cmsField.data('filters')
-        filterContext = $.extend {_image: cmsField.is('img')}, cmsField.data('filterContext')
-
-        # Open content browser with current reference selected.
-        scrivito.content_browser.open
-          filters: filters
-          filter_context: filterContext
-          selection: selected
-          selection_mode: 'single'
-
-        .done (selection) =>
-          onContentBrowserSave(selection, cmsField)
-
-      # Save single reference when content browser calls "save".
-      onContentBrowserSave = (selection, cmsField) ->
-        value = selection[0] || null
-
-        cmsField.scrivito('save', value)
-        .done ->
-          cmsField.trigger('save.scrivito_editors')
-          cmsField.scrivito('reload')
-
-        true

data/app/assets/javascripts/scrivito_editors/referencelist_editor.js.coffee

@@ -1,113 +0,0 @@
-$ ->
-  # An editor for CMS referencelist attributes.
-
-  # Creates the DOM for one reference element of the referencelist and substitutes the
-  # name and id attribute.
-  itemTemplate = ->
-    $("<div class=\"actions\">
-         <a href=\"#\" class=\"editing-button editing-red delete\">
-           <i class=\"editing-icon editing-icon-trash\" />
-         </a>
-       </div>")
-
-  contentBrowserButtonTemplate = ->
-    icon = $('<i></i>')
-      .addClass('editing-icon')
-      .addClass('editing-icon-plus')
-
-    button = $('<button></button>')
-      .addClass('editing-button')
-      .addClass('editing-green')
-      .addClass('content-browser-open')
-      .html(icon)
-
-    button
-
-  # Returns the closest referencelist DOM element.
-  getCmsField = (element) ->
-    element.closest('[data-scrivito-field-type=referencelist]')
-
-  # Saves the referencelist to the CMS when changed and stores the last successfully saved value.
-  save = (ids, cmsField, reload = true) ->
-    lastSaved = getLastSaved(cmsField)
-
-    unless JSON.stringify(ids) == JSON.stringify(lastSaved)
-      cmsField.scrivito('save', ids)
-        .done ->
-          storeLastSaved(cmsField, ids)
-          cmsField.trigger('save.scrivito_editors')
-          cmsField.scrivito('reload') if reload
-
-  # Run when clicking the content browser button.
-  onContentBrowserOpen = (event) ->
-    event.preventDefault()
-
-    cmsField = getCmsField($(event.currentTarget))
-    filters = cmsField.data('filters')
-    filterContext = cmsField.data('filterContext')
-
-    scrivito.content_browser.open
-      filters: filters
-      filter_context: filterContext
-    .done (selection) =>
-      ids = getIds(cmsField).concat(selection)
-      save(ids, cmsField)
-
-  # Collects all reference ids for a given referencelist.
-  getIds = (cmsField) ->
-    items = $(cmsField).find('[data-id]')
-
-    value =
-      for item in items
-        $(item).data('id')
-
-  # Removes a single reference from the referencelist.
-  remove = (event) ->
-    event.preventDefault()
-
-    target = $(event.currentTarget)
-    cmsField = getCmsField(target)
-
-    target.closest('li').remove()
-
-    ids = getIds(cmsField)
-    save(ids, cmsField, false)
-
-  # Turns the server side generated referencelist data into the reference editor using a template.
-  transform = (elements) ->
-    elements.append(contentBrowserButtonTemplate)
-
-    items = elements.find('li')
-
-    for item in items
-      $(item).append(itemTemplate)
-
-  # Returns the last saved value.
-  getLastSaved = (cmsField) ->
-    $(cmsField).data('last-saved')
-
-  # Stores a given value as last saved.
-  storeLastSaved = (cmsField, value) ->
-    $(cmsField).data('last-saved', value)
-
-  # Initialize referencelist editor and setup event callbacks.
-  scrivito.on 'content', (root) ->
-    if scrivito.in_editable_view()
-      elements = $(root).find('[data-scrivito-field-type="referencelist"]:not([data-editor]), [data-editor~="referencelist"]')
-
-      if elements.length
-        transform(elements)
-
-        for element in elements
-          ids = getIds(element)
-          storeLastSaved(element, ids)
-
-        elements.on 'click', 'li a.delete', remove
-        elements.on 'click', 'button.content-browser-open', onContentBrowserOpen
-
-        elements.find('ul').sortable
-          update: (event) ->
-            cmsField = getCmsField($(event.target))
-            ids = getIds(cmsField)
-
-            save(ids, cmsField)

data/app/assets/javascripts/scrivito_editors/reload.js.coffee

@@ -1,12 +0,0 @@
-$ ->
-  # Enable `data-reload=true` for automatic reload when an editor is done.
-  #
-  # For example:
-  #   scrivito_tag(:div, @obj, :my_attribute, data: { reload: true })
-
-  selector = '[data-scrivito-field-type][data-reload=true]'
-
-  scrivito.on 'content', ->
-    if scrivito.in_editable_view()
-      $(':root').on 'scrivito_editors:blur', selector, (event) ->
-        $(this).scrivito("reload")

data/app/assets/javascripts/scrivito_editors/slider_editor.js.coffee

@@ -1,41 +0,0 @@
-$ ->
-  # Slider for integer values stored in a string CMS attribute.
-
-  scrivito.on 'load', ->
-    if scrivito.in_editable_view()
-      template = ->
-        $('<div></div>')
-
-      onStop = (event, ui) ->
-        cmsField = $(@).data('cmsField')
-        content = ui.value
-        cmsField.scrivito('save', content).done ->
-          cmsField.trigger('save.scrivito_editors')
-          cmsField.trigger('scrivito_editors:blur')
-
-      onSlide = (event, ui) ->
-        cmsField = $(@).data('cmsField')
-        content = ui.value
-        cmsField.text(ui.value)
-
-      $('body').on 'click', '[data-editor~="slider"]:not(.active)', (event) ->
-        cmsField = $(event.currentTarget)
-        content = cmsField.scrivito('content')
-        min = cmsField.attr('data-min') || 1
-        max = cmsField.attr('data-max') || 10
-        step = cmsField.attr('data-step') || 1
-
-        cmsField.addClass('active')
-
-        template()
-          .data('cmsField', cmsField)
-          .insertAfter(cmsField)
-          .slider(
-            min: parseInt(min)
-            max: parseInt(max)
-            step: parseInt(step)
-            value: content
-            range: 'min'
-            stop: onStop
-            slide: onSlide
-          )

data/app/assets/javascripts/scrivito_editors/string_editor.js.coffee

@@ -1,136 +0,0 @@
-$ ->
-  # This file integrates contenteditable for string attributes.
-
-  onKey = (event) ->
-    cmsField = $(event.currentTarget)
-    key = event.keyCode || event.which
-
-    switch key
-      when 13 # Enter
-        if !isNewlineAllowed(cmsField)
-          event.preventDefault()
-          cmsField.blur()
-      when 27 # Esc
-        event.stopPropagation()
-        cmsField.blur()
-
-  onInput = (event) ->
-    cmsField = $(event.currentTarget)
-    save(cmsField)
-
-  onFocus = (event) ->
-    cmsField = $(event.currentTarget)
-    prepareForEditing(cmsField)
-
-  onBlur = (event) ->
-    cmsField = $(event.currentTarget)
-
-    save(cmsField).done ->
-      cmsField.trigger('scrivito_editors:blur')
-
-    finishEditing(cmsField)
-
-  save = (cmsField) ->
-    content = getCurrentContent(cmsField)
-
-    # Save only if the content has changed.
-    if content != cmsField.scrivito('content')
-      cmsField.scrivito('save', content).done ->
-        cmsField.trigger('save.scrivito_editors')
-    else
-      $.Deferred().resolve()
-
-  getCurrentContent = (cmsField) ->
-    cleanUp(cmsField)
-
-    clone = cmsFieldAndPastedContent(cmsField).clone()
-    # Starting with empty element, entering 3 lines, per browser:
-    # Chrome: 1<div>2</div><div>3</div>
-    # IE: <p>1</p><p>2</p><p>3</p>
-    # Firefox: 1<br>2<br>3<br>
-    clone.find('div:not(:has(br)),p:not(:first)').before('\n')
-    clone.find('br').replaceWith('\n')
-    content = clone.text()
-    clone.remove()
-    content
-
-  cleanUp = (cmsField) ->
-    siblings = cmsFieldAndPastedContent(cmsField)
-    pasted = siblings.not(cmsField)
-    if pasted.length > 0
-      pasted.remove()
-      cmsField.text(siblings.text())
-
-  cmsFieldAndPastedContent = (cmsField) ->
-    siblingsBefore = cmsField.data('scrivito_editors_siblings_before_edit')
-    siblings = cmsField.siblings()
-    needsReset = !siblingsBefore || siblings.filter(siblingsBefore).length < siblingsBefore.length
-    if needsReset
-      cmsField.data('scrivito_editors_siblings_before_edit', siblings)
-    else
-      cmsField.siblings().addBack().not(siblingsBefore)
-
-  _deprecationLogged = false
-
-  isNewlineAllowed = (cmsField) ->
-    if cmsField.data('editor') == 'text'
-      if !_deprecationLogged
-        console.warn 'Scrivito editors: data-editor="text" is deprecated, please use data-editor="string" data-newlines="true" instead.'
-        _deprecationLogged = true
-      return true
-
-    return true if cmsField.data('newlines') == true
-    return false if cmsField.data('newlines') == false
-    cmsField.css('white-space').match /pre/
-
-  prepareForEditing = (cmsField) ->
-    if isNewlineAllowed(cmsField) && !cmsField.data('scrivito_editors_prepared_for_editing')
-      cmsField.data('scrivito_editors_prepared_for_editing', true)
-      html = cmsField.html()
-      htmlNl2Br = html.replace(/\n/g, '<br />')
-      if html != htmlNl2Br
-        cmsField.html(htmlNl2Br)
-
-  finishEditing = (cmsField) ->
-    cmsField.data('scrivito_editors_prepared_for_editing', false)
-    cmsField.text(cmsField.scrivito('content'))
-
-  DOUBLE_CLICK_MS = 300
-
-  editSelector = '''
-    [data-scrivito-field-type="string"]:not([data-editor]):not([data-scrivito-field-name=_permalink]),
-    [data-editor~="string"],
-    [data-editor~="text"]
-  '''
-
-  initialize = ->
-    $(':root').on 'mouseenter', editSelector, (event) ->
-      cmsField = $(@)
-
-      unless cmsField.attr('contenteditable')?
-        cmsField
-          .attr('contenteditable', true)
-          .blur(onBlur)
-          .focus(onFocus)
-          .keypress(onKey)
-          .keyup(onKey)
-
-        if cmsField.attr('data-autosave') != 'false'
-          cmsField.on('cut input keypress keyup paste', onInput)
-
-      prepareForEditing(cmsField)
-
-    $(':root').on 'click', editSelector, (event) ->
-      cmsField = $(@)
-
-      cmsField.attr('contenteditable', true)
-      cleanUp(cmsField)
-
-      # Prevent editable link strings from being opened on click, but allow an enforcing double click
-      unless event.timeStamp - cmsField.data('scrivito_editors_last_click') < DOUBLE_CLICK_MS
-        event.preventDefault()
-      cmsField.data('scrivito_editors_last_click', event.timeStamp)
-
-  scrivito.on 'load', ->
-    if scrivito.in_editable_view()
-      initialize()

data/app/assets/javascripts/scrivito_editors/stringlist_editor.js.coffee

@@ -1,13 +0,0 @@
-#= require jquery.caret
-#= require jquery.tag-editor
-
-scrivito.on 'content', (content) ->
-  if scrivito.in_editable_view()
-    $(content).find('''
-      [data-scrivito-field-type=stringlist]:not([data-editor]),
-      [data-editor~=stringlist]
-    ''').each ->
-      field = $(this)
-      field.tagEditor
-        initialTags: field.scrivito('content')
-        onChange: (field, editor, tags) -> field.scrivito('save', tags)

data/app/helpers/scrivito_editors/cms_tag_helper.rb

@@ -1,36 +0,0 @@
-module ScrivitoEditors
-  # @deprecated Please use ScrivitoEditors::ScrivitoTagHelper
-  module CmsTagHelper
-
-    def cms_edit_enum(object, attribute_name, options = {})
-      _cms_edit_deprecated __method__
-    end
-
-    def cms_edit_multienum(object, attribute_name, options = {})
-      _cms_edit_deprecated __method__
-    end
-
-    def cms_edit_reference(object, attribute_name, options = {})
-      _cms_edit_deprecated __method__
-    end
-
-    def cms_edit_referencelist(object, attribute_name, options = {})
-      _cms_edit_deprecated __method__
-    end
-
-    def cms_edit_linklist(object, attribute_name, options = {})
-      _cms_edit_deprecated __method__
-    end
-
-    def cms_edit_link(object, attribute_name, options = {})
-      _cms_edit_deprecated __method__
-    end
-
-    private
-
-    def _cms_edit_deprecated(method)
-      raise "The helper method `#{method}' has been removed.\n" +
-          "Please use `#{method.to_s.sub("cms", "scrivito")}' instead."
-    end
-  end
-end