puppet-retrospec 0.12.1 → 0.12.2

data/spec/fixtures/modules/tomcat/manifests/config/server/context.pp

@@ -1,102 +0,0 @@
-# Definition tomcat::config::server::context
-#
-# Configure a Context element in $CATALINA_BASE/conf/server.xml
-#
-# Parameters:
-# - $catalina_base is the root of the Tomcat installation
-# - $context_ensure specifies whether you are trying to add or remove the Context
-#   element. Valid values are 'true', 'false', 'present', or 'absent'. Defaults
-#   to 'present'.
-# - $doc_base is the docBase attribute of the Context.
-#   If not specified, defaults to $name.
-# - $parent_service is the Service element this Context should be nested beneath.
-#   Defaults to 'Catalina'.
-# - $parent_engine is the `name` attribute to the Engine element the Host of this Context 
-#   should be nested beneath. Only valid if $parent_host is specified.
-# - $parent_host is the `name` attribute to the Host element this Context
-#   should be nested beneath.
-# - An optional hash of $additional_attributes to add to the Context. Should be of
-#   the format 'attribute' => 'value'.
-# - An optional array of $attributes_to_remove from the Context.
-#
-define tomcat::config::server::context (
-  $catalina_base         = $::tomcat::catalina_home,
-  $context_ensure        = 'present',
-  $doc_base              = undef,
-  $parent_service        = undef,
-  $parent_engine         = undef,
-  $parent_host           = undef,
-  $additional_attributes = {},
-  $attributes_to_remove  = [],
-  $server_config         = undef,
-) {
-  if versioncmp($::augeasversion, '1.0.0') < 0 {
-    fail('Server configurations require Augeas >= 1.0.0')
-  }
-
-  validate_re($context_ensure, '^(present|absent|true|false)$')
-  validate_hash($additional_attributes)
-  validate_array($attributes_to_remove)
-
-  if $doc_base {
-    $_doc_base = $doc_base
-  } else {
-    $_doc_base = $name
-  }
-
-  if $parent_service {
-    $_parent_service = $parent_service
-  } else {
-    $_parent_service = 'Catalina'
-  }
-
-  if $parent_engine and ! $parent_host {
-    warning('context elements cannot be nested directly under engine elements, ignoring $parent_engine')
-  }
-
-  if $parent_engine and $parent_host {
-    $_parent_engine = $parent_engine
-  } else {
-    $_parent_engine = undef
-  }
-
-  if $server_config {
-    $_server_config = $server_config
-  } else {
-    $_server_config = "${catalina_base}/conf/server.xml"
-  }
-
-  if $parent_host and ! $_parent_engine {
-    $path = "Server/Service[#attribute/name='${_parent_service}']/Engine/Host[#attribute/name='${parent_host}']/Context[#attribute/docBase='${_doc_base}']"
-  } elsif $parent_host and $_parent_engine {
-    $path = "Server/Service[#attribute/name='${_parent_service}']/Engine[#attribute/name='${_parent_engine}']/Host[#attribute/name='${parent_host}']/Context[#attribute/docBase='${_doc_base}']"
-  } else {
-    $path = "Server/Service[#attribute/name='${_parent_service}']/Engine/Host/Context[#attribute/docBase='${_doc_base}']"
-  }
-  
-  if $context_ensure =~ /^(absent|false)$/ {
-    $augeaschanges = "rm ${path}"
-  } else {
-    $context = "set ${path}/#attribute/docBase ${_doc_base}"
-
-    if ! empty($additional_attributes) {
-      $_additional_attributes = suffix(prefix(join_keys_to_values($additional_attributes, " '"), "set ${path}/#attribute/"), "'")
-    } else {
-      $_additional_attributes = undef
-    }
-
-    if ! empty(any2array($attributes_to_remove)) {
-      $_attributes_to_remove = prefix(any2array($attributes_to_remove), "rm ${path}/#attribute/")
-    } else {
-      $_attributes_to_remove = undef
-    }
-
-    $augeaschanges = delete_undef_values(flatten([$context, $_additional_attributes, $_attributes_to_remove]))
-  }
-
-  augeas { "${catalina_base}-${_parent_service}-${_parent_engine}-${parent_host}-context-${name}":
-    lens    => 'Xml.lns',
-    incl    => $_server_config,
-    changes => $augeaschanges,
-  }
-}

