pinkman 0.9.0

data/app/assets/javascripts/pinkman_base/mixins.coffee

@@ -0,0 +1,37 @@
+window.Pinkman.mixin = (name,mix) ->
+  if name? and typeof name == 'string' and mix? and typeof mix == 'object'
+    Pinkman.mixins = new Pinkman.collection unless Pinkman.mixins?
+    mixin = new Pinkman.object
+    mixin.set 'mix', mix
+    mixin.set 'name',name
+    Pinkman.mixins.push mixin
+
+window.Pinkman.mixit = (c,name) ->
+  mixin = Pinkman.mixins.getBy('name',name)
+  if mixin?
+    for n, method of mixin.mix
+      method['super'] = c.prototype[n]
+      c.prototype[n] = method
+    return(true)
+  else
+    false
+
+
+# --- Mixins - Usage --- #
+
+# Pinkman.mixin 'shitty',
+#   shit: (a) ->
+#     "#{a} is shit"
+
+
+# class window.Foo
+#   Pinkman.mixit this, 'shitty'
+
+# class window.Bar extends Pinkman.object
+#   @mixit 'shitty'
+
+# a = new Foo
+# a.shit(abc) -> 'abc is shit'
+
+# a = new Bar
+# a.shit(abc) -> 'abc is shit'

data/app/assets/javascripts/pinkman_base/object.js.coffee.erb

@@ -0,0 +1,195 @@
+class window.PinkmanObject extends window.PinkmanCommon
+
+  @pinkmanType: 'object'
+
+  constructor: (attributesObject) ->
+    
+    @isPink = true
+    @isObject = true
+    @pinkmanType = 'object'
+
+    @collections = new PinkmanCollection
+    @pinkey = Pinkman.all.length
+
+    Pinkman.objects.push(this)
+    Pinkman.all.push(this)
+    
+    @initialize(attributesObject)
+
+  initialize: (attributesObject) ->
+    if typeof attributesObject == 'object'
+      for key, value of attributesObject
+        @set(key,value) if PinkmanObject.privateAttributes.indexOf(key) is -1
+
+  # Desc: assign attributes from a pure javascript object
+  # Usage: a.assign( {attribute: value} )
+  assign: (obj) ->
+    if typeof obj == 'object'
+      for k,v of obj
+        if typeof v == 'object' and this[k]? and this[k].isPink? and not v.isPink
+          this[k].assign(v)
+        else
+          this.set(k,v) 
+      return true
+    else
+      return false
+
+  # Desc: returns a javascript object version of this
+  # Usage: a.attributes() #-> {key: value, key: value, ...}
+  attributes: () ->
+    a = new Object
+    for k,v of this
+      if PinkmanObject.privateAttributes.indexOf(k) == -1 and typeof v != 'function'
+        if v.isPink
+          a[k] = v.attributes()
+        else
+          a[k] = v
+    return a
+  
+  # Desc: returns a array of attributes keys
+  # Usage:
+  # a.set('a','b'); a.set('x',value)
+  # a.attributesKeys() #-> ['a','x']
+  attributesKeys: ->
+    Object.keys(@attributes())
+
+  # Desc: Alias for attributesKeys
+  keys: () ->
+    @attributesKeys()
+
+  toString: () ->
+    array = []
+    array.push("(#{@className()})")
+    for a in @attributesKeys()
+      array.push "#{a}: #{this[a]};"
+    array.join(" ")
+
+  # --- Collection related functions --- # 
+
+  # Desc: return the next obj (after this) in a collection
+  # Try to guess the collection if not provided
+  next: (collection='') ->
+    if collection.isPink and collection.pinkmanType == 'collection'
+      collection.next(this)
+    else if Pinkman.isNumber(collection)
+      c = @collections.get(collection)
+      c.next(this) if c?
+    else if not collection? or collection==''
+      @collections.first().next(this) if @collections.any()
+
+  # Desc: return the previous obj (before this) in a collection
+  # Try to guess the collection if not provided
+  prev: (collection='') ->
+    if collection.isPink and collection.pinkmanType == 'collection'
+      collection.prev(this)
+    else if Pinkman.isNumber(collection)
+      c = @collections.get(collection)
+      c.prev(this) if c?
+    else if not collection? or collection==''
+      @collections.first().prev(this) if @collections.any()
+
+  # Desc: remove this object from all collections
+  clearCollections: ->
+    c.remove(this) for c in @collections.collection
+
+  # alias for clearCollections
+  removeFromCollections: ->
+    @clearCollections()
+
+  # alias for clearCollections
+  removeFromAllCollections: ->
+    @clearCollections()
+
+  # alias for clearCollections
+  removeAllCollections: ->
+    @clearCollections()
+
+  # --- Error related --- #
+
+  # Desc: return first error message
+  firstError: ->
+    if @errors?
+      attr = Object.keys(@errors)[0]
+      "#{attr} #{@errors[attr][0]}"
+
+  # --- Ajax --- #
+
+  @find: (id, callback='') ->
+    obj = new this
+    Pinkman.ajax.get 
+      url: obj.api() + id,
+      complete: (response) ->
+        obj.assign(response)
+        if obj.error? or obj.errors? 
+          throw new Error(obj.firstError())
+          return false
+        else
+          callback(obj) if callback? and typeof callback == 'function'
+    return(obj)
+  
+  create: (callback='') ->
+    unless @id?
+      Pinkman.ajax.post
+        url: @api()
+        data: { pink_obj: @attributes() }
+        complete: (response) =>
+          @assign(response)
+          delete @errors unless response.errors?
+          callback(this) if callback? and typeof callback=='function'
+      return(this)
+
+  update: (callback='') ->
+    console.log this
+    if @id?
+      Pinkman.ajax.patch
+        url: @api() + @id
+        data: { pink_obj: @attributes() }
+        complete: (response) =>
+          @assign(response)
+          delete @errors unless response.errors?
+          callback(this) if callback? and typeof callback=='function'
+      return(this)
+
+  reload: (callback) ->
+    Pinkman.ajax.get 
+      url: @api() + @id,
+      complete: (response) =>
+        @assign(response)
+        if @error? or @errors? 
+          throw new Error(@firstError())
+          return false
+        else
+          callback(this) if callback? and typeof callback == 'function'
+    return(this)
+  
+  updateAttributes: (obj) ->
+    if this.assign(obj)
+      this.save (obj) ->
+        return(obj)
+    else
+      return false
+
+
+  save: (callback='') ->
+    if @id? and @id!='' then @update(callback) else @create(callback)
+        
+  
+  destroy: (callback='') ->
+    if @id?
+      Pinkman.ajax.delete
+        url: @api() + @id
+        complete: (response) =>
+          @assign(response)
+          delete @errors unless response.errors?
+          if @errors?
+            throw new Error(@firstError())
+            return(false)
+          else
+            @id = null
+            @removeFromAllCollections()
+            callback(this) if typeof callback=='function'
+      return(this)
+    else
+      return(false)
+
+window.Pinkman.object = window.PinkmanObject

