reflexion 0.5.3 → 0.7.0

data/src/osx/native_window.mm

@@ -6,10 +6,12 @@
 #import <Cocoa/Cocoa.h>
 #include <rays/rays.h>
 #include "reflex/exception.h"
+#include "../application.h"
 #include "../view.h"
 #include "../pointer.h"
 #include "event.h"
 #include "window.h"
+#include "menu.h"
 #import "opengl_view.h"
 
 
@@ -18,7 +20,7 @@ default_style_mask ()
 {
 	return Reflex::Window_make_style_mask(
 		Reflex::Window_default_flags(),
-		NSTitledWindowMask | NSTexturedBackgroundWindowMask);
+		NSWindowStyleMaskTitled);
 }
 
 static void
@@ -198,6 +200,49 @@ move_to_main_screen_origin (NativeWindow* window)
 		timer = nil;
 	}
 
+	- (void) setTitlebarBackgroundVisible: (BOOL) visible
+	{
+		self.titlebarAppearsTransparent = !visible;
+		self.titleVisibility            =
+			visible ? NSWindowTitleVisible : NSWindowTitleHidden;
+	}
+
+	- (void) setTitlebarButtonsVisible: (BOOL) visible
+	{
+		NSWindowButton buttons[] = {
+			NSWindowCloseButton,
+			NSWindowMiniaturizeButton,
+			NSWindowZoomButton
+		};
+		for (auto button : buttons)
+			[self standardWindowButton: button].hidden = !visible;
+	}
+
+	- (void) setTitlebarContainerVisible: (BOOL) visible
+	{
+		// the titlebar keeps a backdrop that a see-through window shows as a shadow
+		NSView* container =
+			[self standardWindowButton: NSWindowCloseButton].superview.superview;
+		if ([container isKindOfClass: NSClassFromString(@"NSTitlebarContainerView")])
+			container.hidden = !visible;
+	}
+
+	- (void) setBackgroundTransparent: (BOOL) transparent
+	{
+		if (transparent == !self.opaque) return;
+
+		self.opaque          = !transparent;
+		self.backgroundColor =
+			transparent ? NSColor.clearColor : NSColor.windowBackgroundColor;
+
+		[self invalidateShadow];
+	}
+
+	- (BOOL) hasFullScreenFlag
+	{
+		return self.styleMask & NSWindowStyleMaskFullScreen;
+	}
+
 	- (void) update: (NSTimer*) t
 	{
 		Reflex::Window* win = self.window;
@@ -207,39 +252,35 @@ move_to_main_screen_origin (NativeWindow* window)
 
 		Window_call_update_event(win);
 
-		if (win->self->redraw)
-		{
+		if (Xot::check_and_remove_flag(&win->self->flags, Reflex::Window::Data::REDRAW))
 			view.needsDisplay = YES;
-			win->self->redraw = false;
-		}
 	}
 
 	- (void) draw
 	{
-		Reflex::Window* win = self.window;
-		if (!win) return;
+		// guarded here too, since rays can throw before the draw event
+		Reflex::Application_guard([&]()
+		{
+			Reflex::Window* win = self.window;
+			if (!win) return;
 
-		update_pixel_density(win);
+			update_pixel_density(win);
 
-		if (update_count == 0)
-			[self update];
+			if (update_count == 0)
+				[self update];
 
-		double now = Xot::time();
-		double dt  = now - win->self->prev_time_draw;
-		double fps = 1. / dt;
+			double now = Xot::time();
+			double dt  = now - win->self->prev_time_draw;
+			double fps = 1. / dt;
 
-		fps = win->self->prev_fps * 0.9 + fps * 0.1;// LPF
+			fps = win->self->prev_fps * 0.9 + fps * 0.1;// LPF
 
-		win->self->prev_time_draw = now;
-		win->self->prev_fps       = fps;
+			win->self->prev_time_draw = now;
+			win->self->prev_fps       = fps;
 
-		Reflex::DrawEvent e(dt, fps);
-		Window_call_draw_event(win, &e);
-	}
-
-	- (BOOL) hasFullScreenFlag
-	{
-		return self.styleMask & NSWindowStyleMaskFullScreen;
+			Reflex::DrawEvent e(dt, fps);
+			Window_call_draw_event(win, &e);
+		});
 	}
 
 	- (BOOL) windowShouldClose: (id) sender