data/spec/fixtures/modules/tomcat/manifests/config/server/engine.pp

@@ -1,109 +0,0 @@
-# Definition: tomcat::config::server::engine
-#
-# Configure Engine elements in $CATALINA_BASE/conf/server.xml
-#
-# Parameters:
-# - $default_host is the defaultHost attribute for the Engine. This parameter is
-#   required.
-# - $catalina_base is the base directory for the Tomcat installation.
-# - $background_processor_delay is the optional backgroundProcessorDelay
-#   attribute.
-# - $background_processor_delay_ensure specifies whether you are trying to add
-#   or remove the backgroundProcessorDelay attribute. Valid values are 'true',
-#   'false', 'present', and 'absent'. Defaults to 'present'.
-# - $class_name is the optional className attribute.
-# - $class_name_ensure specifies whether you are trying to add or remove the
-#   className attribute. Valid values are 'true', 'false', 'present', and
-#   'absent'. Defaults to 'present'.
-# - $engine_name is the name attribute. Defaults to $name.
-# - $jvm_route is the optional jvmRoute attribute.
-# - $jvm_route_ensure specifies whether you are trying to add or remove the
-#   jvmRoute attribute. Valid values are 'true', 'false', 'present', and
-#   'absent'. Defaults to 'present'.
-# - $parent_service is the Service element this Engine should be nested beneath.
-#   Defaults to 'Catalina'.
-# - $start_stop_threads is the optional startStopThreads attribute
-# - $start_stop_threads_ensure specifies whether you are trying to add or remove
-#   the startStopThreads attribute. Valid values are 'true', 'false', 'present'
-#   and 'absent'. Defaults to 'present'.
-define tomcat::config::server::engine (
-  $default_host,
-  $catalina_base                     = $::tomcat::catalina_home,
-  $background_processor_delay        = undef,
-  $background_processor_delay_ensure = 'present',
-  $class_name                        = undef,
-  $class_name_ensure                 = 'present',
-  $engine_name                       = undef,
-  $jvm_route                         = undef,
-  $jvm_route_ensure                  = 'present',
-  $parent_service                    = 'Catalina',
-  $start_stop_threads                = undef,
-  $start_stop_threads_ensure         = 'present',
-  $server_config                     = undef,
-) {
-  if versioncmp($::augeasversion, '1.0.0') < 0 {
-    fail('Server configurations require Augeas >= 1.0.0')
-  }
-
-  validate_re($background_processor_delay_ensure, '^(present|absent|true|false)$')
-  validate_re($class_name_ensure, '^(present|absent|true|false)$')
-  validate_re($jvm_route_ensure, '^(present|absent|true|false)$')
-  validate_re($start_stop_threads_ensure, '^(present|absent|true|false)$')
-
-  if $engine_name {
-    $_name = $engine_name
-  } else {
-    $_name = $name
-  }
-
-  $base_path = "Server/Service[#attribute/name='${parent_service}']/Engine"
-
-  $_name_change = "set ${base_path}/#attribute/name ${_name}"
-  $_default_host = "set ${base_path}/#attribute/defaultHost ${default_host}"
-
-  if $background_processor_delay_ensure =~ /^(absent|false)$/ {
-    $_background_processor_delay = "rm ${base_path}/#attribute/backgroundProcessorDelay"
-  } elsif $background_processor_delay {
-    $_background_processor_delay = "set ${base_path}/#attribute/backgroundProcessorDelay ${background_processor_delay}"
-  } else {
-    $_background_processor_delay = undef
-  }
-
-  if $class_name_ensure =~ /^(absent|false)$/ {
-    $_class_name = "rm ${base_path}/#attribute/className"
-  } elsif $class_name {
-    $_class_name = "set ${base_path}/#attribute/className ${class_name}"
-  } else {
-    $_class_name = undef
-  }
-
-  if $jvm_route_ensure =~ /^(absent|false)$/ {
-    $_jvm_route = "rm ${base_path}/#attribute/jvmRoute"
-  } elsif $jvm_route {
-    $_jvm_route = "set ${base_path}/#attribute/jvmRoute ${jvm_route}"
-  } else {
-    $_jvm_route = undef
-  }
-
-  if $start_stop_threads_ensure =~ /^(absent|false)$/ {
-    $_start_stop_threads = "rm ${base_path}/#attribute/startStopThreads"
-  } elsif $start_stop_threads {
-    $_start_stop_threads = "set ${base_path}/#attribute/startStopThreads ${start_stop_threads}"
-  } else {
-    $_start_stop_threads = undef
-  }
-
-  if $server_config {
-    $_server_config = $server_config
-  } else {
-    $_server_config = "${catalina_base}/conf/server.xml"
-  }
-
-  $changes = delete_undef_values([$_name_change, $_default_host, $_background_processor_delay, $_class_name, $_jvm_route, $_start_stop_threads])
-
-  augeas { "${catalina_base}-${parent_service}-engine":
-    lens    => 'Xml.lns',
-    incl    => $_server_config,
-    changes => $changes,
-  }
-}

