scrivito_content_browser 0.1.0

data/app/assets/javascripts/scrivito_content_browser/inspector.js.coffee

@@ -0,0 +1,67 @@
+return if !scrivito?
+
+scrivito.content_browser._inspector = do ->
+  inspectorSelector: '.scrivito-content-browser-inspector'
+  contentSelector: '.inspector-content'
+  inspector: undefined
+  objectId: undefined
+
+  _initializeBindings: ->
+    @modal.on 'click', 'li.content-browser-item', (event) =>
+      @_onInspect(event)
+
+    @inspector = @modal.find(@inspectorSelector)
+    @inspector.hide()
+
+  _onInspect: (event) ->
+    if $(event.target).hasClass('scrivito-content-browser-inspect')
+      currentTarget = $(event.currentTarget)
+      id = currentTarget.data('id')
+
+      if id
+        @open(id)
+        @_highlightItem(currentTarget)
+
+  _renderLoading: ->
+    @inspector.html(@_loadingTemplate())
+
+  _loadingTemplate: ->
+    icon = $('<i></i>')
+      .addClass('scrivito-content-browser-icon scrivito-content-browser-icon-refresh')
+
+    $('<div></div>')
+      .addClass('scrivito-content-browser-loading')
+      .html(icon)
+
+  _highlightItem: (element) ->
+    @modal.find('li.content-browser-item.active').removeClass('active')
+    element.addClass('active')
+
+  init: (modal) ->
+    @modal = modal
+    @_initializeBindings()
+
+  # Opens the inspector section in the content browser for the given object ID and displays its edit
+  # view.
+  open: (objectId) ->
+    @objectId = objectId
+
+    @inspector.show()
+    @_renderLoading()
+
+    $.ajax
+      url: '/scrivito_content_browser/inspector'
+      dataType: 'json'
+      data:
+        id: @objectId
+      success: (json) =>
+        @inspector.html(json.content)
+        scrivito.trigger('new_content', @inspector)
+
+      error: =>
+        @inspector.empty()
+
+  # Closes the inspector section of the content browser.
+  close: ->
+    @inspector.empty()
+    @inspector.hide()

data/app/assets/javascripts/scrivito_content_browser/uploader.js.coffee

@@ -0,0 +1,148 @@
+return if !scrivito?
+
+scrivito.content_browser._uploader = do ->
+  dropZoneSelector: '.scrivito-content-browser-items'
+  dropOverCssClass: 'uploader-drag-over'
+
+  _initializeBindings: ->
+    dropZone = @modal.find(@dropZoneSelector)
+
+    dropZone.on 'dragover', (event) =>
+      $(event.currentTarget).addClass(@dropOverCssClass)
+      event.preventDefault()
+
+    dropZone.on 'dragleave', (event) =>
+      $(event.currentTarget).removeClass(@dropOverCssClass)
+      event.preventDefault()
+
+    dropZone.on 'drop', (event) =>
+      $(event.currentTarget).removeClass(@dropOverCssClass)
+      @_onDrop(event)
+      event.preventDefault()
+
+  _objClassForMimeType: (mimeType) ->
+    for mime, objClass of scrivito.content_browser.filter_defaults.upload
+      return objClass if mimeType.match(mime)
+
+    undefined
+
+  _processQueue: (queue, createdObjs, failedUploads, promise) ->
+    file = queue.pop()
+
+    if file?
+      @_createResource(file)
+        .done (obj) =>
+          @_updateProgress(file, '100%')
+          createdObjs.push(obj)
+          @_processQueue(queue, createdObjs, failedUploads, promise)
+        .fail (args) =>
+          @_updateError(file, args.message || "Upload failed. Please check your network connection.")
+          @_updateProgress(file, '0%')
+          failedUploads.push(args)
+          @_processQueue(queue, createdObjs, failedUploads, promise)
+    else
+      return promise.resolve(createdObjs, failedUploads)
+
+  _addProgressWrapper: () ->
+    itemsElement = $('.scrivito-content-browser-items').empty()
+
+    $('<div></div>')
+      .addClass('scrivito-content-browser-loading')
+      .appendTo itemsElement
+
+    $('<div></div>')
+      .addClass('scrivito-content-browser-progress-wrapper')
+      .appendTo itemsElement
+
+  _addProgress: (file) ->
+    progressBar = $('<div></div>')
+      .addClass('scrivito-content-browser-progress-bar')
+      .css('width', '10%')
+
+    progress = $('<div></div>')
+      .addClass('scrivito-content-browser-progress')
+      .html(progressBar)
+
+    fileName = $('<p></p>')
+      .html(file.name)
+
+    error = $('<p></p>')
+      .addClass('scrivito-content-browser-error')
+
+    $('<div></div>')
+      .addClass('scrivito-content-browser-progress-file')
+      .append(fileName)
+      .append(error)
+      .append(progress)
+      .prependTo $('.scrivito-content-browser-progress-wrapper')
+
+    file.progressBar = progressBar
+    file.error = error
+
+  _updateProgress: (file, percent) ->
+    file.progressBar.css('width', percent)
+
+  _updateError: (file, message) ->
+    file.error.text(message)
+
+  _onDrop: (event) ->
+    dataTransfer = event.originalEvent.dataTransfer
+
+    unless dataTransfer?
+      return
+
+    files = dataTransfer.files
+
+    if files.length == 0
+      return
+
+    @_addProgressWrapper()
+
+    queue = for file in files
+      @_addProgress(file)
+      file
+
+    @onUploadStart(queue)
+    promise = $.Deferred()
+      .done (createdObjs, failedUploads) =>
+        @onUploadFailure(failedUploads) if failedUploads.length > 0
+        @onUploadSuccess(createdObjs) if createdObjs.length > 0
+
+    @_processQueue(queue, [], [], promise)
+    promise
+
+  _randomResourceId: ->
+    hex = Math.floor(Math.random() * Math.pow(16, 8)).toString(16)
+
+    while (hex.length < 8)
+      hex = '0' + hex
+
+    hex
+
+  _createResource: (file) ->
+    objName = file.name.replace(/[^a-z0-9_.$\-]/ig, '-')
+    path = "_resources/#{@_randomResourceId()}/#{objName}"
+    objClass = @_objClassForMimeType(file.type)
+
+    if objClass
+      scrivito.create_obj
+        blob: file
+        _path: path
+        _obj_class: objClass
+    else
+      $.Deferred().reject
+        id: "no_obj_class_for_mime_type"
+        file_name: file.name
+        message: "File type #{file.type} rejected by resource configuration."
+
+  init: (@modal) ->
+    @_initializeBindings()
+
+  # Hook for 3rd parties when the upload starts.
+  onUploadStart: (files) ->
+
+  # Hook for 3rd parties when the upload fails.
+  onUploadFailure: (errors) ->
+
+  # Hook for 3rd parties when the upload was successful.
+  onUploadSuccess: (objs) ->

data/app/assets/javascripts/scrivito_content_browser.js

@@ -0,0 +1,13 @@
+// This is a manifest file that'll be compiled into application.js, which will include all the files
+// listed below.
+//
+// Any JavaScript/Coffee file within this directory, lib/assets/javascripts, vendor/assets/javascripts,
+// or vendor/assets/javascripts of plugins, if any, can be referenced here using a relative path.
+//
+// It's not advisable to add code directly here, but if you do, it'll appear at the bottom of the
+// compiled file.
+//
+// Read Sprockets README (https://github.com/sstephenson/sprockets#sprockets-directives) for details
+// about supported directives.
+//
+//= require_tree .