@@ -247,7 +288,7 @@ move_to_main_screen_origin (NativeWindow* window)
 		Reflex::Window* win = self.window;
 		if (!win) return YES;
 
-		win->close();
+		Window_call_close(win);
 		return NO;
 	}
 
@@ -261,6 +302,14 @@ move_to_main_screen_origin (NativeWindow* window)
 		[self setDelegate: nil];
 	}
 
+	- (void) windowDidBecomeMain: (NSNotification*) notification
+	{
+		Reflex::Window* win = self.window;
+		if (!win) return;
+
+		Menu_apply_to_main_menu(win->menu());
+	}
+
 	- (void) windowWillMove: (NSNotification*) notification
 	{
 		Reflex::Window* win = self.window;
@@ -291,32 +340,7 @@ move_to_main_screen_origin (NativeWindow* window)
 
 	- (void) frameChanged
 	{
-		Reflex::Window* win = self.window;
-		if (!win) return;
-
-		Rays::Bounds b           = win->frame();
-		Rays::Point dpos         = b.position() - win->self->prev_position;
-		Rays::Point dsize        = b.size()     - win->self->prev_size;
-		win->self->prev_position = b.position();
-		win->self->prev_size     = b.size();
-
-		if (dpos == 0 && dsize == 0) return;
-
-		Reflex::FrameEvent e(b, dpos.x, dpos.y, 0, dsize.x, dsize.y, 0);
-		if (dpos  != 0) win->on_move(&e);
-		if (dsize != 0)
-		{
-			Rays::Bounds b = win->frame();
-			b.move_to(0, 0);
-
-			if (win->painter())
-				win->painter()->canvas(b, win->painter()->pixel_density());
-
-			if (win->root())
-				View_set_frame(win->root(), b);
-
-			win->on_resize(&e);
-		}
+		Window_call_frame_event(self.window);
 	}
 
 	- (void) windowWillEnterFullScreen: (NSNotification*) notification
@@ -400,6 +424,49 @@ move_to_main_screen_origin (NativeWindow* window)
 		Window_call_key_event(win, &e);
 	}
 
+	- (BOOL) isTextInputEnabled
+	{
+		Reflex::Window* win = self.window;
+		if (!win) return NO;
+
+		const Reflex::View* focus = win->focus();
+		return focus && focus->accepts_text_input();
+	}
+
+	- (void) textPreedit: (NSString*) text selection: (NSRange) selection
+	{
+		Reflex::Window* win = self.window;
+		if (!win) return;
+
+		Reflex::NativeTextEvent e(Reflex::TextEvent::PREEDIT, text, selection);
+		Window_call_text_event(win, &e);
+	}
+
+	- (void) textCommit: (NSString*) text synthesizeKeyEvent: (BOOL) synthesize
+	{
+		Reflex::Window* win = self.window;
+		if (!win) return;
+
+		Reflex::NativeTextEvent e(
+			Reflex::TextEvent::COMMIT, text, NSMakeRange(NSNotFound, 0));
+		Window_call_text_event(win, &e, synthesize);
+	}
+
+	- (NSRect) textInputBounds
+	{
+		Reflex::Window* win = self.window;
+		if (!win) return NSZeroRect;
+
+		const Reflex::View* focus = win->focus();
+		if (!focus) return NSZeroRect;
+
+		Reflex::Bounds b = focus->text_input_bounds();
+		Reflex::Point p1 = focus->to_window(b.position());
+		Reflex::Point p2 = focus->to_window(b.position() + b.size());
+
+		return NSMakeRect(p1.x, view.bounds.size.height - p2.y, p2.x - p1.x, p2.y - p1.y);
+	}
+
 	- (void) mouseDown: (NSEvent*) event
 	{
 		Reflex::Window* win = self.window;
@@ -440,24 +507,41 @@ move_to_main_screen_origin (NativeWindow* window)
 		Reflex::Window* win = self.window;
 		if (!win) return;
 
+		// macos delivers hover moves to the key window even outside its
+		// bounds, but no other platform can see them, so a cross-platform
+		// app must not either
+		NSPoint pos = [view convertPoint: event.locationInWindow fromView: nil];
+		if (!NSPointInRect(pos, view.bounds)) return;
+
 		Reflex::NativePointerEvent e(event, view, Reflex::Pointer::MOVE);
 		Window_call_pointer_event(win, &e);
 	}
 
