qtbindings 4.6.3.4 → 4.8.3.0

data/ext/cmake/modules/MacroOptionalFindPackage.cmake

@@ -7,42 +7,22 @@
 # The standard <name>_FOUND variables can be used in the same way
 # as when using the normal FIND_PACKAGE()
 
-# Copyright (c) 2006-2010 Alexander Neundorf, <neundorf@kde.org>
+# Copyright (c) 2006, Alexander Neundorf, <neundorf@kde.org>
 #
 # Redistribution and use is allowed according to the terms of the BSD license.
 # For details see the accompanying COPYING-CMAKE-SCRIPTS file.
 
-# This is just a helper macro to set a bunch of variables empty.
-# We don't know whether the package uses UPPERCASENAME or CamelCaseName, so we try both:
-macro(_MOFP_SET_EMPTY_IF_DEFINED _name _var)
-   if(DEFINED ${_name}_${_var})
-      set(${_name}_${_var} "")
-   endif(DEFINED ${_name}_${_var})
-
-   string(TOUPPER ${_name} _nameUpper)
-   if(DEFINED ${_nameUpper}_${_var})
-      set(${_nameUpper}_${_var}  "")
-   endif(DEFINED ${_nameUpper}_${_var})
-endmacro(_MOFP_SET_EMPTY_IF_DEFINED _package _var)
-
 
 macro (MACRO_OPTIONAL_FIND_PACKAGE _name )
    option(WITH_${_name} "Search for ${_name} package" ON)
    if (WITH_${_name})
       find_package(${_name} ${ARGN})
    else (WITH_${_name})
-      string(TOUPPER ${_name} _nameUpper)
-      set(${_name}_FOUND FALSE)
-      set(${_nameUpper}_FOUND FALSE)
-
-      _mofp_set_empty_if_defined(${_name} INCLUDE_DIRS)
-      _mofp_set_empty_if_defined(${_name} INCLUDE_DIR)
-      _mofp_set_empty_if_defined(${_name} INCLUDES)
-      _mofp_set_empty_if_defined(${_name} LIBRARY)
-      _mofp_set_empty_if_defined(${_name} LIBRARIES)
-      _mofp_set_empty_if_defined(${_name} LIBS)
-      _mofp_set_empty_if_defined(${_name} FLAGS)
-      _mofp_set_empty_if_defined(${_name} DEFINITIONS)
+      set(${_name}_FOUND)
+      set(${_name}_INCLUDE_DIR)
+      set(${_name}_INCLUDES)
+      set(${_name}_LIBRARY)
+      set(${_name}_LIBRARIES)
    endif (WITH_${_name})
 endmacro (MACRO_OPTIONAL_FIND_PACKAGE)
 

data/ext/cmake/modules/MacroWriteBasicCMakeVersionFile.cmake

@@ -0,0 +1,22 @@
+#  MACRO_WRITE_BASIC_CMAKE_VERSION_FILE( _filename _major _minor _patch)
+#    Writes a file for use as <package>ConfigVersion.cmake file to <_filename>.
+#    See the documentation of FIND_PACKAGE() for details on this.
+#    _filename is the output filename, it should be in the build tree.
+#    _major is the major version number of the project to be installed
+#    _minor is the minor version number of the project to be installed
+#    _patch is the patch version number of the project to be installed
+#
+
+# Copyright (c) 2008, Alexander Neundorf, <neundorf@kde.org>
+#
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+get_filename_component(_currentListFileDir ${CMAKE_CURRENT_LIST_FILE} PATH)
+
+function(MACRO_WRITE_BASIC_CMAKE_VERSION_FILE _filename _major _minor _patch)
+   set(PROJECT_VERSION_MAJOR ${_major})
+   set(PROJECT_VERSION_MINOR ${_minor})
+   set(PROJECT_VERSION_PATCH ${_patch})
+   configure_file(${_currentListFileDir}/BasicFindPackageVersion.cmake.in "${_filename}" @ONLY)
+endfunction(MACRO_WRITE_BASIC_CMAKE_VERSION_FILE _major _minor _patch)

data/ext/cmake/modules/SmokeConfig.cmake.in