data/app/assets/javascripts/pinkman_base/pinkman.coffee

@@ -0,0 +1,131 @@
+class window.Pinkman
+
+  # --- objects and collections manipulation
+
+  @collections = []
+  @objects = []
+  @all = []
+
+  @get: (pinkey) ->
+    this.all[pinkey]
+
+  @count: () ->
+    @all.length
+
+  # --- predicate
+
+  @isNumber: (n) ->
+    !isNaN(parseFloat(n)) && isFinite(n)
+
+  @isArray: (array) ->
+    array? and array.constructor is Array
+
+  @isString: (str) ->
+    str? and typeof str == 'string'
+
+  # --- tools and facilities
+
+  @doAfter: (ds, callback, timer = '_pinkman_doAfter') ->
+    window[timer] = window.setTimeout(callback, ds*100)
+
+  @clearTimeout: (timerName = '_pinkman_doAfter') ->
+    window.clearTimeout(window[timerName])
+
+  @defineGlobalVar: (variable,value) ->
+    window[variable] = value
+  
+  @onlyOnce: (f,args...) ->
+    if typeof f == 'function'
+      
+      func = new Object
+      func.f = f.toString()
+      func.args = args
+
+      if @calledFunctions.indexOf(func) == -1
+        @calledFunctions.push(func)
+        f(args...)
+
+  @calledFunctions = []
+
+  # --- Ajax
+
+  @ajax: 
+    
+    request: (options) ->
+      if options.url?
+        ajax = jQuery.ajax options.url,
+            beforeSend: (xhr) -> 
+              xhr.setRequestHeader('X-CSRF-Token', $('meta[name="csrf-token"]').attr('content'))
+            type: options.type
+            dataType: 'json'
+            data: options.data
+        ajax.done (response) =>
+          if response.errors?
+            options.error(this) if options.error? and typeof options.error == 'function'
+            return(false)
+          else
+            options.success(response) if options.success? and typeof options.success == 'function'
+            options.complete(response) if options.complete? and typeof options.complete == 'function'
+            return(true)
+      else
+        return false
+
+    get: (options) ->
+      options.type = 'GET'
+      @request(options)
+
+    post: (options) ->
+      options.type = 'POST'
+      @request(options)
+
+    put: (options) ->
+      options.type = 'PUT'
+      @request(options)
+
+    patch: (options) ->
+      options.type = 'PATCH'
+      @request(options)
+
+    delete: (options) ->
+      options.type = 'DELETE'
+      @request(options)
+
+    file: (options) ->
+      if options.url?
+        ajax = jQuery.ajax options.url,
+            beforeSend: (xhr) -> 
+              xhr.setRequestHeader('X-CSRF-Token', $('meta[name="csrf-token"]').attr('content'))
+            xhr: ->
+              myXhr = $.ajaxSettings.xhr()
+              myXhr.upload.addEventListener 'progress', (e) ->
+                  if e.lengthComputable
+                    options.progress e.loaded/e.total if options.progress?
+                , false
+              myXhr.addEventListener 'progress', (e) ->
+                  if e.lengthComputable
+                    options.progress e.loaded/e.total if options.progress?
+                , false
+              return myXhr
+            type: "POST"
+            dataType: 'json'
+            data: options.data
+            processData: false
+            contentType: false
+        ajax.done (response) =>
+          if response? and response.errors?
+            options.error(this) if options.error? and typeof options.error == 'function'
+            return false
+          else
+            options.success(response) if options.success? and typeof options.success == 'function'
+          options.complete(response) if options.complete? and typeof options.complete == 'function'
+        return this
+      else
+        return false
+
+    upload: (options...) ->
+      @file(options...)
+
+$(document).ready ->
+  unless Pinkman.pathname?
+    Pinkman.pathname = window.location.pathname
+    Pinkman.pathname = Pinkman.pathname + '/' if Pinkman.pathname.charAt([Pinkman.pathname.length] - 1) != "/"

