ruby-processing 2.6.3 → 2.6.4

data/samples/processing_app/topics/shaders/data/FishEye.glsl

@@ -1,59 +0,0 @@
-// Inspired by the "Angular Fisheye à la Bourke" sketch from
-// Jonathan Cremieux, as shown in the OpenProcessing website:
-// http://openprocessing.org/visuals/?visualID=12140
-// Using the inverse transform of the angular fisheye as
-// explained in Paul Bourke's website:
-// http://paulbourke.net/miscellaneous/domefisheye/fisheye/
-
-#ifdef GL_ES
-precision mediump float;
-precision mediump int;
-#endif
-
-#define PROCESSING_TEXTURE_SHADER
-
-uniform sampler2D texture;
-uniform mat4 texMatrix;
-
-varying vec4 vertColor;
-varying vec4 vertTexCoord;
-
-uniform float aperture;
-
-const float PI = 3.1415926535;
-
-void main(void) {    
-  float apertureHalf = 0.5 * aperture * (PI / 180.0);
-  
-  // This factor ajusts the coordinates in the case that
-  // the aperture angle is less than 180 degrees, in which
-  // case the area displayed is not the entire half-sphere.
-  float maxFactor = sin(apertureHalf);
-  
-  // The st factor takes into account the situation when non-pot
-  // textures are not supported, so that the maximum texture
-  // coordinate to cover the entire image might not be 1.
-  vec2 stFactor = vec2(1.0 / abs(texMatrix[0][0]), 1.0 / abs(texMatrix[1][1]));  
-  vec2 pos = (2.0 * vertTexCoord.st * stFactor - 1.0);
-  
-  float l = length(pos);
-  if (l > 1.0) {
-    gl_FragColor = vec4(0, 0, 0, 1);  
-  } else {
-    float x = maxFactor * pos.x;
-    float y = maxFactor * pos.y;
-    
-    float n = length(vec2(x, y));
-    
-    float z = sqrt(1.0 - n * n);
-  
-    float r = atan(n, z) / PI; 
-  
-    float phi = atan(y, x);
-
-    float u = r * cos(phi) + 0.5;
-    float v = r * sin(phi) + 0.5;
-
-    gl_FragColor = texture2D(texture, vec2(u, v) / stFactor) * vertColor;
-  }
-}

data/samples/processing_app/topics/shaders/data/GlossyFrag.glsl

@@ -1,44 +0,0 @@
-// Copyright (C) 2007 Dave Griffiths
-// Copyright (C) 2007 Dave Griffiths
-// Licence: GPLv2 (see COPYING)
-// Fluxus Shader Library
-// ---------------------
-// Glossy Specular Reflection Shader
-// A more controllable version of blinn shading,
-// Useful for ceramic or fluids - from Advanced 
-// Renderman, thanks to Larry Gritz
-
-#ifdef GL_ES
-precision mediump float;
-precision mediump int;
-#endif
-
-uniform vec3 AmbientColour;
-uniform vec3 DiffuseColour;
-uniform vec3 SpecularColour;
-uniform float AmbientIntensity;
-uniform float DiffuseIntensity;
-uniform float SpecularIntensity;
-uniform float Roughness;
-uniform float Sharpness;
-
-varying vec3 N;
-varying vec3 P;
-varying vec3 V;
-varying vec3 L;
-    
-void main() { 
-  float w = 0.18*(1.0-Sharpness);
-	
-  vec3 l = normalize(L);
-  vec3 n = normalize(N);
-  vec3 v = normalize(V);
-  vec3 h = normalize(l+v);
-
-  float diffuse = dot(l,n);
-  float specular = smoothstep(0.72-w,0.72+w,pow(max(0.0,dot(n,h)),1.0/Roughness));
-    
-  gl_FragColor = vec4(AmbientColour*AmbientIntensity + 
-                      DiffuseColour*diffuse*DiffuseIntensity +
-                      SpecularColour*specular*SpecularIntensity,1);
-}