@@ -0,0 +1,109 @@
+# Find smoke libraries.
+#
+# Use:
+#
+# find_package(Smoke [REQUIRED] COMPONENTS QtCore QtGui <other components>)
+#
+# Defines:
+#
+# SMOKE_INCLUDE_DIR                 Directory in which smoke.h is located
+# SMOKE_CMAKE_MODULE_DIR            Directory with additional cmake files used by kdebindings
+# SMOKE_GEN_BIN                     The path of the smokegen executable
+# SMOKE_GEN_SHARED                  Directory in which commonly used smokegen files reside
+# SMOKE_API_BIN                     The path of the smokeapi executable
+# SMOKE_GENERATOR_SMOKE_LIB         Path of generator_smoke library
+# SMOKE_GENERATOR_DUMP_LIB          Path of generator_dump library
+# SMOKE_<component>_INCLUDE_DIR     Directory in which to find smoke/<component>_smoke.h
+# SMOKE_<component>_LIBRARY         Library for the smoke lib
+#
+# Copyright (c) 2010, Arno Rehn <arno@arnorehn.de>
+#           (c) 2010, Ian Monroe <ian@monroe.nu>
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+#####################
+# utility functions #
+#####################
+
+function (_print type message)
+    if (NOT Smoke_FIND_QUIETLY)
+        message (${type} "${message}")
+    endif (NOT Smoke_FIND_QUIETLY)
+endfunction (_print type message)
+
+
+##############################
+# find individual smoke libs #
+##############################Smoke_FIND_REQUIRED
+
+macro (find_smoke_component name)
+    string(TOUPPER ${name} uppercase)
+    string(TOLOWER ${name} lowercase)
+
+    if (NOT SMOKE_${uppercase}_FOUND)
+        set (SMOKE_${uppercase}_FOUND FALSE CACHE INTERNAL "")
+
+        find_path(SMOKE_${uppercase}_INCLUDE_DIR 
+            ${lowercase}_smoke.h 
+            PATH ${SMOKE_INCLUDE_DIR}
+            NO_DEFAULT_PATH
+            )
+        if(WIN32)
+		    # DLLs are in the bin directory.
+            find_library(SMOKE_${uppercase}_LIBRARY
+                smoke${lowercase}
+                PATHS "@CMAKE_INSTALL_PREFIX@/bin"
+                NO_DEFAULT_PATH)
+        else(WIN32)
+            find_library(SMOKE_${uppercase}_LIBRARY
+                smoke${lowercase}
+                PATHS "@SMOKE_LIBRARY_PREFIX@"
+                NO_DEFAULT_PATH)
+        endif(WIN32)
+
+        if (NOT SMOKE_${uppercase}_INCLUDE_DIR OR NOT SMOKE_${uppercase}_LIBRARY)
+            if (Smoke_FIND_REQUIRED)
+                _print(FATAL_ERROR "Could not find Smoke${name}")
+            else (Smoke_FIND_REQUIRED)
+                _print(STATUS "Could not find Smoke${name}")
+            endif (Smoke_FIND_REQUIRED)
+        else (NOT SMOKE_${uppercase}_INCLUDE_DIR OR NOT SMOKE_${uppercase}_LIBRARY)
+            set (SMOKE_${uppercase}_FOUND TRUE CACHE INTERNAL "")
+            _print(STATUS "Found Smoke${name}: ${SMOKE_${uppercase}_LIBRARY}")
+        endif (NOT SMOKE_${uppercase}_INCLUDE_DIR OR NOT SMOKE_${uppercase}_LIBRARY)
+
+        mark_as_advanced(SMOKE_${uppercase}_INCLUDE_DIR SMOKE_${uppercase}_LIBRARY SMOKE_${uppercase}_FOUND)
+    endif (NOT SMOKE_${uppercase}_FOUND)
+endmacro (find_smoke_component)
+
+################
+# find smoke.h #
+################
+set(SMOKE_INCLUDE_DIR "@SMOKE_INCLUDE_DIR@")
+set(SMOKE_CMAKE_MODULE_DIR "@SMOKE_CMAKE_MODULE_DIR@")
+set(SMOKE_INSTALL_PREFIX "@CMAKE_INSTALL_PREFIX@")
+set(SMOKE_GENERATOR_SMOKE_LIB "@SMOKE_GENERATOR_SMOKE_LIB@")
+set(SMOKE_GENERATOR_DUMP_LIB "@SMOKE_GENERATOR_DUMP_LIB@")
+set(SMOKE_GEN_BIN "@SMOKE_GEN_BIN@")
+set(SMOKE_GEN_SHARED "@SMOKE_GEN_SHARED@")
+set(SMOKE_API_BIN "@SMOKE_API_BIN@")
+
+find_library(SMOKE_BASE_LIBRARY smokebase 
+              PATHS "@SMOKE_LIBRARY_PREFIX@"
+              NO_DEFAULT_PATH)
+
+if (NOT SMOKE_BASE_LIBRARY)
+    if (Smoke_FIND_REQUIRED)
+        _print(FATAL_ERROR "Could not find SMOKE")
+    else (Smoke_FIND_REQUIRED)
+        _print(STATUS "Could not find SMOKE")
+    endif (Smoke_FIND_REQUIRED)
+endif (NOT SMOKE_BASE_LIBRARY)
+
+mark_as_advanced(SMOKE_INCLUDE_DIR SMOKE_BASE_LIBRARY)
+
+if (Smoke_FIND_COMPONENTS)
+    foreach (component ${Smoke_FIND_COMPONENTS})
+        find_smoke_component(${component})
+    endforeach(component)
+endif (Smoke_FIND_COMPONENTS)

