rocket-js 0.0.2 → 0.0.3

data/src/vendor/web-socket-js/flash-src/com/hurlant/crypto/hash/SHA256.as

@@ -1,115 +0,0 @@
-/**
- * SHA256
- * 
- * An ActionScript 3 implementation of Secure Hash Algorithm, SHA-256, as defined
- * in FIPS PUB 180-2
- * Copyright (c) 2007 Henri Torgemane
- * 
- * Derived from:
- * 		A JavaScript implementation of the Secure Hash Standard
- * 		Version 0.3 Copyright Angel Marin 2003-2004 - http://anmar.eu.org/
- * Derived from:
- * 		A JavaScript implementation of the Secure Hash Algorithm, SHA-1, as defined
- * 		in FIPS PUB 180-1
- * 		Version 2.1a Copyright Paul Johnston 2000 - 2002.
- * 		Other contributors: Greg Holt, Andrew Kepert, Ydnar, Lostinet
- * 
- * See LICENSE.txt for full license information.
- */
-package com.hurlant.crypto.hash
-{
-	
-
-	public class SHA256 extends SHABase implements IHash
-	{
-		
-		protected static const k:Array = [
-		0x428a2f98, 0x71374491, 0xb5c0fbcf, 0xe9b5dba5, 0x3956c25b, 0x59f111f1, 0x923f82a4, 0xab1c5ed5,
-		0xd807aa98, 0x12835b01, 0x243185be, 0x550c7dc3, 0x72be5d74, 0x80deb1fe, 0x9bdc06a7, 0xc19bf174,
-		0xe49b69c1, 0xefbe4786, 0x0fc19dc6, 0x240ca1cc, 0x2de92c6f, 0x4a7484aa, 0x5cb0a9dc, 0x76f988da,
-		0x983e5152, 0xa831c66d, 0xb00327c8, 0xbf597fc7, 0xc6e00bf3, 0xd5a79147, 0x06ca6351, 0x14292967,
-		0x27b70a85, 0x2e1b2138, 0x4d2c6dfc, 0x53380d13, 0x650a7354, 0x766a0abb, 0x81c2c92e, 0x92722c85,
-		0xa2bfe8a1, 0xa81a664b, 0xc24b8b70, 0xc76c51a3, 0xd192e819, 0xd6990624, 0xf40e3585, 0x106aa070,
-		0x19a4c116, 0x1e376c08, 0x2748774c, 0x34b0bcb5, 0x391c0cb3, 0x4ed8aa4a, 0x5b9cca4f, 0x682e6ff3,
-		0x748f82ee, 0x78a5636f, 0x84c87814, 0x8cc70208, 0x90befffa, 0xa4506ceb, 0xbef9a3f7, 0xc67178f2];
-		protected var h:Array = [
-		0x6a09e667, 0xbb67ae85, 0x3c6ef372, 0xa54ff53a, 0x510e527f, 0x9b05688c, 0x1f83d9ab, 0x5be0cd19
-		];
-		
-		public function SHA256(){
-		}
-		
-		public override function getHashSize():uint
-		{
-			return 32;
-		}
-		
-		protected override function core(x:Array, len:uint):Array {
-			/* append padding */
-			x[len >> 5] |= 0x80 << (24 - len % 32);
-			x[((len + 64 >> 9) << 4) + 15] = len;
-		
-			var w:Array = [];
-			var a:uint = h[0];
-			var b:uint = h[1];
-			var c:uint = h[2];
-			var d:uint = h[3];
-			var e:uint = h[4];
-			var f:uint = h[5];
-			var g:uint = h[6];
-			var h:uint = h[7];
-			
-			for (var i:uint=0; i<x.length; i+=16) {
-				var olda:uint = a;
-				var oldb:uint = b;
-				var oldc:uint = c;
-				var oldd:uint = d;
-				var olde:uint = e;
-				var oldf:uint = f;
-				var oldg:uint = g;
-				var oldh:uint = h;
-
-				for (var j:uint=0; j<64; j++) {
-					if (j<16) {
-						w[j] = x[i+j] || 0;
-					} else {
-						var s0:uint = rrol(w[j-15],7)^rrol(w[j-15],18)^(w[j-15]>>>3);
-						var s1:uint = rrol(w[j-2], 17)^rrol(w[j-2],19)^(w[j-2]>>>10);
-						w[j] = w[j-16] + s0 + w[j-7] + s1;
-					}
-					var t2:uint = (rrol(a,2) ^ rrol(a,13) ^ rrol(a,22)) + ((a&b) ^ (a&c) ^ (b&c));
-					var t1:uint = h + (rrol(e,6) ^ rrol(e,11) ^ rrol(e,25)) + ((e&f)^(g&~e)) + k[j] + w[j]
-					h = g;
-					g = f;
-					f = e;
-					e = d + t1;
-					d = c;
-					c = b;
-					b = a;
-					a = t1 + t2;
-
-				}
-				a += olda;
-				b += oldb;
-				c += oldc;
-				d += oldd;
-				e += olde;
-				f += oldf;
-				g += oldg;
-				h += oldh;
-			}
-			return [ a,b,c,d,e,f,g,h ];
-		}
-		
-		/*
-		 * Bitwise rotate a 32-bit number to the right.
-		 */
-		protected function rrol(num:uint, cnt:uint):uint {
-		  return (num << (32-cnt)) | (num >>> cnt);
-		}
-		
-		public override function toString():String {
-			return "sha256";
-		}
-	}
-}