data/app/assets/javascripts/pinkman_base/render.coffee.erb

@@ -0,0 +1,80 @@
+PinkmanCollection.prototype.renderQueue = new PinkmanCollection
+PinkmanObject.prototype.renderQueue = new PinkmanCollection
+
+Pinkman.templates = new Pinkman.collection
+
+Pinkman.template_engine = '<%= Pinkman.configuration.js_template_engine %>'
+
+Pinkman.template_engines =
+  handlebars: (options) ->
+    if options? and options.template? and $('#' + options.template).length
+      if Pinkman.templates.include(template: options.template, engine: Pinkman.template_engine)
+        template = Pinkman.templates.get(template: options.template, engine: Pinkman.template_engine)
+      else
+        template = new Pinkman.object(template: options.template, engine: Pinkman.template_engine)
+        template.handlebars = Handlebars.compile $('#' + options.template).html()
+        Pinkman.templates.push(template)
+
+      options.object = options.context if options.context?
+      content = template.handlebars(options.object)
+
+
+      if options.target?
+        $('#' + options.target).html(content)
+        $('#' + options.target).attr('data-pinkey',options.object.pinkey) if options.object? and typeof options.object == 'object' and options.object.isPink
+
+      options.callback(options.object,content) if options.callback? and typeof options.callback == 'function'
+      return(content)
+
+  hogan: (options) ->
+    if options? and options.template? and $('#' + options.template).length
+      if Pinkman.templates.include(template: options.template, engine: Pinkman.template_engine)
+        template = Pinkman.templates.get(template: options.template, engine: Pinkman.template_engine)
+      else
+        template = new Pinkman.object(template: options.template, engine: Pinkman.template_engine)
+        template.hogan = Hogan.compile $('#' + options.template).html()
+        Pinkman.templates.push(template)
+
+      options.object = options.context if options.context?
+      content = template.hogan.render(options.object)
+
+      if options.target?
+        $('#' + options.target).html(content)
+        $('#' + options.target).attr('data-pinkey',options.object.pinkey) if options.object? and typeof options.object == 'object' and options.object.isPink
+
+      options.callback(options.object,content) if options.callback? and typeof options.callback == 'function'
+      return(content)
+
+  markup: (options) ->
+    if options? and options.template? and $('#' + options.template).length
+      if Pinkman.templates.include(template: options.template, engine: Pinkman.template_engine)
+        template = Pinkman.templates.get(template: options.template, engine: Pinkman.template_engine)
+      else
+        template = new Pinkman.object(template: options.template, engine: Pinkman.template_engine)
+        template.markup = (args...) -> Mark.up(args...)
+        Pinkman.templates.push(template)
+
+      options.object = options.context if options.context?
+      content = template.markup($('#'+options.template).html(),options.object)
+
+      if options.target?
+        $('#' + options.target).html(content)
+        $('#' + options.target).attr('data-pinkey',options.object.pinkey) if options.object? and typeof options.object == 'object' and options.object.isPink
+
+      options.callback(options.object,content) if options.callback? and typeof options.callback == 'function'
+      return(content)
+
+Pinkman.render = (options) ->
+  options.reRender = true unless options.reRender? and options.reRender == false
+  options.collectionReRender = true unless options.collectionReRender? and options.collectionReRender == false
+
+  engine = Pinkman.template_engines[Pinkman.template_engine]
+  content = engine(options)
+  options.object.renderQueue.directPush(options) if options.reRender and options.object? and options.object.isPink
+
+Pinkman.reRender = (object) ->
+  engine = Pinkman.template_engines[Pinkman.template_engine]
+  engine(options) for options in object.renderQueue.collection
+  Pinkman.reRender(collection) for collection in object.collections.collection if object.collections? and options.collectionReRender
+  object.renderQueue.any()
+    

data/app/assets/javascripts/pinkman_base/tools.coffee

@@ -0,0 +1,4 @@
+window.sleep = (s,callback) -> 
+  ms = s*1000
+  window['_sleeping'] = setTimeout(callback,ms)
+