data/ext/generator/cmake/BasicFindPackageVersion.cmake.in

@@ -0,0 +1,30 @@
+# This is a very basic file for the new style find_package() search mode,
+# i.e. Config-mode. It is used by MACRO_WRITE_BASIC_CMAKE_VERSION_FILE() from 
+# MacroWriteBasicCMakeVersionFile.cmake.
+# In this mode find_package() searches for a <package>Config.cmake 
+# file and an associated <package>Version.cmake file, which it loads to check 
+# the version number.
+# This file can be used with configure_file() to generate such a file for a project
+# with very basic logic.
+# It sets PACKAGE_VERSION_EXACT if the current version string and the requested
+# version string are exactly the same and it sets PACKAGE_VERSION_COMPATIBLE
+# if the current version is >= requested version.
+# If this is not good enough for your project, you need to write your own
+# improved <package>Version.cmake file.
+# This file requires the following three variables to be set:
+#   PROJECT_VERSION_MAJOR
+#   PROJECT_VERSION_MINOR
+#   PROJECT_VERSION_PATCH
+
+
+set(PACKAGE_VERSION @PROJECT_VERSION_MAJOR@.@PROJECT_VERSION_MINOR@.@PROJECT_VERSION_PATCH@)
+
+if("${PACKAGE_VERSION}" VERSION_LESS "${PACKAGE_FIND_VERSION}" )
+   set(PACKAGE_VERSION_COMPATIBLE FALSE)
+else("${PACKAGE_VERSION}" VERSION_LESS "${PACKAGE_FIND_VERSION}" )
+   set(PACKAGE_VERSION_COMPATIBLE TRUE)
+   if( "${PACKAGE_FIND_VERSION}" STREQUAL "${PACKAGE_VERSION}")
+      set(PACKAGE_VERSION_EXACT TRUE)
+   endif( "${PACKAGE_FIND_VERSION}" STREQUAL "${PACKAGE_VERSION}")
+endif("${PACKAGE_VERSION}" VERSION_LESS "${PACKAGE_FIND_VERSION}" )
+

data/ext/generator/cmake/CMakeLists.txt