data/spec/fixtures/modules/tomcat/manifests/config/server/host.pp

@@ -1,79 +0,0 @@
-# Definition: tomcat::config::server::host
-#
-# Configure Host elements in $CATALINA_BASE/conf/server.xml
-#
-# Parameters:
-# - $app_base is the appBase attribute for the Host. This parameter is required
-#   unless $host_ensure is set to 'false' or 'absent'.
-# - $catalina_base is the base directory for the Tomcat installation.
-# - $host_ensure specifies whether you are trying to add or remove the Host
-#   element. Valid values are 'true', 'false', 'present', and 'absent'. Defaults
-#   to 'present'.
-# - $host_name is the name attribute for the Host. Defaults to $name.
-# - $parent_service is the Service element this Host should be nested beneath.
-#   Defaults to 'Catalina'
-# - An optional hash of $additional_attributes to add to the Host. Should be of
-#   the format 'attribute' => 'value'.
-# - An optional array of $attributes_to_remove from the Host.
-define tomcat::config::server::host (
-  $app_base              = undef,
-  $catalina_base         = $::tomcat::catalina_home,
-  $host_ensure           = 'present',
-  $host_name             = undef,
-  $parent_service        = 'Catalina',
-  $additional_attributes = {},
-  $attributes_to_remove  = [],
-  $server_config         = undef,
-) {
-  if versioncmp($::augeasversion, '1.0.0') < 0 {
-    fail('Server configurations require Augeas >= 1.0.0')
-  }
-
-  validate_re($host_ensure, '^(present|absent|true|false)$')
-  validate_hash($additional_attributes)
-
-  if $host_name {
-    $_host_name = $host_name
-  } else {
-    $_host_name = $name
-  }
-
-  $base_path = "Server/Service[#attribute/name='${parent_service}']/Engine/Host[#attribute/name='${_host_name}']"
-
-  if $server_config {
-    $_server_config = $server_config
-  } else {
-    $_server_config = "${catalina_base}/conf/server.xml"
-  }
-
-  if $host_ensure =~ /^(absent|false)$/ {
-    $changes = "rm ${base_path}"
-  } else {
-    if ! $app_base {
-      fail('$app_base must be specified if you aren\'t removing the host')
-    }
-
-    $_host_name_change = "set ${base_path}/#attribute/name ${_host_name}"
-    $_app_base = "set ${base_path}/#attribute/appBase ${app_base}"
-
-    if ! empty($additional_attributes) {
-      $_additional_attributes = suffix(prefix(join_keys_to_values($additional_attributes, " '"), "set ${base_path}/#attribute/"), "'")
-    } else {
-      $_additional_attributes = undef
-    }
-
-    if ! empty(any2array($attributes_to_remove)) {
-      $_attributes_to_remove = prefix(any2array($attributes_to_remove), "rm ${base_path}/#attribute/")
-    } else {
-      $_attributes_to_remove = undef
-    }
-
-    $changes = delete_undef_values(flatten([$_host_name_change, $_app_base, $_additional_attributes, $_attributes_to_remove]))
-  }
-
-  augeas { "${catalina_base}-${parent_service}-host-${_host_name}":
-    lens    => 'Xml.lns',
-    incl    => $_server_config,
-    changes => $changes,
-  }
-}

data/spec/fixtures/modules/tomcat/manifests/config/server/listener.pp