data/samples/processing_app/topics/shaders/data/GlossyVert.glsl

@@ -1,33 +0,0 @@
-// Copyright (C) 2007 Dave Griffiths
-// Licence: GPLv2 (see COPYING)
-// Fluxus Shader Library
-// ---------------------
-// Glossy Specular Reflection Shader
-// A more controllable version of blinn shading,
-// Useful for ceramic or fluids - from Advanced 
-// Renderman, thanks to Larry Gritz
-
-#define PROCESSING_LIGHT_SHADER
-
-uniform mat4 modelview;
-uniform mat4 transform;
-uniform mat3 normalMatrix;
-
-uniform vec4 lightPosition[8];
-
-attribute vec4 vertex;
-attribute vec3 normal;
-
-varying vec3 N;
-varying vec3 P;
-varying vec3 V;
-varying vec3 L;
-
-void main() {    
-  N = normalize(normalMatrix * normal); 
-  P = vertex.xyz;
-  V = -vec3(modelview * vertex);
-  L = vec3(modelview * (lightPosition[0] - vertex));
-  gl_Position = transform * vertex;
-}
-

data/samples/processing_app/topics/shaders/data/ToonFrag.glsl

@@ -1,25 +0,0 @@
-#ifdef GL_ES
-precision mediump float;
-precision mediump int;
-#endif
-
-varying vec3 vertNormal;
-varying vec3 vertLightDir;
-
-void main() {  
-  float intensity;
-  vec4 color;
-  intensity = max(0.0, dot(vertLightDir, vertNormal));
-
-  if (intensity > 0.95) {
-    color = vec4(1.0, 0.5, 0.5, 1.0);
-  } else if (intensity > 0.5) {
-    color = vec4(0.6, 0.3, 0.3, 1.0);
-  } else if (intensity > 0.25) {
-    color = vec4(0.4, 0.2, 0.2, 1.0);
-  } else {
-    color = vec4(0.2, 0.1, 0.1, 1.0);
-  }
-
-  gl_FragColor = color;  
-}

data/samples/processing_app/topics/shaders/data/ToonVert.glsl

@@ -1,31 +0,0 @@
-// Toon shader using per-pixel lighting. Based on the glsl 
-// tutorial from lighthouse 3D:
-// http://www.lighthouse3d.com/tutorials/glsl-tutorial/toon-shader-version-ii/
-
-#define PROCESSING_LIGHT_SHADER
-
-uniform mat4 modelview;
-uniform mat4 transform;
-uniform mat3 normalMatrix;
-
-uniform vec3 lightNormal[8];
-
-attribute vec4 vertex;
-attribute vec3 normal;
-
-varying vec3 vertNormal;
-varying vec3 vertLightDir;
-
-void main() {
-  // Vertex in clip coordinates
-  gl_Position = transform * vertex;
-  
-  // Normal vector in eye coordinates is passed
-  // to the fragment shader
-  vertNormal = normalize(normalMatrix * normal);
-  
-  // Assuming that there is only one directional light.
-  // Its normal vector is passed to the fragment shader
-  // in order to perform per-pixel lighting calculation.  
-  vertLightDir = -lightNormal[0]; 
-}

data/samples/processing_app/topics/shaders/data/blur.glsl