@@ -0,0 +1,24 @@
+set(SMOKE_LIBRARY_PREFIX ${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX})
+set(SMOKE_INCLUDE_DIR ${CMAKE_INSTALL_PREFIX}/include ${CMAKE_INSTALL_PREFIX}/include/smoke)
+set(SMOKE_CMAKE_MODULE_DIR ${CMAKE_INSTALL_PREFIX}/share/smoke/cmake)
+set(SMOKE_GEN_BIN ${CMAKE_INSTALL_PREFIX}/bin/smokegen${CMAKE_EXECUTABLE_SUFFIX})
+set(SMOKE_GEN_SHARED ${CMAKE_INSTALL_PREFIX}/share/smokegen)
+set(SMOKE_API_BIN ${CMAKE_INSTALL_PREFIX}/bin/smokeapi${CMAKE_EXECUTABLE_SUFFIX})
+set(SMOKE_GENERATOR_SMOKE_LIB ${LIB_INSTALL_DIR}/smokegen/generator_smoke)
+set(SMOKE_GENERATOR_DUMP_LIB ${LIB_INSTALL_DIR}/smokegen/generator_dump)
+
+configure_file(SmokeConfig.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/SmokeConfig.cmake @ONLY)
+
+set(smoke_cmake_files 
+        FindLibraryWithDebug.cmake
+        FindPhonon.cmake
+        FindQImageBlitz.cmake
+        FindQScintilla.cmake
+        FindQwt5.cmake
+        HandleImportedTargetsInCMakeRequiredLibraries.cmake
+        MacroLogFeature.cmake
+        MacroOptionalAddBindings.cmake
+        MacroOptionalFindPackage.cmake
+        )
+
+install(FILES ${CMAKE_CURRENT_BINARY_DIR}/SmokeConfig.cmake ${smoke_cmake_files} DESTINATION ${SMOKE_CMAKE_MODULE_DIR})

data/ext/generator/cmake/FindLibraryWithDebug.cmake

@@ -0,0 +1,113 @@
+#
+#  FIND_LIBRARY_WITH_DEBUG
+#  -> enhanced FIND_LIBRARY to allow the search for an
+#     optional debug library with a WIN32_DEBUG_POSTFIX similar
+#     to CMAKE_DEBUG_POSTFIX when creating a shared lib
+#     it has to be the second and third argument
+
+# Copyright (c) 2007, Christian Ehrlicher, <ch.ehrlicher@gmx.de>
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+MACRO(FIND_LIBRARY_WITH_DEBUG var_name win32_dbg_postfix_name dgb_postfix libname)
+
+  IF(NOT "${win32_dbg_postfix_name}" STREQUAL "WIN32_DEBUG_POSTFIX")
+
+     # no WIN32_DEBUG_POSTFIX -> simply pass all arguments to FIND_LIBRARY
+     FIND_LIBRARY(${var_name}
+                  ${win32_dbg_postfix_name}
+                  ${dgb_postfix}
+                  ${libname}
+                  ${ARGN}
+     )
+
+  ELSE(NOT "${win32_dbg_postfix_name}" STREQUAL "WIN32_DEBUG_POSTFIX")
+
+    IF(NOT WIN32)
+      # on non-win32 we don't need to take care about WIN32_DEBUG_POSTFIX
+
+      FIND_LIBRARY(${var_name} ${libname} ${ARGN})
+
+    ELSE(NOT WIN32)
+
+      # 1. get all possible libnames
+      SET(args ${ARGN})
+      SET(newargs "")
+      SET(libnames_release "")
+      SET(libnames_debug "")
+
+      LIST(LENGTH args listCount)
+
+      IF("${libname}" STREQUAL "NAMES")
+        SET(append_rest 0)
+        LIST(APPEND args " ")
+
+        FOREACH(i RANGE ${listCount})
+          LIST(GET args ${i} val)
+
+          IF(append_rest)
+            LIST(APPEND newargs ${val})
+          ELSE(append_rest)
+            IF("${val}" STREQUAL "PATHS")
+              LIST(APPEND newargs ${val})
+              SET(append_rest 1)
+            ELSE("${val}" STREQUAL "PATHS")
+              LIST(APPEND libnames_release "${val}")
+              LIST(APPEND libnames_debug   "${val}${dgb_postfix}")
+            ENDIF("${val}" STREQUAL "PATHS")
+          ENDIF(append_rest)
+
+        ENDFOREACH(i)
+
+      ELSE("${libname}" STREQUAL "NAMES")
+
+        # just one name
+        LIST(APPEND libnames_release "${libname}")
+        LIST(APPEND libnames_debug   "${libname}${dgb_postfix}")
+
+        SET(newargs ${args})
+
+      ENDIF("${libname}" STREQUAL "NAMES")
+
+      # search the release lib
+      FIND_LIBRARY(${var_name}_RELEASE
+                   NAMES ${libnames_release}
+                   ${newargs}
+      )
+
+      # search the debug lib
+      FIND_LIBRARY(${var_name}_DEBUG
+                   NAMES ${libnames_debug}
+                   ${newargs}
+      )
+
+      IF(${var_name}_RELEASE AND ${var_name}_DEBUG)
+
+        # both libs found
+        SET(${var_name} optimized ${${var_name}_RELEASE}
+                        debug     ${${var_name}_DEBUG})
+
+      ELSE(${var_name}_RELEASE AND ${var_name}_DEBUG)
+
+        IF(${var_name}_RELEASE)
+
+          # only release found
+          SET(${var_name} ${${var_name}_RELEASE})
+
+        ELSE(${var_name}_RELEASE)
+
+          # only debug (or nothing) found
+          SET(${var_name} ${${var_name}_DEBUG})
+
+        ENDIF(${var_name}_RELEASE)
+       
+      ENDIF(${var_name}_RELEASE AND ${var_name}_DEBUG)
+
+      MARK_AS_ADVANCED(${var_name}_RELEASE)
+      MARK_AS_ADVANCED(${var_name}_DEBUG)
+
+    ENDIF(NOT WIN32)
+
+  ENDIF(NOT "${win32_dbg_postfix_name}" STREQUAL "WIN32_DEBUG_POSTFIX")
+
+ENDMACRO(FIND_LIBRARY_WITH_DEBUG)

