rocket-js 0.0.1 → 0.0.2

data/src/vendor/web-socket-js/flash-src/com/hurlant/util/der/PEM.as

@@ -0,0 +1,118 @@
+/**
+ * PEM
+ * 
+ * A class to parse some PEM stuff.
+ * Copyright (c) 2007 Henri Torgemane
+ * 
+ * See LICENSE.txt for full license information.
+ */
+package com.hurlant.util.der
+{
+	import com.hurlant.crypto.rsa.RSAKey;
+	import com.hurlant.math.BigInteger;
+	import com.hurlant.util.Base64;
+	
+	import flash.utils.ByteArray;
+	import com.hurlant.util.Hex;
+	
+	public class PEM
+	{
+		private static const RSA_PRIVATE_KEY_HEADER:String = "-----BEGIN RSA PRIVATE KEY-----";
+		private static const RSA_PRIVATE_KEY_FOOTER:String = "-----END RSA PRIVATE KEY-----";
+		private static const RSA_PUBLIC_KEY_HEADER:String = "-----BEGIN PUBLIC KEY-----";
+		private static const RSA_PUBLIC_KEY_FOOTER:String = "-----END PUBLIC KEY-----";
+		private static const CERTIFICATE_HEADER:String = "-----BEGIN CERTIFICATE-----";
+		private static const CERTIFICATE_FOOTER:String = "-----END CERTIFICATE-----";
+		
+		
+		
+		/**
+		 * 
+		 * Read a structure encoded according to
+		 * ftp://ftp.rsasecurity.com/pub/pkcs/ascii/pkcs-1v2.asc
+		 * section 11.1.2
+		 * 
+		 * @param str
+		 * @return 
+		 * 
+		 */
+		public static function readRSAPrivateKey(str:String):RSAKey {
+			var der:ByteArray = extractBinary(RSA_PRIVATE_KEY_HEADER, RSA_PRIVATE_KEY_FOOTER, str);
+			if (der==null) return null;
+			var obj:* = DER.parse(der);
+			if (obj is Array) {
+				var arr:Array = obj as Array;
+				// arr[0] is Version. should be 0. should be checked. shoulda woulda coulda.
+				return new RSAKey(
+					arr[1],				// N
+					arr[2].valueOf(),	// E
+					arr[3],				// D
+					arr[4],				// P
+					arr[5],				// Q
+					arr[6],				// DMP1
+					arr[7],				// DMQ1	
+					arr[8]);			// IQMP
+			} else {
+				// dunno
+				return null;
+			}
+		}
+		
+		
+		/**
+		 * Read a structure encoded according to some spec somewhere
+		 * Also, follows some chunk from
+		 * ftp://ftp.rsasecurity.com/pub/pkcs/ascii/pkcs-1v2.asc
+		 * section 11.1
+		 * 
+		 * @param str
+		 * @return 
+		 * 
+		 */
+		public static function readRSAPublicKey(str:String):RSAKey {
+			var der:ByteArray = extractBinary(RSA_PUBLIC_KEY_HEADER, RSA_PUBLIC_KEY_FOOTER, str);
+			if (der==null) return null;
+			var obj:* = DER.parse(der);
+			if (obj is Array) {
+				var arr:Array = obj as Array;
+				// arr[0] = [ <some crap that means "rsaEncryption">, null ]; ( apparently, that's an X-509 Algorithm Identifier.
+				if (arr[0][0].toString()!=OID.RSA_ENCRYPTION) {
+					return null;
+				}
+				// arr[1] is a ByteArray begging to be parsed as DER
+				arr[1].position = 1; // there's a 0x00 byte up front. find out why later. like, read a spec.
+				obj = DER.parse(arr[1]);
+				if (obj is Array) {
+					arr = obj as Array;
+					// arr[0] = modulus
+					// arr[1] = public expt.
+					return new RSAKey(arr[0], arr[1]);
+				} else {
+					return null;
+				}
+			} else {
+				// dunno
+				return null;
+			}
+		}
+
+		public static function readCertIntoArray(str:String):ByteArray {
+			var tmp:ByteArray = extractBinary(CERTIFICATE_HEADER, CERTIFICATE_FOOTER, str);
+			return tmp;
+		}
+		
+		private static function extractBinary(header:String, footer:String, str:String):ByteArray {
+			var i:int = str.indexOf(header);
+			if (i==-1) return null;
+			i += header.length;
+			var j:int = str.indexOf(footer);
+			if (j==-1) return null;
+			var b64:String = str.substring(i, j);
+			// remove whitesapces.
+			b64 = b64.replace(/\s/mg, '');
+			// decode
+			return Base64.decodeToByteArray(b64);
+		}
+		
+	}
+}