@@ -1,42 +0,0 @@
-#ifdef GL_ES
-precision mediump float;
-precision mediump int;
-#endif
-
-#define PROCESSING_TEXTURE_SHADER
-
-uniform sampler2D texture;
-uniform vec2 texOffset;
-
-varying vec4 vertColor;
-varying vec4 vertTexCoord;
-
-void main(void) {
-  // Grouping texcoord variables in order to make it work in the GMA 950. See post #13
-  // in this thread:
-  // http://www.idevgames.com/forums/thread-3467.html
-  vec2 tc0 = vertTexCoord.st + vec2(-texOffset.s, -texOffset.t);
-  vec2 tc1 = vertTexCoord.st + vec2(         0.0, -texOffset.t);
-  vec2 tc2 = vertTexCoord.st + vec2(+texOffset.s, -texOffset.t);
-  vec2 tc3 = vertTexCoord.st + vec2(-texOffset.s,          0.0);
-  vec2 tc4 = vertTexCoord.st + vec2(         0.0,          0.0);
-  vec2 tc5 = vertTexCoord.st + vec2(+texOffset.s,          0.0);
-  vec2 tc6 = vertTexCoord.st + vec2(-texOffset.s, +texOffset.t);
-  vec2 tc7 = vertTexCoord.st + vec2(         0.0, +texOffset.t);
-  vec2 tc8 = vertTexCoord.st + vec2(+texOffset.s, +texOffset.t);
-
-  vec4 col0 = texture2D(texture, tc0);
-  vec4 col1 = texture2D(texture, tc1);
-  vec4 col2 = texture2D(texture, tc2);
-  vec4 col3 = texture2D(texture, tc3);
-  vec4 col4 = texture2D(texture, tc4);
-  vec4 col5 = texture2D(texture, tc5);
-  vec4 col6 = texture2D(texture, tc6);
-  vec4 col7 = texture2D(texture, tc7);
-  vec4 col8 = texture2D(texture, tc8);
-
-  vec4 sum = (1.0 * col0 + 2.0 * col1 + 1.0 * col2 +  
-              2.0 * col3 + 4.0 * col4 + 2.0 * col5 +
-              1.0 * col6 + 2.0 * col7 + 1.0 * col8) / 16.0;            
-  gl_FragColor = vec4(sum.rgb, 1.0) * vertColor;  
-}

data/samples/processing_app/topics/shaders/data/bwfrag.glsl

@@ -1,23 +0,0 @@
-#ifdef GL_ES
-precision mediump float;
-precision mediump int;
-#endif
-
-#define PROCESSING_TEXTURE_SHADER
-
-uniform sampler2D texture;
-
-varying vec4 vertColor;
-varying vec4 vertTexCoord;
-
-const vec4 lumcoeff = vec4(0.299, 0.587, 0.114, 0);
-
-void main() {
-  vec4 col = texture2D(texture, vertTexCoord.st);
-  float lum = dot(col, lumcoeff);
-  if (0.5 < lum) {
-    gl_FragColor = vertColor;
-  } else {
-    gl_FragColor = vec4(0, 0, 0, 1);
-  }     
-}

data/samples/processing_app/topics/shaders/data/conway.glsl

@@ -1,57 +0,0 @@
-// Conway's game of life
-
-#ifdef GL_ES
-precision highp float;
-#endif
-
-#define PROCESSING_COLOR_SHADER
-
-uniform float time;
-uniform vec2 mouse;
-uniform vec2 resolution;
-uniform sampler2D ppixels;
-
-vec4 live = vec4(0.5,1.0,0.7,1.);
-vec4 dead = vec4(0.,0.,0.,1.);
-vec4 blue = vec4(0.,0.,1.,1.);
-
-void main( void ) {
-	vec2 position = ( gl_FragCoord.xy / resolution.xy );
-	vec2 pixel = 1./resolution;
-
-	if (length(position-mouse) < 0.01) {
-		float rnd1 = mod(fract(sin(dot(position + time * 0.001, vec2(14.9898,78.233))) * 43758.5453), 1.0);
-		if (rnd1 > 0.5) {
-			gl_FragColor = live;
-		} else {
-			gl_FragColor = blue;
-		}
-	} else {
-		float sum = 0.;
-		sum += texture2D(ppixels, position + pixel * vec2(-1., -1.)).g;
-		sum += texture2D(ppixels, position + pixel * vec2(-1., 0.)).g;
-		sum += texture2D(ppixels, position + pixel * vec2(-1., 1.)).g;
-		sum += texture2D(ppixels, position + pixel * vec2(1., -1.)).g;
-		sum += texture2D(ppixels, position + pixel * vec2(1., 0.)).g;
-		sum += texture2D(ppixels, position + pixel * vec2(1., 1.)).g;
-		sum += texture2D(ppixels, position + pixel * vec2(0., -1.)).g;
-		sum += texture2D(ppixels, position + pixel * vec2(0., 1.)).g;
-		vec4 me = texture2D(ppixels, position);
-
-		if (me.g <= 0.1) {
-			if ((sum >= 2.9) && (sum <= 3.1)) {
-				gl_FragColor = live;
-			} else if (me.b > 0.004) {
-				gl_FragColor = vec4(0., 0., max(me.b - 0.004, 0.25), 0.);
-			} else {
-				gl_FragColor = dead;
-			}
-		} else {
-			if ((sum >= 1.9) && (sum <= 3.1)) {
-				gl_FragColor = live;
-			} else {
-				gl_FragColor = blue;
-			}
-		}
-	}
-}