data/src/vendor/web-socket-js/flash-src/com/hurlant/crypto/hash/SHABase.as

@@ -1,71 +0,0 @@
-/**
- * SHABase
- * 
- * An ActionScript 3 abstract class for the SHA family of hash functions
- * Copyright (c) 2007 Henri Torgemane
- * 
- * See LICENSE.txt for full license information.
- */
-package com.hurlant.crypto.hash
-{
-	import flash.utils.ByteArray;
-	import flash.utils.Endian;
-
-	public class SHABase implements IHash
-	{
-
-        public function SHABase() { }
-
-		public var pad_size:int = 40;
-		public function getInputSize():uint
-		{
-			return 64;
-		}
-		
-		public function getHashSize():uint
-		{
-			return 0;
-		}
-		
-		public function getPadSize():int 
-		{
-			return pad_size;
-		}
-		
-		public function hash(src:ByteArray):ByteArray
-		{
-			var savedLength:uint = src.length;
-			var savedEndian:String = src.endian;
-			
-			src.endian = Endian.BIG_ENDIAN;
-			var len:uint = savedLength *8;
-			// pad to nearest int.
-			while (src.length%4!=0) {
-				src[src.length]=0;
-			}
-			// convert ByteArray to an array of uint
-			src.position=0;
-			var a:Array = [];
-			for (var i:uint=0;i<src.length;i+=4) {
-				a.push(src.readUnsignedInt());
-			}
-			var h:Array = core(a, len);
-			var out:ByteArray = new ByteArray;
-			var words:uint = getHashSize()/4;
-			for (i=0;i<words;i++) {
-				out.writeUnsignedInt(h[i]);
-			}
-			// unpad, to leave the source untouched.
-			src.length = savedLength;
-			src.endian = savedEndian;
-			return out;
-		}
-		protected function core(x:Array, len:uint):Array {
-			return null;
-		}
-		
-		public function toString():String {
-			return "sha";
-		}
-	}
-}

data/src/vendor/web-socket-js/flash-src/com/hurlant/crypto/prng/ARC4.as

@@ -1,90 +0,0 @@
-/**
- * ARC4
- * 
- * An ActionScript 3 implementation of RC4
- * Copyright (c) 2007 Henri Torgemane
- * 
- * Derived from:
- * 		The jsbn library, Copyright (c) 2003-2005 Tom Wu
- * 
- * See LICENSE.txt for full license information.
- */
-package com.hurlant.crypto.prng
-{
-	import com.hurlant.crypto.symmetric.IStreamCipher;
-	import com.hurlant.util.Memory;
-	
-	import flash.utils.ByteArray;
-
-	public class ARC4 implements IPRNG, IStreamCipher {
-		private var i:int = 0;
-		private var j:int = 0;
-		private var S:ByteArray;
-		private const psize:uint = 256;
-		public function ARC4(key:ByteArray = null){
-			S = new ByteArray;
-			if (key) {
-				init(key);
-			}
-		}
-		public function getPoolSize():uint {
-			return psize;
-		}
-		public function init(key:ByteArray):void {
-			var i:int;
-			var j:int;
-			var t:int;
-			for (i=0; i<256; ++i) {
-				S[i] = i;
-			}
-			j=0;
-			for (i=0; i<256; ++i) {
-				j = (j + S[i] + key[i%key.length]) & 255;
-				t = S[i];
-				S[i] = S[j];
-				S[j] = t;
-			}
-			this.i=0;
-			this.j=0;
-		}
-		public function next():uint {
-			var t:int;
-			i = (i+1)&255;
-			j = (j+S[i])&255;
-			t = S[i];
-			S[i] = S[j];
-			S[j] = t;
-			return S[(t+S[i])&255];
-		}
-
-		public function getBlockSize():uint {
-			return 1;
-		}
-		
-		public function encrypt(block:ByteArray):void {
-			var i:uint = 0;
-			while (i<block.length) {
-				block[i++] ^= next();
-			}
-		}
-		public function decrypt(block:ByteArray):void {
-			encrypt(block); // the beauty of XOR.
-		}
-		public function dispose():void {
-			var i:uint = 0;
-			if (S!=null) {
-				for (i=0;i<S.length;i++) {
-					S[i] = Math.random()*256;
-				}
-				S.length=0;
-				S = null;
-			}
-			this.i = 0;
-			this.j = 0;
-			Memory.gc();
-		}
-		public function toString():String {
-			return "rc4";
-		}
-	}
-}

