schleyfox-ernie 2.2.1

data/elib/ernie_server.erl

@@ -0,0 +1,326 @@
+-module(ernie_server).
+-behaviour(gen_server).
+-include_lib("ernie.hrl").
+
+%% api
+-export([start_link/1, start/1, process/1, kick/0]).
+
+%% gen_server callbacks
+-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
+         terminate/2, code_change/3]).
+
+%%====================================================================
+%% API
+%%====================================================================
+
+start_link(Args) ->
+  gen_server:start_link({global, ?MODULE}, ?MODULE, Args, []).
+
+start(Args) ->
+  gen_server:start({global, ?MODULE}, ?MODULE, Args, []).
+
+process(Sock) ->
+  gen_server:cast({global, ?MODULE}, {process, Sock}).
+
+kick() ->
+  gen_server:cast({global, ?MODULE}, kick).
+
+%%====================================================================
+%% gen_server callbacks
+%%====================================================================
+
+%%--------------------------------------------------------------------
+%% Function: init(Args) -> {ok, State} |
+%%                         {ok, State, Timeout} |
+%%                         ignore               |
+%%                         {stop, Reason}
+%% Description: Initiates the server
+%%--------------------------------------------------------------------
+init([Port, Configs]) ->
+  process_flag(trap_exit, true),
+  error_logger:info_msg("~p starting~n", [?MODULE]),
+  {ok, LSock} = try_listen(Port, 500),
+  spawn(fun() -> loop(LSock) end),
+  Map = init_map(Configs),
+  run_init_functions(Configs),
+  io:format("pidmap = ~p~n", [Map]),
+  {ok, #state{lsock = LSock, map = Map}}.
+
+%%--------------------------------------------------------------------
+%% Function: %% handle_call(Request, From, State) -> {reply, Reply, State} |
+%%                                      {reply, Reply, State, Timeout} |
+%%                                      {noreply, State} |
+%%                                      {noreply, State, Timeout} |
+%%                                      {stop, Reason, Reply, State} |
+%%                                      {stop, Reason, State}
+%% Description: Handling call messages
+%%--------------------------------------------------------------------
+handle_call(_Request, _From, State) ->
+  {reply, ok, State}.
+
+%%--------------------------------------------------------------------
+%% Function: handle_cast(Msg, State) -> {noreply, State} |
+%%                                      {noreply, State, Timeout} |
+%%                                      {stop, Reason, State}
+%% Description: Handling cast messages
+%%--------------------------------------------------------------------
+handle_cast({process, Sock}, State) ->
+  Log = #log{hq = queue:len(State#state.hq),
+             lq = queue:len(State#state.lq),
+             taccept = erlang:now()},
+  Request = #request{sock = Sock, log = Log},
+  State2 = receive_term(Request, State),
+  {noreply, State2};
+handle_cast(kick, State) ->
+  case queue:out(State#state.hq) of
+    {{value, Request}, Hq2} ->
+      State2 = process_request(Request, hq, Hq2, State),
+      {noreply, State2};
+    {empty, _Hq} ->
+      case queue:out(State#state.lq) of
+        {{value, Request}, Lq2} ->
+          State2 = process_request(Request, lq, Lq2, State),
+          {noreply, State2};
+        {empty, _Lq} ->
+          {noreply, State}
+      end
+  end;
+handle_cast(_Msg, State) -> {noreply, State}.
+
+handle_info(Msg, State) ->
+  error_logger:error_msg("Unexpected message: ~p~n", [Msg]),
+  {noreply, State}.
+
+terminate(_Reason, _State) -> ok.
+code_change(_OldVersion, State, _Extra) -> {ok, State}.
+
+%%====================================================================
+%% Internal
+%%====================================================================
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% Module mapping
+
+init_map(Configs) ->
+  lists:map((fun extract_mapping/1), Configs).
+
+extract_mapping(Config) ->
+  Id = proplists:get_value(id, Config),
+  Mod = proplists:get_value(module, Config),
+  {Mod, Id}.
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% Init Function
+
+run_init_functions(Configs) ->
+  lists:foreach(fun(Config) ->
+      case proplists:get_value(init, Config) of
+        undefined -> undefined;
+        {Mod, Func, Args} -> apply(Mod, Func, Args)
+      end
+    end,
+    Configs).
+
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% Listen and loop
+
+try_listen(Port, 0) ->
+  error_logger:error_msg("Could not listen on port ~p~n", [Port]),
+  {error, "Could not listen on port"};
+try_listen(Port, Times) ->
+  Res = gen_tcp:listen(Port, [binary, {packet, 4}, {active, false}, {reuseaddr, true}]),
+  case Res of
+    {ok, LSock} ->
+      error_logger:info_msg("Listening on port ~p~n", [Port]),
+      {ok, LSock};
+    {error, Reason} ->
+      error_logger:info_msg("Could not listen on port ~p: ~p~n", [Port, Reason]),
+      timer:sleep(5000),
+      try_listen(Port, Times - 1)
+  end.
+
+loop(LSock) ->
+  {ok, Sock} = gen_tcp:accept(LSock),
+  logger:debug("Accepted socket: ~p~n", [Sock]),
+  ernie_server:process(Sock),
+  loop(LSock).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% Receive and process
+
+receive_term(Request, State) ->
+  Sock = Request#request.sock,
+  case gen_tcp:recv(Sock, 0) of
+    {ok, BinaryTerm} ->
+      logger:debug("Got binary term: ~p~n", [BinaryTerm]),
+      Term = binary_to_term(BinaryTerm),
+      logger:info("Got term: ~p~n", [Term]),
+      case Term of
+        {call, '__admin__', Fun, Args} ->
+          ernie_admin:process(Sock, Fun, Args, State);
+        {info, Command, Args} ->
+          Infos = Request#request.infos,
+          Infos2 = [BinaryTerm | Infos],
+          Request2 = Request#request{infos = Infos2},
+          Request3 = process_info(Request2, Command, Args),
+          receive_term(Request3, State);
+        _Any ->
+          Request2 = Request#request{action = BinaryTerm},
+          close_if_cast(Term, Request2),
+          case Request2#request.priority of
+            high ->
+              Hq2 = queue:in(Request2, State#state.hq),
+              Lq2 = State#state.lq;
+            low ->
+              Hq2 = State#state.hq,
+              Lq2 = queue:in(Request2, State#state.lq)
+          end,
+          ernie_server:kick(),
+          State#state{hq = Hq2, lq = Lq2}
+      end;
+    {error, closed} ->
+      ok = gen_tcp:close(Sock),
+      State
+  end.
+
+process_info(Request, priority, [Priority]) ->
+  Request#request{priority = Priority};
+process_info(Request, _Command, _Args) ->
+  Request.
+
+process_request(Request, Priority, Q2, State) ->
+  ActionTerm = bert:decode(Request#request.action),
+  {_Type, Mod, _Fun, _Args} = ActionTerm,
+  Specs = lists:filter(fun({X, _Id}) -> Mod =:= X end, State#state.map),
+  process_module(ActionTerm, Specs, Request, Priority, Q2, State).
+
+process_module(ActionTerm, [], Request, Priority, Q2, State) ->
+  {_Type, Mod, _Fun, _Args} = ActionTerm,
+  logger:debug("No such module ~p~n", [Mod]),
+  Sock = Request#request.sock,
+  Class = <<"ServerError">>,
+  Message = list_to_binary(io_lib:format("No such module '~p'", [Mod])),
+  gen_tcp:send(Sock, term_to_binary({error, [server, 0, Class, Message, []]})),
+  ok = gen_tcp:close(Sock),
+  finish(Priority, Q2, State);
+process_module(ActionTerm, Specs, Request, Priority, Q2, State) ->
+  [{_Mod, Id} | OtherSpecs] = Specs,
+  case Id of
+    native ->
+      logger:debug("Dispatching to native module~n", []),
+      {_Type, Mod, Fun, Args} = ActionTerm,
+      case erlang:function_exported(Mod, Fun, length(Args)) of
+        false ->
+          logger:debug("Not found in native module ~p~n", [Mod]),
+          process_module(ActionTerm, OtherSpecs, Request, Priority, Q2, State);
+        true ->
+          PredFun = list_to_atom(atom_to_list(Fun) ++ "_pred"),
+          logger:debug("Checking ~p:~p(~p) for selection.~n", [Mod, PredFun, Args]),
+          case erlang:function_exported(Mod, PredFun, length(Args)) of
+            false ->
+              logger:debug("No such predicate function ~p:~p(~p).~n", [Mod, PredFun, Args]),
+              process_native_request(ActionTerm, Request, Priority, Q2, State);
+            true ->
+              case apply(Mod, PredFun, Args) of
+                false ->
+                  logger:debug("Predicate ~p:~p(~p) returned false.~n", [Mod, PredFun, Args]),
+                  process_module(ActionTerm, OtherSpecs, Request, Priority, Q2, State);
+                true ->
+                  logger:debug("Predicate ~p:~p(~p) returned true.~n", [Mod, PredFun, Args]),
+                  process_native_request(ActionTerm, Request, Priority, Q2, State)
+              end
+          end
+      end;
+    ValidPid when is_pid(ValidPid) ->
+      logger:debug("Found external pid ~p~n", [ValidPid]),
+      process_external_request(ValidPid, Request, Priority, Q2, State)
+  end.
+
+close_if_cast(ActionTerm, Request) ->
+  case ActionTerm of
+    {cast, _Mod, _Fun, _Args} ->
+      Sock = Request#request.sock,
+      gen_tcp:send(Sock, term_to_binary({noreply})),
+      ok = gen_tcp:close(Sock),
+      logger:debug("Closed cast.~n", []);
+    _Any ->
+      ok
+  end.
+
+finish(Priority, Q2, State) ->
+  case Priority of
+    hq -> State#state{hq = Q2};
+    lq -> State#state{lq = Q2}
+  end.
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% Native
+
+process_native_request(ActionTerm, Request, Priority, Q2, State) ->
+  Count = State#state.count,
+  State2 = State#state{count = Count + 1},
+  logger:debug("Count = ~p~n", [Count + 1]),
+  Log = Request#request.log,
+  Log2 = Log#log{type = native, tprocess = erlang:now()},
+  Request2 = Request#request{log = Log2},
+  spawn(fun() -> ernie_native:process(ActionTerm, Request2) end),
+  finish(Priority, Q2, State2).
+
+%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
+% External
+
+process_external_request(Pid, Request, Priority, Q2, State) ->
+  Count = State#state.count,
+  State2 = State#state{count = Count + 1},
+  logger:debug("Count = ~p~n", [Count + 1]),
+  case asset_pool:lease(Pid) of
+    {ok, Asset} ->
+      logger:debug("Leased asset for pool ~p~n", [Pid]),
+      Log = Request#request.log,
+      Log2 = Log#log{type = external, tprocess = erlang:now()},
+      Request2 = Request#request{log = Log2},
+      spawn(fun() -> process_now(Pid, Request2, Asset) end),
+      finish(Priority, Q2, State2);
+    empty ->
+      State
+  end.
+
+process_now(Pid, Request, Asset) ->
+  try unsafe_process_now(Request, Asset) of
+    _AnyResponse ->
+      Log = Request#request.log,
+      Log2 = Log#log{tdone = erlang:now()},
+      Request2 = Request#request{log = Log2},
+      ernie_access_logger:acc(Request2)
+  catch
+    AnyClass:AnyError ->
+      Log = Request#request.log,
+      Log2 = Log#log{tdone = erlang:now()},
+      Request2 = Request#request{log = Log2},
+      ernie_access_logger:err(Request2, "External process error ~w: ~w", [AnyClass, AnyError])
+  after
+    asset_pool:return(Pid, Asset),
+    ernie_server:kick(),
+    logger:debug("Returned asset ~p~n", [Asset]),
+    gen_tcp:close(Request#request.sock),
+    logger:debug("Closed socket ~p~n", [Request#request.sock])
+  end.
+
+unsafe_process_now(Request, Asset) ->
+  BinaryTerm = Request#request.action,
+  Term = binary_to_term(BinaryTerm),
+  case Term of
+    {call, Mod, Fun, Args} ->
+      logger:debug("Calling ~p:~p(~p)~n", [Mod, Fun, Args]),
+      Sock = Request#request.sock,
+      {asset, Port, Token} = Asset,
+      logger:debug("Asset: ~p ~p~n", [Port, Token]),
+      {ok, Data} = port_wrapper:rpc(Port, BinaryTerm),
+      ok = gen_tcp:send(Sock, Data);
+    {cast, Mod, Fun, Args} ->
+      logger:debug("Casting ~p:~p(~p)~n", [Mod, Fun, Args]),
+      {asset, Port, Token} = Asset,
+      logger:debug("Asset: ~p ~p~n", [Port, Token]),
+      {ok, _Data} = port_wrapper:rpc(Port, BinaryTerm)
+  end.

data/elib/ernie_server_app.erl

@@ -0,0 +1,20 @@
+-module(ernie_server_app).
+-behaviour(application).
+
+-export([boot/0, start/2, stop/1]).
+
+boot() ->
+  application:start(ernie_server_app).
+
+start(_Type, _Args) ->
+  case application:get_env(ernie_server_app, access_log) of
+    {ok, AccessFile} ->
+      ernie_access_logger_sup:start_link(AccessFile);
+    undefined ->
+      ernie_access_logger_sup:start_link(undefined)
+  end,
+  logger_sup:start_link(),
+  ernie_server_sup:start_link().
+
+stop(_State) ->
+  ok.

data/elib/ernie_server_sup.erl

@@ -0,0 +1,22 @@
+-module(ernie_server_sup).
+-behaviour(supervisor).
+-export([start_link/0, init/1]).
+
+start_link() ->
+  supervisor:start_link({local, ?MODULE}, ?MODULE, []).
+
+init([]) ->
+  {ok, Port} = application:get_env(ernie_server_app, port),
+  io:format("Using port ~p~n", [Port]),
+  case application:get_env(ernie_server_app, pidfile) of
+    {ok, Location} ->
+      Pid = os:getpid(),
+      ok = file:write_file(Location, list_to_binary(Pid));
+    undefined -> ok
+  end,
+  {ok, Config} = application:get_env(ernie_server_app, config),
+  {ok, Configs} = ernie_config:load(Config),
+  io:format("~p~n", [Configs]),
+  {ok, {{one_for_one, 1, 60},
+    [{ernie_server, {ernie_server, start_link, [[Port, Configs]]},
+    permanent, brutal_kill, worker, [ernie_server]}]}}.

data/elib/logger.erl

@@ -0,0 +1,108 @@
+-module(logger).
+-behaviour(gen_server).
+
+%% api
+-export([start_link/1, start/1, set_log_level/1, debug/2, info/2, warn/2, error/2, fatal/2]).
+
+%% gen_server callbacks
+-export([init/1, handle_call/3, handle_cast/2, handle_info/2,
+         terminate/2, code_change/3]).
+
+-record(state, {log_level = undefined}).
+
+%%====================================================================
+%% API
+%%====================================================================
+
+start_link(Args) ->
+  gen_server:start_link({global, ?MODULE}, ?MODULE, Args, []).
+
+start(Args) ->
+  gen_server:start({global, ?MODULE}, ?MODULE, Args, []).
+
+set_log_level(Level) ->
+  gen_server:call({global, ?MODULE}, {set_log_level, Level}).
+
+debug(Msg, Args) ->
+  gen_server:cast({global, ?MODULE}, {debug, Msg, Args}).
+
+info(Msg, Args) ->
+  gen_server:cast({global, ?MODULE}, {info, Msg, Args}).
+
+warn(Msg, Args) ->
+  gen_server:cast({global, ?MODULE}, {warn, Msg, Args}).
+
+error(Msg, Args) ->
+  gen_server:cast({global, ?MODULE}, {error, Msg, Args}).
+
+fatal(Msg, Args) ->
+  gen_server:cast({global, ?MODULE}, {fatal, Msg, Args}).
+
+%%====================================================================
+%% gen_server callbacks
+%%====================================================================
+
+%%--------------------------------------------------------------------
+%% Function: init(Args) -> {ok, State} |
+%%                         {ok, State, Timeout} |
+%%                         ignore               |
+%%                         {stop, Reason}
+%% Description: Initiates the server
+%%--------------------------------------------------------------------
+init([LogLevel]) ->
+  error_logger:info_msg("~p starting~n", [?MODULE]),
+  {ok, #state{log_level = LogLevel}}.
+
+%%--------------------------------------------------------------------
+%% Function: %% handle_call(Request, From, State) -> {reply, Reply, State} |
+%%                                      {reply, Reply, State, Timeout} |
+%%                                      {noreply, State} |
+%%                                      {noreply, State, Timeout} |
+%%                                      {stop, Reason, Reply, State} |
+%%                                      {stop, Reason, State}
+%% Description: Handling call messages
+%%--------------------------------------------------------------------
+handle_call({set_log_level, Level}, _From, State) ->
+  {reply, ok, State#state{log_level = Level}};
+handle_call(_Request, _From, State) ->
+  {reply, ok, State}.
+
+%%--------------------------------------------------------------------
+%% Function: handle_cast(Msg, State) -> {noreply, State} |
+%%                                      {noreply, State, Timeout} |
+%%                                      {stop, Reason, State}
+%% Description: Handling cast messages
+%%--------------------------------------------------------------------
+handle_cast({debug, Msg, Args}, State) ->
+  log(State#state.log_level, 4, Msg, Args),
+  {noreply, State};
+handle_cast({info, Msg, Args}, State) ->
+  log(State#state.log_level, 3, Msg, Args),
+  {noreply, State};
+handle_cast({warn, Msg, Args}, State) ->
+  log(State#state.log_level, 2, Msg, Args),
+  {noreply, State};
+handle_cast({error, Msg, Args}, State) ->
+  log(State#state.log_level, 1, Msg, Args),
+  {noreply, State};
+handle_cast({fatal, Msg, Args}, State) ->
+  log(State#state.log_level, 0, Msg, Args),
+  {noreply, State};
+handle_cast(_Msg, State) -> {noreply, State}.
+
+handle_info(Msg, State) ->
+  error_logger:error_msg("Unexpected message: ~p~n", [Msg]),
+  {noreply, State}.
+
+terminate(_Reason, _State) -> ok.
+code_change(_OldVersion, State, _Extra) -> {ok, State}.
+
+%%====================================================================
+%% Internal
+%%====================================================================
+
+log(SystemLogLevel, MessageLogLevel, Message, Args) ->
+  case SystemLogLevel >= MessageLogLevel of
+    false -> ok;
+    true -> io:format(Message, Args)
+  end.

data/elib/logger_sup.erl

@@ -0,0 +1,13 @@
+-module(logger_sup).
+-behaviour(supervisor).
+-export([start_link/0, init/1]).
+
+start_link() ->
+  supervisor:start_link({local, ?MODULE}, ?MODULE, []).
+
+init([]) ->
+  {ok, LogLevel} = application:get_env(ernie_server_app, log_level),
+  io:format("Using log level ~p~n", [LogLevel]),
+  {ok, {{one_for_one, 1, 60},
+    [{logger, {logger, start_link, [[LogLevel]]},
+    permanent, brutal_kill, worker, [logger]}]}}.

data/elib/port_wrapper.erl

@@ -0,0 +1,65 @@
+-module(port_wrapper).
+-export([wrap/1, wrap/2, wrap_link/1, wrap_link/2, send/2, shutdown/1, close/1, rpc/2]).
+
+wrap(Command) ->
+ spawn(fun() -> process_flag(trap_exit, true), Port = create_port(Command), loop(Port, infinity, Command) end).
+wrap(Command, Timeout) ->
+  spawn(fun() -> process_flag(trap_exit, true), Port = create_port(Command), loop(Port, Timeout, Command) end).
+
+wrap_link(Command) ->
+ spawn_link(fun() -> process_flag(trap_exit, true), Port = create_port(Command), link(Port), loop(Port, infinity, Command) end).
+wrap_link(Command, Timeout) ->
+  spawn_link(fun() -> process_flag(trap_exit, true), Port = create_port(Command), link(Port), loop(Port, Timeout, Command) end).
+
+rpc(WrappedPort, Message) ->
+  send(WrappedPort, Message),
+  receive
+    {WrappedPort, Result} -> {ok, Result}
+  end.
+
+send(WrappedPort, Message) ->
+  WrappedPort ! {self(), {command, Message}},
+  WrappedPort.
+
+shutdown(WrappedPort) ->
+  WrappedPort ! shutdown,
+  true.
+
+close(WrappedPort) ->
+  WrappedPort ! noose,
+  true.
+
+create_port(Command) ->
+  open_port({spawn, Command}, [{packet, 4}, nouse_stdio, exit_status, binary]).
+
+loop(Port, Timeout, Command) ->
+  receive
+    noose ->
+      port_close(Port),
+      noose;
+    shutdown ->
+      port_close(Port),
+      exit(shutdown);
+    {Source, {command, Message}} ->
+      Port ! {self(), {command, Message}},
+      receive
+        {Port, {data, Result}} ->
+          Source ! {self(), Result}
+      after Timeout ->
+        error_logger:error_msg("Port Wrapper ~p timed out in mid operation (~p)!~n", [self(),Message]),
+        % We timed out, which means we need to close and then restart the port
+        port_close(Port), % Should SIGPIPE the child.
+        exit(timed_out)
+      end,
+      loop(Port,Timeout,Command);
+    {Port, {exit_status, _Code}} ->
+      % Hard and Unanticipated Crash
+      error_logger:error_msg( "Port closed! ~p~n", [Port] ),
+      exit({error, _Code});
+    {'EXIT',_Pid,shutdown} ->
+      port_close(Port),
+      exit(shutdown);
+    Any ->
+      error_logger:warning_msg("PortWrapper ~p got unexpected message: ~p~n", [self(), Any]),
+      loop(Port, Timeout, Command)
+  end.

data/ernie.gemspec

@@ -0,0 +1,94 @@
+# Generated by jeweler
+# DO NOT EDIT THIS FILE DIRECTLY
+# Instead, edit Jeweler::Tasks in rakefile, and run the gemspec command
+# -*- encoding: utf-8 -*-
+
+Gem::Specification.new do |s|
+  s.name = %q{schleyfox-ernie}
+  s.version = "2.2.1"
+
+  s.required_rubygems_version = Gem::Requirement.new(">= 0") if s.respond_to? :required_rubygems_version=
+  s.authors = ["Tom Preston-Werner"]
+  s.date = %q{2010-03-12}
+  s.default_executable = %q{ernie}
+  s.description = %q{Ernie is an Erlang/Ruby hybrid BERT-RPC server implementation packaged as a gem.}
+  s.email = %q{tom@mojombo.com}
+  s.executables = ["ernie"]
+  s.extensions = ["ext/extconf.rb", "ext/extconf.rb"]
+  s.extra_rdoc_files = [
+    "LICENSE",
+     "README.md"
+  ]
+  s.files = [
+    ".document",
+     ".gitignore",
+     "History.txt",
+     "LICENSE",
+     "README.md",
+     "Rakefile",
+     "VERSION.yml",
+     "bin/ernie",
+     "contrib/ebench.erl",
+     "ebin/ernie_server_app.app",
+     "elib/asset_pool.erl",
+     "elib/asset_pool_sup.erl",
+     "elib/bert.erl",
+     "elib/ernie.hrl",
+     "elib/ernie_access_logger.erl",
+     "elib/ernie_access_logger_sup.erl",
+     "elib/ernie_admin.erl",
+     "elib/ernie_config.erl",
+     "elib/ernie_native.erl",
+     "elib/ernie_server.erl",
+     "elib/ernie_server_app.erl",
+     "elib/ernie_server_sup.erl",
+     "elib/logger.erl",
+     "elib/logger_sup.erl",
+     "elib/port_wrapper.erl",
+     "ernie.gemspec",
+     "examples/example.cfg",
+     "examples/ext.erl",
+     "examples/ext.rb",
+     "examples/nat.erl",
+     "ext/Makefile",
+     "ext/extconf.rb",
+     "lib/ernie.rb",
+     "test/ernie_server_test.rb",
+     "test/ernie_test.rb",
+     "test/helper.rb",
+     "test/load.rb",
+     "test/sample/ext.rb",
+     "test/sample/sample.cfg"
+  ]
+  s.homepage = %q{http://github.com/mojombo/ernie}
+  s.rdoc_options = ["--charset=UTF-8"]
+  s.require_paths = ["lib"]
+  s.rubyforge_project = %q{ernie}
+  s.rubygems_version = %q{1.3.5}
+  s.summary = %q{Ernie is a BERT-RPC server implementation.}
+  s.test_files = [
+    "test/ernie_server_test.rb",
+     "test/ernie_test.rb",
+     "test/helper.rb",
+     "test/load.rb",
+     "test/sample/ext.rb",
+     "examples/ext.rb"
+  ]
+
+  if s.respond_to? :specification_version then
+    current_version = Gem::Specification::CURRENT_SPECIFICATION_VERSION
+    s.specification_version = 3
+
+    if Gem::Version.new(Gem::RubyGemsVersion) >= Gem::Version.new('1.2.0') then
+      s.add_runtime_dependency(%q<bert>, [">= 1.1.0"])
+      s.add_runtime_dependency(%q<bertrpc>, [">= 1.0.0"])
+    else
+      s.add_dependency(%q<bert>, [">= 1.1.0"])
+      s.add_dependency(%q<bertrpc>, [">= 1.0.0"])
+    end
+  else
+    s.add_dependency(%q<bert>, [">= 1.1.0"])
+    s.add_dependency(%q<bertrpc>, [">= 1.0.0"])
+  end
+end
+

data/examples/example.cfg

@@ -0,0 +1,12 @@
+[{module, ext},
+ {type, native},
+ {codepaths, ["examples"]}].
+
+[{module, ext},
+ {type, external},
+ {command, "ruby examples/ext.rb"},
+ {count, 2}].
+
+[{module, nat},
+ {type, native},
+ {codepaths, ["examples"]}].

data/examples/ext.erl

@@ -0,0 +1,8 @@
+-module(ext).
+-export([shadow_pred/1, shadow/1]).
+
+shadow_pred(X) ->
+  X > 10.
+
+shadow(_X) ->
+  <<"erlang">>.