data/samples/processing_app/topics/shaders/data/cubemapfrag.glsl

@@ -1 +0,0 @@
-uniform samplerCube cubemap;
  vec3 color = vec3(textureCube(cubemap, reflectDir));
  gl_FragColor = vec4(color, 1.0);      

data/samples/processing_app/topics/shaders/data/cubemapvert.glsl

@@ -1 +0,0 @@
-uniform mat4 transform;
  gl_Position = transform * vertex;
    
  vec3 ecNormal = normalize(normalMatrix * normal); // Vertex in eye coordinates
  vec3 ecVertex = vec3(modelview * vertex); // Normal vector in eye coordinates
  vec3 eyeDir = ecVertex.xyz;
  reflectDir = reflect(eyeDir, ecNormal);

data/samples/processing_app/topics/shaders/data/deform.glsl

@@ -1,31 +0,0 @@
-#ifdef GL_ES
-precision mediump float;
-precision mediump int;
-#endif
-
-#define PROCESSING_TEXTURE_SHADER
-
-uniform sampler2D texture;
-
-uniform float time;
-uniform vec2 resolution;
-uniform vec2 mouse;
-
-void main(void) {
-  vec2 p = -1.0 + 2.0 * gl_FragCoord.xy / resolution.xy;
-  vec2 m = -1.0 + 2.0 * mouse.xy / resolution.xy;
-
-  float a1 = atan(p.y - m.y, p.x - m.x);
-  float r1 = sqrt(dot(p - m, p - m));
-  float a2 = atan(p.y + m.y, p.x + m.x);
-  float r2 = sqrt(dot(p + m, p + m));
-
-  vec2 uv;
-  uv.x = 0.2 * time + (r1 - r2) * 0.25;
-  uv.y = sin(2.0 * (a1 - a2));
-
-  float w = r1 * r2 * 0.8;
-  vec3 col = texture2D(texture, 0.5 - 0.495 * uv).xyz;
-
-  gl_FragColor = vec4(col / (0.1 + w), 1.0);
-}

data/samples/processing_app/topics/shaders/data/displaceFrag.glsl

@@ -1,8 +0,0 @@
-
-uniform sampler2D colorMap;
-
-varying vec4 vertTexCoord;
-
-void main() {
-  gl_FragColor = texture2D(colorMap, vertTexCoord.st);
-}

data/samples/processing_app/topics/shaders/data/displaceVert.glsl

