puppet-retrospec 0.8.1 → 0.9.0

data/spec/fixtures/modules/tomcat/manifests/config/server/service.pp

@@ -0,0 +1,54 @@
+# Definition: tomcat::config::server::service
+#
+# Configure a Service element nested in the Server element in
+# $CATALINA_BASE/conf/server.xml
+#
+# Parameters:
+# - $catalina_base is the root of the Tomcat installation.
+# - $class_name is the optional className attribute
+# - $class_name_ensure specifies whether you are trying to set or remove the
+#   className attribute. Valid values are 'true', 'false', 'present', or
+#   'absent'. Defaults to 'present'.
+# - $service_ensure specifies whether you are trying to add or remove the
+#   service element. Valid values are 'true', 'false', 'present', or 'absent'.
+#   Defaults to 'present'.
+define tomcat::config::server::service (
+  $catalina_base     = $::tomcat::catalina_home,
+  $class_name        = undef,
+  $class_name_ensure = 'present',
+  $service_ensure    = 'present',
+  $server_config     = undef,
+) {
+  if versioncmp($::augeasversion, '1.0.0') < 0 {
+    fail('Server configurations require Augeas >= 1.0.0')
+  }
+
+  validate_re($service_ensure, '^(present|absent|true|false)$')
+  validate_re($class_name_ensure, '^(present|absent|true|false)$')
+
+  if $server_config {
+    $_server_config = $server_config
+  } else {
+    $_server_config = "${catalina_base}/conf/server.xml"
+  }
+
+  if $service_ensure =~ /^(absent|false)$/ {
+    $changes = "rm Server/Service[#attribute/name='${name}']"
+  } else {
+    if $class_name_ensure =~ /^(absent|false)$/ {
+      $_class_name = "rm Server/Service[#attribute/name='${name}']/#attribute/className"
+    } elsif $class_name {
+      $_class_name = "set Server/Service[#attribute/name='${name}']/#attribute/className ${class_name}"
+    }
+    $_service = "set Server/Service[#attribute/name='${name}']/#attribute/name ${name}"
+    $changes = delete_undef_values([$_service, $_class_name])
+  }
+
+  if ! empty($changes) {
+    augeas { "server-${catalina_base}-service-${name}":
+      lens    => 'Xml.lns',
+      incl    => $_server_config,
+      changes => $changes,
+    }
+  }
+}

data/spec/fixtures/modules/tomcat/manifests/config/server/tomcat_users.pp

