reflexion 0.1.1

data/reflex.gemspec

@@ -0,0 +1,57 @@
+# -*- mode: ruby; coding: utf-8 -*-
+$: << File.join(File.dirname(__FILE__), 'lib')
+require 'rake'
+require 'reflex/module'
+
+
+FILES = FileList[*%w[
+  ChangeLog
+  README
+  Rakefile
+  support.rb
+  reflex.gemspec
+  VERSION
+  task/**/*.rake
+  ext/**/*.rb
+  ext/**/*.h
+  ext/**/*.cpp
+  include/**/*.h
+  lib/**/*.rb
+  src/**/*.h
+  src/**/*.cpp
+  src/**/*.mm
+  examples/**/README
+  examples/**/Rakefile
+  examples/**/*.h
+  examples/**/*.cpp
+  examples/**/*.rb
+  test/**/*.rb
+]]
+
+Gem::Specification.new do |s|
+  s.name        = 'reflexion'
+  s.summary     = 'A Graphical User Interface Tool Kit.'
+  s.description = 'This library helps you to develop interactive graphical user interface.'
+  s.version     = Reflex.version
+
+  s.authors  = %w[snori]
+  s.email    = 'snori@xord.org'
+  s.homepage = 'http://github.com/xord/reflex'
+
+  s.platform              = Gem::Platform::RUBY
+  s.required_ruby_version = '>=1.9.0'
+  s.require_paths         << 'ext'
+
+  s.add_runtime_dependency 'rucy'
+  s.add_runtime_dependency 'rays'
+  s.add_development_dependency 'rake'
+  s.add_development_dependency 'gemcutter'
+
+  s.files      = FILES.to_a
+  s.test_files = FileList['test/**/test_*.rb'].to_a
+
+  s.has_rdoc         = true
+  s.extra_rdoc_files = ['README']
+
+  s.extensions << 'Rakefile'
+end

data/src/cocoa/application.mm

@@ -0,0 +1,90 @@
+// -*- objc -*-
+#include "reflex/application.h"
+
+
+#import <Cocoa/Cocoa.h>
+#include "applicationdata.h"
+#import "cocoaapplication.h"
+
+
+namespace Reflex
+{
+
+
+	Application::Application ()
+	{
+		self->this_ = this;
+		self->self_ = NSApp ? [NSApp retain] : nil;
+		if (self->self_)
+			[self->self_ setApplicationData: self];
+	}
+
+	Application::~Application ()
+	{
+		if (self->self_)
+		{
+			[self->self_ release];
+			self->self_ = nil;
+		}
+		self->this_ = NULL;
+	}
+
+	bool
+	Application::run ()
+	{
+		if (!*this) return false;
+		[self->self_ run];
+		return true;
+	}
+
+	bool
+	Application::quit ()
+	{
+		if (!*this) return false;
+		[self->self_ terminate: nil];
+		return true;
+	}
+
+	bool
+	Application::preference ()
+	{
+		return *this;
+	}
+
+	bool
+	Application::about ()
+	{
+		if (!*this) return false;
+		[self->self_ orderFrontStandardAboutPanel: nil];
+		return true;
+	}
+
+	bool
+	Application::get_name (String* name) const
+	{
+		if (!*this || !name) return false;
+		*name = self->name;
+		return true;
+	}
+
+	bool
+	Application::set_name (const char* name)
+	{
+		if (!*this || !name) return false;
+		self->name = name;
+		return true;
+	}
+
+	Application::operator bool () const
+	{
+		return self && *self;
+	}
+
+	bool
+	Application::operator ! () const
+	{
+		return !operator bool();
+	}
+
+
+}// Reflex

data/src/cocoa/applicationdata.h

@@ -0,0 +1,51 @@
+// -*- c++ -*-
+#pragma once
+#ifndef __REFLEX_COCOA_APPLICATIONDATA_H__
+#define __REFLEX_COCOA_APPLICATIONDATA_H__
+
+
+#include <boost/shared_ptr.hpp>
+#include <reflex/application.h>
+
+
+@class CocoaApplication;
+
+
+namespace Reflex
+{
+
+
+	struct Application::Data
+	{
+
+		Application* this_;
+
+		CocoaApplication* self_;
+
+		String name;
+
+		Data ()
+		:	this_(NULL), self_(nil)
+		{
+		}
+
+		operator bool () const
+		{
+			return this_ && self_;
+		}
+
+		bool operator ! () const
+		{
+			return !operator bool();
+		}
+
+	};// Application::Data
+
+
+	typedef boost::shared_ptr<Reflex::Application::Data> ApplicationData;
+
+
+}// Reflex
+
+
+#endif//EOH