data/src/vendor/web-socket-js/flash-src/com/hurlant/crypto/prng/IPRNG.as

@@ -1,20 +0,0 @@
-/**
- * IPRNG
- * 
- * An interface for classes that can be used a pseudo-random number generators
- * Copyright (c) 2007 Henri Torgemane
- * 
- * See LICENSE.txt for full license information.
- */
-package com.hurlant.crypto.prng
-{
-	import flash.utils.ByteArray;
-		
-	public interface IPRNG {
-		function getPoolSize():uint;
-		function init(key:ByteArray):void;
-		function next():uint;
-		function dispose():void;
-		function toString():String;
-	}
-}

data/src/vendor/web-socket-js/flash-src/com/hurlant/crypto/prng/Random.as

@@ -1,119 +0,0 @@
-/**
- * Random
- * 
- * An ActionScript 3 implementation of a Random Number Generator
- * Copyright (c) 2007 Henri Torgemane
- * 
- * Derived from:
- * 		The jsbn library, Copyright (c) 2003-2005 Tom Wu
- * 
- * See LICENSE.txt for full license information.
- */
-package com.hurlant.crypto.prng
-{
-	import flash.utils.ByteArray;
-	import com.hurlant.util.Memory;
-	import flash.system.System;
-	import flash.system.Capabilities;
-	import flash.accessibility.AccessibilityProperties;
-	import flash.display.SWFVersion;
-	import flash.display.Stage;
-	import flash.utils.getTimer;
-	import flash.text.Font;
-	
-	public class Random
-	{
-		private var state:IPRNG;
-		private var ready:Boolean = false;
-		private var pool:ByteArray;
-		private var psize:int;
-		private var pptr:int;
-		private var seeded:Boolean = false;
-		
-		public function Random(prng:Class = null) {
-			if (prng==null) prng = ARC4;
-			state = new prng as IPRNG;
-			psize= state.getPoolSize();
-			pool = new ByteArray;
-			pptr = 0;
-			while (pptr <psize) {
-				var t:uint = 65536*Math.random();
-				pool[pptr++] = t >>> 8;
-				pool[pptr++] = t&255;
-			}
-			pptr=0;
-			seed();
-		}
-		
-		public function seed(x:int = 0):void {
-			if (x==0) {
-				x = new Date().getTime();
-			}
-			pool[pptr++] ^= x & 255;
-			pool[pptr++] ^= (x>>8)&255;
-			pool[pptr++] ^= (x>>16)&255;
-			pool[pptr++] ^= (x>>24)&255;
-			pptr %= psize;
-			seeded = true;
-		}
-		
-		/**
-		 * Gather anything we have that isn't entirely predictable:
-		 *  - memory used
-		 *  - system capabilities
-		 *  - timing stuff
-		 *  - installed fonts
-		 */
-		public function autoSeed():void {
-			var b:ByteArray = new ByteArray;
-			b.writeUnsignedInt(System.totalMemory);
-			b.writeUTF(Capabilities.serverString);
-			b.writeUnsignedInt(getTimer());
-			b.writeUnsignedInt((new Date).getTime());
-			var a:Array = Font.enumerateFonts(true);
-			for each (var f:Font in a) {
-				b.writeUTF(f.fontName);
-				b.writeUTF(f.fontStyle);
-				b.writeUTF(f.fontType);
-			}
-			b.position=0;
-			while (b.bytesAvailable>=4) {
-				seed(b.readUnsignedInt());
-			}
-		}
-		
-		
-		public function nextBytes(buffer:ByteArray, length:int):void {
-			while (length--) {
-				buffer.writeByte(nextByte());
-			}
-		}
-		public function nextByte():int {
-			if (!ready) {
-				if (!seeded) {
-					autoSeed();
-				}
-				state.init(pool);
-				pool.length = 0;
-				pptr = 0;
-				ready = true;
-			}
-			return state.next();
-		}
-		public function dispose():void {
-			for (var i:uint=0;i<pool.length;i++) {
-				pool[i] = Math.random()*256;
-			}
-			pool.length=0;
-			pool = null;
-			state.dispose();
-			state = null;
-			psize = 0;
-			pptr = 0;
-			Memory.gc();
-		}
-		public function toString():String {
-			return "random-"+state.toString();
-		}
-	}
-}

data/src/vendor/web-socket-js/flash-src/com/hurlant/crypto/prng/TLSPRF.as