data/ext/generator/cmake/FindPhonon.cmake

@@ -0,0 +1,71 @@
+# Find libphonon
+# Once done this will define
+#
+#  PHONON_FOUND    - system has Phonon Library
+#  PHONON_INCLUDES - the Phonon include directory
+#  PHONON_LIBS     - link these to use Phonon
+#  PHONON_VERSION  - the version of the Phonon Library
+
+# Copyright (c) 2008, Matthias Kretz <kretz@kde.org>
+#
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+macro(_phonon_find_version)
+   set(_phonon_namespace_header_file "${PHONON_INCLUDE_DIR}/phonon/phononnamespace.h")
+   if (APPLE AND EXISTS "${PHONON_INCLUDE_DIR}/Headers/phononnamespace.h")
+      set(_phonon_namespace_header_file "${PHONON_INCLUDE_DIR}/Headers/phononnamespace.h")
+   endif (APPLE AND EXISTS "${PHONON_INCLUDE_DIR}/Headers/phononnamespace.h")
+   file(READ ${_phonon_namespace_header_file} _phonon_header LIMIT 5000 OFFSET 1000)
+   string(REGEX MATCH "define PHONON_VERSION_STR \"(4\\.[0-9]+\\.[0-9a-z]+)\"" _phonon_version_match "${_phonon_header}")
+   set(PHONON_VERSION "${CMAKE_MATCH_1}")
+   message(STATUS "Phonon Version: ${PHONON_VERSION}")
+endmacro(_phonon_find_version)
+
+if(PHONON_FOUND)
+   # Already found, nothing more to do except figuring out the version
+   _phonon_find_version()
+else(PHONON_FOUND)
+   if(PHONON_INCLUDE_DIR AND PHONON_LIBRARY)
+      set(PHONON_FIND_QUIETLY TRUE)
+   endif(PHONON_INCLUDE_DIR AND PHONON_LIBRARY)
+
+   # As discussed on kde-buildsystem: first look at CMAKE_PREFIX_PATH, then at the suggested PATHS (kde4 install dir)
+   find_library(PHONON_LIBRARY NAMES phonon PATHS ${KDE4_LIB_INSTALL_DIR} ${QT_LIBRARY_DIR} NO_SYSTEM_ENVIRONMENT_PATH NO_CMAKE_SYSTEM_PATH)
+   # then at the default system locations (CMAKE_SYSTEM_PREFIX_PATH, i.e. /usr etc.)
+   find_library(PHONON_LIBRARY NAMES phonon)
+
+   find_path(PHONON_INCLUDE_DIR NAMES phonon/phonon_export.h PATHS ${KDE4_INCLUDE_INSTALL_DIR} ${QT_INCLUDE_DIR} ${INCLUDE_INSTALL_DIR} ${QT_LIBRARY_DIR} NO_SYSTEM_ENVIRONMENT_PATH NO_CMAKE_SYSTEM_PATH)
+   find_path(PHONON_INCLUDE_DIR NAMES phonon/phonon_export.h)
+
+   if(PHONON_INCLUDE_DIR AND PHONON_LIBRARY)
+      set(PHONON_LIBS ${phonon_LIB_DEPENDS} ${PHONON_LIBRARY})
+      set(PHONON_INCLUDES ${PHONON_INCLUDE_DIR}/KDE ${PHONON_INCLUDE_DIR})
+      set(PHONON_FOUND TRUE)
+      _phonon_find_version()
+   else(PHONON_INCLUDE_DIR AND PHONON_LIBRARY)
+      set(PHONON_FOUND FALSE)
+   endif(PHONON_INCLUDE_DIR AND PHONON_LIBRARY)
+
+   if(PHONON_FOUND)
+      if(NOT PHONON_FIND_QUIETLY)
+         message(STATUS "Found Phonon: ${PHONON_LIBRARY}")
+         message(STATUS "Found Phonon Includes: ${PHONON_INCLUDES}")
+      endif(NOT PHONON_FIND_QUIETLY)
+   else(PHONON_FOUND)
+      if(Phonon_FIND_REQUIRED)
+         if(NOT PHONON_INCLUDE_DIR)
+            message(STATUS "Phonon includes NOT found!")
+         endif(NOT PHONON_INCLUDE_DIR)
+         if(NOT PHONON_LIBRARY)
+            message(STATUS "Phonon library NOT found!")
+         endif(NOT PHONON_LIBRARY)
+         message(FATAL_ERROR "Phonon library or includes NOT found!")
+      else(Phonon_FIND_REQUIRED)
+         message(STATUS "Unable to find Phonon")
+      endif(Phonon_FIND_REQUIRED)
+   endif(PHONON_FOUND)
+
+
+   mark_as_advanced(PHONON_INCLUDE_DIR PHONON_LIBRARY PHONON_INCLUDES)
+endif(PHONON_FOUND)