data/src/cocoa/cocoaapplication.h

@@ -0,0 +1,19 @@
+// -*- objc -*-
+#import <AppKit/NSApplication.h>
+#include "applicationdata.h"
+
+
+@interface CocoaApplication : NSApplication <NSApplicationDelegate>
+
+	{
+		@private
+			Reflex::ApplicationData data;
+	}
+
+	- (void) about;
+
+	- (void) quit;
+
+	- (BOOL) setApplicationData: (Reflex::ApplicationData) data;
+
+@end// CocoaApplication

data/src/cocoa/cocoaapplication.mm

@@ -0,0 +1,180 @@
+// -*- objc -*-
+#import "cocoaapplication.h"
+
+
+#import <Cocoa/Cocoa.h>
+#include <reflex/reflex.h>
+
+
+@implementation CocoaApplication
+
+	- (id) init
+	{
+		self = [super init];
+		if (!self) return nil;
+
+		[self setDelegate: self];
+		[self setActivationPolicy: NSApplicationActivationPolicyRegular];
+		[self activateIgnoringOtherApps: YES];
+
+		return self;
+	}
+
+	- (BOOL) setApplicationData: (Reflex::ApplicationData) data_
+	{
+		if (data || !data_) return NO;
+		data = data_;
+		return YES;
+	}
+
+	- (void) quit
+	{
+		if (data && *data)
+			data->this_->quit();
+		else
+			Reflex::quit();
+	}
+
+	- (void) about
+	{
+		if (data && *data)
+			data->this_->about();
+		else
+			[self orderFrontStandardAboutPanel: nil];
+	}
+
+	- (BOOL) setupApplicationMenu: (NSMenu*) parent
+	{
+		if (!parent) return NO;
+
+		NSMenu* menu = [[[NSMenu alloc]
+			initWithTitle: @"Application"]
+			autorelease];
+		if ([self respondsToSelector: @selector(setAppleMenu:)])
+			[self performSelector: @selector(setAppleMenu:) withObject: menu];
+
+		NSString* name = !data->name.empty() ?
+			[NSString stringWithUTF8String: data->name.c_str()] : @"";
+		if ([name length] > 0)
+			name = [@" " stringByAppendingString: name];
+
+		NSMenu* submenu = nil;
+		NSMenuItem* item = nil;
+
+		[menu
+			addItemWithTitle: [@"About" stringByAppendingString: name]
+			action: @selector(about)
+			keyEquivalent: @""];
+
+		[menu addItem: [NSMenuItem separatorItem]];
+
+		[menu
+			addItemWithTitle: @"Preferences"
+			action: @selector(preference:)
+			keyEquivalent: @","];
+
+		[menu addItem: [NSMenuItem separatorItem]];
+
+		item = [menu
+			addItemWithTitle: @"Services"
+			action: nil
+			keyEquivalent: @""];
+		submenu = [[[NSMenu alloc] initWithTitle: @"Services"] autorelease];
+		[item setSubmenu: submenu];
+		[self setServicesMenu: submenu];
+
+		[menu addItem: [NSMenuItem separatorItem]];
+
+		[menu
+			addItemWithTitle: [@"Hide" stringByAppendingString: name]
+			action: @selector(hide:)
+			keyEquivalent: @"h"];
+
+		item = [menu
+			addItemWithTitle: @"Hide Others"
+			action: @selector(hideOtherApplications:)
+			keyEquivalent: @"h"];
+		[item setKeyEquivalentModifierMask: NSAlternateKeyMask | NSCommandKeyMask];
+
+		[menu
+			addItemWithTitle: @"ShowAll"
+			action: @selector(unhideAllApplications:)
+			keyEquivalent: @""];
+
+		[menu addItem: [NSMenuItem separatorItem]];
+
+		[menu
+			addItemWithTitle: [@"Quit" stringByAppendingString: name]
+			action: @selector(quit)
+			keyEquivalent: @"q"];
+
+		item =
+			[parent addItemWithTitle: @"Application" action: nil keyEquivalent: @""];
+		[parent setSubmenu: menu forItem: item];
+
+		return YES;
+	}
+
+	- (BOOL) setupWindowMenu: (NSMenu*) parent
+	{
+		if (!parent) return NO;
+
+		NSMenu* menu = [[[NSMenu alloc]
+			initWithTitle: @"Window"]
+			autorelease];
+
+		[menu
+			addItemWithTitle: @"Minimize"
+			action: @selector(performMiniaturize:)
+			keyEquivalent: @"m"];
+
+		[menu
+			addItemWithTitle: @"Zoom"
+			action: @selector(performZoom:)
+			keyEquivalent: @""];
+
+		[menu addItem: [NSMenuItem separatorItem]];
+
+		[menu
+			addItemWithTitle: @"Bring All to Front"
+			action: @selector(arrangeInFront:)
+			keyEquivalent: @""];
+
+		NSMenuItem* item =
+			[parent addItemWithTitle: @"Window" action: nil keyEquivalent: @""];
+		[parent setSubmenu: menu forItem: item];
+
+		[self setWindowsMenu: menu];
+
+		return YES;
+	}
+
+	- (BOOL) setupMenu
+	{
+		if ([self mainMenu]) return NO;
+
+		NSMenu* menu = [[[NSMenu alloc] initWithTitle: @"MainMenu"] autorelease];
+
+		if (
+			![self setupApplicationMenu: menu] ||
+			![self setupWindowMenu: menu])
+		{
+			return NO;
+		}
+
+		[self setMainMenu: menu];
+
+		return YES;
+	}
+
+	- (BOOL) applicationShouldTerminateAfterLastWindowClosed: (NSApplication*) app
+	{
+		return YES;
+	}
+
+	- (void) applicationDidFinishLaunching: (NSNotification*) notification
+	{
+		[self setupMenu];
+	}
+
+@end// CocoaApplication