@@ -1,98 +0,0 @@
-# Definition: tomcat::config::server::listener
-#
-# Configure Listener elements in $CATALINA_BASE/conf/server.xml
-#
-# Parameters:
-# - $catalina_base is the base directory for the Tomcat installation.
-# - $listener_ensure specifies whether you are trying to add or remove the
-#   Listener element. Valid values are 'true', 'false', 'present', and
-#   'absent'. Defaults to 'present'.
-# - $class_name is the Java class name of the implementation to use.
-#   Defaults to $name.
-# - $parent_service is the Service element this Listener should be nested 
-#   beneath. Only valid if $parent_host or $parent_engine is specified. Defaults
-#   to 'Catalina' if $parent_host or $parent_engine was specified.
-# - $parent_engine is the `name` attribute to the Engine element this Listener
-#   should be nested beneath.
-# - $parent_host is the `name` attribute to the Engine element this Listener
-#   should be nested beneath.
-# - An optional hash of $additional_attributes to add to the Listener. Should
-#   be of the format 'attribute' => 'value'.
-# - An optional array of $attributes_to_remove from the Listener.
-define tomcat::config::server::listener (
-  $catalina_base         = $::tomcat::catalina_home,
-  $listener_ensure       = 'present',
-  $class_name            = undef,
-  $parent_service        = undef,
-  $parent_engine         = undef,
-  $parent_host           = undef,
-  $additional_attributes = {},
-  $attributes_to_remove  = [],
-  $server_config         = undef,
-) {
-  if versioncmp($::augeasversion, '1.0.0') < 0 {
-    fail('Server configurations require Augeas >= 1.0.0')
-  }
-  
-  validate_re($listener_ensure, '^(present|absent|true|false)$')
-  validate_hash($additional_attributes)
-  validate_array($attributes_to_remove)
-  
-  if $parent_service and ! ($parent_host or $parent_engine) {
-    warning('listener elements cannot be nested directly under service elements, ignoring $parent_service')
-  }
-
-  if ! $parent_service and ($parent_engine or $parent_host) {
-    $_parent_service = 'Catalina'
-  } else {
-    $_parent_service = $parent_service
-  }
-
-  if $class_name {
-    $_class_name = $class_name
-  } else {
-    $_class_name = $name
-  }
-  
-  if $parent_engine and ! $parent_host {
-    $path = "Server/Service[#attribute/name='${_parent_service}']/Engine[#attribute/name='${parent_engine}']/Listener[#attribute/className='${_class_name}']"
-  } elsif $parent_engine and $parent_host {
-    $path = "Server/Service[#attribute/name='${_parent_service}']/Engine[#attribute/name='${parent_engine}']/Host[#attribute/name='${parent_host}']/Listener[#attribute/className='${_class_name}']"
-  } elsif $parent_host {
-    $path = "Server/Service[#attribute/name='${_parent_service}']/Engine/Host[#attribute/name='${parent_host}']/Listener[#attribute/className='${_class_name}']"
-  } else {
-    $path = "Server/Listener[#attribute/className='${_class_name}']"
-  }
-
-  if $server_config {
-    $_server_config = $server_config
-  } else {
-    $_server_config = "${catalina_base}/conf/server.xml"
-  }
-
-  if $listener_ensure =~ /^(absent|false)$/ {
-    $augeaschanges = "rm ${path}"
-  } else {
-    $listener = "set ${path}/#attribute/className ${_class_name}"
-
-    if ! empty($additional_attributes) {
-      $_additional_attributes = suffix(prefix(join_keys_to_values($additional_attributes, " '"), "set ${path}/#attribute/"), "'")
-    } else {
-      $_additional_attributes = undef
-    }
-
-    if ! empty(any2array($attributes_to_remove)) {
-      $_attributes_to_remove = prefix(any2array($attributes_to_remove), "rm ${path}/#attribute/")
-    } else {
-      $_attributes_to_remove = undef
-    }
-
-    $augeaschanges = delete_undef_values(flatten([$listener, $_additional_attributes, $_attributes_to_remove]))
-  }
-
-  augeas { "${catalina_base}-${_parent_service}-${parent_engine}-${parent_host}-listener-${name}":
-    lens    => 'Xml.lns',
-    incl    => $_server_config,
-    changes => $augeaschanges,
-  }
-}

data/spec/fixtures/modules/tomcat/manifests/config/server/realm.pp