@@ -0,0 +1,97 @@
+# Definition tomcat::config::server::tomcat_users
+#
+# Configures roles and users in $CATALINA_BASE/conf/tomcat-users.xml
+# or any other specified file
+#
+# Parameters:
+# - $catalina_base is the base directory for the Tomcat installation
+# - $element specifies the element type. Valid values are 'user' or 'role'.
+#   Defaults to 'user'.
+# - $element_name sets the 'username' or 'rolename'. Depends on the $element.
+#   Defaults to $name.
+# - $ensure specifies whether you are trying to add or remove the element.
+#   Valid values are 'present', 'absent', 'true', and 'false'. Defaults to
+#   'present'.
+# - $file: The path to the file to manage. Must be fully qualified.
+#   Defaults to $CATALINA_BASE/conf/tomcat-users.xml.
+# - Set $manage_file to true for managing the file. It sets file permission,
+#   owner, group and create a basic tomcat-users XML if file does not exist yet.
+# - $password specifies the password for a user ($element = 'user').
+# - $roles specifies the roles for a user ($element = 'user').
+#
+define tomcat::config::server::tomcat_users (
+  $catalina_base = $::tomcat::catalina_home,
+  $element       = 'user',
+  $element_name  = undef,
+  $ensure        = present,
+  $file          = undef,
+  $manage_file   = true,
+  $password      = undef,
+  $roles         = [],
+) {
+
+  if versioncmp($::augeasversion, '1.0.0') < 0 {
+    fail('Server configurations require Augeas >= 1.0.0')
+  }
+
+  validate_re($element, '^(user|role)$')
+  validate_re($ensure, '^(present|absent|true|false)$')
+  validate_array($roles)
+  validate_bool($manage_file)
+
+  if $element == 'role' and ( $password or ! empty($roles) ) {
+    warning('$password and $roles are useless when $element is set to \'role\'')
+  }
+  
+  if $element == 'user' {
+    $element_identifier = 'username'
+  } else {
+    $element_identifier = 'rolename'
+  }
+
+  if $element_name {
+    $_element_name = $element_name
+  } else {
+    $_element_name = $name
+  }
+  
+  if $file {
+    $_file = $file
+  } else {
+    $_file = "${catalina_base}/conf/tomcat-users.xml"
+  }
+  
+  if $manage_file {
+    ensure_resource('file', $_file, {
+      ensure  => file,
+      path    => $_file,
+      replace => false,
+      content => '<?xml version=\'1.0\' encoding=\'utf-8\'?><tomcat-users></tomcat-users>',
+      owner   => $::tomcat::user,
+      group   => $::tomcat::group,
+      mode    => '0640',
+    })
+  }
+
+  $path = "tomcat-users/${element}[#attribute/${element_identifier}='${_element_name}']"
+
+  if $ensure =~ /^(absent|false)$/ {
+    $remove_entry = "rm ${path}"
+  } else {
+    $add_entry = "set ${path}/#attribute/${element_identifier} ${_element_name}"
+    if $element == 'user' {
+      $add_password = "set ${path}/#attribute/password '${password}'"
+      $add_roles = join(["set ${path}/#attribute/roles '",join($roles, ','),"'"])
+    }
+  }
+
+  $changes = delete_undef_values(flatten([$remove_entry, $add_entry, $add_password, $add_roles]))
+
+  augeas { "${catalina_base}-tomcat_users-${element}-${_element_name}-${name}":
+    lens    => 'Xml.lns',
+    incl    => $_file,
+    changes => $changes,
+    require => File[$_file],
+  }
+
+}

data/spec/fixtures/modules/tomcat/manifests/config/server/valve.pp

@@ -0,0 +1,77 @@
+# Definition tomcat::config::server::valve
+#
+# Configure a Valve element in $CATALINA_BASE/conf/server.xml
+#
+# Parameters:
+# - $catalina_base is the root of the Tomcat installation
+# - $class_name is the className attribute. If not specified, defaults to $name.
+# - $parent_host is the Host element this Valve should be nested beneath. If not
+#   specified, the Valve will be nested beneath the Engine under
+#   $parent_service.
+# - $parent_service is the Service element this Valve should be nested beneath.
+#   Defaults to 'Catalina'.
+# - $valve_ensure specifies whether you are trying to add or remove the Vavle
+#   element. Valid values are 'true', 'false', 'present', or 'absent'. Defaults
+#   to 'present'.
+# - An optional hash of $additional_attributes to add to the Valve. Should be of
+#   the format 'attribute' => 'value'.
+# - An optional array of $attributes_to_remove from the Valve.
+define tomcat::config::server::valve (
+  $catalina_base         = $::tomcat::catalina_home,
+  $class_name            = undef,
+  $parent_host           = undef,
+  $parent_service        = 'Catalina',
+  $valve_ensure          = 'present',
+  $additional_attributes = {},
+  $attributes_to_remove  = [],
+  $server_config         = undef,
+) {
+  if versioncmp($::augeasversion, '1.0.0') < 0 {
+    fail('Server configurations require Augeas >= 1.0.0')
+  }
+
+  validate_re($valve_ensure, '^(present|absent|true|false)$')
+  validate_hash($additional_attributes)
+
+  if $class_name {
+    $_class_name = $class_name
+  } else {
+    $_class_name = $name
+  }
+
+  if $parent_host {
+    $base_path = "Server/Service[#attribute/name='${parent_service}']/Engine/Host[#attribute/name='${parent_host}']/Valve[#attribute/className='${_class_name}']"
+  } else {
+    $base_path = "Server/Service[#attribute/name='${parent_service}']/Engine/Valve[#attribute/className='${_class_name}']"
+  }
+
+  if $server_config {
+    $_server_config = $server_config
+  } else {
+    $_server_config = "${catalina_base}/conf/server.xml"
+  }
+
+  if $valve_ensure =~ /^(absent|false)$/ {
+    $changes = "rm ${base_path}"
+  } else {
+    $_class_name_change = "set ${base_path}/#attribute/className ${_class_name}"
+    if ! empty($additional_attributes) {
+      $_additional_attributes = suffix(prefix(join_keys_to_values($additional_attributes, " '"), "set ${base_path}/#attribute/"), "'")
+    } else {
+      $_additional_attributes = undef
+    }
+    if ! empty(any2array($attributes_to_remove)) {
+      $_attributes_to_remove = prefix(any2array($attributes_to_remove), "rm ${base_path}/#attribute/")
+    } else {
+      $_attributes_to_remove = undef
+    }
+
+    $changes = delete_undef_values(flatten([$_class_name_change, $_additional_attributes, $_attributes_to_remove]))
+  }
+
+  augeas { "${catalina_base}-${parent_service}-${parent_host}-valve-${_class_name}":
+    lens    => 'Xml.lns',
+    incl    => $_server_config,
+    changes => $changes,
+  }
+}

