pulse_meter_visualizer 0.4.11

data/lib/pulse_meter/visualize/base.rb

@@ -0,0 +1,15 @@
+module PulseMeter
+  module Visualize
+    class Base
+      def initialize(opts)
+        @opts = opts
+      end
+
+      def method_missing(name, *args)
+        @opts[name.to_sym]
+      end
+    end
+  end
+end
+
+

data/lib/pulse_meter/visualize/coffee/application.coffee

@@ -0,0 +1,40 @@
+#= require extensions
+#= require models/page_info
+#= require models/widget
+#= require models/dinamic_widget
+#= require models/sensor_info
+#= require collections/page_info_list
+#= require collections/sensor_info_list
+#= require collections/widget_list
+#= require presenters/widget
+#= require presenters/pie
+#= require presenters/timeline
+#= require presenters/series
+#= require presenters/line
+#= require presenters/area
+#= require presenters/table
+#= require presenters/gauge
+#= require views/page_title
+#= require views/page_titles
+#= require views/sensor_info_list
+#= require views/dynamic_chart
+#= require views/dynamic_widget
+#= require views/widget_chart
+#= require views/widget
+#= require views/widget_list
+#= require router
+
+document.startApp = ->
+	pageInfos = new PageInfoList
+	pageTitlesApp = new PageTitlesView(pageInfos)
+	pageInfos.reset gon.pageInfos
+
+	widgetList = new WidgetList
+	widgetList.setContext(pageInfos)
+	widgetList.startPolling()
+
+	widgetListApp = new WidgetListView {widgetList: widgetList, pageInfos: pageInfos}
+
+	appRouter = new AppRouter(pageInfos, widgetList)
+
+	Backbone.history.start()

data/lib/pulse_meter/visualize/coffee/collections/page_info_list.coffee

@@ -0,0 +1,17 @@
+PageInfoList = Backbone.Collection.extend {
+	model: PageInfo
+	selected: ->
+		@find (m) ->
+			m.get 'selected'
+
+	selectFirst: ->
+		@at(0).set('selected', true) if @length > 0
+	
+	selectNone: ->
+		@each (m) ->
+			m.set 'selected', false
+
+	selectPage: (id) ->
+		@each (m) ->
+			m.set 'selected', m.id == id
+}

data/lib/pulse_meter/visualize/coffee/collections/sensor_info_list.coffee

@@ -0,0 +1,4 @@
+SensorInfoList = Backbone.Collection.extend {
+	model: SensorInfo
+	url: -> ROOT + 'sensors'
+}

data/lib/pulse_meter/visualize/coffee/collections/widget_list.coffee

@@ -0,0 +1,14 @@
+WidgetList = Backbone.Collection.extend {
+	model: Widget
+
+	setContext: (@pageInfos) ->
+
+	url: -> ROOT + 'pages/' + @pageInfos.selected().id + '/widgets'
+
+	startPolling: ->
+		setInterval( =>
+			if @pageInfos.selected()
+				@each (w) ->
+					w.refetch()
+		, 200)
+}

data/lib/pulse_meter/visualize/coffee/extensions.coffee

@@ -0,0 +1,26 @@
+String::capitalize = ->
+	@charAt(0).toUpperCase() + @slice(1)
+String::strip = ->
+	if String::trim? then @trim() else @replace /^\s+|\s+$/g, ""
+
+Number::humanize = ->
+	interval = this
+	res = ""
+	s = interval % 60
+	res = "#{s} s" if s > 0
+	interval = (interval - s) / 60
+	return res unless interval > 0
+
+	m = interval % 60
+	res = "#{m} m #{res}".strip() if m > 0
+	interval = (interval - m) / 60
+	return res unless interval > 0
+
+	h = interval % 24
+	res = "#{h} h #{res}".strip() if h > 0
+	d = (interval - h) / 24
+	if d > 0
+		"#{d} d #{res}".strip()
+	else
+		res
+

data/lib/pulse_meter/visualize/coffee/models/dinamic_widget.coffee