data/src/vendor/web-socket-js/flash-src/com/hurlant/util/der/PrintableString.as

@@ -0,0 +1,49 @@
+/**
+ * PrintableString
+ * 
+ * An ASN1 type for a PrintableString, held within a String
+ * Copyright (c) 2007 Henri Torgemane
+ * 
+ * See LICENSE.txt for full license information.
+ */
+package com.hurlant.util.der
+{
+	import flash.utils.ByteArray;
+	
+	public class PrintableString implements IAsn1Type
+	{
+		protected var type:uint;
+		protected var len:uint;
+		protected var str:String;
+		
+		public function PrintableString(type:uint, length:uint) {
+			this.type = type;
+			this.len = length;
+		}
+		
+		public function getLength():uint
+		{
+			return len;
+		}
+		
+		public function getType():uint
+		{
+			return type;
+		}
+		
+		public function setString(s:String):void {
+			str = s;
+		}
+		public function getString():String {
+			return str;
+		}
+		
+		public function toString():String {
+			return DER.indent+str;
+		}
+		
+		public function toDER():ByteArray {
+			return null; // XXX not implemented
+		}
+	}
+}

data/src/vendor/web-socket-js/flash-src/com/hurlant/util/der/Sequence.as

@@ -0,0 +1,90 @@
+/**
+ * Sequence
+ * 
+ * An ASN1 type for a Sequence, implemented as an Array
+ * Copyright (c) 2007 Henri Torgemane
+ * 
+ * See LICENSE.txt for full license information.
+ */
+package com.hurlant.util.der
+{
+	import flash.utils.ByteArray;
+	
+	public dynamic class Sequence extends Array implements IAsn1Type
+	{
+		protected var type:uint;
+		protected var len:uint;
+		
+		public function Sequence(type:uint = 0x30, length:uint = 0x00) {
+			this.type = type;
+			this.len = length;
+		}
+		
+		public function getLength():uint
+		{
+			return len;
+		}
+		
+		public function getType():uint
+		{
+			return type;
+		}
+
+		public function toDER():ByteArray {
+			var tmp:ByteArray = new ByteArray;
+			for (var i:int=0;i<length;i++) {
+				var e:IAsn1Type = this[i];
+				if (e == null) { // XXX Arguably, I could have a der.Null class instead
+					tmp.writeByte(0x05);
+					tmp.writeByte(0x00);
+				} else {
+					tmp.writeBytes(e.toDER());
+				}
+			}
+			return DER.wrapDER(type, tmp);
+		}
+		
+		public function toString():String {
+			var s:String = DER.indent;
+			DER.indent += "    ";
+			var t:String = "";
+			for (var i:int=0;i<length;i++) {
+				if (this[i]==null) continue;
+				var found:Boolean = false;
+				for (var key:String in this) {
+					if ( (i.toString()!=key) && this[i]==this[key]) {
+						t += key+": "+this[i]+"\n";
+						found = true;
+						break;
+					}
+				}
+				if (!found) t+=this[i]+"\n";
+			}
+//			var t:String = join("\n");
+			DER.indent= s;
+			return DER.indent+"Sequence["+type+"]["+len+"][\n"+t+"\n"+s+"]";
+		}
+		
+		/////////
+		
+		public function findAttributeValue(oid:String):IAsn1Type {
+			for each (var set:* in this) {
+				if (set is Set) {
+					var child:* = set[0];
+					if (child is Sequence) {
+						var tmp:* = child[0];
+						if (tmp is ObjectIdentifier) {
+							var id:ObjectIdentifier = tmp as ObjectIdentifier;
+							if (id.toString()==oid) {
+								return child[1] as IAsn1Type;
+							}
+						}
+					}
+				}
+			}
+			return null;
+		}
+		
+		
+	}
+}