@@ -1,104 +0,0 @@
-# Definition: tomcat::config::server::realm
-#
-# Configure Realm elements in $CATALINA_BASE/conf/server.xml
-#
-# Parameters:
-# - $catalina_base is the base directory for the Tomcat installation.
-# - $class_name is the Java class name of the Realm implementation to use.
-# - $realm_ensure specifies whether you are adding or removing a
-#   Realm element. Valid values are 'true', 'false', 'present', and
-#   'absent'. Defaults to 'present'.
-# - $parent_service is the `name` attribute for the Service element this Realm
-#   should be nested beneath. Defaults to 'Catalina'.
-# - $parent_engine is the `name` attribute for the Engine element this Realm
-#   should be nested beneath. Defaults to 'Catalina'.
-# - $parent_host is the `name` attribute for the Host element this Realm
-#   should be nested beneath.
-# - $parent_realm is the `name` attribute for the Realm element this Realm
-#   should be nested beneath.
-# - An optional hash of $additional_attributes to add to the Realm. Should
-#   be of the format 'attribute' => 'value'.
-# - An optional array of $attributes_to_remove from the Realm.
-define tomcat::config::server::realm (
-  $catalina_base         = $::tomcat::catalina_home,
-  $class_name            = $name,
-  $realm_ensure          = 'present',
-  $parent_service        = 'Catalina',
-  $parent_engine         = 'Catalina',
-  $parent_host           = undef,
-  $parent_realm          = undef,
-  $additional_attributes = {},
-  $attributes_to_remove  = [],
-  $purge_realms          = $::tomcat::purge_realms,
-  $server_config         = undef,
-) {
-
-  if versioncmp($::augeasversion, '1.0.0') < 0 {
-    fail('Server configurations require Augeas >= 1.0.0')
-  }
-  validate_re($realm_ensure, '^(present|absent|true|false)$')
-  validate_hash($additional_attributes)
-  validate_array($attributes_to_remove)
-  validate_bool($purge_realms)
-
-  if $purge_realms and ($realm_ensure =~ /^(absent|false)$/) {
-    fail('$realm_ensure must be set to \'true\' or \'present\' to use $purge_realms')
-  }
-
-  if $purge_realms {
-    $_purge_realms = 'rm Server//Realm'
-  } else {
-    $_purge_realms = undef
-  }
-
-  $engine_path = "Server/Service[#attribute/name='${parent_service}']/Engine[#attribute/name='${parent_engine}']"
-
-  # The Realm may be nested under a Host element.
-  if $parent_host {
-    $host_path = "${engine_path}/Host[#attribute/name='${parent_host}']"
-  } else {
-    $host_path = $engine_path
-  }
-
-  # The Realm could also be nested under another Realm element if the parent realm is a CombinedRealm.
-  if $parent_realm {
-    $path = "${host_path}/Realm[#attribute/className='${parent_realm}']/Realm"
-  }
-  else {
-    $path = "${host_path}/Realm"
-  }
-
-  if $server_config {
-    $_server_config = $server_config
-  } else {
-    $_server_config = "${catalina_base}/conf/server.xml"
-  }
-
-  if $realm_ensure =~ /^(absent|false)$/ {
-    $changes = "rm ${path}[#attribute/className='${class_name}']"
-  }
-  else {
-
-    $_class_name = "set ${path}/#attribute/className ${class_name}"
-
-    if ! empty($additional_attributes) {
-      $_additional_attributes = suffix(prefix(join_keys_to_values($additional_attributes, " '"), "set ${path}[#attribute/className='${class_name}']/#attribute/"), "'")
-    } else {
-      $_additional_attributes = undef
-    }
-    if ! empty(any2array($attributes_to_remove)) {
-      $_attributes_to_remove = prefix(any2array($attributes_to_remove), "rm ${path}[#attribute/className='${class_name}']/#attribute/")
-    } else {
-      $_attributes_to_remove = undef
-    }
-
-    $changes = delete_undef_values(flatten([ $_purge_realms, $_class_name, $_additional_attributes, $_attributes_to_remove ]))
-  }
-
-  augeas { "${catalina_base}-${parent_service}-${parent_engine}-${parent_host}-${parent_realm}-realm-${class_name}":
-    lens    => 'Xml.lns',
-    incl    => $_server_config,
-    changes => $changes,
-  }
-
-}