@@ -1,201 +0,0 @@
-
-#define PROCESSING_TEXLIGHT_SHADER
-
-uniform mat4 modelview;
-uniform mat4 transform;
-uniform mat3 normalMatrix;
-uniform mat4 texMatrix;
-
-uniform int lightCount;
-uniform vec4 lightPosition[8];
-uniform vec3 lightNormal[8];
-uniform vec3 lightAmbient[8];
-uniform vec3 lightDiffuse[8];
-uniform vec3 lightSpecular[8];
-uniform vec3 lightFalloff[8];
-uniform vec2 lightSpot[8];
-
-attribute vec4 vertex;
-attribute vec4 color;
-attribute vec3 normal;
-attribute vec2 texCoord;
-
-attribute vec4 ambient;
-attribute vec4 specular;
-attribute vec4 emissive;
-attribute float shininess;
-
-varying vec4 vertColor;
-varying vec4 vertTexCoord;
-
-const float zero_float = 0.0;
-const float one_float = 1.0;
-const vec3 zero_vec3 = vec3(0);
-
-uniform float displaceStrength;
-uniform float time;
-
-float falloffFactor(vec3 lightPos, vec3 vertPos, vec3 coeff) {
-  vec3 lpv = lightPos - vertPos;
-  vec3 dist = vec3(one_float);
-  dist.z = dot(lpv, lpv);
-  dist.y = sqrt(dist.z);
-  return one_float / dot(dist, coeff);
-}
-
-float spotFactor(vec3 lightPos, vec3 vertPos, vec3 lightNorm, float minCos, float spotExp) {
-  vec3 lpv = normalize(lightPos - vertPos);
-  vec3 nln = -one_float * lightNorm;
-  float spotCos = dot(nln, lpv);
-  return spotCos <= minCos ? zero_float : pow(spotCos, spotExp);
-}
-
-float lambertFactor(vec3 lightDir, vec3 vecNormal) {
-  return max(zero_float, dot(lightDir, vecNormal));
-}
-
-float blinnPhongFactor(vec3 lightDir, vec3 vertPos, vec3 vecNormal, float shine) {
-  vec3 np = normalize(vertPos);
-  vec3 ldp = normalize(lightDir - np);
-  return pow(max(zero_float, dot(ldp, vecNormal)), shine);
-}
-
-// Source code for GLSL Perlin noise courtesy of:
-// https://github.com/ashima/webgl-noise/wiki
-
-vec3 mod289(vec3 x) {
-  return x - floor(x * (1.0 / 289.0)) * 289.0;
-}
-
-vec2 mod289(vec2 x) {
-  return x - floor(x * (1.0 / 289.0)) * 289.0;
-}
-
-vec3 permute(vec3 x) {
-  return mod289(((x*34.0)+1.0)*x);
-}
-
-float snoise(vec2 v)
-  {
-  const vec4 C = vec4(0.211324865405187, // (3.0-sqrt(3.0))/6.0
-                      0.366025403784439, // 0.5*(sqrt(3.0)-1.0)
-                     -0.577350269189626, // -1.0 + 2.0 * C.x
-                      0.024390243902439); // 1.0 / 41.0
-// First corner
-  vec2 i = floor(v + dot(v, C.yy) );
-  vec2 x0 = v - i + dot(i, C.xx);
-
-// Other corners
-  vec2 i1;
-  //i1.x = step( x0.y, x0.x ); // x0.x > x0.y ? 1.0 : 0.0
-  //i1.y = 1.0 - i1.x;
-  i1 = (x0.x > x0.y) ? vec2(1.0, 0.0) : vec2(0.0, 1.0);
-  // x0 = x0 - 0.0 + 0.0 * C.xx ;
-  // x1 = x0 - i1 + 1.0 * C.xx ;
-  // x2 = x0 - 1.0 + 2.0 * C.xx ;
-  vec4 x12 = x0.xyxy + C.xxzz;
-  x12.xy -= i1;
-
-// Permutations
-  i = mod289(i); // Avoid truncation effects in permutation
-  vec3 p = permute( permute( i.y + vec3(0.0, i1.y, 1.0 ))
-+ i.x + vec3(0.0, i1.x, 1.0 ));
-
-  vec3 m = max(0.5 - vec3(dot(x0,x0), dot(x12.xy,x12.xy), dot(x12.zw,x12.zw)), 0.0);
-  m = m*m ;
-  m = m*m ;
-
-// Gradients: 41 points uniformly over a line, mapped onto a diamond.
-// The ring size 17*17 = 289 is close to a multiple of 41 (41*7 = 287)
-
-  vec3 x = 2.0 * fract(p * C.www) - 1.0;
-  vec3 h = abs(x) - 0.5;
-  vec3 ox = floor(x + 0.5);
-  vec3 a0 = x - ox;
-
-// Normalise gradients implicitly by scaling m
-// Approximation of: m *= inversesqrt( a0*a0 + h*h );
-  m *= 1.79284291400159 - 0.85373472095314 * ( a0*a0 + h*h );
-
-// Compute final noise value at P
-  vec3 g;
-  g.x = a0.x * x0.x + h.x * x0.y;
-  g.yz = a0.yz * x12.xz + h.yz * x12.yw;
-  return 130.0 * dot(m, g);
-}
-
-void main() {
-  // Calculating texture coordinates, with r and q set both to one
-  vertTexCoord = texMatrix * vec4(texCoord, 1.0, 1.0);
-
-  vec2 p = texCoord; // put coordinates into vec2 p for convenience
-  p.x += time; // add time to make the noise and the subsequent displacement move
-  float df = snoise( p ); // create displacement float value from shader-based 2D Perlin noise
-  vec4 newVertexPos = vertex + vec4(normal * df * displaceStrength, 0.0); // regular vertex position + direction * displacementMap * displaceStrength
-
-  // Vertex in clip coordinates
-  gl_Position = transform * newVertexPos;
-    
-  // Vertex in eye coordinates
-  vec3 ecVertex = vec3(modelview * vertex);
-  
-  // Normal vector in eye coordinates
-  vec3 ecNormal = normalize(normalMatrix * normal);
-  
-  if (dot(-one_float * ecVertex, ecNormal) < zero_float) {
-    // If normal is away from camera, choose its opposite.
-    // If we add backface culling, this will be backfacing
-    ecNormal *= -one_float;
-  }
-
-  // Light calculations
-  vec3 totalAmbient = vec3(0, 0, 0);
-  vec3 totalDiffuse = vec3(0, 0, 0);
-  vec3 totalSpecular = vec3(0, 0, 0);
-  for (int i = 0; i < 8; i++) {
-    if (lightCount == i) break;
-    
-    vec3 lightPos = lightPosition[i].xyz;
-    bool isDir = zero_float < lightPosition[i].w;
-    float spotCos = lightSpot[i].x;
-    float spotExp = lightSpot[i].y;
-    
-    vec3 lightDir;
-    float falloff;
-    float spotf;
-      
-    if (isDir) {
-      falloff = one_float;
-      lightDir = -one_float * lightNormal[i];
-    } else {
-      falloff = falloffFactor(lightPos, ecVertex, lightFalloff[i]);
-      lightDir = normalize(lightPos - ecVertex);
-    }
-  
-    spotf = spotExp > zero_float ? spotFactor(lightPos, ecVertex, lightNormal[i],
-                                              spotCos, spotExp)
-                                 : one_float;
-    
-    if (any(greaterThan(lightAmbient[i], zero_vec3))) {
-      totalAmbient += lightAmbient[i] * falloff;
-    }
-    
-    if (any(greaterThan(lightDiffuse[i], zero_vec3))) {
-      totalDiffuse += lightDiffuse[i] * falloff * spotf *
-                       lambertFactor(lightDir, ecNormal);
-    }
-    
-    if (any(greaterThan(lightSpecular[i], zero_vec3))) {
-      totalSpecular += lightSpecular[i] * falloff * spotf *
-                       blinnPhongFactor(lightDir, ecVertex, ecNormal, shininess);
-    }
-  }
-  
-  // Calculating final color as result of all lights (plus emissive term).
-  // Transparency is determined exclusively by the diffuse component.
-  vertColor = vec4(totalAmbient, 0) * ambient +
-              vec4(totalDiffuse, 1) * color +
-              vec4(totalSpecular, 0) * specular +
-              vec4(emissive.rgb, 0);
-              
-}