data/spec/fixtures/modules/tomcat/manifests/init.pp

@@ -0,0 +1,71 @@
+# == Class: tomcat
+#
+# Class to manage installation and configuration of Tomcat.
+#
+# === Parameters
+#
+# [*catalina_home*]
+#   The base directory for the Tomcat installation.
+#
+# [*user*]
+#   The user to run Tomcat as.
+#
+# [*group*]
+#   The group to run Tomcat as.
+#
+# [*manage_user*]
+#   Boolean specifying whether or not to manage the user. Defaults to true.
+#
+# [*purge_connectors*]
+#   Boolean specifying whether to purge all Connector elements from server.xml. Defaults to false.
+#
+# [*purge_realms*]
+#   Boolean specifying whether to purge all Realm elements from server.xml. Defaults to false.
+#
+# [*manage_group*]
+#   Boolean specifying whether or not to manage the group. Defaults to true.
+#
+class tomcat (
+  $catalina_home       = $::tomcat::params::catalina_home,
+  $user                = $::tomcat::params::user,
+  $group               = $::tomcat::params::group,
+  $install_from_source = true,
+  $purge_connectors    = false,
+  $purge_realms        = false,
+  $manage_user         = true,
+  $manage_group        = true,
+) inherits ::tomcat::params {
+  validate_bool($install_from_source)
+  validate_bool($purge_connectors)
+  validate_bool($purge_realms)
+  validate_bool($manage_user)
+  validate_bool($manage_group)
+
+  case $::osfamily {
+    'windows','Solaris','Darwin': {
+      fail("Unsupported osfamily: ${::osfamily}")
+    }
+    default: { }
+  }
+
+  if $install_from_source {
+    file { $catalina_home:
+      ensure => directory,
+      owner  => $user,
+      group  => $group,
+    }
+  }
+
+  if $manage_user {
+    user { $user:
+      ensure => present,
+      gid    => $group
+    }
+  }
+
+  if $manage_group {
+    group { $group:
+      ensure => present,
+    }
+  }
+}

data/spec/fixtures/modules/tomcat/manifests/instance.pp

