rugged 0.28.4.1 → 1.1.0

data/vendor/libgit2/COPYING

@@ -991,3 +991,31 @@ AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
 SOFTWARE.
+
+----------------------------------------------------------------------
+
+The bundled wildmatch code is licensed under the BSD license:
+
+Copyright Rich Salz.
+All rights reserved.
+
+Redistribution and use in any form are permitted provided that the
+following restrictions are are met:
+
+1.  Source distributions must retain this entire copyright notice
+    and comment.
+2.  Binary distributions must include the acknowledgement ``This
+    product includes software developed by Rich Salz'' in the
+    documentation or other materials provided with the
+    distribution.  This must not be represented as an endorsement
+   or promotion without specific prior written permission.
+3.  The origin of this software must not be misrepresented, either
+    by explicit claim or by omission.  Credits must appear in the
+    source and documentation.
+4.  Altered versions must be plainly marked as such in the source
+    and documentation and must not be misrepresented as being the
+    original software.
+
+THIS SOFTWARE IS PROVIDED ``AS IS'' AND WITHOUT ANY EXPRESS OR IMPLIED
+WARRANTIES, INCLUDING, WITHOUT LIMITATION, THE IMPLIED WARRANTIES OF
+MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.

data/vendor/libgit2/cmake/{Modules/EnableWarnings.cmake → EnableWarnings.cmake}

@@ -7,5 +7,9 @@ MACRO(DISABLE_WARNINGS flag)
 ENDMACRO()
 
 IF(ENABLE_WERROR)
-	ADD_C_FLAG_IF_SUPPORTED(-Werror)
+	IF(MSVC)
+		ADD_COMPILE_OPTIONS(-WX)
+	ELSE()
+		ADD_C_FLAG_IF_SUPPORTED(-Werror)
+	ENDIF()
 ENDIF()

data/vendor/libgit2/cmake/{Modules/FindCoreFoundation.cmake → FindCoreFoundation.cmake}

@@ -10,14 +10,14 @@ FIND_PATH(COREFOUNDATION_INCLUDE_DIR NAMES CoreFoundation.h)
 FIND_LIBRARY(COREFOUNDATION_LIBRARIES NAMES CoreFoundation)
 IF (COREFOUNDATION_INCLUDE_DIR AND COREFOUNDATION_LIBRARIES)
 	IF (NOT CoreFoundation_FIND_QUIETLY)
-		MESSAGE("-- Found CoreFoundation ${COREFOUNDATION_LIBRARIES}")
+		MESSAGE(STATUS "Found CoreFoundation ${COREFOUNDATION_LIBRARIES}")
 	ENDIF()
 	SET(COREFOUNDATION_FOUND TRUE)
 	SET(COREFOUNDATION_LDFLAGS "-framework CoreFoundation")
 ENDIF ()
 
 IF (CoreFoundation_FIND_REQUIRED AND NOT COREFOUNDATION_FOUND)