@@ -0,0 +1,34 @@
+DynamicWidget = Backbone.Model.extend {
+
+	setStartTime: (@startTime) ->
+
+	setEndTime: (@endTime) ->
+
+	increaseTimespan: (inc) ->
+		@set('timespan', @timespan() + inc)
+
+	resetTimespan: ->
+		@startTime = null
+		@endTime = null
+		@set('timespan', null)
+
+	timespan: -> @get('timespan')
+
+	sensorArgs: ->
+		_.map(@get('sensorIds'), (name) -> "sensor[]=#{name}").join('&')
+
+	url: ->
+		timespan = @timespan()
+		url = "#{ROOT}dynamic_widget?#{@sensorArgs()}&type=#{@get('type')}"
+		url += "&timespan=#{timespan}" if timespan? && !_.isNaN(timespan)
+		url += "&startTime=#{@startTime}" if @startTime
+		url += "&endTime=#{@endTime}" if @endTime
+		url
+
+		
+	forceUpdate: ->
+		@fetch {
+			success: (model, response) ->
+				model.trigger('redraw')
+		}
+}

data/lib/pulse_meter/visualize/coffee/models/page_info.coffee

@@ -0,0 +1,2 @@
+PageInfo = Backbone.Model.extend {
+}

data/lib/pulse_meter/visualize/coffee/models/sensor_info.coffee

@@ -0,0 +1,2 @@
+SensorInfo = Backbone.Model.extend {
+}

data/lib/pulse_meter/visualize/coffee/models/widget.coffee

@@ -0,0 +1,54 @@
+Widget = Backbone.Model.extend {
+	initialize: ->
+		@needRefresh = true
+		@setNextFetch()
+		@timespanInc = 0
+
+	setStartTime: (@startTime) ->
+
+	setEndTime: (@endTime) ->
+
+	increaseTimespan: (inc) ->
+		@timespanInc = @timespanInc + inc
+		@forceUpdate()
+
+	resetTimespan: ->
+		@timespanInc = 0
+		@startTime = null
+		@endTime = null
+		@forceUpdate()
+
+	timespan: -> @get('timespan') + @timespanInc
+
+	url: ->
+		timespan = @timespan()
+		url = "#{@collection.url()}/#{@get('id')}?"
+		url += "&timespan=#{timespan}" unless _.isNaN(timespan)
+		url += "&startTime=#{@startTime}" if @startTime
+		url += "&endTime=#{@endTime}" if @endTime
+		url
+
+	time: -> (new Date()).getTime()
+
+	setNextFetch: ->
+		@nextFetch = @time() + @get('redrawInterval') * 1000
+
+	setRefresh: (needRefresh) ->
+		@needRefresh = needRefresh
+
+	needFetch: ->
+		interval = @get('redrawInterval')
+		@time() > @nextFetch && @needRefresh && interval? && interval > 0
+
+	refetch: ->
+		if @needFetch()
+			@forceUpdate()
+			@setNextFetch()
+
+	forceUpdate: ->
+		@fetch {
+			success: (model, response) ->
+				model.trigger('redraw')
+		}
+
+}

data/lib/pulse_meter/visualize/coffee/presenters/area.coffee

@@ -0,0 +1,2 @@
+class AreaPresenter extends SeriesPresenter
+	visualization: 'AreaChart'

data/lib/pulse_meter/visualize/coffee/presenters/gauge.coffee

@@ -0,0 +1,11 @@
+class GaugePresenter extends WidgetPresenter
+	visualization: 'Gauge'
+
+	cutoff: ->
+
+	data: ->
+		data = super()
+		data.addColumn('string', 'Label')
+		data.addColumn('number', @get('valuesTitle'))
+		data.addRows(@get('series'))
+		data

data/lib/pulse_meter/visualize/coffee/presenters/line.coffee

@@ -0,0 +1,2 @@
+class LinePresenter extends SeriesPresenter
+	visualization: 'LineChart'

data/lib/pulse_meter/visualize/coffee/presenters/pie.coffee