-	- (void) scrollWheel: (NSEvent*) event
+	- (void) mouseEntered: (NSEvent*) event
 	{
 		Reflex::Window* win = self.window;
 		if (!win) return;
 
-		Reflex::NativeWheelEvent e(event, view);
-		Window_call_wheel_event(win, &e);
+		Reflex::NativePointerEvent e(event, view, Reflex::Pointer::ENTER);
+		Window_call_pointer_event(win, &e);
 	}
 
-	+ (NSRect) frameRectForContentRect: (NSRect) contentRect
+	- (void) mouseExited: (NSEvent*) event
 	{
-		return [NSWindow
-			frameRectForContentRect: contentRect
-			styleMask: default_style_mask()];
+		Reflex::Window* win = self.window;
+		if (!win) return;
+
+		Reflex::NativePointerEvent e(event, view, Reflex::Pointer::LEAVE);
+		Window_call_pointer_event(win, &e);
+	}
+
+	- (void) scrollWheel: (NSEvent*) event
+	{
+		Reflex::Window* win = self.window;
+		if (!win) return;
+
+		Reflex::NativeWheelEvent e(event, view);
+		Window_call_wheel_event(win, &e);
 	}
 
 @end// NativeWindow

data/src/osx/opengl_view.h

@@ -1,8 +1,9 @@
 // -*- objc -*-
 #import <AppKit/NSOpenGLView.h>
+#import <AppKit/NSTextInputClient.h>
 
 
-@interface OpenGLView : NSOpenGLView
+@interface OpenGLView : NSOpenGLView <NSTextInputClient>
 
 	- (id) initWithFrame: (NSRect) frame;
 

data/src/osx/opengl_view.mm

@@ -8,13 +8,25 @@
 #import "native_window.h"
 
 
-//#define TRANSPARENT_BACKGROUND
-
 
 @implementation OpenGLView
 
 	{
 		bool setup_context_done;
+		GLint surface_opacity;
+		NSTrackingArea* tracking_area;
+
+		// the text being composed by the input method
+		NSString* marked_text;
+
+		// the clause being converted, relative to marked_text
+		NSRange marked_selection;
+
+		// whether marked text existed when the current keyDown: started
+		BOOL was_marked;
+
+		// whether the input method handled the key in the current keyDown:
+		BOOL consumed_by_ime;
 	}
 
 	- (id) initWithFrame: (NSRect) frame
@@ -30,6 +42,12 @@
 		if (!self) return nil;
 
 		setup_context_done = false;
+		surface_opacity    = 1;
+		tracking_area      = nil;
+		marked_text        = nil;
+		marked_selection   = NSMakeRange(NSNotFound, 0);
+		was_marked         = NO;
+		consumed_by_ime    = NO;
 
 		return self;
 	}
@@ -45,12 +63,7 @@
 		[self setOpenGLContext: context];
 
 		GLint swapInterval = 1;
-		[context setValues: &swapInterval forParameter: NSOpenGLCPSwapInterval];
-
-#ifdef TRANSPARENT_BACKGROUND
-		GLint opacity = 0;
-		[context setValues: &opacity forParameter: NSOpenGLCPSurfaceOpacity];
-#endif
+		[context setValues: &swapInterval forParameter: NSOpenGLContextParameterSwapInterval];
 	}
 
 	- (void) activateContext
@@ -58,8 +71,22 @@
 		[self setupContext];
 
 		NSOpenGLContext* context = self.openGLContext;
-		if (context.view != self) [context setView: self];
+
+		// these have no replacement but Metal
+		#pragma GCC diagnostic push
+		#pragma GCC diagnostic ignored "-Wdeprecated-declarations"
+		BOOL moved = context.view != self;
+		if (moved) [context setView: self];
+		#pragma GCC diagnostic pop
+
 		[context makeCurrentContext];