data/src/vendor/web-socket-js/flash-src/com/hurlant/util/der/Set.as

@@ -0,0 +1,27 @@
+/**
+ * Set
+ * 
+ * An ASN1 type for an Set, that extends a Sequence
+ * Copyright (c) 2007 Henri Torgemane
+ * 
+ * See LICENSE.txt for full license information.
+ */
+package com.hurlant.util.der
+{
+	public dynamic class Set extends Sequence implements IAsn1Type
+	{
+		public function Set(type:uint = 0x31, length:uint = 0x00) {
+			super(type, length);
+		}
+
+
+		public override function toString():String {
+			var s:String = DER.indent;
+			DER.indent += "    ";
+			var t:String = join("\n");
+			DER.indent= s;
+			return DER.indent+"Set["+type+"]["+len+"][\n"+t+"\n"+s+"]";
+		}
+		
+	}
+}

data/src/vendor/web-socket-js/flash-src/com/hurlant/util/der/Type.as

@@ -0,0 +1,94 @@
+/**
+ * Type
+ * 
+ * A few Asn-1 structures
+ * Copyright (c) 2007 Henri Torgemane
+ * 
+ * See LICENSE.txt for full license information.
+ */
+package com.hurlant.util.der
+{
+	import com.hurlant.util.Hex;
+	
+	public class Type
+	{
+		public static const TLS_CERT:Array = [ 
+			{name:"signedCertificate", extract:true, value: [
+				{name:"versionHolder", optional:true, value: [
+					{name:"version"}
+				], defaultValue: function():Sequence{ 
+						var s:Sequence = new Sequence(0, 0); 
+						var v:Integer = new Integer(2,1, Hex.toArray("00"));
+						s.push(v);
+						s.version = v;
+						return s;
+					}()
+				},
+				{name:"serialNumber"},
+				{name:"signature", value: [
+					{name:"algorithmId"}
+				]},
+				{name:"issuer", extract:true, value: [ 
+					{name:"type"},
+					{name:"value"}
+				]},
+				{name:"validity", value: [
+					{name:"notBefore"},
+					{name:"notAfter"}
+				]},
+				{name:"subject", extract:true, value: [
+				]},
+				{name:"subjectPublicKeyInfo", value: [
+					{name:"algorithm", value: [
+						{name:"algorithmId"}
+					]},
+					{name:"subjectPublicKey"}
+				]},
+				{name:"extensions", value: [
+				]}
+			]}, 
+			{name:"algorithmIdentifier",value:[
+				{name:"algorithmId"}
+			]}, 
+			{name:"encrypted", value:null}
+		];
+		public static const CERTIFICATE:Array = [
+			{name:"tbsCertificate", value:[
+				{name:"tag0", value:[
+					{name:"version"}
+				]},
+				{name:"serialNumber"},
+				{name:"signature"},
+				{name:"issuer", value:[
+					{name:"type"},
+					{name:"value"}
+				]},
+				{name:"validity", value:[
+					{name:"notBefore"},
+					{name:"notAfter"}
+				]},
+				{name:"subject"},
+				{name:"subjectPublicKeyInfo", value:[
+					{name:"algorithm"},
+					{name:"subjectPublicKey"}
+				]},
+				{name:"issuerUniqueID"},
+				{name:"subjectUniqueID"},
+				{name:"extensions"}
+			]},
+			{name:"signatureAlgorithm"},
+			{name:"signatureValue"}
+		];
+		public static const RSA_PUBLIC_KEY:Array = [
+			{name:"modulus"},
+			{name:"publicExponent"}
+		];
+		public static const RSA_SIGNATURE:Array = [
+			{name:"algorithm", value:[
+				{name:"algorithmId"}
+			 ]},
+			{name:"hash"}
+		];
+		
+	}
+}