@@ -0,0 +1,20 @@
+class PiePresenter extends WidgetPresenter
+	visualization: 'PieChart'
+
+	cutoff: ->
+	
+	data: ->
+		data = super()
+		data.addColumn('string', 'Title')
+		data.addColumn('number', @get('valuesTitle'))
+		data.addRows(@get('series').data)
+		data
+
+	options: ->
+		$.extend true, super(), {
+			slices: @get('series').options
+			legend: {
+				position: 'bottom'
+			}
+		}
+

data/lib/pulse_meter/visualize/coffee/presenters/series.coffee

@@ -0,0 +1,44 @@
+class SeriesPresenter extends TimelinePresenter
+	options: ->
+		secondPart = if @get('interval') % 60 == 0 then '' else ':ss'
+		format = if @model.timespan() > 24 * 60 * 60
+			"yyyy.MM.dd HH:mm#{secondPart}"
+		else
+			"HH:mm#{secondPart}"
+
+		$.extend true, super(), {
+			lineWidth: 1
+			chartArea: {
+				width: '100%'
+			}
+			legend: {
+				position: 'bottom'
+			}
+			vAxis: {
+				title: @valuesTitle()
+				textPosition: 'in'
+			}
+			hAxis: {
+				format: format
+			}
+			series: @get('series').options
+			axisTitlesPosition: 'in'
+		}
+
+	valuesTitle: ->
+		if @get('valuesTitle')
+			"#{@get('valuesTitle')} / #{@humanizedInterval()}"
+		else
+			@humanizedInterval()
+
+
+	humanizedInterval: ->
+		@get('interval').humanize()
+	
+	cutoff: (min, max) ->
+		_.each(@get('series').rows, (row) =>
+			for i in [1 .. row.length - 1]
+				value = row[i]
+				value = 0 unless value?
+				row[i] = @cutoffValue(value, min, max)
+		)

data/lib/pulse_meter/visualize/coffee/presenters/table.coffee

@@ -0,0 +1,10 @@
+class TablePresenter extends TimelinePresenter
+	visualization: 'Table'
+
+	cutoff: ->
+
+	options: ->
+		$.extend true, super(), {
+			sortColumn: 0
+			sortAscending: false
+		}

data/lib/pulse_meter/visualize/coffee/presenters/timeline.coffee

@@ -0,0 +1,13 @@
+class TimelinePresenter extends WidgetPresenter
+	data: ->
+		data = super()
+		data.addColumn('datetime', 'Time')
+		dateOffset = @dateOffset() + @get('interval') * 1000
+		series = @get('series')
+		_.each series.titles, (t) ->
+			data.addColumn('number', t)
+
+		_.each series.rows, (row) ->
+			row[0] = new Date(row[0] + dateOffset)
+			data.addRow(row)
+		data

data/lib/pulse_meter/visualize/coffee/presenters/widget.coffee

@@ -0,0 +1,65 @@
+class WidgetPresenter
+	constructor: (@pageInfos, @model, el) ->
+		chartClass = @chartClass()
+		@chart = new chartClass(el)
+		@draw()
+
+	get: (arg) -> @model.get(arg)
+
+	globalOptions: -> gon.options
+
+	dateOffset: ->
+		if @globalOptions.useUtc
+			(new Date).getTimezoneOffset() * 60000
+		else
+			0
+	
+	options: ->
+		{
+			title: @get('title')
+			height: 300
+			chartArea:
+				left: 10
+		}
+
+	mergedOptions: ->
+		pageOptions = if @pageInfos.selected()
+			@pageInfos.selected().get('gchartOptions')
+		else
+			{}
+
+		$.extend(true,
+			@options(),
+			@globalOptions.gchartOptions,
+			pageOptions,
+			@get('gchartOptions')
+		)
+
+	data: -> new google.visualization.DataTable
+
+	chartClass: -> google.visualization[@visualization]
+
+	cutoff: ->
+	
+	cutoffValue: (v, min, max) ->
+		if v?
+			if min? && v < min
+				min
+			else if max? && v > max
+				max
+			else
+				v
+		else
+			0
+
+	draw: (min, max) ->
+		@cutoff(min, max)
+		@chart.draw(@data(), @mergedOptions())
+
+WidgetPresenter.create = (pageInfos, model, el) ->
+	type = model.get('type')
+	if type? && type.match(/^\w+$/)
+		presenterClass = eval("#{type.capitalize()}Presenter")
+		new presenterClass(pageInfos, model, el)
+	else
+		null