data/ext/generator/cmake/FindQImageBlitz.cmake

@@ -0,0 +1,51 @@
+# - Try to find the qimageblitz lib
+# Once done this will define
+#
+#  QIMAGEBLITZ_FOUND - system has qimageblitz lib
+#  QIMAGEBLITZ_INCLUDES - the qimageblitz include directory
+#  QIMAGEBLITZ_LIBRARIES - The libraries needed to use qimageblitz
+
+# Copyright (c) 2006, Montel Laurent, <montel@kde.org>
+# Copyright (c) 2007, Allen Winter, <winter@kde.org>
+# Redistribution and use is allowed according to the terms of the BSD license.
+# For details see the accompanying COPYING-CMAKE-SCRIPTS file.
+
+include(FindLibraryWithDebug)
+
+if (QIMAGEBLITZ_INCLUDES AND QIMAGEBLITZ_LIBRARIES)
+  set(QImageBlitz_FIND_QUIETLY TRUE)
+endif (QIMAGEBLITZ_INCLUDES AND QIMAGEBLITZ_LIBRARIES)
+
+if (NOT WIN32)
+    # use pkg-config to get the directories and then use these values
+    # in the FIND_PATH() and FIND_LIBRARY() calls
+    find_package(PkgConfig)
+    pkg_check_modules(PC_QIMAGEBLITZ QUIET qimageblitz)
+endif (NOT WIN32)
+
+find_path(QIMAGEBLITZ_INCLUDES
+  NAMES
+  qimageblitz.h
+  PATH_SUFFIXES qimageblitz
+  HINTS
+  $ENV{QIMAGEBLITZDIR}/include
+  ${PC_QIMAGEBLITZ_INCLUDEDIR}
+  ${KDE4_INCLUDE_DIR}
+  ${INCLUDE_INSTALL_DIR}
+)
+
+find_library_with_debug(QIMAGEBLITZ_LIBRARIES
+  WIN32_DEBUG_POSTFIX d
+  qimageblitz
+  HINTS
+  $ENV{QIMAGEBLITZDIR}/lib
+  ${PC_QIMAGEBLITZ_LIBDIR}
+  ${KDE4_LIB_DIR}
+  ${LIB_INSTALL_DIR}
+)
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(QImageBlitz DEFAULT_MSG 
+                                  QIMAGEBLITZ_INCLUDES QIMAGEBLITZ_LIBRARIES)
+
+mark_as_advanced(QIMAGEBLITZ_INCLUDES QIMAGEBLITZ_LIBRARIES)