data/src/cocoa/cocoawindow.h

@@ -0,0 +1,44 @@
+// -*- objc -*-
+#import <AppKit/NSWindow.h>
+#include "windowdata.h"
+
+
+@class OpenGLView;
+
+
+@interface CocoaWindow : NSWindow <NSWindowDelegate>
+
+	{
+		@private
+			Reflex::WindowData data;
+			OpenGLView* view;
+			NSTimer* timer;
+	}
+
+	- (id) initWithWindowData: (Reflex::WindowData) data;
+
+	- (void) setupContentView;
+
+	- (void) startTimer: (int) fps;
+
+	- (void) stopTimer;
+
+	- (void) update: (NSTimer*) t;
+
+	- (void) draw;
+
+	- (void) redraw;
+
+	- (void) keyDown: (NSEvent*) event;
+
+	- (void) keyUp: (NSEvent*) event;
+
+	- (void) mouseDown: (NSEvent*) event;
+
+	- (void) mouseUp: (NSEvent*) event;
+
+	- (void) mouseMoved: (NSEvent*) event;
+
+	- (void) mouseDragged: (NSEvent*) event;
+
+@end// CocoaWindow

data/src/cocoa/cocoawindow.mm

@@ -0,0 +1,171 @@
+// -*- objc -*-
+#import "cocoawindow.h"
+
+
+#import <Cocoa/Cocoa.h>
+#import "openglview.h"
+
+#include <reflex/window.h>
+#include "defs.h"
+
+
+@implementation CocoaWindow
+
+	- (id) initWithWindowData: (Reflex::WindowData) data_
+	{
+		NSRect frame = NSMakeRect(0, 0, 0, 0);
+
+		self = [super
+			initWithContentRect: NSMakeRect(0, 0, 0, 0)
+			styleMask:
+				NSTitledWindowMask |
+				NSClosableWindowMask |
+				NSMiniaturizableWindowMask |
+				NSResizableWindowMask |
+				0//NSTexturedBackgroundWindowMask
+			backing: NSBackingStoreBuffered
+			defer: NO];
+		if (!self) return nil;
+
+		data  = data_;
+		view  = nil;
+		timer = nil;
+
+		[self setDelegate: self];
+		//[self setReleasedWhenClosed: NO];
+
+		[self setupContentView];
+		[self startTimer: 60];
+
+		return self;
+	}
+
+	- (void) dealloc
+	{
+		[self stopTimer];
+		[view release];
+
+		[super dealloc];
+	}
+
+	- (void) setupContentView
+	{
+		NSRect rect = [self contentRectForFrameRect: [self frame]];
+		rect.origin.x = rect.origin.y = 0;
+		view = [[OpenGLView alloc] initWithFrame: rect];
+		[self setContentView: view];
+	}
+
+	- (void) startTimer: (int) fps
+	{
+		[self stopTimer];
+
+		if (fps <= 0) return;
+
+		timer = [[NSTimer
+			timerWithTimeInterval: 1.f / (float) fps
+			target: self
+			selector: @selector(update:)
+			userInfo: nil
+			repeats: YES] retain];
+		if (!timer) return;
+
+		[[NSRunLoop currentRunLoop]
+			addTimer: timer forMode: NSDefaultRunLoopMode];
+		[[NSRunLoop currentRunLoop]
+			addTimer: timer forMode: NSEventTrackingRunLoopMode];
+	}
+
+	- (void) stopTimer
+	{
+		if (timer)
+		{
+			if ([timer isValid]) [timer invalidate];
+			[timer release];
+			timer = nil;
+		}
+	}
+
+	- (void) update: (NSTimer*) t
+	{
+		if (!data || !*data) return;
+		data->this_->update();
+	}
+
+	- (void) draw
+	{
+		if (!data || !*data) return;
+		data->this_->draw();
+	}
+
+	- (void) redraw
+	{
+		[self display];
+	}
+
+	- (BOOL) windowShouldClose: (id) sender
+	{
+		if (!data || !*data) return YES;
+		data->this_->close();
+		return NO;
+	}
+
+	- (void) windowWillClose: (NSNotification*) notification
+	{
+		[self stopTimer];
+		data.reset();
+	}
+
+	- (void) windowDidMove: (NSNotification*) notification
+	{
+		if (!data || !*data) return;
+		Reflex::coord x = 0, y = 0;
+		data->this_->get_bounds(&x, &y);
+		data->this_->moved(x, y);
+	}
+
+	- (void) windowDidResize: (NSNotification*) notification
+	{
+		if (!data || !*data) return;
+		Reflex::coord w = 0, h = 0;
+		data->this_->get_bounds(NULL, NULL, &w, &h);
+		data->this_->resized(w, h);
+	}
+
+	- (void) keyDown: (NSEvent*) event
+	{
+		if (!data || !*data) return;
+		data->this_->key_down(Reflex::CocoaKey(event));
+	}
+
+	- (void) keyUp: (NSEvent*) event
+	{
+		if (!data || !*data) return;
+		data->this_->key_up(Reflex::CocoaKey(event));
+	}
+
+	- (void) mouseDown: (NSEvent*) event
+	{
+		if (!data || !*data) return;
+		data->this_->points_down(Reflex::CocoaPoints(event, view));
+	}
+
+	- (void) mouseUp: (NSEvent*) event
+	{
+		if (!data || !*data) return;
+		data->this_->points_up(Reflex::CocoaPoints(event, view));
+	}
+
+	- (void) mouseMoved: (NSEvent*) event
+	{
+		if (!data || !*data) return;
+		data->this_->points_moved(Reflex::CocoaPoints(event, view));
+	}
+
+	- (void) mouseDragged: (NSEvent*) event
+	{
+		if (!data || !*data) return;
+		data->this_->points_moved(Reflex::CocoaPoints(event, view));
+	}
+
+@end// CocoaWindow

data/src/cocoa/defs.h

@@ -0,0 +1,34 @@
+// -*- c++ -*-
+#pragma once
+#ifndef __REFLEX_COCOA_DEFS_H__
+#define __REFLEX_COCOA_DEFS_H__
+
+
+#import <AppKit/NSEvent.h>
+#include <reflex/defs.h>
+
+
+namespace Reflex
+{
+
+
+	struct CocoaKey : public Key
+	{
+
+		CocoaKey (NSEvent* event);
+
+	};// CocoaKey
+
+
+	struct CocoaPoints : public Points
+	{
+
+		CocoaPoints (NSEvent* event, NSView* view);
+
+	};// CocoaPoints
+
+
+}// Reflex
+
+
+#endif//EOH