data/lib/pulse_meter/visualize/coffee/router.coffee

@@ -0,0 +1,21 @@
+AppRouter = Backbone.Router.extend {
+	initialize: (@pageInfos, @widgetList) ->
+	routes: {
+		'pages/:id': 'getPage'
+		'custom': 'custom'
+		'*actions': 'defaultRoute'
+	}
+	getPage: (ids) ->
+		id = parseInt(ids)
+		@pageInfos.selectPage(id)
+		@widgetList.fetch()
+	custom: ->
+		@pageInfos.selectNone()
+		dynamicWidget = new DynamicWidgetView {pageInfos: @pageInfos}
+		dynamicWidget.render($('#widgets'))
+	defaultRoute: (actions) ->
+		if @pageInfos.length > 0
+			@navigate('//pages/1')
+		else
+			@navigate('//custom')
+}

data/lib/pulse_meter/visualize/coffee/views/dynamic_chart.coffee

@@ -0,0 +1,91 @@
+DynamicChartView = Backbone.View.extend {
+	initialize: (options) ->
+		@pageInfos = options['pageInfos']
+		@sensors = []
+		@type = 'Area'
+		@widget = new DynamicWidget
+		
+		@widget.bind('destroy', @remove, this)
+		@widget.bind('redraw', @redrawChart, this)
+
+	tagName: 'div'
+
+	events: {
+		"click #refresh-chart": 'update'
+		"click #extend-timespan": 'extendTimespan'
+		"click #reset-timespan": 'resetTimespan'
+		"change #start-time input": 'maybeEnableStopTime'
+		"click #set-interval": 'setTimelineInterval'
+	}
+
+	template: -> _.template($("#dynamic-widget-plotarea").html())
+
+	render: ->
+		@$el.html(@template()())
+		@initDatePickers()
+
+	initDatePickers: ->
+		@$el.find(".datepicker").each (i) ->
+			$(this).datetimepicker
+				showOtherMonths: true
+				selectOtherMonths: true
+		@$el.find("#end-time input").prop("disabled", true)
+
+	setTimelineInterval: ->
+		start = @unixtimeFromDatepicker("#start-time input")
+		end = @unixtimeFromDatepicker("#end-time input")
+		@widget.setStartTime(start)
+		@widget.setEndTime(end)
+		@update()
+
+	dateFromDatepicker: (id) ->
+		@$el.find(id).datetimepicker("getDate")
+
+	unixtimeFromDatepicker: (id) ->
+		date = @dateFromDatepicker(id)
+		if date
+			date.getTime() / 1000
+		else
+			null
+
+	maybeEnableStopTime: ->
+		date = @dateFromDatepicker("#start-time input")
+		disabled = if date then false else true
+		@$el.find("#end-time input").prop("disabled", disabled)
+
+	extendTimespan: ->
+		select = @$el.find("#extend-timespan-val")
+		val = select.first().val()
+		@widget.increaseTimespan(parseInt(val))
+		@update()
+
+	resetTimespan: ->
+		@widget.resetTimespan()
+		@update()
+
+	sensorIds: -> _.map(@sensors, (s) -> s.id)
+
+	redrawChart: ->
+		if @presenter
+			@presenter.draw()
+		else
+			@presenter = WidgetPresenter.create(@pageInfos, @widget, @chartContainer())
+
+
+	chartContainer: ->
+		@$el.find('#chart')[0]
+
+	update: ->
+		@widget.forceUpdate() if @sensors.length > 0
+
+	draw: (sensors, type) ->
+		@sensors = sensors
+		@type = type
+
+		@widget.set('sensorIds', @sensorIds())
+		@widget.set('type', @type)
+		
+		@presenter = null
+		$(@chartContainer()).empty()
+		@widget.forceUpdate()
+}