+
+		GLint opacity = !self.window || self.window.isOpaque ? 1 : 0;
+		if (moved || opacity != surface_opacity)
+		{
+			surface_opacity = opacity;
+			[context setValues: &opacity forParameter: NSOpenGLContextParameterSurfaceOpacity];
+		}
 	}
 
 	- (BOOL) acceptsFirstResponder
@@ -72,52 +99,87 @@
 		return YES;
 	}
 
-#ifdef TRANSPARENT_BACKGROUND
 	- (BOOL) isOpaque
 	{
-		return YES;
+		return self.window ? self.window.isOpaque : YES;
+	}
+
+	- (BOOL) mouseDownCanMoveWindow
+	{
+		return NO;
 	}
-#endif
 
 	- (void) drawRect: (NSRect) rect
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[self activateContext];
 		[win draw];
 		[[NSOpenGLContext currentContext] flushBuffer];
+
+		if (!win.isOpaque && win.hasShadow)
+			[win invalidateShadow];// the shadow is made from what was drawn
 	}
 
 	- (void) viewDidMoveToWindow
 	{
-		[[self window] setAcceptsMouseMovedEvents: YES];
-		[[self window] makeFirstResponder: self];
+		[self.window setAcceptsMouseMovedEvents: YES];
+		[self.window makeFirstResponder: self];
+	}
 
-#ifdef TRANSPARENT_BACKGROUND
-		[[self window] setBackgroundColor: [NSColor clearColor]];
-		[[self window] setOpaque: NO];
-#endif
+	- (void) updateTrackingAreas
+	{
+		[super updateTrackingAreas];
+
+		if (tracking_area)
+		{
+			[self removeTrackingArea: tracking_area];
+			[tracking_area release];
+		}
+
+		// to track pointer enter/leave event of the window bounds
+		tracking_area = [[NSTrackingArea alloc]
+			initWithRect: NSZeroRect
+			options:
+				NSTrackingMouseEnteredAndExited |
+				NSTrackingActiveAlways |
+				NSTrackingInVisibleRect
+			owner: self
+			userInfo: nil];
+		[self addTrackingArea: tracking_area];
 	}
 
-	- (void) insertText: (id) str
+	- (void) dealloc
 	{
-		//NSLog(@"interText: %@", str);
+		if (tracking_area)
+		{
+			[self removeTrackingArea: tracking_area];
+			[tracking_area release];
+			tracking_area = nil;
+		}
+		[self clearMarkedText];
+		[super dealloc];
 	}
 
 	- (void) keyDown: (NSEvent*) event
 	{
-		//[self interpretKeyEvents: [NSArray arrayWithObject: event]];
-
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
-		[win keyDown: event];
+		was_marked      = self.hasMarkedText;
+		consumed_by_ime = NO;
+
+		if (win.isTextInputEnabled)
+			[self interpretKeyEvents: [NSArray arrayWithObject: event]];
+
+		if (!consumed_by_ime)
+			[win keyDown: event];
 	}
 
 	- (void) keyUp: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win keyUp: event];
@@ -125,7 +187,7 @@
 
 	- (void) flagsChanged: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win flagsChanged: event];
@@ -133,7 +195,7 @@
 
 	- (void) mouseDown: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win mouseDown: event];
@@ -141,7 +203,7 @@
 
 	- (void) mouseUp: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win mouseUp: event];
@@ -149,7 +211,7 @@
 
 	- (void) mouseDragged: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win mouseDragged: event];
@@ -157,7 +219,7 @@
 
 	- (void) rightMouseDown: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win mouseDown: event];
@@ -165,7 +227,7 @@
 
 	- (void) rightMouseUp: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win mouseUp: event];
@@ -173,7 +235,7 @@
 
 	- (void) rightMouseDragged: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win mouseDragged: event];
@@ -181,7 +243,7 @@
 
 	- (void) otherMouseDown: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win mouseDown: event];
@@ -189,7 +251,7 @@
 
 	- (void) otherMouseUp: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win mouseUp: event];
@@ -197,7 +259,7 @@
 
 	- (void) otherMouseDragged: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win mouseDragged: event];