@@ -1,142 +0,0 @@
-/**
- * TLSPRF
- * 
- * An ActionScript 3 implementation of a pseudo-random generator
- * that follows the TLS specification
- * Copyright (c) 2007 Henri Torgemane
- * 
- * See LICENSE.txt for full license information.
- */
-package com.hurlant.crypto.prng
-{
-	import flash.utils.ByteArray;
-	import com.hurlant.crypto.hash.HMAC;
-	import com.hurlant.crypto.hash.MD5;
-	import com.hurlant.crypto.hash.SHA1;
-	import com.hurlant.util.Memory;
-	import com.hurlant.util.Hex;
-	import flash.utils.IDataOutput;
-
-	/**
-	 * There's "Random", and then there's TLS Random.
-	 * .
-	 * Still Pseudo-random, though.
-	 */
-	public class TLSPRF
-	{
-		// XXX WAY TOO MANY STRUCTURES HERE
-		
-		// seed
-		private var seed:ByteArray;
-		// P_MD5's secret
-		private var s1:ByteArray;
-		// P_SHA-1's secret
-		private var s2:ByteArray;
-		// HMAC_MD5's A
-		private var a1:ByteArray;
-		// HMAC_SHA1's A
-		private var a2:ByteArray;
-		// Pool for P_MD5
-		private var p1:ByteArray;
-		// Pool for P_SHA1
-		private var p2:ByteArray;
-		// Data for HMAC_MD5
-		private var d1:ByteArray;
-		// Data for HMAC_SHA1
-		private var d2:ByteArray;
-		
-		
-		private var hmac_md5:HMAC;
-		private var hmac_sha1:HMAC;
-		
-		public function TLSPRF(secret:ByteArray, label:String, seed:ByteArray) {
-			var l:int = Math.ceil(secret.length/2);
-			var s1:ByteArray = new ByteArray;
-			var s2:ByteArray = new ByteArray;
-			s1.writeBytes(secret, 0, l);
-			s2.writeBytes(secret, secret.length-l, l);
-			var s:ByteArray = new ByteArray;
-			s.writeUTFBytes(label);
-			s.writeBytes(seed);
-			this.seed = s;
-			this.s1 = s1;
-			this.s2 = s2;
-			hmac_md5 = new HMAC(new MD5);
-			hmac_sha1 = new HMAC(new SHA1);
-			
-			this.a1 = hmac_md5.compute(s1, this.seed);
-			this.a2 = hmac_sha1.compute(s2, this.seed);
-			
-			p1 = new ByteArray;
-			p2 = new ByteArray;
-			
-			d1 = new ByteArray;
-			d2 = new ByteArray;
-			d1.position = MD5.HASH_SIZE;
-			d1.writeBytes(this.seed);
-			d2.position = SHA1.HASH_SIZE;
-			d2.writeBytes(this.seed);
-		}
-		
-		// XXX HORRIBLY SLOW. REWRITE.
-		public function nextBytes(buffer:IDataOutput, length:int):void {
-			while (length--) {
-				buffer.writeByte(nextByte());
-			}
-		}
-		public function nextByte():int {
-			if (p1.bytesAvailable==0) {
-				more_md5();
-			}
-			if (p2.bytesAvailable==0) {
-				more_sha1();
-			}
-			return p1.readUnsignedByte()^p2.readUnsignedByte();
-		}
-		public function dispose():void {
-			seed = dba(seed);
-			s1 = dba(s1);
-			s2 = dba(s2);
-			a1 = dba(a1);
-			a2 = dba(a2);
-			p1 = dba(p1);
-			p2 = dba(p2);
-			d1 = dba(d1);
-			d2 = dba(d2);
-			hmac_md5.dispose();
-			hmac_md5 = null;
-			hmac_sha1.dispose();
-			hmac_sha1 = null;
-			Memory.gc();
-		}
-		public function toString():String {
-			return "tls-prf";
-		}
-		private function dba(ba:ByteArray):ByteArray {
-			for (var i:uint=0;i<ba.length;i++) {
-				ba[i]=0;
-			}
-			ba.length=0;
-			return null;
-		}
-		private function more_md5():void {
-			d1.position=0;
-			d1.writeBytes(a1);
-			var p:int = p1.position;
-			var more:ByteArray = hmac_md5.compute(s1, d1);
-			a1 = hmac_md5.compute(s1, a1);
-			p1.writeBytes(more);
-			p1.position=p;
-		}
-		private function more_sha1():void {
-			d2.position=0;
-			d2.writeBytes(a2);
-			var p:int = p2.position;
-			var more:ByteArray = hmac_sha1.compute(s2, d2);
-			a2 = hmac_sha1.compute(s2, a2);
-			p2.writeBytes(more);
-			p2.position=p;
-		}
-		
-	}
-}