-	MESSAGE(FATAL "-- CoreFoundation not found")
+	MESSAGE(FATAL_ERROR "CoreFoundation not found")
 ENDIF()
 
 MARK_AS_ADVANCED(

data/vendor/libgit2/cmake/{Modules/FindGSSAPI.cmake → FindGSSAPI.cmake}

@@ -6,7 +6,7 @@
 #
 # Read-Only variables:
 #  GSSAPI_FLAVOR_MIT - set to TURE if MIT Kerberos has been found
-#  GSSAPI_FLAVOR_HEIMDAL - set to TRUE if Heimdal Keberos has been found
+#  GSSAPI_FLAVOR_HEIMDAL - set to TRUE if Heimdal Kerberos has been found
 #  GSSAPI_FOUND - system has GSSAPI
 #  GSSAPI_INCLUDE_DIR - the GSSAPI include directory
 #  GSSAPI_LIBRARIES - Link these to use GSSAPI

data/vendor/libgit2/cmake/FindGSSFramework.cmake

@@ -0,0 +1,28 @@
+# Find GSS.framework
+# This will define :
+#
+# GSSFRAMEWORK_FOUND
+# GSSFRAMEWORK_INCLUDE_DIR
+# GSSFRAMEWORK_LIBRARIES
+# GSSFRAMEWORK_LDFLAGS
+#
+
+FIND_PATH(GSSFRAMEWORK_INCLUDE_DIR NAMES GSS.h)
+FIND_LIBRARY(GSSFRAMEWORK_LIBRARIES NAMES GSS)
+IF (GSSFRAMEWORK_INCLUDE_DIR AND GSSFRAMEWORK_LIBRARIES)
+	IF (NOT CoreFoundation_FIND_QUIETLY)
+		MESSAGE(STATUS "Found GSS.framework ${GSSFRAMEWORK_LIBRARIES}")
+	ENDIF()
+	SET(GSSFRAMEWORK_FOUND TRUE)
+	SET(GSSFRAMEWORK_LDFLAGS "-framework GSS")
+ENDIF ()
+
+IF (GSS_FIND_REQUIRED AND NOT GSSFRAMEWORK_FOUND)
+	MESSAGE(FATAL_ERROR "CoreFoundation not found")
+ENDIF()
+
+MARK_AS_ADVANCED(
+	GSSFRAMEWORK_INCLUDE_DIR
+	GSSFRAMEWORK_LIBRARIES
+	GSSFRAMEWORK_LDFLAGS
+)

data/vendor/libgit2/cmake/FindPCRE.cmake

@@ -0,0 +1,38 @@
+# Copyright (C) 2007-2009 LuaDist.
+# Created by Peter Kapec <kapecp@gmail.com>
+# Redistribution and use of this file is allowed according to the terms of the MIT license.
+# For details see the COPYRIGHT file distributed with LuaDist.
+#	Note:
+#		Searching headers and libraries is very simple and is NOT as powerful as scripts
+#		distributed with CMake, because LuaDist defines directories to search for.
+#		Everyone is encouraged to contact the author with improvements. Maybe this file
+#		becomes part of CMake distribution sometimes.
+
+# - Find pcre
+# Find the native PCRE headers and libraries.
+#
+# PCRE_INCLUDE_DIRS	- where to find pcre.h, etc.
+# PCRE_LIBRARIES	- List of libraries when using pcre.
+# PCRE_FOUND	- True if pcre found.
+
+# Look for the header file.
+FIND_PATH(PCRE_INCLUDE_DIR NAMES pcreposix.h)
+
+# Look for the library.
+FIND_LIBRARY(PCRE_LIBRARY NAMES pcre)
+FIND_LIBRARY(PCRE_POSIX_LIBRARY NAMES pcreposix)
+
+# Handle the QUIETLY and REQUIRED arguments and set PCRE_FOUND to TRUE if all listed variables are TRUE.
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(PCRE DEFAULT_MSG PCRE_LIBRARY PCRE_POSIX_LIBRARY PCRE_INCLUDE_DIR)
+
+# Copy the results to the output variables.
+IF(PCRE_FOUND)
+	SET(PCRE_LIBRARIES ${PCRE_LIBRARY} ${PCRE_POSIX_LIBRARY})
+	SET(PCRE_INCLUDE_DIRS ${PCRE_INCLUDE_DIR})
+ELSE(PCRE_FOUND)
+	SET(PCRE_LIBRARIES)
+	SET(PCRE_INCLUDE_DIRS)
+ENDIF(PCRE_FOUND)
+
+MARK_AS_ADVANCED(PCRE_INCLUDE_DIRS PCRE_LIBRARIES)

data/vendor/libgit2/cmake/FindPCRE2.cmake

@@ -0,0 +1,37 @@
+# Copyright (C) 2007-2009 LuaDist.
+# Created by Peter Kapec <kapecp@gmail.com>
+# Redistribution and use of this file is allowed according to the terms of the MIT license.
+# For details see the COPYRIGHT file distributed with LuaDist.
+#	Note:
+#		Searching headers and libraries is very simple and is NOT as powerful as scripts
+#		distributed with CMake, because LuaDist defines directories to search for.
+#		Everyone is encouraged to contact the author with improvements. Maybe this file
+#		becomes part of CMake distribution sometimes.
+
+# - Find pcre
+# Find the native PCRE2 headers and libraries.
+#
+# PCRE2_INCLUDE_DIRS	- where to find pcre.h, etc.
+# PCRE2_LIBRARIES	- List of libraries when using pcre.
+# PCRE2_FOUND	- True if pcre found.
+
+# Look for the header file.
+FIND_PATH(PCRE2_INCLUDE_DIR NAMES pcre2posix.h)
+
+# Look for the library.
+FIND_LIBRARY(PCRE2_LIBRARY NAMES pcre2-8)
+
+# Handle the QUIETLY and REQUIRED arguments and set PCRE2_FOUND to TRUE if all listed variables are TRUE.
+INCLUDE(FindPackageHandleStandardArgs)
+FIND_PACKAGE_HANDLE_STANDARD_ARGS(PCRE2 DEFAULT_MSG PCRE2_LIBRARY PCRE2_INCLUDE_DIR)
+
+# Copy the results to the output variables.
+IF(PCRE2_FOUND)
+	SET(PCRE2_LIBRARIES ${PCRE2_LIBRARY})
+	SET(PCRE2_INCLUDE_DIRS ${PCRE2_INCLUDE_DIR})
+ELSE(PCRE2_FOUND)
+	SET(PCRE2_LIBRARIES)
+	SET(PCRE2_INCLUDE_DIRS)
+ENDIF(PCRE2_FOUND)
+
+MARK_AS_ADVANCED(PCRE2_INCLUDE_DIRS PCRE2_LIBRARIES)

data/vendor/libgit2/cmake/{Modules/FindSecurity.cmake → FindSecurity.cmake}

@@ -11,7 +11,7 @@ FIND_PATH(SECURITY_INCLUDE_DIR NAMES Security/Security.h)
 FIND_LIBRARY(SECURITY_LIBRARIES NAMES Security)
 IF (SECURITY_INCLUDE_DIR AND SECURITY_LIBRARIES)
 	IF (NOT Security_FIND_QUIETLY)
-		MESSAGE("-- Found Security ${SECURITY_LIBRARIES}")
+		MESSAGE(STATUS "Found Security ${SECURITY_LIBRARIES}")
 	ENDIF()
 	SET(SECURITY_FOUND TRUE)
 	SET(SECURITY_LDFLAGS "-framework Security")
@@ -19,7 +19,7 @@ IF (SECURITY_INCLUDE_DIR AND SECURITY_LIBRARIES)
 ENDIF ()
 
 IF (Security_FIND_REQUIRED AND NOT SECURITY_FOUND)
-	MESSAGE(FATAL "-- Security not found")
+	MESSAGE(FATAL_ERROR "Security not found")
 ENDIF()
 
 MARK_AS_ADVANCED(

data/vendor/libgit2/cmake/{Modules/FindStatNsec.cmake → FindStatNsec.cmake}

@@ -1,3 +1,5 @@
+INCLUDE(FeatureSummary)
+
 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_mtim "sys/types.h;sys/stat.h"
 	HAVE_STRUCT_STAT_ST_MTIM LANGUAGE C)
 CHECK_STRUCT_HAS_MEMBER ("struct stat" st_mtimespec "sys/types.h;sys/stat.h"
@@ -17,4 +19,8 @@ ENDIF()
 
 IF (HAVE_STRUCT_STAT_NSEC OR WIN32)
 	OPTION( USE_NSEC		"Care about sub-second file mtimes and ctimes"	ON  )
+ELSE()
+	SET(USE_NSEC OFF)
 ENDIF()
+
+ADD_FEATURE_INFO(nanoseconds USE_NSEC "whether to use sub-second file mtimes and ctimes")

data/vendor/libgit2/cmake/PkgBuildConfig.cmake

@@ -0,0 +1,77 @@
+# pkg-config file generation
+#
+
+function(pkg_build_config)
+    set(options)
+    set(oneValueArgs NAME DESCRIPTION VERSION FILENAME LIBS_SELF)
+    set(multiValueArgs LIBS PRIVATE_LIBS REQUIRES CFLAGS)
+
+    cmake_parse_arguments(PKGCONFIG "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+    if (NOT DEFINED PKGCONFIG_FILENAME AND DEFINED PKGCONFIG_NAME)
+        set(PKGCONFIG_FILENAME ${PKGCONFIG_NAME})
+    endif()
+    if (NOT DEFINED PKGCONFIG_FILENAME)
+        message(FATAL_ERROR "Missing FILENAME argument")
+    endif()
+    set(PKGCONFIG_FILE "${PROJECT_BINARY_DIR}/${PKGCONFIG_FILENAME}.pc")
+
+    if (NOT DEFINED PKGCONFIG_DESCRIPTION)
+        message(FATAL_ERROR "Missing DESCRIPTION argument")
+    endif()
+
+    if (NOT DEFINED PKGCONFIG_VERSION)
+        message(FATAL_ERROR "Missing VERSION argument")
+    endif()
+
+    # Write .pc "header"
+    file(WRITE "${PKGCONFIG_FILE}"
+        "prefix=\"${CMAKE_INSTALL_PREFIX}\"\n"
+        "libdir=\"${CMAKE_INSTALL_FULL_LIBDIR}\"\n"
+        "includedir=\"${CMAKE_INSTALL_FULL_INCLUDEDIR}\"\n"
+        "\n"
+        "Name: ${PKGCONFIG_NAME}\n"
+        "Description: ${PKGCONFIG_DESCRIPTION}\n"
+        "Version: ${PKGCONFIG_VERSION}\n"
+    )
+
+    # Prepare Libs
+    if(NOT DEFINED PKGCONFIG_LIBS_SELF)
+        set(PKGCONFIG_LIBS_SELF "${PKGCONFIG_FILE}")
+    endif()
+
+    if(NOT DEFINED PKGCONFIG_LIBS)
+        set(PKGCONFIG_LIBS "-l${PKGCONFIG_LIBS_SELF}")
+    else()
+        list(INSERT PKGCONFIG_LIBS 0 "-l${PKGCONFIG_LIBS_SELF}")
+    endif()
+
+    list(REMOVE_DUPLICATES PKGCONFIG_LIBS)
+    string(REPLACE ";" " " PKGCONFIG_LIBS "${PKGCONFIG_LIBS}")
+    file(APPEND "${PKGCONFIG_FILE}" "Libs: -L\${libdir} ${PKGCONFIG_LIBS}\n")
+
+    # Prepare Libs.private
+    if(DEFINED PKGCONFIG_PRIVATE_LIBS)
+        list(REMOVE_DUPLICATES PKGCONFIG_PRIVATE_LIBS)
+        string(REPLACE ";" " " PKGCONFIG_PRIVATE_LIBS "${PKGCONFIG_PRIVATE_LIBS}")
+        file(APPEND "${PKGCONFIG_FILE}" "Libs.private: ${PKGCONFIG_PRIVATE_LIBS}\n")
+    endif()
+
+    # Prepare Requires.private
+    if(DEFINED PKGCONFIG_REQUIRES)
+        list(REMOVE_DUPLICATES PKGCONFIG_REQUIRES)
+        string(REPLACE ";" " " PKGCONFIG_REQUIRES "${PKGCONFIG_REQUIRES}")
+        file(APPEND "${PKGCONFIG_FILE}" "Requires.private: ${PKGCONFIG_REQUIRES}\n")
+    endif()
+
+    # Prepare Cflags
+    if(DEFINED PKGCONFIG_CFLAGS)
+        string(REPLACE ";" " " PKGCONFIG_CFLAGS "${PKGCONFIG_CFLAGS}")
+    else()
+        set(PKGCONFIG_CFLAGS "")
+    endif()
+    file(APPEND "${PKGCONFIG_FILE}" "Cflags: -I\${includedir} ${PKGCONFIG_CFLAGS}\n")
+
+    # Install .pc file
+    install(FILES "${PKGCONFIG_FILE}" DESTINATION "${CMAKE_INSTALL_LIBDIR}/pkgconfig")
+endfunction()

data/vendor/libgit2/cmake/SanitizeBool.cmake

@@ -0,0 +1,20 @@
+FUNCTION(SanitizeBool VAR)
+	STRING(TOLOWER "${${VAR}}" VALUE)
+	IF(VALUE STREQUAL "on")
+		SET(${VAR} "ON" PARENT_SCOPE)
+	ELSEIF(VALUE STREQUAL "yes")
+		SET(${VAR} "ON" PARENT_SCOPE)
+	ELSEIF(VALUE STREQUAL "true")
+		SET(${VAR} "ON" PARENT_SCOPE)
+	ELSEIF(VALUE STREQUAL "1")
+		SET(${VAR} "ON" PARENT_SCOPE)
+	ELSEIF(VALUE STREQUAL "off")
+		SET(${VAR} "OFF" PARENT_SCOPE)
+	ELSEIF(VALUE STREQUAL "no")
+		SET(${VAR} "OFF" PARENT_SCOPE)
+	ELSEIF(VALUE STREQUAL "false")
+		SET(${VAR} "OFF" PARENT_SCOPE)
+	ELSEIF(VALUE STREQUAL "0")
+		SET(${VAR} "OFF" PARENT_SCOPE)
+	ENDIF()
+ENDFUNCTION()

data/vendor/libgit2/cmake/SelectGSSAPI.cmake

@@ -0,0 +1,48 @@
+INCLUDE(SanitizeBool)
+
+# We try to find any packages our backends might use
+FIND_PACKAGE(GSSAPI)
+IF (CMAKE_SYSTEM_NAME MATCHES "Darwin")
+	INCLUDE(FindGSSFramework)
+ENDIF()
+
+IF(USE_GSSAPI)
+	# Auto-select GSS backend
+	SanitizeBool(USE_GSSAPI)
+	IF (USE_GSSAPI STREQUAL ON)
+		IF (GSSFRAMEWORK_FOUND)
+			SET(USE_GSSAPI "GSS.framework")
+		ELSEIF(GSSAPI_FOUND)
+			SET(USE_GSSAPI "gssapi")
+		ELSE()
+			MESSAGE(FATAL_ERROR "Unable to autodetect a usable GSS backend."
+				"Please pass the backend name explicitly (-DUSE_GSS=backend)")
+		ENDIF()
+	ENDIF()
+
+	# Check that we can find what's required for the selected backend
+	IF (USE_GSSAPI STREQUAL "GSS.framework")
+		IF (NOT GSSFRAMEWORK_FOUND)
+			MESSAGE(FATAL_ERROR "Asked for GSS.framework backend, but it wasn't found")
+		ENDIF()
+
+		LIST(APPEND LIBGIT2_LIBS ${GSSFRAMEWORK_LIBRARIES})
+
+		SET(GIT_GSSFRAMEWORK 1)
+		ADD_FEATURE_INFO(SPNEGO GIT_GSSFRAMEWORK "SPNEGO authentication support (${USE_GSSAPI})")
+	ELSEIF (USE_GSSAPI STREQUAL "gssapi")
+		IF (NOT GSSAPI_FOUND)
+			MESSAGE(FATAL_ERROR "Asked for gssapi GSS backend, but it wasn't found")
+		ENDIF()
+
+		LIST(APPEND LIBGIT2_LIBS ${GSSAPI_LIBRARIES})
+
+		SET(GIT_GSSAPI 1)
+		ADD_FEATURE_INFO(SPNEGO GIT_GSSAPI "SPNEGO authentication support (${USE_GSSAPI})")
+	ELSE()
+		MESSAGE(FATAL_ERROR "Asked for backend ${USE_GSSAPI} but it wasn't found")
+	ENDIF()
+ELSE()
+	SET(GIT_GSSAPI 0)
+	ADD_FEATURE_INFO(SPNEGO NO "SPNEGO authentication support")
+ENDIF()

data/vendor/libgit2/cmake/SelectHTTPSBackend.cmake

@@ -0,0 +1,120 @@
+INCLUDE(SanitizeBool)
+
+# We try to find any packages our backends might use
+FIND_PACKAGE(OpenSSL)
+FIND_PACKAGE(mbedTLS)
+IF (CMAKE_SYSTEM_NAME MATCHES "Darwin")
+	FIND_PACKAGE(Security)
+	FIND_PACKAGE(CoreFoundation)
+ENDIF()
+
+IF(USE_HTTPS)
+	# Auto-select TLS backend
+	SanitizeBool(USE_HTTPS)
+	IF (USE_HTTPS STREQUAL ON)
+		IF (SECURITY_FOUND)
+			IF (SECURITY_HAS_SSLCREATECONTEXT)
+				SET(USE_HTTPS "SecureTransport")
+			ELSE()
+				MESSAGE(STATUS "Security framework is too old, falling back to OpenSSL")
+				SET(USE_HTTPS "OpenSSL")
+			ENDIF()
+		ELSEIF (WINHTTP)
+			SET(USE_HTTPS "WinHTTP")
+		ELSEIF(OPENSSL_FOUND)
+			SET(USE_HTTPS "OpenSSL")
+		ELSEIF(MBEDTLS_FOUND)
+			SET(USE_HTTPS "mbedTLS")
+		ELSE()
+			MESSAGE(FATAL_ERROR "Unable to autodetect a usable HTTPS backend."
+				"Please pass the backend name explicitly (-DUSE_HTTPS=backend)")
+		ENDIF()
+	ENDIF()
+
+	# Check that we can find what's required for the selected backend
+	IF (USE_HTTPS STREQUAL "SecureTransport")
+		IF (NOT COREFOUNDATION_FOUND)
+			MESSAGE(FATAL_ERROR "Cannot use SecureTransport backend, CoreFoundation.framework not found")
+		ENDIF()
+		IF (NOT SECURITY_FOUND)
+			MESSAGE(FATAL_ERROR "Cannot use SecureTransport backend, Security.framework not found")
+		ENDIF()
+		IF (NOT SECURITY_HAS_SSLCREATECONTEXT)
+			MESSAGE(FATAL_ERROR "Cannot use SecureTransport backend, SSLCreateContext not supported")
+		ENDIF()
+
+		SET(GIT_SECURE_TRANSPORT 1)
+		LIST(APPEND LIBGIT2_SYSTEM_INCLUDES ${SECURITY_INCLUDE_DIR})
+		LIST(APPEND LIBGIT2_LIBS ${COREFOUNDATION_LDFLAGS} ${SECURITY_LDFLAGS})
+		LIST(APPEND LIBGIT2_PC_LIBS ${COREFOUNDATION_LDFLAGS} ${SECURITY_LDFLAGS})
+	ELSEIF (USE_HTTPS STREQUAL "OpenSSL")
+		IF (NOT OPENSSL_FOUND)
+			MESSAGE(FATAL_ERROR "Asked for OpenSSL TLS backend, but it wasn't found")
+		ENDIF()
+
+		SET(GIT_OPENSSL 1)
+		LIST(APPEND LIBGIT2_SYSTEM_INCLUDES ${OPENSSL_INCLUDE_DIR})
+		LIST(APPEND LIBGIT2_LIBS ${OPENSSL_LIBRARIES})
+		LIST(APPEND LIBGIT2_PC_LIBS ${OPENSSL_LDFLAGS})
+		LIST(APPEND LIBGIT2_PC_REQUIRES "openssl")
+	ELSEIF(USE_HTTPS STREQUAL "mbedTLS")
+		IF (NOT MBEDTLS_FOUND)
+			MESSAGE(FATAL_ERROR "Asked for mbedTLS backend, but it wasn't found")
+		ENDIF()
+
+		IF(NOT CERT_LOCATION)
+			MESSAGE(STATUS "Auto-detecting default certificates location")
+			IF(CMAKE_SYSTEM_NAME MATCHES Darwin)
+				# Check for an Homebrew installation
+				SET(OPENSSL_CMD "/usr/local/opt/openssl/bin/openssl")
+			ELSE()
+				SET(OPENSSL_CMD "openssl")
+			ENDIF()
+			EXECUTE_PROCESS(COMMAND ${OPENSSL_CMD} version -d OUTPUT_VARIABLE OPENSSL_DIR OUTPUT_STRIP_TRAILING_WHITESPACE)
+			IF(OPENSSL_DIR)
+				STRING(REGEX REPLACE "^OPENSSLDIR: \"(.*)\"$" "\\1/" OPENSSL_DIR ${OPENSSL_DIR})
+
+				SET(OPENSSL_CA_LOCATIONS
+					"ca-bundle.pem"             # OpenSUSE Leap 42.1
+					"cert.pem"                  # Ubuntu 14.04, FreeBSD
+					"certs/ca-certificates.crt" # Ubuntu 16.04
+					"certs/ca.pem"              # Debian 7
+				)
+				FOREACH(SUFFIX IN LISTS OPENSSL_CA_LOCATIONS)
+					SET(LOC "${OPENSSL_DIR}${SUFFIX}")
+					IF(NOT CERT_LOCATION AND EXISTS "${OPENSSL_DIR}${SUFFIX}")
+						SET(CERT_LOCATION ${LOC})
+					ENDIF()
+				ENDFOREACH()
+			ELSE()
+				MESSAGE(FATAL_ERROR "Unable to find OpenSSL executable. Please provide default certificate location via CERT_LOCATION")
+			ENDIF()
+		ENDIF()
+
+		IF(CERT_LOCATION)
+			IF(NOT EXISTS ${CERT_LOCATION})
+				MESSAGE(FATAL_ERROR "Cannot use CERT_LOCATION=${CERT_LOCATION} as it doesn't exist")
+			ENDIF()
+			ADD_FEATURE_INFO(CERT_LOCATION ON "using certificates from ${CERT_LOCATION}")
+			ADD_DEFINITIONS(-DGIT_DEFAULT_CERT_LOCATION="${CERT_LOCATION}")
+		ENDIF()
+
+		SET(GIT_MBEDTLS 1)
+		LIST(APPEND LIBGIT2_SYSTEM_INCLUDES ${MBEDTLS_INCLUDE_DIR})
+		LIST(APPEND LIBGIT2_LIBS ${MBEDTLS_LIBRARIES})
+		# mbedTLS has no pkgconfig file, hence we can't require it
+		# https://github.com/ARMmbed/mbedtls/issues/228
+		# For now, pass its link flags as our own
+		LIST(APPEND LIBGIT2_PC_LIBS ${MBEDTLS_LIBRARIES})
+	ELSEIF (USE_HTTPS STREQUAL "WinHTTP")
+		# WinHTTP setup was handled in the WinHTTP-specific block above
+	ELSE()
+		MESSAGE(FATAL_ERROR "Asked for backend ${USE_HTTPS} but it wasn't found")
+	ENDIF()
+
+	SET(GIT_HTTPS 1)
+	ADD_FEATURE_INFO(HTTPS GIT_HTTPS "using ${USE_HTTPS}")
+ELSE()
+	SET(GIT_HTTPS 0)
+	ADD_FEATURE_INFO(HTTPS NO "")
+ENDIF()