data/src/vendor/web-socket-js/flash-src/com/hurlant/util/der/UTCTime.as

@@ -0,0 +1,60 @@
+/**
+ * UTCTime
+ * 
+ * An ASN1 type for UTCTime, represented as a Date
+ * Copyright (c) 2007 Henri Torgemane
+ * 
+ * See LICENSE.txt for full license information.
+ */
+package com.hurlant.util.der
+{
+	import flash.utils.ByteArray;
+	
+	public class UTCTime implements IAsn1Type
+	{
+		protected var type:uint;
+		protected var len:uint;
+		public var date:Date;
+		
+		public function UTCTime(type:uint, len:uint)
+		{
+			this.type = type;
+			this.len = len;
+		}
+		
+		public function getLength():uint
+		{
+			return len;
+		}
+		
+		public function getType():uint
+		{
+			return type;
+		}
+		
+		public function setUTCTime(str:String):void {
+			
+			var year:uint = parseInt(str.substr(0, 2));
+			if (year<50) {
+				year+=2000;
+			} else {
+				year+=1900;
+			}
+			var month:uint = parseInt(str.substr(2,2));
+			var day:uint = parseInt(str.substr(4,2));
+			var hour:uint = parseInt(str.substr(6,2));
+			var minute:uint = parseInt(str.substr(8,2));
+			// XXX this could be off by up to a day. parse the rest. someday.
+			date = new Date(year, month-1, day, hour, minute);
+		}
+		
+		
+		public function toString():String {
+			return DER.indent+"UTCTime["+type+"]["+len+"]["+date+"]";
+		}
+		
+		public function toDER():ByteArray {
+			return null // XXX not implemented
+		}
+	}
+}

data/src/vendor/web-socket-js/sample.html

@@ -0,0 +1,76 @@
+<!--
+  Lincense: Public Domain
+-->
+
+<html><head>
+  <meta http-equiv="Content-Type" content="text/html; charset=utf-8">
+  <title>Sample of web_socket.js</title>
+  
+  <!-- Include these three JS files: -->
+  <script type="text/javascript" src="swfobject.js"></script>
+  <script type="text/javascript" src="FABridge.js"></script>
+  <script type="text/javascript" src="web_socket.js"></script>
+
+  <script type="text/javascript">
+    
+    // Set URL of your WebSocketMain.swf here:
+    WEB_SOCKET_SWF_LOCATION = "WebSocketMain.swf";
+    // Set this to dump debug message from Flash to console.log:
+    WEB_SOCKET_DEBUG = true;
+    
+    // Everything below is the same as using standard WebSocket.
+    
+    var ws;
+    
+    function init() {
+
+      // Connect to Web Socket.
+      // Change host/port here to your own Web Socket server.
+      ws = new WebSocket("ws://localhost:10081/");
+
+      // Set event handlers.
+      ws.onopen = function() {
+        output("onopen");
+      };
+      ws.onmessage = function(e) {
+        // e.data contains received string.
+        output("onmessage: " + e.data);
+      };
+      ws.onclose = function() {
+        output("onclose");
+      };
+      ws.onerror = function() {
+        output("onerror");
+      };
+
+    }
+    
+    function onSubmit() {
+      var input = document.getElementById("input");
+      // You can send message to the Web Socket using ws.send.
+      ws.send(input.value);
+      output("send: " + input.value);
+      input.value = "";
+      input.focus();
+    }
+    
+    function onCloseClick() {
+      ws.close();
+    }
+    
+    function output(str) {
+      var log = document.getElementById("log");
+      var escaped = str.replace(/&/, "&amp;").replace(/</, "&lt;").
+        replace(/>/, "&gt;").replace(/"/, "&quot;"); // "
+      log.innerHTML = escaped + "<br>" + log.innerHTML;
+    }
+
+  </script>
+</head><body onload="init();">
+  <form onsubmit="onSubmit(); return false;">
+    <input type="text" id="input">
+    <input type="submit" value="Send">
+    <button onclick="onCloseClick(); return false;">close</button>
+  </form>
+  <div id="log"></div>
+</body></html>