@@ -0,0 +1,88 @@
+# Definition: tomcat::instance
+#
+# This define installs an instance of Tomcat.
+#
+# Parameters:
+# - $catalina_home is the root of the Tomcat installation. This parameter only
+#   affects the instance when $install_from_source is true.
+# - $catalina_base is the base directory for the Tomcat installation. This
+#   parameter only affects the instance when $install_from_source is true.
+# - $install_from_source is a boolean specifying whether or not to install from
+#   source. Defaults to true.
+# - The $source_url to install from. Required if $install_from_source is true.
+# - $source_strip_first_dir is a boolean specifying whether or not to strip
+#   the first directory when unpacking the source tarball. Defaults to true
+#   when installing from source. Requires nanliu/staging > 0.4.0
+# - $package_ensure when installing from package, what the ensure should be set
+#   to in the package resource.
+# - $package_name is the name of the package you want to install. Required if
+#   $install_from_source is false.
+define tomcat::instance (
+  $catalina_home          = undef,
+  $catalina_base          = undef,
+  $install_from_source    = $::tomcat::install_from_source,
+  $source_url             = undef,
+  $source_strip_first_dir = undef,
+  $package_ensure         = undef,
+  $package_name           = undef,
+) {
+
+  if $install_from_source {
+    validate_bool($install_from_source)
+  }
+  if $source_strip_first_dir {
+    validate_bool($source_strip_first_dir)
+  }
+
+  if $install_from_source and ! $source_url {
+    fail('If installing from source $source_url must be specified')
+  }
+
+  if ! $install_from_source and ! $package_name {
+    fail('If not installing from source $package_name must be specified')
+  }
+
+  if ! $install_from_source and ($catalina_home or $catalina_base) {
+    warning('Setting $catalina_home or $catalina_base when not installing from source doesn\'t affect the installation.')
+  }
+
+  if ! $catalina_home {
+    $_catalina_home = $::tomcat::catalina_home
+  } else {
+    $_catalina_home = $catalina_home
+  }
+
+  if ! $catalina_base {
+    $_catalina_base = $::tomcat::catalina_home
+  } else {
+    $_catalina_base = $catalina_base
+  }
+
+  if $install_from_source {
+    if ! $source_strip_first_dir {
+      $source_strip = true
+    } else {
+      $source_strip = $source_strip_first_dir
+    }
+
+    tomcat::instance::source { $name:
+      catalina_home          => $_catalina_home,
+      catalina_base          => $_catalina_base,
+      source_url             => $source_url,
+      source_strip_first_dir => $source_strip,
+      require                => File[$_catalina_base],
+    }
+  } else {
+    tomcat::instance::package { $package_name:
+      package_ensure => $package_ensure,
+    }
+  }
+
+  if $install_from_source and $_catalina_base != $_catalina_home {
+    file { $_catalina_base:
+      ensure => directory,
+      owner  => $::tomcat::user,
+      group  => $::tomcat::group,
+    }
+  }
+}

data/spec/fixtures/modules/tomcat/manifests/instance/package.pp

@@ -0,0 +1,26 @@
+# Definition: tomcat::instance::package
+#
+# Private define to install Tomcat from a package.
+#
+# Parameters:
+# - $package_ensure is the ensure passed to the package resource.
+# - The $package_name you want to install.
+define tomcat::instance::package (
+  $package_ensure = 'installed',
+  $package_name = undef,
+) {
+  if $caller_module_name != $module_name {
+    fail("Use of private class ${name} by ${caller_module_name}")
+  }
+
+  if $package_name {
+    $_package_name = $package_name
+  } else {
+    $_package_name = $name
+  }
+
+  package { $_package_name:
+    ensure => $package_ensure
+  }
+
+}

data/spec/fixtures/modules/tomcat/manifests/instance/source.pp

@@ -0,0 +1,46 @@
+# Definition: tomcat::instance::source
+#
+# Private define to install Tomcat from source.
+#
+# Parameters:
+# - $catalina_home is the root of the Tomcat installation.
+# - $catalina_base is the base directory for the Tomcat installation.
+# - The $source_url to install from.
+# - $source_strip_first_dir is a boolean specifying whether or not to strip
+#   the first directory when unpacking the source tarball. Defaults to true
+#   when installing from source on non-Solaris systems. Requires nanliu/staging
+#   > 0.4.0
+define tomcat::instance::source (
+  $catalina_home,
+  $catalina_base,
+  $source_url,
+  $source_strip_first_dir = undef,
+) {
+  include staging
+
+  if $caller_module_name != $module_name {
+    fail("Use of private class ${name} by ${caller_module_name}")
+  }
+
+  if $source_strip_first_dir {
+    $_strip = 1
+  }
+
+  $filename = regsubst($source_url, '.*/(.*)', '\1')
+
+  if ! defined(Staging::File[$filename]) {
+    staging::file { $filename:
+      source => $source_url,
+    }
+  }
+
+  staging::extract { "${name}-${filename}":
+    source  => "${::staging::path}/tomcat/${filename}",
+    target  => $catalina_base,
+    require => Staging::File[$filename],
+    unless  => "test \"\$(ls -A ${catalina_base})\"",
+    user    => $::tomcat::user,
+    group   => $::tomcat::group,
+    strip   => $_strip,
+  }
+}