@@ -205,10 +267,140 @@
 
 	- (void) mouseMoved: (NSEvent*) event
 	{
-		NativeWindow* win = (NativeWindow*) [self window];
+		NativeWindow* win = (NativeWindow*) self.window;
 		if (!win) return;
 
 		[win mouseMoved: event];
 	}
 
+	- (void) mouseEntered: (NSEvent*) event
+	{
+		NativeWindow* win = (NativeWindow*) self.window;
+		if (!win) return;
+
+		[win mouseEntered: event];
+	}
+
+	- (void) mouseExited: (NSEvent*) event
+	{
+		NativeWindow* win = (NativeWindow*) self.window;
+		if (!win) return;
+
+		[win mouseExited: event];
+	}
+
+	static NSString*
+	to_string (id str)
+	{
+		return [str isKindOfClass: NSAttributedString.class]
+			?	[(NSAttributedString*) str string]
+			:	(NSString*) str;
+	}
+
+	- (void) insertText: (id) string replacementRange: (NSRange) range
+	{
+		NativeWindow* win = (NativeWindow*) self.window;
+		if (!win) return;
+
+		// text committed from a composition session, or inserted without a key
+		// event (candidate window, emoji palette, dictation), has no key to
+		// report, so a key event is synthesized for it.
+		// otherwise, let keyDown: deliver the original key event.
+		BOOL synthesize = was_marked || NSApp.currentEvent.type != NSEventTypeKeyDown;
+		consumed_by_ime = synthesize;
+
+		[self clearMarkedText];
+		[win textCommit: to_string(string) synthesizeKeyEvent: synthesize];
+	}
+
+	- (void) setMarkedText: (id) string
+		selectedRange: (NSRange) selection
+		replacementRange: (NSRange) range
+	{
+		NativeWindow* win = (NativeWindow*) self.window;
+		if (!win) return;
+
+		NSString* text  = to_string(string);
+		consumed_by_ime = YES;
+
+		[self clearMarkedText];
+		if (text.length > 0)
+		{
+			marked_text      = [text retain];
+			marked_selection = selection;
+		}
+
+		[win textPreedit: text selection: selection];
+	}
+
+	- (void) unmarkText
+	{
+		if (!marked_text) return;
+
+		NativeWindow* win = (NativeWindow*) self.window;
+		if (!win) return;
+
+		[self clearMarkedText];
+		[win textPreedit: @"" selection: NSMakeRange(NSNotFound, 0)];
+	}
+
+	- (BOOL) hasMarkedText
+	{
+		return marked_text != nil;
+	}
+
+	- (NSRange) markedRange
+	{
+		return marked_text
+			?	NSMakeRange(0, marked_text.length)
+			:	NSMakeRange(NSNotFound, 0);
+	}
+
+	- (NSRange) selectedRange
+	{
+		return marked_selection;
+	}
+
+	- (void) clearMarkedText
+	{
+		if (marked_text)
+		{
+			[marked_text release];
+			marked_text = nil;
+		}
+		marked_selection = NSMakeRange(NSNotFound, 0);
+	}
+
+	- (NSRect) firstRectForCharacterRange: (NSRange) range
+		actualRange: (NSRangePointer) actual
+	{
+		NativeWindow* win = (NativeWindow*) self.window;
+		if (!win) return NSZeroRect;
+
+		NSRect rect = win.textInputBounds;
+		return [win convertRectToScreen: [self convertRect: rect toView: nil]];
+	}
+
+	- (NSAttributedString*) attributedSubstringForProposedRange: (NSRange) range
+		actualRange: (NSRangePointer) actual
+	{
+		return nil;
+	}
+
+	- (NSUInteger) characterIndexForPoint: (NSPoint) point
+	{
+		return NSNotFound;
+	}
+
+	- (NSArray*) validAttributesForMarkedText
+	{
+		return [NSArray array];
+	}
+
+	- (void) doCommandBySelector: (SEL) selector
+	{
+		// NSResponder's default beeps for unhandled selectors, and keyDown:
+		// delivers the event as a key event anyway.
+	}
+
 @end// OpenGLView